t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  12
  13 plan skip_all => <<'EOM' unless $dsn && $user;
  14 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  15 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  16 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  17 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  18 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  19 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  28   {
  29     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  30
  31     ok (!$s->storage->_dbh, 'definitely not connected');
  32
  33     # Check that datetime_parser returns correctly before we explicitly connect.
  34     SKIP: {
  35         skip (
  36           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  37           2
  38         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  39
  40         my $store = ref $s->storage;
  41         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  42
  43         my $parser = $s->storage->datetime_parser;
  44         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  45     }
  46
  47     ok (!$s->storage->_dbh, 'still not connected');
  48   }
  49
  50   {
  51     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  52     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  53     ok (!$s->storage->_dbh, 'definitely not connected');
  54     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  55     ok (!$s->storage->_dbh, 'still not connected');
  56   }
  57
  58 # test LIMIT support
  59 {
  60   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  61   drop_test_schema($schema);
  62   create_test_schema($schema);
  63   for (1..6) {
  64     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  65   }
  66   my $it = $schema->resultset('Artist')->search( {},
  67     { rows => 3,
  68       offset => 2,
  69       order_by => 'artistid' }
  70   );
  71   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  72   is( $it->next->name, "Artist 3", "iterator->next ok" );
  73   $it->next;
  74   $it->next;
  75   $it->next;
  76   is( $it->next, undef, "next past end of resultset ok" );
  77
  78   # Limit with select-lock
  79   lives_ok {
  80     $schema->txn_do (sub {
  81       isa_ok (
  82         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  83         'DBICTest::Schema::Artist',
  84       );
  85     });
  86   } 'Limited FOR UPDATE select works';
  87 }
  88
  89 # check if we indeed do support stuff
  90 my $test_server_supports_insert_returning = do {
  91   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  92                    ->storage
  93                     ->_get_dbh
  94                      ->get_info(18);
  95   $v =~ /^(\d+)\.(\d+)/
  96     or die "Unparseable Pg server version: $v\n";
  97
  98   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
  99 };
 100 is (
 101   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 102   $test_server_supports_insert_returning,
 103   'insert returning capability guessed correctly'
 104 );
 105
 106 my $schema;
 107 for my $use_insert_returning ($test_server_supports_insert_returning
 108   ? (0,1)
 109   : (0)
 110 ) {
 111
 112   no warnings qw/once/;
 113   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 114     my $s = shift->next::method (@_);
 115     $s->storage->_use_insert_returning ($use_insert_returning);
 116     $s;
 117   };
 118
 119 ### test capability override
 120   {
 121     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 122
 123     ok (!$s->storage->_dbh, 'definitely not connected');
 124
 125     ok (
 126       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 127       'insert returning capability set correctly',
 128     );
 129     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 130   }
 131
 132 ### connect, create postgres-specific test schema
 133
 134   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 135   $schema->storage->ensure_connected;
 136
 137   drop_test_schema($schema);
 138   create_test_schema($schema);
 139
 140 ### begin main tests
 141
 142 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 143 # discovery
 144   run_apk_tests($schema); #< older set of auto-pk tests
 145   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 146
 147 ### type_info tests
 148
 149   my $test_type_info = {
 150       'artistid' => {
 151           'data_type' => 'integer',
 152           'is_nullable' => 0,
 153           'size' => 4,
 154       },
 155       'name' => {
 156           'data_type' => 'character varying',
 157           'is_nullable' => 1,
 158           'size' => 100,
 159           'default_value' => undef,
 160       },
 161       'rank' => {
 162           'data_type' => 'integer',
 163           'is_nullable' => 0,
 164           'size' => 4,
 165           'default_value' => 13,
 166
 167       },
 168       'charfield' => {
 169           'data_type' => 'character',
 170           'is_nullable' => 1,
 171           'size' => 10,
 172           'default_value' => undef,
 173       },
 174       'arrayfield' => {
 175           'data_type' => 'integer[]',
 176           'is_nullable' => 1,
 177           'size' => undef,
 178           'default_value' => undef,
 179       },
 180   };
 181
 182   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 183   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 184   like($artistid_defval,
 185        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 186        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 187   is_deeply($type_info, $test_type_info,
 188             'columns_info_for - column data types');
 189
 190
 191
 192
 193 ####### Array tests
 194
 195   BEGIN {
 196     package DBICTest::Schema::ArrayTest;
 197     push @main::test_classes, __PACKAGE__;
 198
 199     use strict;
 200     use warnings;
 201     use base 'DBICTest::BaseResult';
 202
 203     __PACKAGE__->table('dbic_t_schema.array_test');
 204     __PACKAGE__->add_columns(qw/id arrayfield/);
 205     __PACKAGE__->column_info_from_storage(1);
 206     __PACKAGE__->set_primary_key('id');
 207
 208   }
 209   SKIP: {
 210     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 211
 212     my $arr_rs = $schema->resultset('ArrayTest');
 213
 214     lives_ok {
 215       $arr_rs->create({
 216         arrayfield => [1, 2],
 217       });
 218     } 'inserting arrayref as pg array data';
 219
 220     lives_ok {
 221       $arr_rs->update({
 222         arrayfield => [3, 4],
 223       });
 224     } 'updating arrayref as pg array data';
 225
 226     $arr_rs->create({
 227       arrayfield => [5, 6],
 228     });
 229
 230     # Search using arrays
 231     lives_ok {
 232       is_deeply (
 233         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 234         [3,4],
 235         'Array value matches'
 236       );
 237     } 'searching by arrayref';
 238
 239     lives_ok {
 240       is_deeply (
 241         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 242         [3,4],,
 243         'Array value matches explicit equal'
 244       );
 245     } 'searching by arrayref (explicit equal sign)';
 246
 247     lives_ok {
 248       is_deeply (
 249         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 250         [3,4],
 251         'Array value matches greater than'
 252       );
 253     } 'searching by arrayref (greater than)';
 254
 255     lives_ok {
 256       is (
 257         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 258         1,
 259         'Greater than search found [5,6]',
 260       );
 261     } 'searching by arrayref (greater than)';
 262
 263     # Find using arrays
 264     lives_ok {
 265       is_deeply (
 266         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 267         [3,4],
 268         'Array value matches implicit equal'
 269       );
 270     } 'find by arrayref';
 271
 272     lives_ok {
 273       is_deeply (
 274         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 275         [3,4],
 276         'Array value matches explicit equal'
 277       );
 278     } 'find by arrayref (equal)';
 279
 280     # test inferred condition for creation
 281     TODO: for my $cond (
 282       { -value => [3,4] },
 283       \[ '= ?' => [arrayfield => [3, 4]] ],
 284     ) {
 285       local $TODO = 'No introspection of complex conditions :(';
 286       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 287
 288       my $row = $arr_rs_cond->create({});
 289       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 290       $row->discard_changes;
 291       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 292     }
 293   }
 294
 295 ########## Case check
 296
 297   BEGIN {
 298     package DBICTest::Schema::Casecheck;
 299     push @main::test_classes, __PACKAGE__;
 300
 301     use strict;
 302     use warnings;
 303     use base 'DBIx::Class::Core';
 304
 305     __PACKAGE__->table('dbic_t_schema.casecheck');
 306     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 307     __PACKAGE__->column_info_from_storage(1);
 308     __PACKAGE__->set_primary_key('id');
 309   }
 310
 311   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 312   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 313
 314   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 315   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 316
 317   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 318   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 319
 320
 321 ## Test ResultSet->update
 322 my $artist = $schema->resultset('Artist')->first;
 323 my $cds = $artist->cds_unordered->search({
 324     year => { '!=' => 2010 }
 325 }, { prefetch => 'liner_notes' });
 326 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 327
 328 ## Test SELECT ... FOR UPDATE
 329
 330   SKIP: {
 331       if(eval { require Sys::SigAction }) {
 332           Sys::SigAction->import( 'set_sig_handler' );
 333       }
 334       else {
 335         skip "Sys::SigAction is not available", 6;
 336       }
 337
 338       my ($timed_out, $artist2);
 339
 340       for my $t (
 341         {
 342           # Make sure that an error was raised, and that the update failed
 343           update_lock => 1,
 344           test_sub => sub {
 345             ok($timed_out, "update from second schema times out");
 346             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 347           },
 348         },
 349         {
 350           # Make sure that an error was NOT raised, and that the update succeeded
 351           update_lock => 0,
 352           test_sub => sub {
 353             ok(! $timed_out, "update from second schema DOES NOT timeout");
 354             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 355           },
 356         },
 357       ) {
 358         # create a new schema
 359         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 360         $schema2->source("Artist")->name("dbic_t_schema.artist");
 361
 362         $schema->txn_do( sub {
 363           my $rs = $schema->resultset('Artist')->search(
 364               {
 365                   artistid => 1
 366               },
 367               $t->{update_lock} ? { for => 'update' } : {}
 368           );
 369           ok ($rs->count, 'Count works');
 370
 371           my $artist = $rs->next;
 372           is($artist->artistid, 1, "select returns artistid = 1");
 373
 374           $timed_out = 0;
 375           eval {
 376               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 377               alarm(2);
 378               $artist2 = $schema2->resultset('Artist')->find(1);
 379               $artist2->name('fooey');
 380               $artist2->update;
 381               alarm(0);
 382           };
 383           $timed_out = $@ =~ /DBICTestTimeout/;
 384         });
 385
 386         $t->{test_sub}->();
 387       }
 388   }
 389
 390
 391 ######## other older Auto-pk tests
 392
 393   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 394   for (1..5) {
 395       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 396       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 397       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 398       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 399   }
 400   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 401   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 402
 403
 404 ######## test non-serial auto-pk
 405
 406   if ($schema->storage->_use_insert_returning) {
 407     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 408     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 409     ok $row->id;
 410   }
 411
 412 ######## test with_deferred_fk_checks
 413
 414   $schema->source('CD')->name('dbic_t_schema.cd');
 415   $schema->source('Track')->name('dbic_t_schema.track');
 416   lives_ok {
 417     $schema->storage->with_deferred_fk_checks(sub {
 418       $schema->resultset('Track')->create({
 419         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 420       });
 421       $schema->resultset('CD')->create({
 422         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 423       });
 424     });
 425   } 'with_deferred_fk_checks code survived';
 426
 427   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 428      'code in with_deferred_fk_checks worked';
 429
 430   throws_ok {
 431     $schema->resultset('Track')->create({
 432       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 433     });
 434   } qr/constraint/i, 'with_deferred_fk_checks is off';
 435 }
 436
 437 done_testing;
 438
 439 END {
 440     return unless $schema;
 441     drop_test_schema($schema);
 442     eapk_drop_all( $schema)
 443 };
 444
 445
 446 ######### SUBROUTINES
 447
 448 sub create_test_schema {
 449     my $schema = shift;
 450     $schema->storage->dbh_do(sub {
 451       my (undef,$dbh) = @_;
 452
 453       local $dbh->{Warn} = 0;
 454
 455       my $std_artist_table = <<EOS;
 456 (
 457   artistid serial PRIMARY KEY
 458   , name VARCHAR(100)
 459   , rank INTEGER NOT NULL DEFAULT '13'
 460   , charfield CHAR(10)
 461   , arrayfield INTEGER[]
 462 )
 463 EOS
 464
 465       $dbh->do("CREATE SCHEMA dbic_t_schema");
 466       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 467
 468       $dbh->do(<<EOS);
 469 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 470   id timestamp default current_timestamp
 471 )
 472 EOS
 473       $dbh->do(<<EOS);
 474 CREATE TABLE dbic_t_schema.cd (
 475   cdid int PRIMARY KEY,
 476   artist int,
 477   title varchar(255),
 478   year varchar(4),
 479   genreid int,
 480   single_track int
 481 )
 482 EOS
 483       $dbh->do(<<EOS);
 484 CREATE TABLE dbic_t_schema.track (
 485   trackid int,
 486   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 487   position int,
 488   title varchar(255),
 489   last_updated_on date,
 490   last_updated_at date,
 491   small_dt date
 492 )
 493 EOS
 494
 495       $dbh->do(<<EOS);
 496 CREATE TABLE dbic_t_schema.sequence_test (
 497     pkid1 integer
 498     , pkid2 integer
 499     , nonpkid integer
 500     , name VARCHAR(100)
 501     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 502 )
 503 EOS
 504       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 505       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 506       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 507       $dbh->do(<<EOS);
 508 CREATE TABLE dbic_t_schema.casecheck (
 509     id serial PRIMARY KEY
 510     , "name" VARCHAR(1)
 511     , "NAME" VARCHAR(2)
 512     , "UC_NAME" VARCHAR(3)
 513 )
 514 EOS
 515       $dbh->do(<<EOS);
 516 CREATE TABLE dbic_t_schema.array_test (
 517     id serial PRIMARY KEY
 518     , arrayfield INTEGER[]
 519 )
 520 EOS
 521       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 522       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 523       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 524       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 525       $dbh->do('set search_path=dbic_t_schema,public');
 526       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 527       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 528       $dbh->do(<<EOS);
 529  CREATE TABLE dbic_t_schema_4.artist
 530  (
 531    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 532    , name VARCHAR(100)
 533    , rank INTEGER NOT NULL DEFAULT '13'
 534    , charfield CHAR(10)
 535    , arrayfield INTEGER[]
 536  );
 537 EOS
 538       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 539       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 540       $dbh->do(<<EOS);
 541  CREATE TABLE dbic_t_schema_5.artist
 542  (
 543    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 544    , name VARCHAR(100)
 545    , rank INTEGER NOT NULL DEFAULT '13'
 546    , charfield CHAR(10)
 547    , arrayfield INTEGER[]
 548  );
 549 EOS
 550       $dbh->do('set search_path=dbic_t_schema,public');
 551   });
 552 }
 553
 554
 555
 556 sub drop_test_schema {
 557     my ( $schema, $warn_exceptions ) = @_;
 558
 559     $schema->storage->dbh_do(sub {
 560         my (undef,$dbh) = @_;
 561
 562         local $dbh->{Warn} = 0;
 563
 564         for my $stat (
 565                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 566                       'DROP SEQUENCE public.artist_artistid_seq',
 567                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 568                       'DROP SCHEMA dbic_t_schema CASCADE',
 569                       'DROP SEQUENCE pkid1_seq',
 570                       'DROP SEQUENCE pkid2_seq',
 571                       'DROP SEQUENCE nonpkid_seq',
 572                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 573                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 574                      ) {
 575             eval { $dbh->do ($stat) };
 576             diag $@ if $@ && $warn_exceptions;
 577         }
 578     });
 579 }
 580
 581
 582 ###  auto-pk / last_insert_id / sequence discovery
 583 sub run_apk_tests {
 584     my $schema = shift;
 585
 586     # This is in Core now, but it's here just to test that it doesn't break
 587     $schema->class('Artist')->load_components('PK::Auto');
 588     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 589
 590     # test that auto-pk also works with the defined search path by
 591     # un-schema-qualifying the table name
 592     apk_t_set($schema,'artist');
 593
 594     my $unq_new;
 595     lives_ok {
 596         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 597     } 'insert into unqualified, shadowed table succeeds';
 598
 599     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 600
 601     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 602                          [qw| dbic_t_schema_3    1  |],
 603                          [qw| dbic_t_schema_4    2  |],
 604                          [qw| dbic_t_schema_5    1  |],
 605                        );
 606     foreach my $t ( @test_schemas ) {
 607         my ($sch_name, $start_num) = @$t;
 608         #test with dbic_t_schema_2
 609         apk_t_set($schema,"$sch_name.artist");
 610         my $another_new;
 611         lives_ok {
 612             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 613             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 614                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 615         } "$sch_name liid 1 did not die"
 616             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 617         lives_ok {
 618             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 619             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 620                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 621         } "$sch_name liid 2 did not die"
 622             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 623
 624     }
 625
 626     lives_ok {
 627         apk_t_set($schema,'dbic_t_schema.artist');
 628         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 629         is($new->artistid, 4, "Auto-PK worked");
 630         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 631         is($new->artistid, 5, "Auto-PK worked");
 632     } 'old auto-pk tests did not die either';
 633 }
 634
 635 # sets the artist table name and clears sequence name cache
 636 sub apk_t_set {
 637     my ( $s, $n ) = @_;
 638     $s->source("Artist")->name($n);
 639     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 640 }
 641
 642
 643 ######## EXTENDED AUTO-PK TESTS
 644
 645 my @eapk_id_columns;
 646 BEGIN {
 647   package DBICTest::Schema::ExtAPK;
 648   push @main::test_classes, __PACKAGE__;
 649
 650   use strict;
 651   use warnings;
 652   use base 'DBIx::Class::Core';
 653
 654   __PACKAGE__->table('apk');
 655
 656   @eapk_id_columns = qw( id1 id2 id3 id4 );
 657   __PACKAGE__->add_columns(
 658     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 659        @eapk_id_columns
 660   );
 661
 662   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 663                                        #the primary key
 664 }
 665
 666 my @eapk_schemas;
 667 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 668 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 669
 670 sub run_extended_apk_tests {
 671   my $schema = shift;
 672
 673   #save the search path and reset it at the end
 674   my $search_path_save = eapk_get_search_path($schema);
 675
 676   eapk_drop_all($schema);
 677   %seqs = ();
 678
 679   # make the test schemas and sequences
 680   $schema->storage->dbh_do(sub {
 681     my ( undef, $dbh ) = @_;
 682
 683     $dbh->do("CREATE SCHEMA $_")
 684         for @eapk_schemas;
 685
 686     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 687     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 688     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 689
 690     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 691     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 692     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 693
 694     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 695     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 696     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 697
 698     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 699   });
 700
 701   # clear our search_path cache
 702   $schema->storage->{_pg_search_path} = undef;
 703
 704   eapk_create( $schema,
 705                with_search_path => [0,1],
 706              );
 707   eapk_create( $schema,
 708                with_search_path => [1,0,'public'],
 709                nextval => "$eapk_schemas[5].fooseq",
 710              );
 711   eapk_create( $schema,
 712                with_search_path => ['public',0,1],
 713                qualify_table => 2,
 714              );
 715   eapk_create( $schema,
 716                with_search_path => [3,1,0,'public'],
 717                nextval => "$eapk_schemas[4].fooseq",
 718              );
 719   eapk_create( $schema,
 720                with_search_path => [3,1,0,'public'],
 721                nextval => "$eapk_schemas[3].fooseq",
 722                qualify_table => 4,
 723              );
 724
 725   eapk_poke( $schema );
 726   eapk_poke( $schema, 0 );
 727   eapk_poke( $schema, 2 );
 728   eapk_poke( $schema, 4 );
 729   eapk_poke( $schema, 1 );
 730   eapk_poke( $schema, 0 );
 731   eapk_poke( $schema, 1 );
 732   eapk_poke( $schema );
 733   eapk_poke( $schema, 4 );
 734   eapk_poke( $schema, 3 );
 735   eapk_poke( $schema, 1 );
 736   eapk_poke( $schema, 2 );
 737   eapk_poke( $schema, 0 );
 738
 739   # set our search path back
 740   eapk_set_search_path( $schema, @$search_path_save );
 741 }
 742
 743 # do a DBIC create on the apk table in the given schema number (which is an
 744 # index of @eapk_schemas)
 745
 746 sub eapk_poke {
 747   my ($s, $schema_num) = @_;
 748
 749   my $schema_name = defined $schema_num
 750       ? $eapk_schemas[$schema_num]
 751       : '';
 752
 753   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 754
 755   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 756   #< clear sequence name cache
 757   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 758       for @eapk_id_columns;
 759
 760   no warnings 'uninitialized';
 761   lives_ok {
 762     my $new;
 763     for my $inc (1,2,3) {
 764       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 765       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 766       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 767           or eapk_seq_diag($s,$schema_name);
 768       $new->discard_changes;
 769       is( $new->id1, 1 );
 770       for my $id ('id3','id4') {
 771         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 772         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 773             or eapk_seq_diag($s,$schema_name);
 774       }
 775     }
 776   } "create in schema '$schema_name' lives"
 777       or eapk_seq_diag($s,$schema_name);
 778 }
 779
 780 # print diagnostic info on which sequences were found in the ExtAPK
 781 # class
 782 sub eapk_seq_diag {
 783     my $s = shift;
 784     my $schema = shift || eapk_find_visible_schema($s);
 785
 786     diag "$schema.apk sequences: ",
 787         join(', ',
 788              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 789              @eapk_id_columns
 790             );
 791 }
 792
 793 # get the postgres search path as an arrayref
 794 sub eapk_get_search_path {
 795     my ( $s ) = @_;
 796     # cache the search path as ['schema','schema',...] in the storage
 797     # obj
 798
 799     return $s->storage->dbh_do(sub {
 800         my (undef, $dbh) = @_;
 801         my @search_path;
 802         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 803         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 804             unless( defined $1 and length $1 ) {
 805                 die "search path sanity check failed: '$1'";
 806             }
 807             push @search_path, $1;
 808         }
 809         \@search_path
 810     });
 811 }
 812 sub eapk_set_search_path {
 813     my ($s,@sp) = @_;
 814     my $sp = join ',',@sp;
 815     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 816 }
 817
 818 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 819 sub eapk_create {
 820     my ($schema, %a) = @_;
 821
 822     $schema->storage->dbh_do(sub {
 823         my (undef,$dbh) = @_;
 824
 825         my $searchpath_save;
 826         if ( $a{with_search_path} ) {
 827             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 828
 829             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 830
 831             $dbh->do("SET search_path = $search_path");
 832         }
 833
 834         my $table_name = $a{qualify_table}
 835             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 836             : 'apk';
 837         local $_[1]->{Warn} = 0;
 838
 839         my $id_def = $a{nextval}
 840             ? "integer not null default nextval('$a{nextval}'::regclass)"
 841             : 'serial';
 842         $dbh->do(<<EOS);
 843 CREATE TABLE $table_name (
 844   id1 serial
 845   , id2 $id_def
 846   , id3 serial primary key
 847   , id4 serial
 848 )
 849 EOS
 850
 851         if( $searchpath_save ) {
 852             $dbh->do("SET search_path = $searchpath_save");
 853         }
 854     });
 855 }
 856
 857 sub eapk_drop_all {
 858     my ( $schema, $warn_exceptions ) = @_;
 859
 860     $schema->storage->dbh_do(sub {
 861         my (undef,$dbh) = @_;
 862
 863         local $dbh->{Warn} = 0;
 864
 865         # drop the test schemas
 866         for (@eapk_schemas ) {
 867             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 868             diag $@ if $@ && $warn_exceptions;
 869         }
 870
 871
 872     });
 873 }
 874
 875 sub eapk_find_visible_schema {
 876     my ($s) = @_;
 877
 878     my ($schema) =
 879         $s->storage->dbh_do(sub {
 880             $_[1]->selectrow_array(<<EOS);
 881 SELECT n.nspname
 882 FROM pg_catalog.pg_namespace n
 883 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 884 WHERE c.relname = 'apk'
 885   AND pg_catalog.pg_table_is_visible(c.oid)
 886 EOS
 887         });
 888     return $schema;
 889 }