t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my $schema = DBICTest->init_schema();
   9
  10 plan tests => 84;
  11
  12 eval { require DateTime::Format::MySQL };
  13 my $NO_DTFM = $@ ? 1 : 0;
  14
  15 # figure out if we've got a version of sqlite that is older than 3.2.6, in
  16 # which case COUNT(DISTINCT()) doesn't work
  17 my $is_broken_sqlite = 0;
  18 my ($sqlite_major_ver,$sqlite_minor_ver,$sqlite_patch_ver) =
  19     split /\./, $schema->storage->dbh->get_info(18);
  20 if( $schema->storage->dbh->get_info(17) eq 'SQLite' &&
  21     ( ($sqlite_major_ver < 3) ||
  22       ($sqlite_major_ver == 3 && $sqlite_minor_ver < 2) ||
  23       ($sqlite_major_ver == 3 && $sqlite_minor_ver == 2 && $sqlite_patch_ver < 6) ) ) {
  24     $is_broken_sqlite = 1;
  25 }
  26
  27
  28 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  29
  30 cmp_ok(@art, '==', 3, "Three artists returned");
  31
  32 my $art = $art[0];
  33
  34 is($art->name, 'We Are Goth', "Correct order too");
  35
  36 $art->name('We Are In Rehab');
  37
  38 is($art->name, 'We Are In Rehab', "Accessor update ok");
  39
  40 my %dirty = $art->get_dirty_columns();
  41 cmp_ok(scalar(keys(%dirty)), '==', 1, '1 dirty column');
  42 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  43
  44 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  45
  46 ok($art->update, 'Update run');
  47
  48 my %not_dirty = $art->get_dirty_columns();
  49 cmp_ok(scalar(keys(%not_dirty)), '==', 0, 'Nothing is dirty');
  50
  51 eval {
  52   my $ret = $art->make_column_dirty('name2');
  53 };
  54 ok(defined($@), 'Failed to make non-existent column dirty');
  55 $art->make_column_dirty('name');
  56 my %fake_dirty = $art->get_dirty_columns();
  57 cmp_ok(scalar(keys(%fake_dirty)), '==', 1, '1 fake dirty column');
  58 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  59
  60 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  61
  62 ok($record_jp, "prefetch on same rel okay");
  63
  64 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  65
  66 ok($record_fn, "funny join is okay");
  67
  68 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  69
  70 cmp_ok(@art, '==', 1, "Changed artist returned by search");
  71
  72 cmp_ok($art[0]->artistid, '==', 3,'Correct artist too');
  73
  74 $art->delete;
  75
  76 @art = $schema->resultset("Artist")->search({ });
  77
  78 cmp_ok(@art, '==', 2, 'And then there were two');
  79
  80 ok(!$art->in_storage, "It knows it's dead");
  81
  82 eval { $art->delete; };
  83
  84 ok($@, "Can't delete twice: $@");
  85
  86 is($art->name, 'We Are In Rehab', 'But the object is still live');
  87
  88 $art->insert;
  89
  90 ok($art->in_storage, "Re-created");
  91
  92 @art = $schema->resultset("Artist")->search({ });
  93
  94 cmp_ok(@art, '==', 3, 'And now there are three again');
  95
  96 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  97
  98 cmp_ok($new->artistid, '==', 4, 'Create produced record ok');
  99
 100 @art = $schema->resultset("Artist")->search({ });
 101
 102 cmp_ok(@art, '==', 4, "Oh my god! There's four of them!");
 103
 104 $new->set_column('name' => 'Man With A Fork');
 105
 106 is($new->name, 'Man With A Fork', 'set_column ok');
 107
 108 $new->discard_changes;
 109
 110 ok(!defined $new->name, 'Discard ok');
 111
 112 $new->name('Man With A Spoon');
 113
 114 $new->update;
 115
 116 my $new_again = $schema->resultset("Artist")->find(4);
 117
 118 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 119
 120 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 121
 122 # Test backwards compatibility
 123 {
 124   my $warnings = '';
 125   local $SIG{__WARN__} = sub { $warnings .= $_[0] };
 126
 127   my $artist_by_hash = $schema->resultset('Artist')->find(artistid => 4);
 128   is($artist_by_hash->name, 'Man With A Spoon', 'Retrieved correctly');
 129   is($artist_by_hash->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 130   like($warnings, qr/deprecated/, 'warned about deprecated find usage');
 131 }
 132
 133 is($schema->resultset("Artist")->count, 4, 'count ok');
 134
 135 # test find_or_new
 136 {
 137   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 138     artistid => 4,
 139   });
 140
 141   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 142   ok($existing_obj->in_storage, 'existing artist is in storage');
 143
 144   my $new_obj = $schema->resultset('Artist')->find_or_new({
 145     artistid => 5,
 146     name     => 'find_or_new',
 147   });
 148
 149   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 150   ok(! $new_obj->in_storage, 'new artist is not in storage');
 151 }
 152
 153 my $cd = $schema->resultset("CD")->find(1);
 154 my %cols = $cd->get_columns;
 155
 156 cmp_ok(keys %cols, '==', 5, 'get_columns number of columns ok');
 157
 158 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 159
 160 %cols = ( title => 'Forkful of bees', year => 2005);
 161 $cd->set_columns(\%cols);
 162
 163 is($cd->title, 'Forkful of bees', 'set_columns ok');
 164
 165 is($cd->year, 2005, 'set_columns ok');
 166
 167 $cd->discard_changes;
 168
 169 # check whether ResultSource->columns returns columns in order originally supplied
 170 my @cd = $schema->source("CD")->columns;
 171
 172 is_deeply( \@cd, [qw/cdid artist title year genreid/], 'column order');
 173
 174 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 175 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 176
 177 $cd = $schema->resultset("CD")->search(undef, { include_columns => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 178
 179 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 180 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 181
 182 # update_or_insert
 183 $new = $schema->resultset("Track")->new( {
 184   trackid => 100,
 185   cd => 1,
 186   position => 4,
 187   title => 'Insert or Update',
 188   last_updated_on => '1973-07-19 12:01:02'
 189 } );
 190 $new->update_or_insert;
 191 ok($new->in_storage, 'update_or_insert insert ok');
 192
 193 # test in update mode
 194 $new->pos(5);
 195 $new->update_or_insert;
 196 is( $schema->resultset("Track")->find(100)->pos, 5, 'update_or_insert update ok');
 197
 198 # get_inflated_columns w/relation and accessor alias
 199 SKIP: {
 200     skip "This test requires DateTime::Format::MySQL", 8 if $NO_DTFM;
 201
 202     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 203     my %tdata = $new->get_inflated_columns;
 204     is($tdata{'trackid'}, 100, 'got id');
 205     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 206     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 207     is($tdata{'position'}, 5, 'got position from pos');
 208     is($tdata{'title'}, 'Insert or Update');
 209     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 210     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 211 }
 212
 213 eval { $schema->class("Track")->load_components('DoesNotExist'); };
 214
 215 ok $@, $@;
 216
 217 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 218
 219 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 220
 221 my( $or_rs ) = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 222                                                   order_by => 'cdid' });
 223
 224 cmp_ok($or_rs->count, '==', 5, 'Search with OR ok');
 225
 226 my $distinct_rs = $schema->resultset("CD")->search($search, { join => 'tags', distinct => 1 });
 227 cmp_ok($distinct_rs->all, '==', 4, 'DISTINCT search with OR ok');
 228
 229 SKIP: {
 230   skip "SQLite < 3.2.6 doesn't understand COUNT(DISTINCT())", 1
 231     if $is_broken_sqlite;
 232
 233   my $tcount = $schema->resultset("Track")->search(
 234     {},
 235     {
 236        select => {count => {distinct => ['position', 'title']}},
 237            as => ['count']
 238     }
 239   );
 240   cmp_ok($tcount->next->get_column('count'), '==', 13, 'multiple column COUNT DISTINCT ok');
 241
 242 }
 243 my $tag_rs = $schema->resultset('Tag')->search(
 244                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 245
 246 my $rel_rs = $tag_rs->search_related('cd');
 247
 248 cmp_ok($rel_rs->count, '==', 5, 'Related search ok');
 249
 250 cmp_ok($or_rs->next->cdid, '==', $rel_rs->next->cdid, 'Related object ok');
 251 $or_rs->reset;
 252 $rel_rs->reset;
 253
 254 my $tag = $schema->resultset('Tag')->search(
 255                [ { 'me.tag' => 'Blue' } ], { cols=>[qw/tagid/] } )->next;
 256
 257 cmp_ok($tag->has_column_loaded('tagid'), '==', 1, 'Has tagid loaded');
 258 cmp_ok($tag->has_column_loaded('tag'), '==', 0, 'Has not tag  loaded');
 259
 260 ok($schema->storage(), 'Storage available');
 261
 262 {
 263   my $rs = $schema->resultset("Artist")->search({
 264     -and => [
 265       artistid => { '>=', 1 },
 266       artistid => { '<', 3 }
 267     ]
 268   });
 269
 270   $rs->update({ name => 'Test _cond_for_update_delete' });
 271
 272   my $art;
 273
 274   $art = $schema->resultset("Artist")->find(1);
 275   is($art->name, 'Test _cond_for_update_delete', 'updated first artist name');
 276
 277   $art = $schema->resultset("Artist")->find(2);
 278   is($art->name, 'Test _cond_for_update_delete', 'updated second artist name');
 279 }
 280
 281 # test source_name
 282 {
 283   # source_name should be set for normal modules
 284   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 285
 286   # test the result source that sets source_name explictly
 287   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 288
 289   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 290   cmp_ok(@artsn, '==', 4, "Four artists returned");
 291
 292   # make sure subclasses that don't set source_name are ok
 293   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 294 }
 295
 296 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 297
 298 $@ = '';
 299 eval {
 300 my $newlink = $newbook->link;
 301 };
 302 ok(!$@, "stringify to false value doesn't cause error");
 303
 304 # test cascade_delete through many_to_many relations
 305 {
 306   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 307   $art_del->delete;
 308   cmp_ok( $schema->resultset("CD")->search({artist => 1}), '==', 0, 'Cascading through has_many top level.');
 309   cmp_ok( $schema->resultset("CD_to_Producer")->search({cd => 1}), '==', 0, 'Cascading through has_many children.');
 310 }
 311
 312 # test column_info
 313 {
 314   $schema->source("Artist")->{_columns}{'artistid'} = {};
 315   $schema->source("Artist")->column_info_from_storage(1);
 316
 317   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 318   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 319   $schema->source("Artist")->column_info('artistid');
 320   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info flag set');
 321 }
 322
 323 # test source_info
 324 {
 325   my $expected = {
 326     "source_info_key_A" => "source_info_value_A",
 327     "source_info_key_B" => "source_info_value_B",
 328     "source_info_key_C" => "source_info_value_C",
 329   };
 330
 331   my $sinfo = $schema->source("Artist")->source_info;
 332
 333   is_deeply($sinfo, $expected, 'source_info data works');
 334 }
 335
 336 # test remove_columns
 337 {
 338   is_deeply([$schema->source('CD')->columns], [qw/cdid artist title year genreid/]);
 339   $schema->source('CD')->remove_columns('year');
 340   is_deeply([$schema->source('CD')->columns], [qw/cdid artist title genreid/]);
 341   ok(! exists $schema->source('CD')->_columns->{'year'}, 'year still exists in _columns');
 342 }
 343
 344 # test get_inflated_columns with objects
 345 SKIP: {
 346     skip "This test requires DateTime::Format::MySQL", 5 if $NO_DTFM;
 347     my $event = $schema->resultset('Event')->search->first;
 348     my %edata = $event->get_inflated_columns;
 349     is($edata{'id'}, $event->id, 'got id');
 350     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 351     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 352     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 353     is($edata{'created_on'}, $event->created_on, 'got created date');
 354 }
 355
 356 # test resultsource->table return value when setting
 357 {
 358     my $class = $schema->class('Event');
 359     diag $class;
 360     my $table = $class->table($class->table);
 361     is($table, $class->table, '->table($table) returns $table');
 362 }