t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 eval { require DateTime::Format::SQLite };
  13 my $NO_DTFM = $@ ? 1 : 0;
  14
  15 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  16
  17 is(@art, 3, "Three artists returned");
  18
  19 my $art = $art[0];
  20
  21 is($art->name, 'We Are Goth', "Correct order too");
  22
  23 $art->name('We Are In Rehab');
  24
  25 is($art->name, 'We Are In Rehab', "Accessor update ok");
  26
  27 my %dirty = $art->get_dirty_columns();
  28 is(scalar(keys(%dirty)), 1, '1 dirty column');
  29 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  30
  31 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  32
  33 ok($art->update, 'Update run');
  34
  35 my %not_dirty = $art->get_dirty_columns();
  36 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  37
  38 eval {
  39   my $ret = $art->make_column_dirty('name2');
  40 };
  41 ok(defined($@), 'Failed to make non-existent column dirty');
  42 $art->make_column_dirty('name');
  43 my %fake_dirty = $art->get_dirty_columns();
  44 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  45 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  46
  47 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  48
  49 ok($record_jp, "prefetch on same rel okay");
  50
  51 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  52
  53 ok($record_fn, "funny join is okay");
  54
  55 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  56
  57 is(@art, 1, "Changed artist returned by search");
  58
  59 is($art[0]->artistid, 3,'Correct artist too');
  60
  61 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  62
  63 @art = $schema->resultset("Artist")->search({ });
  64
  65 is(@art, 2, 'And then there were two');
  66
  67 ok(!$art->in_storage, "It knows it's dead");
  68
  69 dies_ok ( sub { $art->delete }, "Can't delete twice");
  70
  71 is($art->name, 'We Are In Rehab', 'But the object is still live');
  72
  73 $art->insert;
  74
  75 ok($art->in_storage, "Re-created");
  76
  77 @art = $schema->resultset("Artist")->search({ });
  78
  79 is(@art, 3, 'And now there are three again');
  80
  81 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  82
  83 is($new->artistid, 4, 'Create produced record ok');
  84
  85 @art = $schema->resultset("Artist")->search({ });
  86
  87 is(@art, 4, "Oh my god! There's four of them!");
  88
  89 $new->set_column('name' => 'Man With A Fork');
  90
  91 is($new->name, 'Man With A Fork', 'set_column ok');
  92
  93 $new->discard_changes;
  94
  95 ok(!defined $new->name, 'Discard ok');
  96
  97 $new->name('Man With A Spoon');
  98
  99 $new->update;
 100
 101 my $new_again = $schema->resultset("Artist")->find(4);
 102
 103 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 104
 105 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 106
 107 # test that store_column is called once for create() for non sequence columns
 108 {
 109   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 110   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 111   $artist->delete;
 112 }
 113
 114 # Test backwards compatibility
 115 {
 116   my $warnings = '';
 117   local $SIG{__WARN__} = sub { $warnings .= $_[0] };
 118
 119   my $artist_by_hash = $schema->resultset('Artist')->find(artistid => 4);
 120   is($artist_by_hash->name, 'Man With A Spoon', 'Retrieved correctly');
 121   is($artist_by_hash->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 122   like($warnings, qr/deprecated/, 'warned about deprecated find usage');
 123 }
 124
 125 is($schema->resultset("Artist")->count, 4, 'count ok');
 126
 127 # test find_or_new
 128 {
 129   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 130     artistid => 4,
 131   });
 132
 133   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 134   ok($existing_obj->in_storage, 'existing artist is in storage');
 135
 136   my $new_obj = $schema->resultset('Artist')->find_or_new({
 137     artistid => 5,
 138     name     => 'find_or_new',
 139   });
 140
 141   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 142   ok(! $new_obj->in_storage, 'new artist is not in storage');
 143 }
 144
 145 my $cd = $schema->resultset("CD")->find(1);
 146 my %cols = $cd->get_columns;
 147
 148 is(keys %cols, 6, 'get_columns number of columns ok');
 149
 150 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 151
 152 %cols = ( title => 'Forkful of bees', year => 2005);
 153 $cd->set_columns(\%cols);
 154
 155 is($cd->title, 'Forkful of bees', 'set_columns ok');
 156
 157 is($cd->year, 2005, 'set_columns ok');
 158
 159 $cd->discard_changes;
 160
 161 # check whether ResultSource->columns returns columns in order originally supplied
 162 my @cd = $schema->source("CD")->columns;
 163
 164 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 165
 166 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 167 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 168
 169 $cd = $schema->resultset("CD")->search(undef, { include_columns => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 170
 171 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 172 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 173
 174 # check if new syntax +columns also works for this
 175 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 176
 177 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 178 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 179
 180 # check if new syntax for +columns select specifiers works for this
 181 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 182
 183 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 184 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 185
 186 # update_or_insert
 187 $new = $schema->resultset("Track")->new( {
 188   trackid => 100,
 189   cd => 1,
 190   title => 'Insert or Update',
 191   last_updated_on => '1973-07-19 12:01:02'
 192 } );
 193 $new->update_or_insert;
 194 ok($new->in_storage, 'update_or_insert insert ok');
 195
 196 # test in update mode
 197 $new->title('Insert or Update - updated');
 198 $new->update_or_insert;
 199 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 200
 201 # get_inflated_columns w/relation and accessor alias
 202 SKIP: {
 203     skip "This test requires DateTime::Format::SQLite", 8 if $NO_DTFM;
 204
 205     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 206     my %tdata = $new->get_inflated_columns;
 207     is($tdata{'trackid'}, 100, 'got id');
 208     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 209     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 210     is(
 211         $tdata{'position'},
 212         $schema->resultset ('Track')->search ({cd => 1})->count,
 213         'Ordered assigned proper position',
 214     );
 215     is($tdata{'title'}, 'Insert or Update - updated');
 216     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 217     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 218 }
 219
 220 eval { $schema->class("Track")->load_components('DoesNotExist'); };
 221
 222 ok $@, $@;
 223
 224 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 225
 226 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 227
 228 my( $or_rs ) = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 229                                                   order_by => 'cdid' });
 230 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 231 is($or_rs->count, 5, 'Search count with OR ok');
 232
 233 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 234 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 235 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 236
 237 {
 238   my $tcount = $schema->resultset('Track')->search(
 239     {},
 240     {
 241       select => [ qw/position title/ ],
 242       distinct => 1,
 243     }
 244   );
 245   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 246
 247   $tcount = $schema->resultset('Track')->search(
 248     {},
 249     {
 250       columns => [ qw/position title/ ],
 251       distinct => 1,
 252     }
 253   );
 254   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 255
 256   $tcount = $schema->resultset('Track')->search(
 257     {},
 258     {
 259        group_by => [ qw/position title/ ]
 260     }
 261   );
 262   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 263 }
 264
 265 my $tag_rs = $schema->resultset('Tag')->search(
 266                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 267
 268 my $rel_rs = $tag_rs->search_related('cd');
 269
 270 is($rel_rs->count, 5, 'Related search ok');
 271
 272 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 273 $or_rs->reset;
 274 $rel_rs->reset;
 275
 276 my $tag = $schema->resultset('Tag')->search(
 277                [ { 'me.tag' => 'Blue' } ], { cols=>[qw/tagid/] } )->next;
 278
 279 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 280 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 281
 282 ok($schema->storage(), 'Storage available');
 283
 284 {
 285   my $rs = $schema->resultset("Artist")->search({
 286     -and => [
 287       artistid => { '>=', 1 },
 288       artistid => { '<', 3 }
 289     ]
 290   });
 291
 292   $rs->update({ name => 'Test _cond_for_update_delete' });
 293
 294   my $art;
 295
 296   $art = $schema->resultset("Artist")->find(1);
 297   is($art->name, 'Test _cond_for_update_delete', 'updated first artist name');
 298
 299   $art = $schema->resultset("Artist")->find(2);
 300   is($art->name, 'Test _cond_for_update_delete', 'updated second artist name');
 301 }
 302
 303 # test source_name
 304 {
 305   # source_name should be set for normal modules
 306   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 307
 308   # test the result source that sets source_name explictly
 309   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 310
 311   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 312   is(@artsn, 4, "Four artists returned");
 313
 314   # make sure subclasses that don't set source_name are ok
 315   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 316 }
 317
 318 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 319
 320 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 321
 322 # test cascade_delete through many_to_many relations
 323 {
 324   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 325   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 326   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 327   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 328 }
 329
 330 # test column_info
 331 {
 332   $schema->source("Artist")->{_columns}{'artistid'} = {};
 333   $schema->source("Artist")->column_info_from_storage(1);
 334
 335   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 336   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 337   $schema->source("Artist")->column_info('artistid');
 338   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info flag set');
 339 }
 340
 341 # test source_info
 342 {
 343   my $expected = {
 344     "source_info_key_A" => "source_info_value_A",
 345     "source_info_key_B" => "source_info_value_B",
 346     "source_info_key_C" => "source_info_value_C",
 347   };
 348
 349   my $sinfo = $schema->source("Artist")->source_info;
 350
 351   is_deeply($sinfo, $expected, 'source_info data works');
 352 }
 353
 354 # test remove_columns
 355 {
 356   is_deeply(
 357     [$schema->source('CD')->columns],
 358     [qw/cdid artist title year genreid single_track/],
 359     'initial columns',
 360   );
 361
 362   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 363   is_deeply(
 364     [$schema->source('CD')->columns],
 365     [qw/cdid artist title year genreid single_track/],
 366     'nothing removed when removing a non-existent column',
 367   );
 368
 369   $schema->source('CD')->remove_columns('genreid', 'year');
 370   is_deeply(
 371     [$schema->source('CD')->columns],
 372     [qw/cdid artist title single_track/],
 373     'removed two columns',
 374   );
 375
 376   my $priv_columns = $schema->source('CD')->_columns;
 377   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 378   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 379 }
 380
 381 # test get_inflated_columns with objects
 382 SKIP: {
 383     skip "This test requires DateTime::Format::SQLite", 5 if $NO_DTFM;
 384     my $event = $schema->resultset('Event')->search->first;
 385     my %edata = $event->get_inflated_columns;
 386     is($edata{'id'}, $event->id, 'got id');
 387     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 388     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 389     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 390     is($edata{'created_on'}, $event->created_on, 'got created date');
 391 }
 392
 393 # test resultsource->table return value when setting
 394 {
 395     my $class = $schema->class('Event');
 396     my $table = $class->table($class->table);
 397     is($table, $class->table, '->table($table) returns $table');
 398 }
 399
 400 #make sure insert doesn't use set_column
 401 {
 402   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 403   is($en_row->encoded, 'amliw', 'new encodes');
 404   $en_row->insert;
 405   is($en_row->encoded, 'amliw', 'insert does not encode again');
 406 }
 407
 408 # make sure we got rid of the compat shims
 409 SKIP: {
 410     skip "Remove in 0.09", 5 if $DBIx::Class::VERSION < 0.09;
 411
 412     for (qw/compare_relationship_keys pk_depends_on resolve_condition resolve_join resolve_prefetch/) {
 413       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource");
 414     }
 415 }
 416
 417 #------------------------------
 418 # READ THIS BEFORE "FIXING"
 419 #------------------------------
 420 #
 421 # make sure we got rid of discard_changes mess - this is a mess and a source
 422 # of great confusion. Here I simply die if the methods are available, which
 423 # is wrong on its own (we *have* to provide some sort of back-compat, even
 424 # if with warnings). Here is how I envision things should actually be. Also
 425 # note that a lot of the deprecation can be started today (i.e. the switch
 426 # from get_from_storage to copy_from_storage). So:
 427 #
 428 # $row->discard_changes =>
 429 #   warning, and delegation to reload_from_storage
 430 #
 431 # $row->reload_from_storage =>
 432 #   does what discard changes did in 0.08 - issues a query to the db
 433 #   and repopulates all column slots, regardless of dirty states etc.
 434 #
 435 # $row->revert_changes =>
 436 #   does what discard_changes should have done initially (before it became
 437 #   a dual-purpose call). In order to make this work we will have to
 438 #   augment $row to carry its own initial-state, much like svn has a
 439 #   copy of the current checkout in contrast to cvs.
 440 #
 441 # my $db_row = $row->get_from_storage =>
 442 #   warns and delegates to an improved name copy_from_storage, with the
 443 #   same semantics
 444 #
 445 # my $db_row = $row->copy_from_storage =>
 446 #   a much better/descriptive name than get_from_storage
 447 #
 448 #------------------------------
 449 # READ THIS BEFORE "FIXING"
 450 #------------------------------
 451 #
 452 SKIP: {
 453     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 454
 455     my $row = $schema->resultset ('Artist')->next;
 456
 457     for (qw/discard_changes get_from_storage/) {
 458       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 459     }
 460 }
 461
 462 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 463
 464 done_testing;