t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::SqlMakerTest;
  10
  11 my $schema = DBICTest->init_schema();
  12
  13 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  14
  15 is(@art, 3, "Three artists returned");
  16
  17 my $art = $art[0];
  18
  19 is($art->name, 'We Are Goth', "Correct order too");
  20
  21 $art->name('We Are In Rehab');
  22
  23 is($art->name, 'We Are In Rehab', "Accessor update ok");
  24
  25 my %dirty = $art->get_dirty_columns();
  26 is(scalar(keys(%dirty)), 1, '1 dirty column');
  27 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  28
  29 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  30
  31 ok($art->update, 'Update run');
  32
  33 my %not_dirty = $art->get_dirty_columns();
  34 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  35
  36 throws_ok ( sub {
  37   my $ret = $art->make_column_dirty('name2');
  38 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  39
  40 $art->make_column_dirty('name');
  41 my %fake_dirty = $art->get_dirty_columns();
  42 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  43 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  44
  45 ok($art->update, 'Update run');
  46
  47 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  48
  49 ok($record_jp, "prefetch on same rel okay");
  50
  51 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  52
  53 ok($record_fn, "funny join is okay");
  54
  55 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  56
  57 is(@art, 1, "Changed artist returned by search");
  58
  59 is($art[0]->artistid, 3,'Correct artist too');
  60
  61 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  62
  63 @art = $schema->resultset("Artist")->search({ });
  64
  65 is(@art, 2, 'And then there were two');
  66
  67 is($art->in_storage, 0, "It knows it's dead");
  68
  69 lives_ok { $art->update } 'No changes so update should be OK';
  70
  71 dies_ok ( sub { $art->delete }, "Can't delete twice");
  72
  73 is($art->name, 'We Are In Rehab', 'But the object is still live');
  74
  75 $art->insert;
  76
  77 ok($art->in_storage, "Re-created");
  78
  79 @art = $schema->resultset("Artist")->search({ });
  80
  81 is(@art, 3, 'And now there are three again');
  82
  83 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  84
  85 is($new->artistid, 4, 'Create produced record ok');
  86
  87 @art = $schema->resultset("Artist")->search({ });
  88
  89 is(@art, 4, "Oh my god! There's four of them!");
  90
  91 $new->set_column('name' => 'Man With A Fork');
  92
  93 is($new->name, 'Man With A Fork', 'set_column ok');
  94
  95 $new->discard_changes;
  96
  97 ok(!defined $new->name, 'Discard ok');
  98
  99 $new->name('Man With A Spoon');
 100
 101 $new->update;
 102
 103 my $new_again = $schema->resultset("Artist")->find(4);
 104
 105 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 106
 107 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 108
 109 # test that store_column is called once for create() for non sequence columns
 110 {
 111   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 112   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 113
 114   # call store_column even though the column doesn't seem to be dirty
 115   $artist->name($artist->name);
 116   is($artist->name, 'X X store_column test');
 117   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 118
 119   $artist->delete;
 120 }
 121
 122 # deprecation of rolled-out search
 123 warnings_exist {
 124   $schema->resultset('Artist')->search_rs(id => 4)
 125 } qr/\Qsearch( %condition ) is deprecated/, 'Deprecation warning on ->search( %condition )';
 126
 127 # this has been warning for 4 years, killing
 128 throws_ok {
 129   $schema->resultset('Artist')->find(artistid => 4);
 130 } qr|expects either a column/value hashref, or a list of values corresponding to the columns of the specified unique constraint|;
 131
 132 is($schema->resultset("Artist")->count, 4, 'count ok');
 133
 134 # test find_or_new
 135 {
 136   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 137     artistid => 4,
 138   });
 139
 140   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 141   ok($existing_obj->in_storage, 'existing artist is in storage');
 142
 143   my $new_obj = $schema->resultset('Artist')->find_or_new({
 144     artistid => 5,
 145     name     => 'find_or_new',
 146   });
 147
 148   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 149   is($new_obj->in_storage, 0, 'new artist is not in storage');
 150 }
 151
 152 my $cd = $schema->resultset("CD")->find(1);
 153 my %cols = $cd->get_columns;
 154
 155 is(keys %cols, 6, 'get_columns number of columns ok');
 156
 157 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 158
 159 %cols = ( title => 'Forkful of bees', year => 2005);
 160 $cd->set_columns(\%cols);
 161
 162 is($cd->title, 'Forkful of bees', 'set_columns ok');
 163
 164 is($cd->year, 2005, 'set_columns ok');
 165
 166 $cd->discard_changes;
 167
 168 # check whether ResultSource->columns returns columns in order originally supplied
 169 my @cd = $schema->source("CD")->columns;
 170
 171 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 172
 173 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 174 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 175
 176 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 177
 178 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 179 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 180
 181 # check if new syntax +columns also works for this
 182 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 183
 184 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 185 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 186
 187 # check if new syntax for +columns select specifiers works for this
 188 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 189
 190 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 191 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 192
 193 # update_or_insert
 194 $new = $schema->resultset("Track")->new( {
 195   trackid => 100,
 196   cd => 1,
 197   title => 'Insert or Update',
 198   last_updated_on => '1973-07-19 12:01:02'
 199 } );
 200 $new->update_or_insert;
 201 ok($new->in_storage, 'update_or_insert insert ok');
 202
 203 # test in update mode
 204 $new->title('Insert or Update - updated');
 205 $new->update_or_insert;
 206 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 207
 208 SKIP: {
 209     skip "Tests require " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_sqlite'), 13
 210       unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_sqlite');
 211
 212     # test get_inflated_columns with objects
 213     my $event = $schema->resultset('Event')->search->first;
 214     my %edata = $event->get_inflated_columns;
 215     is($edata{'id'}, $event->id, 'got id');
 216     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 217     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 218     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 219     is($edata{'created_on'}, $event->created_on, 'got created date');
 220
 221
 222     # get_inflated_columns w/relation and accessor alias
 223     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 224     my %tdata = $new->get_inflated_columns;
 225     is($tdata{'trackid'}, 100, 'got id');
 226     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 227     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 228     is(
 229         $tdata{'position'},
 230         $schema->resultset ('Track')->search ({cd => 1})->count,
 231         'Ordered assigned proper position',
 232     );
 233     is($tdata{'title'}, 'Insert or Update - updated');
 234     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 235     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 236 }
 237
 238 throws_ok (sub {
 239   $schema->class("Track")->load_components('DoesNotExist');
 240 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 241
 242 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 243
 244 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 245
 246 my $or_rs = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 247                                                   order_by => 'cdid' });
 248 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 249 is($or_rs->count, 5, 'Search count with OR ok');
 250
 251 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 252 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 253 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 254
 255 # make sure sure distinct on a grouped rs is warned about
 256 {
 257   my $cd_rs = $schema->resultset ('CD')
 258                 ->search ({}, { distinct => 1, group_by => 'title' });
 259   warnings_exist (sub {
 260     $cd_rs->next;
 261   }, qr/Useless use of distinct/, 'UUoD warning');
 262 }
 263
 264 {
 265   my $tcount = $schema->resultset('Track')->search(
 266     {},
 267     {
 268       select => [ qw/position title/ ],
 269       distinct => 1,
 270     }
 271   );
 272   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 273
 274   $tcount = $schema->resultset('Track')->search(
 275     {},
 276     {
 277       columns => [ qw/position title/ ],
 278       distinct => 1,
 279     }
 280   );
 281   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 282
 283   $tcount = $schema->resultset('Track')->search(
 284     {},
 285     {
 286        group_by => [ qw/position title/ ]
 287     }
 288   );
 289   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 290 }
 291
 292 my $tag_rs = $schema->resultset('Tag')->search(
 293                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 294
 295 my $rel_rs = $tag_rs->search_related('cd', {}, { order_by => 'cd.cdid'} );
 296
 297 is($rel_rs->count, 5, 'Related search ok');
 298
 299 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 300 $or_rs->reset;
 301 $rel_rs->reset;
 302
 303 # at this point there should be no active statements
 304 # (finish() was called everywhere, either explicitly via
 305 # reset() or on DESTROY)
 306 for (keys %{$schema->storage->dbh->{CachedKids}}) {
 307   fail("Unreachable cached statement still active: $_")
 308     if $schema->storage->dbh->{CachedKids}{$_}->FETCH('Active');
 309 }
 310
 311 my $tag = $schema->resultset('Tag')->search(
 312   [ { 'me.tag' => 'Blue' } ],
 313   { columns => 'tagid' }
 314 )->next;
 315
 316 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 317 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 318
 319 ok($schema->storage(), 'Storage available');
 320
 321 {
 322   my $rs = $schema->resultset("Artist")->search({
 323     -and => [
 324       artistid => { '>=', 1 },
 325       artistid => { '<', 3 }
 326     ]
 327   });
 328
 329   $rs->update({ rank => 6134 });
 330
 331   my $art;
 332
 333   $art = $schema->resultset("Artist")->find(1);
 334   is($art->rank, 6134, 'updated first artist rank');
 335
 336   $art = $schema->resultset("Artist")->find(2);
 337   is($art->rank, 6134, 'updated second artist rank');
 338 }
 339
 340 # test source_name
 341 {
 342   # source_name should be set for normal modules
 343   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 344
 345   # test the result source that sets source_name explictly
 346   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 347
 348   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 349   is(@artsn, 4, "Four artists returned");
 350
 351   # make sure subclasses that don't set source_name are ok
 352   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 353 }
 354
 355 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 356
 357 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 358
 359 # test cascade_delete through many_to_many relations
 360 {
 361   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 362   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 363   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 364   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 365 }
 366
 367 # test column_info
 368 {
 369   $schema->source("Artist")->{_columns}{'artistid'} = {};
 370   $schema->source("Artist")->column_info_from_storage(1);
 371
 372   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 373   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 374   $schema->source("Artist")->column_info('artistid');
 375   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 376 }
 377
 378 # test columns_info
 379 {
 380   $schema->source("Artist")->{_columns}{'artistid'} = {};
 381   $schema->source("Artist")->column_info_from_storage(1);
 382   $schema->source("Artist")->{_columns_info_loaded} = 0;
 383
 384   is_deeply (
 385     $schema->source('Artist')->columns_info,
 386     {
 387       artistid => {
 388         data_type => "INTEGER",
 389         default_value => undef,
 390         is_nullable => 0,
 391         size => undef
 392       },
 393       charfield => {
 394         data_type => "char",
 395         default_value => undef,
 396         is_nullable => 1,
 397         size => 10
 398       },
 399       name => {
 400         data_type => "varchar",
 401         default_value => undef,
 402         is_nullable => 1,
 403         is_numeric => 0,
 404         size => 100
 405       },
 406       rank => {
 407         data_type => "integer",
 408         default_value => 13,
 409         is_nullable => 0,
 410         size => undef
 411       },
 412     },
 413     'columns_info works',
 414   );
 415
 416   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 417
 418   is_deeply (
 419     $schema->source('Artist')->columns_info([qw/artistid rank/]),
 420     {
 421       artistid => {
 422         data_type => "INTEGER",
 423         default_value => undef,
 424         is_nullable => 0,
 425         size => undef
 426       },
 427       rank => {
 428         data_type => "integer",
 429         default_value => 13,
 430         is_nullable => 0,
 431         size => undef
 432       },
 433     },
 434     'limited columns_info works',
 435   );
 436 }
 437
 438 # test source_info
 439 {
 440   my $expected = {
 441     "source_info_key_A" => "source_info_value_A",
 442     "source_info_key_B" => "source_info_value_B",
 443     "source_info_key_C" => "source_info_value_C",
 444   };
 445
 446   my $sinfo = $schema->source("Artist")->source_info;
 447
 448   is_deeply($sinfo, $expected, 'source_info data works');
 449 }
 450
 451 # test remove_columns
 452 {
 453   is_deeply(
 454     [$schema->source('CD')->columns],
 455     [qw/cdid artist title year genreid single_track/],
 456     'initial columns',
 457   );
 458
 459   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 460   is_deeply(
 461     [$schema->source('CD')->columns],
 462     [qw/cdid artist title year genreid single_track/],
 463     'nothing removed when removing a non-existent column',
 464   );
 465
 466   $schema->source('CD')->remove_columns('genreid', 'year');
 467   is_deeply(
 468     [$schema->source('CD')->columns],
 469     [qw/cdid artist title single_track/],
 470     'removed two columns',
 471   );
 472
 473   my $priv_columns = $schema->source('CD')->_columns;
 474   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 475   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 476 }
 477
 478 # test resultsource->table return value when setting
 479 {
 480     my $class = $schema->class('Event');
 481     my $table = $class->table($class->table);
 482     is($table, $class->table, '->table($table) returns $table');
 483 }
 484
 485 #make sure insert doesn't use set_column
 486 {
 487   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 488   is($en_row->encoded, 'amliw', 'new encodes');
 489   $en_row->insert;
 490   is($en_row->encoded, 'amliw', 'insert does not encode again');
 491 }
 492
 493 #make sure multicreate encoding still works
 494 {
 495   my $empl_rs = $schema->resultset('Employee');
 496
 497   my $empl = $empl_rs->create ({
 498     name => 'Secret holder',
 499     secretkey => {
 500       encoded => 'CAN HAZ',
 501     },
 502   });
 503   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 504
 505   my $empl2 = $empl_rs->create ({
 506     name => 'Same secret holder',
 507     secretkey => {
 508       encoded => 'CAN HAZ',
 509     },
 510   });
 511   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 512
 513   $empl_rs->create ({
 514     name => 'cat1',
 515     secretkey => {
 516       encoded => 'CHEEZBURGER',
 517       keyholders => [
 518         {
 519           name => 'cat2',
 520         },
 521         {
 522           name => 'cat3',
 523         },
 524       ],
 525     },
 526   });
 527
 528   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 529   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 530   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 531
 532 }
 533
 534 # make sure that obsolete handle-based source tracking continues to work for the time being
 535 {
 536   my $handle = $schema->source('Artist')->handle;
 537
 538   my $rowdata = { $schema->resultset('Artist')->next->get_columns };
 539
 540   my $rs = DBIx::Class::ResultSet->new($handle);
 541   my $rs_result = $rs->next;
 542   isa_ok( $rs_result, 'DBICTest::Artist' );
 543   is_deeply (
 544     { $rs_result->get_columns },
 545     $rowdata,
 546     'Correct columns retrieved (rset/source link healthy)'
 547   );
 548
 549   my $row = DBICTest::Artist->new({ -source_handle => $handle });
 550   is_deeply(
 551     { $row->get_columns },
 552     {},
 553     'No columns yet'
 554   );
 555
 556   # store_column to fool the _orig_ident tracker
 557   $row->store_column('artistid', $rowdata->{artistid});
 558   $row->in_storage(1);
 559
 560   $row->discard_changes;
 561   is_deeply(
 562     { $row->get_columns },
 563     $rowdata,
 564     'Storage refetch successful'
 565   );
 566 }
 567
 568 # test to make sure that calling ->new() on a resultset object gives
 569 # us a row object
 570 {
 571     my $new_artist = $schema->resultset('Artist')->new({});
 572     isa_ok( $new_artist, 'DBIx::Class::Row', '$rs->new gives a row object' );
 573 }
 574
 575
 576 # make sure we got rid of the compat shims
 577 SKIP: {
 578     my $remove_version = 0.083;
 579     skip "Remove in $remove_version", 3 if $DBIx::Class::VERSION < $remove_version;
 580
 581     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 582       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource, removed before $remove_version");
 583     }
 584 }
 585
 586 #------------------------------
 587 # READ THIS BEFORE "FIXING"
 588 #------------------------------
 589 #
 590 # make sure we got rid of discard_changes mess - this is a mess and a source
 591 # of great confusion. Here I simply die if the methods are available, which
 592 # is wrong on its own (we *have* to provide some sort of back-compat, even
 593 # if with warnings). Here is how I envision things should actually be. Also
 594 # note that a lot of the deprecation can be started today (i.e. the switch
 595 # from get_from_storage to copy_from_storage). So:
 596 #
 597 # $row->discard_changes =>
 598 #   warning, and delegation to reload_from_storage
 599 #
 600 # $row->reload_from_storage =>
 601 #   does what discard changes did in 0.08 - issues a query to the db
 602 #   and repopulates all column slots, regardless of dirty states etc.
 603 #
 604 # $row->revert_changes =>
 605 #   does what discard_changes should have done initially (before it became
 606 #   a dual-purpose call). In order to make this work we will have to
 607 #   augment $row to carry its own initial-state, much like svn has a
 608 #   copy of the current checkout in contrast to cvs.
 609 #
 610 # my $db_row = $row->get_from_storage =>
 611 #   warns and delegates to an improved name copy_from_storage, with the
 612 #   same semantics
 613 #
 614 # my $db_row = $row->copy_from_storage =>
 615 #   a much better/descriptive name than get_from_storage
 616 #
 617 #------------------------------
 618 # READ THIS BEFORE "FIXING"
 619 #------------------------------
 620 #
 621 SKIP: {
 622     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 623
 624     my $row = $schema->resultset ('Artist')->next;
 625
 626     for (qw/discard_changes get_from_storage/) {
 627       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 628     }
 629 }
 630
 631 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 632
 633 done_testing;