t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9 my $schema = DBICTest->init_schema();
  10
  11 plan tests => 103;
  12
  13 eval { require DateTime::Format::MySQL };
  14 my $NO_DTFM = $@ ? 1 : 0;
  15
  16 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  17
  18 is(@art, 3, "Three artists returned");
  19
  20 my $art = $art[0];
  21
  22 is($art->name, 'We Are Goth', "Correct order too");
  23
  24 $art->name('We Are In Rehab');
  25
  26 is($art->name, 'We Are In Rehab', "Accessor update ok");
  27
  28 my %dirty = $art->get_dirty_columns();
  29 is(scalar(keys(%dirty)), 1, '1 dirty column');
  30 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  31
  32 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  33
  34 ok($art->update, 'Update run');
  35
  36 my %not_dirty = $art->get_dirty_columns();
  37 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  38
  39 eval {
  40   my $ret = $art->make_column_dirty('name2');
  41 };
  42 ok(defined($@), 'Failed to make non-existent column dirty');
  43 $art->make_column_dirty('name');
  44 my %fake_dirty = $art->get_dirty_columns();
  45 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  46 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  47
  48 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  49
  50 ok($record_jp, "prefetch on same rel okay");
  51
  52 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  53
  54 ok($record_fn, "funny join is okay");
  55
  56 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  57
  58 is(@art, 1, "Changed artist returned by search");
  59
  60 is($art[0]->artistid, 3,'Correct artist too');
  61
  62 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  63
  64 @art = $schema->resultset("Artist")->search({ });
  65
  66 is(@art, 2, 'And then there were two');
  67
  68 ok(!$art->in_storage, "It knows it's dead");
  69
  70 dies_ok ( sub { $art->delete }, "Can't delete twice");
  71
  72 is($art->name, 'We Are In Rehab', 'But the object is still live');
  73
  74 $art->insert;
  75
  76 ok($art->in_storage, "Re-created");
  77
  78 @art = $schema->resultset("Artist")->search({ });
  79
  80 is(@art, 3, 'And now there are three again');
  81
  82 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  83
  84 is($new->artistid, 4, 'Create produced record ok');
  85
  86 @art = $schema->resultset("Artist")->search({ });
  87
  88 is(@art, 4, "Oh my god! There's four of them!");
  89
  90 $new->set_column('name' => 'Man With A Fork');
  91
  92 is($new->name, 'Man With A Fork', 'set_column ok');
  93
  94 $new->discard_changes;
  95
  96 ok(!defined $new->name, 'Discard ok');
  97
  98 $new->name('Man With A Spoon');
  99
 100 $new->update;
 101
 102 my $new_again = $schema->resultset("Artist")->find(4);
 103
 104 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 105
 106 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 107
 108 # Test backwards compatibility
 109 {
 110   my $warnings = '';
 111   local $SIG{__WARN__} = sub { $warnings .= $_[0] };
 112
 113   my $artist_by_hash = $schema->resultset('Artist')->find(artistid => 4);
 114   is($artist_by_hash->name, 'Man With A Spoon', 'Retrieved correctly');
 115   is($artist_by_hash->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 116   like($warnings, qr/deprecated/, 'warned about deprecated find usage');
 117 }
 118
 119 is($schema->resultset("Artist")->count, 4, 'count ok');
 120
 121 # test find_or_new
 122 {
 123   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 124     artistid => 4,
 125   });
 126
 127   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 128   ok($existing_obj->in_storage, 'existing artist is in storage');
 129
 130   my $new_obj = $schema->resultset('Artist')->find_or_new({
 131     artistid => 5,
 132     name     => 'find_or_new',
 133   });
 134
 135   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 136   ok(! $new_obj->in_storage, 'new artist is not in storage');
 137 }
 138
 139 my $cd = $schema->resultset("CD")->find(1);
 140 my %cols = $cd->get_columns;
 141
 142 is(keys %cols, 6, 'get_columns number of columns ok');
 143
 144 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 145
 146 %cols = ( title => 'Forkful of bees', year => 2005);
 147 $cd->set_columns(\%cols);
 148
 149 is($cd->title, 'Forkful of bees', 'set_columns ok');
 150
 151 is($cd->year, 2005, 'set_columns ok');
 152
 153 $cd->discard_changes;
 154
 155 # check whether ResultSource->columns returns columns in order originally supplied
 156 my @cd = $schema->source("CD")->columns;
 157
 158 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 159
 160 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 161 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 162
 163 $cd = $schema->resultset("CD")->search(undef, { include_columns => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 164
 165 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 166 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 167
 168 # check if new syntax +columns also works for this
 169 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 170
 171 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 172 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 173
 174 # check if new syntax for +columns select specifiers works for this
 175 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 176
 177 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 178 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 179
 180 # update_or_insert
 181 $new = $schema->resultset("Track")->new( {
 182   trackid => 100,
 183   cd => 1,
 184   title => 'Insert or Update',
 185   last_updated_on => '1973-07-19 12:01:02'
 186 } );
 187 $new->update_or_insert;
 188 ok($new->in_storage, 'update_or_insert insert ok');
 189
 190 # test in update mode
 191 $new->title('Insert or Update - updated');
 192 $new->update_or_insert;
 193 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 194
 195 # get_inflated_columns w/relation and accessor alias
 196 SKIP: {
 197     skip "This test requires DateTime::Format::MySQL", 8 if $NO_DTFM;
 198
 199     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 200     my %tdata = $new->get_inflated_columns;
 201     is($tdata{'trackid'}, 100, 'got id');
 202     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 203     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 204     is(
 205         $tdata{'position'},
 206         $schema->resultset ('Track')->search ({cd => 1})->count,
 207         'Ordered assigned proper position',
 208     );
 209     is($tdata{'title'}, 'Insert or Update - updated');
 210     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 211     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 212 }
 213
 214 eval { $schema->class("Track")->load_components('DoesNotExist'); };
 215
 216 ok $@, $@;
 217
 218 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 219
 220 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 221
 222 my( $or_rs ) = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 223                                                   order_by => 'cdid' });
 224 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 225 is($or_rs->count, 5, 'Search count with OR ok');
 226
 227 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 228 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 229 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 230
 231 {
 232   my $tcount = $schema->resultset('Track')->search(
 233     {},
 234     {
 235       select => [ qw/position title/ ],
 236       distinct => 1,
 237     }
 238   );
 239   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 240
 241   $tcount = $schema->resultset('Track')->search(
 242     {},
 243     {
 244       columns => [ qw/position title/ ],
 245       distinct => 1,
 246     }
 247   );
 248   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 249
 250   $tcount = $schema->resultset('Track')->search(
 251     {},
 252     {
 253        group_by => [ qw/position title/ ]
 254     }
 255   );
 256   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 257 }
 258
 259 my $tag_rs = $schema->resultset('Tag')->search(
 260                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 261
 262 my $rel_rs = $tag_rs->search_related('cd');
 263
 264 is($rel_rs->count, 5, 'Related search ok');
 265
 266 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 267 $or_rs->reset;
 268 $rel_rs->reset;
 269
 270 my $tag = $schema->resultset('Tag')->search(
 271                [ { 'me.tag' => 'Blue' } ], { cols=>[qw/tagid/] } )->next;
 272
 273 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 274 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 275
 276 ok($schema->storage(), 'Storage available');
 277
 278 {
 279   my $rs = $schema->resultset("Artist")->search({
 280     -and => [
 281       artistid => { '>=', 1 },
 282       artistid => { '<', 3 }
 283     ]
 284   });
 285
 286   $rs->update({ name => 'Test _cond_for_update_delete' });
 287
 288   my $art;
 289
 290   $art = $schema->resultset("Artist")->find(1);
 291   is($art->name, 'Test _cond_for_update_delete', 'updated first artist name');
 292
 293   $art = $schema->resultset("Artist")->find(2);
 294   is($art->name, 'Test _cond_for_update_delete', 'updated second artist name');
 295 }
 296
 297 # test source_name
 298 {
 299   # source_name should be set for normal modules
 300   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 301
 302   # test the result source that sets source_name explictly
 303   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 304
 305   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 306   is(@artsn, 4, "Four artists returned");
 307
 308   # make sure subclasses that don't set source_name are ok
 309   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 310 }
 311
 312 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 313
 314 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 315
 316 # test cascade_delete through many_to_many relations
 317 {
 318   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 319   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 320   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 321   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 322 }
 323
 324 # test column_info
 325 {
 326   $schema->source("Artist")->{_columns}{'artistid'} = {};
 327   $schema->source("Artist")->column_info_from_storage(1);
 328
 329   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 330   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 331   $schema->source("Artist")->column_info('artistid');
 332   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info flag set');
 333 }
 334
 335 # test source_info
 336 {
 337   my $expected = {
 338     "source_info_key_A" => "source_info_value_A",
 339     "source_info_key_B" => "source_info_value_B",
 340     "source_info_key_C" => "source_info_value_C",
 341   };
 342
 343   my $sinfo = $schema->source("Artist")->source_info;
 344
 345   is_deeply($sinfo, $expected, 'source_info data works');
 346 }
 347
 348 # test remove_columns
 349 {
 350   is_deeply(
 351     [$schema->source('CD')->columns],
 352     [qw/cdid artist title year genreid single_track/],
 353     'initial columns',
 354   );
 355
 356   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 357   is_deeply(
 358     [$schema->source('CD')->columns],
 359     [qw/cdid artist title year genreid single_track/],
 360     'nothing removed when removing a non-existent column',
 361   );
 362
 363   $schema->source('CD')->remove_columns('genreid', 'year');
 364   is_deeply(
 365     [$schema->source('CD')->columns],
 366     [qw/cdid artist title single_track/],
 367     'removed two columns',
 368   );
 369
 370   my $priv_columns = $schema->source('CD')->_columns;
 371   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 372   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 373 }
 374
 375 # test get_inflated_columns with objects
 376 SKIP: {
 377     skip "This test requires DateTime::Format::MySQL", 5 if $NO_DTFM;
 378     my $event = $schema->resultset('Event')->search->first;
 379     my %edata = $event->get_inflated_columns;
 380     is($edata{'id'}, $event->id, 'got id');
 381     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 382     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 383     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 384     is($edata{'created_on'}, $event->created_on, 'got created date');
 385 }
 386
 387 # test resultsource->table return value when setting
 388 {
 389     my $class = $schema->class('Event');
 390     my $table = $class->table($class->table);
 391     is($table, $class->table, '->table($table) returns $table');
 392 }
 393
 394 #make sure insert doesn't use set_column
 395 {
 396   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 397   is($en_row->encoded, 'amliw', 'new encodes');
 398   $en_row->insert;
 399   is($en_row->encoded, 'amliw', 'insert does not encode again');
 400 }
 401
 402 # make sure we got rid of the compat shims
 403 SKIP: {
 404     skip "Remove in 0.09", 5 if $DBIx::Class::VERSION < 0.09;
 405
 406     for (qw/compare_relationship_keys pk_depends_on resolve_condition resolve_join resolve_prefetch/) {
 407       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource");
 408     }
 409 }