t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use lib qw(t/lib);
   8 use DBICTest ':DiffSQL';
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  13
  14 is(@art, 3, "Three artists returned");
  15
  16 my $art = $art[0];
  17
  18 is($art->name, 'We Are Goth', "Correct order too");
  19
  20 $art->name('We Are In Rehab');
  21
  22 is($art->name, 'We Are In Rehab', "Accessor update ok");
  23
  24 my %dirty = $art->get_dirty_columns();
  25 is(scalar(keys(%dirty)), 1, '1 dirty column');
  26 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  27
  28 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  29
  30 ok($art->update, 'Update run');
  31
  32 my %not_dirty = $art->get_dirty_columns();
  33 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  34
  35 throws_ok ( sub {
  36   my $ret = $art->make_column_dirty('name2');
  37 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  38
  39 $art->make_column_dirty('name');
  40 my %fake_dirty = $art->get_dirty_columns();
  41 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  42 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  43
  44 ok($art->update, 'Update run');
  45
  46 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  47
  48 ok($record_jp, "prefetch on same rel okay");
  49
  50 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  51
  52 ok($record_fn, "funny join is okay");
  53
  54 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  55
  56 is(@art, 1, "Changed artist returned by search");
  57
  58 is($art[0]->artistid, 3,'Correct artist too');
  59
  60 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  61
  62 @art = $schema->resultset("Artist")->search({ });
  63
  64 is(@art, 2, 'And then there were two');
  65
  66 is($art->in_storage, 0, "It knows it's dead");
  67
  68 lives_ok { $art->update } 'No changes so update should be OK';
  69
  70 dies_ok ( sub { $art->delete }, "Can't delete twice");
  71
  72 is($art->name, 'We Are In Rehab', 'But the object is still live');
  73
  74 $art->insert;
  75
  76 ok($art->in_storage, "Re-created");
  77
  78 @art = $schema->resultset("Artist")->search({ });
  79
  80 is(@art, 3, 'And now there are three again');
  81
  82 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  83
  84 is($new->artistid, 4, 'Create produced record ok');
  85
  86 @art = $schema->resultset("Artist")->search({ });
  87
  88 is(@art, 4, "Oh my god! There's four of them!");
  89
  90 $new->set_column('name' => 'Man With A Fork');
  91
  92 is($new->name, 'Man With A Fork', 'set_column ok');
  93
  94 $new->discard_changes;
  95
  96 ok(!defined $new->name, 'Discard ok');
  97
  98 $new->name('Man With A Spoon');
  99
 100 $new->update;
 101
 102 my $new_again = $schema->resultset("Artist")->find(4);
 103
 104 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 105
 106 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 107
 108 # test that store_column is called once for create() for non sequence columns
 109 {
 110   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 111   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 112
 113   # call store_column even though the column doesn't seem to be dirty
 114   $artist->name($artist->name);
 115   is($artist->name, 'X X store_column test');
 116   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 117
 118   $artist->delete;
 119 }
 120
 121 # deprecation of rolled-out search
 122 warnings_exist {
 123   $schema->resultset('Artist')->search_rs(id => 4)
 124 } qr/\Qsearch( %condition ) is deprecated/, 'Deprecation warning on ->search( %condition )';
 125
 126 # this has been warning for 4 years, killing
 127 throws_ok {
 128   $schema->resultset('Artist')->find(artistid => 4);
 129 } qr|expects either a column/value hashref, or a list of values corresponding to the columns of the specified unique constraint|;
 130
 131 is($schema->resultset("Artist")->count, 4, 'count ok');
 132
 133 # test find on an unresolvable condition
 134 is(
 135   $schema->resultset('Artist')->find({ artistid => [ -and => 1, 2 ]}),
 136   undef
 137 );
 138
 139
 140 # test find_or_new
 141 {
 142   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 143     artistid => 4,
 144   });
 145
 146   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 147   ok($existing_obj->in_storage, 'existing artist is in storage');
 148
 149   my $new_obj = $schema->resultset('Artist')->find_or_new({
 150     artistid => 5,
 151     name     => 'find_or_new',
 152   });
 153
 154   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 155   is($new_obj->in_storage, 0, 'new artist is not in storage');
 156 }
 157
 158 my $cd = $schema->resultset("CD")->find(1);
 159 my %cols = $cd->get_columns;
 160
 161 is(keys %cols, 6, 'get_columns number of columns ok');
 162
 163 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 164
 165 %cols = ( title => 'Forkful of bees', year => 2005);
 166 $cd->set_columns(\%cols);
 167
 168 is($cd->title, 'Forkful of bees', 'set_columns ok');
 169
 170 is($cd->year, 2005, 'set_columns ok');
 171
 172 $cd->discard_changes;
 173
 174 # check whether ResultSource->columns returns columns in order originally supplied
 175 my @cd = $schema->source("CD")->columns;
 176
 177 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 178
 179 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 180 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 181
 182 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 183
 184 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 185 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 186
 187 # check if new syntax +columns also works for this
 188 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 189
 190 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 191 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 192
 193 # check if new syntax for +columns select specifiers works for this
 194 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 195
 196 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 197 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 198
 199 # update_or_insert
 200 $new = $schema->resultset("Track")->new( {
 201   trackid => 100,
 202   cd => 1,
 203   title => 'Insert or Update',
 204   last_updated_on => '1973-07-19 12:01:02'
 205 } );
 206 $new->update_or_insert;
 207 ok($new->in_storage, 'update_or_insert insert ok');
 208
 209 # test in update mode
 210 $new->title('Insert or Update - updated');
 211 $new->update_or_insert;
 212 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 213
 214 SKIP: {
 215     skip "Tests require " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_sqlite'), 13
 216       unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_sqlite');
 217
 218     # test get_inflated_columns with objects
 219     my $event = $schema->resultset('Event')->search->first;
 220     my %edata = $event->get_inflated_columns;
 221     is($edata{'id'}, $event->id, 'got id');
 222     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 223     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 224     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 225     is($edata{'created_on'}, $event->created_on, 'got created date');
 226
 227
 228     # get_inflated_columns w/relation and accessor alias
 229     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 230     my %tdata = $new->get_inflated_columns;
 231     is($tdata{'trackid'}, 100, 'got id');
 232     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 233     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 234     is(
 235         $tdata{'position'},
 236         $schema->resultset ('Track')->search ({cd => 1})->count,
 237         'Ordered assigned proper position',
 238     );
 239     is($tdata{'title'}, 'Insert or Update - updated');
 240     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 241     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 242 }
 243
 244 throws_ok (sub {
 245   $schema->class("Track")->load_components('DoesNotExist');
 246 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 247
 248 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 249
 250 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 251
 252 my $or_rs = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 253                                                   order_by => 'cdid' });
 254 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 255 is($or_rs->count, 5, 'Search count with OR ok');
 256
 257 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 258 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 259 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 260
 261 # make sure sure distinct on a grouped rs is warned about
 262 {
 263   my $cd_rs = $schema->resultset ('CD')
 264                 ->search ({}, { distinct => 1, group_by => 'title' });
 265   warnings_exist (sub {
 266     $cd_rs->next;
 267   }, qr/Useless use of distinct/, 'UUoD warning');
 268 }
 269
 270 {
 271   my $tcount = $schema->resultset('Track')->search(
 272     {},
 273     {
 274       select => [ qw/position title/ ],
 275       distinct => 1,
 276     }
 277   );
 278   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 279
 280   $tcount = $schema->resultset('Track')->search(
 281     {},
 282     {
 283       columns => [ qw/position title/ ],
 284       distinct => 1,
 285     }
 286   );
 287   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 288
 289   $tcount = $schema->resultset('Track')->search(
 290     {},
 291     {
 292        group_by => [ qw/position title/ ]
 293     }
 294   );
 295   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 296 }
 297
 298 my $tag_rs = $schema->resultset('Tag')->search(
 299                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 300
 301 my $rel_rs = $tag_rs->search_related('cd', {}, { order_by => 'cd.cdid'} );
 302
 303 is($rel_rs->count, 5, 'Related search ok');
 304
 305 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 306 $or_rs->reset;
 307 $rel_rs->reset;
 308
 309 # at this point there should be no active statements
 310 # (finish() was called everywhere, either explicitly via
 311 # reset() or on DESTROY)
 312 for (keys %{$schema->storage->dbh->{CachedKids}}) {
 313   fail("Unreachable cached statement still active: $_")
 314     if $schema->storage->dbh->{CachedKids}{$_}->FETCH('Active');
 315 }
 316
 317 my $tag = $schema->resultset('Tag')->search(
 318   [ { 'me.tag' => 'Blue' } ],
 319   { columns => 'tagid' }
 320 )->next;
 321
 322 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 323 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 324
 325 ok($schema->storage(), 'Storage available');
 326
 327 {
 328   my $rs = $schema->resultset("Artist")->search({
 329     -and => [
 330       artistid => { '>=', 1 },
 331       artistid => { '<', 3 }
 332     ]
 333   });
 334
 335   $rs->update({ rank => 6134 });
 336
 337   my $art;
 338
 339   $art = $schema->resultset("Artist")->find(1);
 340   is($art->rank, 6134, 'updated first artist rank');
 341
 342   $art = $schema->resultset("Artist")->find(2);
 343   is($art->rank, 6134, 'updated second artist rank');
 344 }
 345
 346 # test source_name
 347 {
 348   # source_name should be set for normal modules
 349   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 350
 351   # test the result source that sets source_name explictly
 352   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 353
 354   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 355   is(@artsn, 4, "Four artists returned");
 356
 357   # make sure subclasses that don't set source_name are ok
 358   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 359 }
 360
 361 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 362
 363 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 364
 365 # test cascade_delete through many_to_many relations
 366 {
 367   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 368   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 369   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 370   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 371 }
 372
 373 # test column_info
 374 {
 375   $schema->source("Artist")->{_columns}{'artistid'} = {};
 376   $schema->source("Artist")->column_info_from_storage(1);
 377
 378   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 379   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 380   $schema->source("Artist")->column_info('artistid');
 381   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 382 }
 383
 384 # test columns_info
 385 {
 386   $schema->source("Artist")->{_columns}{'artistid'} = {};
 387   $schema->source("Artist")->column_info_from_storage(1);
 388   $schema->source("Artist")->{_columns_info_loaded} = 0;
 389
 390   is_deeply (
 391     $schema->source('Artist')->columns_info,
 392     {
 393       artistid => {
 394         data_type => "INTEGER",
 395         default_value => undef,
 396         is_nullable => 0,
 397         size => undef
 398       },
 399       charfield => {
 400         data_type => "char",
 401         default_value => undef,
 402         is_nullable => 1,
 403         size => 10
 404       },
 405       name => {
 406         data_type => "varchar",
 407         default_value => undef,
 408         is_nullable => 1,
 409         is_numeric => 0,
 410         size => 100
 411       },
 412       rank => {
 413         data_type => "integer",
 414         default_value => 13,
 415         is_nullable => 0,
 416         size => undef
 417       },
 418     },
 419     'columns_info works',
 420   );
 421
 422   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 423
 424   is_deeply (
 425     $schema->source('Artist')->columns_info([qw/artistid rank/]),
 426     {
 427       artistid => {
 428         data_type => "INTEGER",
 429         default_value => undef,
 430         is_nullable => 0,
 431         size => undef
 432       },
 433       rank => {
 434         data_type => "integer",
 435         default_value => 13,
 436         is_nullable => 0,
 437         size => undef
 438       },
 439     },
 440     'limited columns_info works',
 441   );
 442 }
 443
 444 # test source_info
 445 {
 446   my $expected = {
 447     "source_info_key_A" => "source_info_value_A",
 448     "source_info_key_B" => "source_info_value_B",
 449     "source_info_key_C" => "source_info_value_C",
 450   };
 451
 452   my $sinfo = $schema->source("Artist")->source_info;
 453
 454   is_deeply($sinfo, $expected, 'source_info data works');
 455 }
 456
 457 # test remove_columns
 458 {
 459   is_deeply(
 460     [$schema->source('CD')->columns],
 461     [qw/cdid artist title year genreid single_track/],
 462     'initial columns',
 463   );
 464
 465   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 466   is_deeply(
 467     [$schema->source('CD')->columns],
 468     [qw/cdid artist title year genreid single_track/],
 469     'nothing removed when removing a non-existent column',
 470   );
 471
 472   $schema->source('CD')->remove_columns('genreid', 'year');
 473   is_deeply(
 474     [$schema->source('CD')->columns],
 475     [qw/cdid artist title single_track/],
 476     'removed two columns',
 477   );
 478
 479   my $priv_columns = $schema->source('CD')->_columns;
 480   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 481   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 482 }
 483
 484 # test resultsource->table return value when setting
 485 {
 486     my $class = $schema->class('Event');
 487     my $table = $class->table($class->table);
 488     is($table, $class->table, '->table($table) returns $table');
 489 }
 490
 491 #make sure insert doesn't use set_column
 492 {
 493   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 494   is($en_row->encoded, 'amliw', 'new encodes');
 495   $en_row->insert;
 496   is($en_row->encoded, 'amliw', 'insert does not encode again');
 497 }
 498
 499 #make sure multicreate encoding still works
 500 {
 501   my $empl_rs = $schema->resultset('Employee');
 502
 503   my $empl = $empl_rs->create ({
 504     name => 'Secret holder',
 505     secretkey => {
 506       encoded => 'CAN HAZ',
 507     },
 508   });
 509   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 510
 511   my $empl2 = $empl_rs->create ({
 512     name => 'Same secret holder',
 513     secretkey => {
 514       encoded => 'CAN HAZ',
 515     },
 516   });
 517   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 518
 519   $empl_rs->create ({
 520     name => 'cat1',
 521     secretkey => {
 522       encoded => 'CHEEZBURGER',
 523       keyholders => [
 524         {
 525           name => 'cat2',
 526         },
 527         {
 528           name => 'cat3',
 529         },
 530       ],
 531     },
 532   });
 533
 534   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 535   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 536   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 537
 538 }
 539
 540 # make sure that obsolete handle-based source tracking continues to work for the time being
 541 {
 542   my $handle = $schema->source('Artist')->handle;
 543
 544   my $rowdata = { $schema->resultset('Artist')->next->get_columns };
 545
 546   my $rs = DBIx::Class::ResultSet->new($handle);
 547   my $rs_result = $rs->next;
 548   isa_ok( $rs_result, 'DBICTest::Artist' );
 549   is_deeply (
 550     { $rs_result->get_columns },
 551     $rowdata,
 552     'Correct columns retrieved (rset/source link healthy)'
 553   );
 554
 555   my $row = DBICTest::Artist->new({ -source_handle => $handle });
 556   is_deeply(
 557     { $row->get_columns },
 558     {},
 559     'No columns yet'
 560   );
 561
 562   # store_column to fool the _orig_ident tracker
 563   $row->store_column('artistid', $rowdata->{artistid});
 564   $row->in_storage(1);
 565
 566   $row->discard_changes;
 567   is_deeply(
 568     { $row->get_columns },
 569     $rowdata,
 570     'Storage refetch successful'
 571   );
 572 }
 573
 574 # test to make sure that calling ->new() on a resultset object gives
 575 # us a row object
 576 {
 577     my $new_artist = $schema->resultset('Artist')->new({});
 578     isa_ok( $new_artist, 'DBIx::Class::Row', '$rs->new gives a row object' );
 579     lives_ok { $new_artist->insert() } 'inserting without specifying any columns works';
 580     $new_artist->discard_changes;
 581     $new_artist->delete;
 582 }
 583
 584 # make sure we got rid of the compat shims
 585 SKIP: {
 586     my $remove_version = 0.083;
 587     skip "Remove in $remove_version", 3 if $DBIx::Class::VERSION < $remove_version;
 588
 589     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 590       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource, removed before $remove_version");
 591     }
 592 }
 593
 594 #------------------------------
 595 # READ THIS BEFORE "FIXING"
 596 #------------------------------
 597 #
 598 # make sure we got rid of discard_changes mess - this is a mess and a source
 599 # of great confusion. Here I simply die if the methods are available, which
 600 # is wrong on its own (we *have* to provide some sort of back-compat, even
 601 # if with warnings). Here is how I envision things should actually be. Also
 602 # note that a lot of the deprecation can be started today (i.e. the switch
 603 # from get_from_storage to copy_from_storage). So:
 604 #
 605 # $row->discard_changes =>
 606 #   warning, and delegation to reload_from_storage
 607 #
 608 # $row->reload_from_storage =>
 609 #   does what discard changes did in 0.08 - issues a query to the db
 610 #   and repopulates all column slots, regardless of dirty states etc.
 611 #
 612 # $row->revert_changes =>
 613 #   does what discard_changes should have done initially (before it became
 614 #   a dual-purpose call). In order to make this work we will have to
 615 #   augment $row to carry its own initial-state, much like svn has a
 616 #   copy of the current checkout in contrast to cvs.
 617 #
 618 # my $db_row = $row->get_from_storage =>
 619 #   warns and delegates to an improved name copy_from_storage, with the
 620 #   same semantics
 621 #
 622 # my $db_row = $row->copy_from_storage =>
 623 #   a much better/descriptive name than get_from_storage
 624 #
 625 #------------------------------
 626 # READ THIS BEFORE "FIXING"
 627 #------------------------------
 628 #
 629 SKIP: {
 630     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 631
 632     my $row = $schema->resultset ('Artist')->next;
 633
 634     for (qw/discard_changes get_from_storage/) {
 635       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 636     }
 637 }
 638
 639 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 640
 641 done_testing;