t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::SqlMakerTest;
  10
  11 my $schema = DBICTest->init_schema();
  12
  13 eval { require DateTime::Format::SQLite };
  14 my $NO_DTFM = $@ ? 1 : 0;
  15
  16 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  17
  18 is(@art, 3, "Three artists returned");
  19
  20 my $art = $art[0];
  21
  22 is($art->name, 'We Are Goth', "Correct order too");
  23
  24 $art->name('We Are In Rehab');
  25
  26 is($art->name, 'We Are In Rehab', "Accessor update ok");
  27
  28 my %dirty = $art->get_dirty_columns();
  29 is(scalar(keys(%dirty)), 1, '1 dirty column');
  30 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  31
  32 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  33
  34 ok($art->update, 'Update run');
  35
  36 my %not_dirty = $art->get_dirty_columns();
  37 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  38
  39 throws_ok ( sub {
  40   my $ret = $art->make_column_dirty('name2');
  41 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  42
  43 $art->make_column_dirty('name');
  44 my %fake_dirty = $art->get_dirty_columns();
  45 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  46 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  47
  48 ok($art->update, 'Update run');
  49
  50 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  51
  52 ok($record_jp, "prefetch on same rel okay");
  53
  54 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  55
  56 ok($record_fn, "funny join is okay");
  57
  58 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  59
  60 is(@art, 1, "Changed artist returned by search");
  61
  62 is($art[0]->artistid, 3,'Correct artist too');
  63
  64 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  65
  66 @art = $schema->resultset("Artist")->search({ });
  67
  68 is(@art, 2, 'And then there were two');
  69
  70 is($art->in_storage, 0, "It knows it's dead");
  71
  72 lives_ok { $art->update } 'No changes so update should be OK';
  73
  74 dies_ok ( sub { $art->delete }, "Can't delete twice");
  75
  76 is($art->name, 'We Are In Rehab', 'But the object is still live');
  77
  78 $art->insert;
  79
  80 ok($art->in_storage, "Re-created");
  81
  82 @art = $schema->resultset("Artist")->search({ });
  83
  84 is(@art, 3, 'And now there are three again');
  85
  86 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  87
  88 is($new->artistid, 4, 'Create produced record ok');
  89
  90 @art = $schema->resultset("Artist")->search({ });
  91
  92 is(@art, 4, "Oh my god! There's four of them!");
  93
  94 $new->set_column('name' => 'Man With A Fork');
  95
  96 is($new->name, 'Man With A Fork', 'set_column ok');
  97
  98 $new->discard_changes;
  99
 100 ok(!defined $new->name, 'Discard ok');
 101
 102 $new->name('Man With A Spoon');
 103
 104 $new->update;
 105
 106 my $new_again = $schema->resultset("Artist")->find(4);
 107
 108 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 109
 110 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 111
 112 # test that store_column is called once for create() for non sequence columns
 113 {
 114   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 115   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 116
 117   # call store_column even though the column doesn't seem to be dirty
 118   $artist->name($artist->name);
 119   is($artist->name, 'X X store_column test');
 120   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 121
 122   $artist->delete;
 123 }
 124
 125 # this has been warning for 4 years, killing
 126 throws_ok {
 127   $schema->resultset('Artist')->find(artistid => 4);
 128 } qr|expects either a column/value hashref, or a list of values corresponding to the columns of the specified unique constraint|;
 129
 130 is($schema->resultset("Artist")->count, 4, 'count ok');
 131
 132 # test find_or_new
 133 {
 134   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 135     artistid => 4,
 136   });
 137
 138   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 139   ok($existing_obj->in_storage, 'existing artist is in storage');
 140
 141   my $new_obj = $schema->resultset('Artist')->find_or_new({
 142     artistid => 5,
 143     name     => 'find_or_new',
 144   });
 145
 146   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 147   is($new_obj->in_storage, 0, 'new artist is not in storage');
 148 }
 149
 150 my $cd = $schema->resultset("CD")->find(1);
 151 my %cols = $cd->get_columns;
 152
 153 is(keys %cols, 6, 'get_columns number of columns ok');
 154
 155 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 156
 157 %cols = ( title => 'Forkful of bees', year => 2005);
 158 $cd->set_columns(\%cols);
 159
 160 is($cd->title, 'Forkful of bees', 'set_columns ok');
 161
 162 is($cd->year, 2005, 'set_columns ok');
 163
 164 $cd->discard_changes;
 165
 166 # check whether ResultSource->columns returns columns in order originally supplied
 167 my @cd = $schema->source("CD")->columns;
 168
 169 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 170
 171 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 172 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 173
 174 $cd = $schema->resultset("CD")->search(undef, { include_columns => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 175
 176 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 177 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 178
 179 # check if new syntax +columns also works for this
 180 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 181
 182 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 183 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 184
 185 # check if new syntax for +columns select specifiers works for this
 186 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 187
 188 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 189 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 190
 191 # update_or_insert
 192 $new = $schema->resultset("Track")->new( {
 193   trackid => 100,
 194   cd => 1,
 195   title => 'Insert or Update',
 196   last_updated_on => '1973-07-19 12:01:02'
 197 } );
 198 $new->update_or_insert;
 199 ok($new->in_storage, 'update_or_insert insert ok');
 200
 201 # test in update mode
 202 $new->title('Insert or Update - updated');
 203 $new->update_or_insert;
 204 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 205
 206 # get_inflated_columns w/relation and accessor alias
 207 SKIP: {
 208     skip "This test requires DateTime::Format::SQLite", 8 if $NO_DTFM;
 209
 210     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 211     my %tdata = $new->get_inflated_columns;
 212     is($tdata{'trackid'}, 100, 'got id');
 213     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 214     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 215     is(
 216         $tdata{'position'},
 217         $schema->resultset ('Track')->search ({cd => 1})->count,
 218         'Ordered assigned proper position',
 219     );
 220     is($tdata{'title'}, 'Insert or Update - updated');
 221     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 222     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 223 }
 224
 225 throws_ok (sub {
 226   $schema->class("Track")->load_components('DoesNotExist');
 227 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 228
 229 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 230
 231 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 232
 233 my( $or_rs ) = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 234                                                   order_by => 'cdid' });
 235 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 236 is($or_rs->count, 5, 'Search count with OR ok');
 237
 238 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 239 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 240 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 241
 242 # make sure sure distinct on a grouped rs is warned about
 243 my $cd_rs = $schema->resultset ('CD')
 244               ->search ({}, { distinct => 1, group_by => 'title' });
 245 warnings_exist (sub {
 246   $cd_rs->next;
 247 }, qr/Useless use of distinct/, 'UUoD warning');
 248
 249 {
 250   my $tcount = $schema->resultset('Track')->search(
 251     {},
 252     {
 253       select => [ qw/position title/ ],
 254       distinct => 1,
 255     }
 256   );
 257   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 258
 259   $tcount = $schema->resultset('Track')->search(
 260     {},
 261     {
 262       columns => [ qw/position title/ ],
 263       distinct => 1,
 264     }
 265   );
 266   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 267
 268   $tcount = $schema->resultset('Track')->search(
 269     {},
 270     {
 271        group_by => [ qw/position title/ ]
 272     }
 273   );
 274   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 275 }
 276
 277 my $tag_rs = $schema->resultset('Tag')->search(
 278                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 279
 280 my $rel_rs = $tag_rs->search_related('cd');
 281
 282 is($rel_rs->count, 5, 'Related search ok');
 283
 284 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 285 $or_rs->reset;
 286 $rel_rs->reset;
 287
 288 my $tag = $schema->resultset('Tag')->search(
 289                [ { 'me.tag' => 'Blue' } ], { cols=>[qw/tagid/] } )->next;
 290
 291 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 292 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 293
 294 ok($schema->storage(), 'Storage available');
 295
 296 {
 297   my $rs = $schema->resultset("Artist")->search({
 298     -and => [
 299       artistid => { '>=', 1 },
 300       artistid => { '<', 3 }
 301     ]
 302   });
 303
 304   $rs->update({ rank => 6134 });
 305
 306   my $art;
 307
 308   $art = $schema->resultset("Artist")->find(1);
 309   is($art->rank, 6134, 'updated first artist rank');
 310
 311   $art = $schema->resultset("Artist")->find(2);
 312   is($art->rank, 6134, 'updated second artist rank');
 313 }
 314
 315 # test source_name
 316 {
 317   # source_name should be set for normal modules
 318   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 319
 320   # test the result source that sets source_name explictly
 321   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 322
 323   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 324   is(@artsn, 4, "Four artists returned");
 325
 326   # make sure subclasses that don't set source_name are ok
 327   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 328 }
 329
 330 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 331
 332 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 333
 334 # test cascade_delete through many_to_many relations
 335 {
 336   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 337   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 338   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 339   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 340 }
 341
 342 # test column_info
 343 {
 344   $schema->source("Artist")->{_columns}{'artistid'} = {};
 345   $schema->source("Artist")->column_info_from_storage(1);
 346
 347   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 348   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 349   $schema->source("Artist")->column_info('artistid');
 350   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info flag set');
 351 }
 352
 353 # test source_info
 354 {
 355   my $expected = {
 356     "source_info_key_A" => "source_info_value_A",
 357     "source_info_key_B" => "source_info_value_B",
 358     "source_info_key_C" => "source_info_value_C",
 359   };
 360
 361   my $sinfo = $schema->source("Artist")->source_info;
 362
 363   is_deeply($sinfo, $expected, 'source_info data works');
 364 }
 365
 366 # test remove_columns
 367 {
 368   is_deeply(
 369     [$schema->source('CD')->columns],
 370     [qw/cdid artist title year genreid single_track/],
 371     'initial columns',
 372   );
 373
 374   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 375   is_deeply(
 376     [$schema->source('CD')->columns],
 377     [qw/cdid artist title year genreid single_track/],
 378     'nothing removed when removing a non-existent column',
 379   );
 380
 381   $schema->source('CD')->remove_columns('genreid', 'year');
 382   is_deeply(
 383     [$schema->source('CD')->columns],
 384     [qw/cdid artist title single_track/],
 385     'removed two columns',
 386   );
 387
 388   my $priv_columns = $schema->source('CD')->_columns;
 389   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 390   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 391 }
 392
 393 # test get_inflated_columns with objects
 394 SKIP: {
 395     skip "This test requires DateTime::Format::SQLite", 5 if $NO_DTFM;
 396     my $event = $schema->resultset('Event')->search->first;
 397     my %edata = $event->get_inflated_columns;
 398     is($edata{'id'}, $event->id, 'got id');
 399     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 400     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 401     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 402     is($edata{'created_on'}, $event->created_on, 'got created date');
 403 }
 404
 405 # test resultsource->table return value when setting
 406 {
 407     my $class = $schema->class('Event');
 408     my $table = $class->table($class->table);
 409     is($table, $class->table, '->table($table) returns $table');
 410 }
 411
 412 #make sure insert doesn't use set_column
 413 {
 414   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 415   is($en_row->encoded, 'amliw', 'new encodes');
 416   $en_row->insert;
 417   is($en_row->encoded, 'amliw', 'insert does not encode again');
 418 }
 419
 420 #make sure multicreate encoding still works
 421 {
 422   my $empl_rs = $schema->resultset('Employee');
 423
 424   my $empl = $empl_rs->create ({
 425     name => 'Secret holder',
 426     secretkey => {
 427       encoded => 'CAN HAZ',
 428     },
 429   });
 430   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 431
 432   my $empl2 = $empl_rs->create ({
 433     name => 'Same secret holder',
 434     secretkey => {
 435       encoded => 'CAN HAZ',
 436     },
 437   });
 438   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 439
 440   $empl_rs->create ({
 441     name => 'cat1',
 442     secretkey => {
 443       encoded => 'CHEEZBURGER',
 444       keyholders => [
 445         {
 446           name => 'cat2',
 447         },
 448         {
 449           name => 'cat3',
 450         },
 451       ],
 452     },
 453   });
 454
 455   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 456   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 457   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 458
 459 }
 460
 461 # make sure we got rid of the compat shims
 462 SKIP: {
 463     skip "Remove in 0.082", 3 if $DBIx::Class::VERSION < 0.082;
 464
 465     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 466       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource");
 467     }
 468 }
 469
 470 #------------------------------
 471 # READ THIS BEFORE "FIXING"
 472 #------------------------------
 473 #
 474 # make sure we got rid of discard_changes mess - this is a mess and a source
 475 # of great confusion. Here I simply die if the methods are available, which
 476 # is wrong on its own (we *have* to provide some sort of back-compat, even
 477 # if with warnings). Here is how I envision things should actually be. Also
 478 # note that a lot of the deprecation can be started today (i.e. the switch
 479 # from get_from_storage to copy_from_storage). So:
 480 #
 481 # $row->discard_changes =>
 482 #   warning, and delegation to reload_from_storage
 483 #
 484 # $row->reload_from_storage =>
 485 #   does what discard changes did in 0.08 - issues a query to the db
 486 #   and repopulates all column slots, regardless of dirty states etc.
 487 #
 488 # $row->revert_changes =>
 489 #   does what discard_changes should have done initially (before it became
 490 #   a dual-purpose call). In order to make this work we will have to
 491 #   augment $row to carry its own initial-state, much like svn has a
 492 #   copy of the current checkout in contrast to cvs.
 493 #
 494 # my $db_row = $row->get_from_storage =>
 495 #   warns and delegates to an improved name copy_from_storage, with the
 496 #   same semantics
 497 #
 498 # my $db_row = $row->copy_from_storage =>
 499 #   a much better/descriptive name than get_from_storage
 500 #
 501 #------------------------------
 502 # READ THIS BEFORE "FIXING"
 503 #------------------------------
 504 #
 505 SKIP: {
 506     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 507
 508     my $row = $schema->resultset ('Artist')->next;
 509
 510     for (qw/discard_changes get_from_storage/) {
 511       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 512     }
 513 }
 514
 515 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 516
 517 done_testing;