t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use lib qw(t/lib);
   8 use DBICTest ':DiffSQL';
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  13
  14 is(@art, 3, "Three artists returned");
  15
  16 my $art = $art[0];
  17
  18 is($art->name, 'We Are Goth', "Correct order too");
  19
  20 $art->name('We Are In Rehab');
  21
  22 is($art->name, 'We Are In Rehab', "Accessor update ok");
  23
  24 my %dirty = $art->get_dirty_columns();
  25 is(scalar(keys(%dirty)), 1, '1 dirty column');
  26 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  27
  28 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  29
  30 ok($art->update, 'Update run');
  31
  32 my %not_dirty = $art->get_dirty_columns();
  33 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  34
  35 throws_ok ( sub {
  36   my $ret = $art->make_column_dirty('name2');
  37 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  38
  39 $art->make_column_dirty('name');
  40 my %fake_dirty = $art->get_dirty_columns();
  41 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  42 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  43
  44 ok($art->update, 'Update run');
  45
  46 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  47
  48 ok($record_jp, "prefetch on same rel okay");
  49
  50 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  51
  52 ok($record_fn, "funny join is okay");
  53
  54 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  55
  56 is(@art, 1, "Changed artist returned by search");
  57
  58 is($art[0]->artistid, 3,'Correct artist too');
  59
  60 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  61
  62 @art = $schema->resultset("Artist")->search({ });
  63
  64 is(@art, 2, 'And then there were two');
  65
  66 is($art->in_storage, 0, "It knows it's dead");
  67
  68 lives_ok { $art->update } 'No changes so update should be OK';
  69
  70 dies_ok ( sub { $art->delete }, "Can't delete twice");
  71
  72 is($art->name, 'We Are In Rehab', 'But the object is still live');
  73
  74 $art->insert;
  75
  76 ok($art->in_storage, "Re-created");
  77
  78 @art = $schema->resultset("Artist")->search({ });
  79
  80 is(@art, 3, 'And now there are three again');
  81
  82 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  83
  84 is($new->artistid, 4, 'Create produced record ok');
  85
  86 @art = $schema->resultset("Artist")->search({ });
  87
  88 is(@art, 4, "Oh my god! There's four of them!");
  89
  90 $new->set_column('name' => 'Man With A Fork');
  91
  92 is($new->name, 'Man With A Fork', 'set_column ok');
  93
  94 $new->discard_changes;
  95
  96 ok(!defined $new->name, 'Discard ok');
  97
  98 $new->name('Man With A Spoon');
  99
 100 $new->update;
 101
 102 my $new_again = $schema->resultset("Artist")->find(4);
 103
 104 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 105
 106 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 107
 108 # test that store_column is called once for create() for non sequence columns
 109 {
 110   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 111   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 112
 113   # call store_column even though the column doesn't seem to be dirty
 114   $artist->name($artist->name);
 115   is($artist->name, 'X X store_column test');
 116   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 117
 118   $artist->delete;
 119 }
 120
 121 # deprecation of rolled-out search
 122 warnings_exist {
 123   $schema->resultset('Artist')->search_rs(id => 4)
 124 } qr/\Qsearch( %condition ) is deprecated/, 'Deprecation warning on ->search( %condition )';
 125
 126 # this has been warning for 4 years, killing
 127 throws_ok {
 128   $schema->resultset('Artist')->find(artistid => 4);
 129 } qr|expects either a column/value hashref, or a list of values corresponding to the columns of the specified unique constraint|;
 130
 131 is($schema->resultset("Artist")->count, 4, 'count ok');
 132
 133 # test find on an unresolvable condition
 134 is(
 135   $schema->resultset('Artist')->find({ artistid => [ -and => 1, 2 ]}),
 136   undef
 137 );
 138
 139
 140 # test find_or_new
 141 {
 142   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 143     artistid => 4,
 144   });
 145
 146   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 147   ok($existing_obj->in_storage, 'existing artist is in storage');
 148
 149   my $new_obj = $schema->resultset('Artist')->find_or_new({
 150     artistid => 5,
 151     name     => 'find_or_new',
 152   });
 153
 154   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 155   is($new_obj->in_storage, 0, 'new artist is not in storage');
 156 }
 157
 158 my $cd = $schema->resultset("CD")->find(1);
 159 my %cols = $cd->get_columns;
 160
 161 is(keys %cols, 6, 'get_columns number of columns ok');
 162
 163 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 164
 165 %cols = ( title => 'Forkful of bees', year => 2005);
 166 $cd->set_columns(\%cols);
 167
 168 is($cd->title, 'Forkful of bees', 'set_columns ok');
 169
 170 is($cd->year, 2005, 'set_columns ok');
 171
 172 $cd->discard_changes;
 173
 174 # check whether ResultSource->columns returns columns in order originally supplied
 175 my @cd = $schema->source("CD")->columns;
 176
 177 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 178
 179 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 180 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 181
 182 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 183
 184 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 185 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 186
 187 # check if new syntax +columns also works for this
 188 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 189
 190 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 191 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 192
 193 # check if new syntax for +columns select specifiers works for this
 194 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 195
 196 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 197 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 198
 199 # update_or_insert
 200 $new = $schema->resultset("Track")->new( {
 201   trackid => 100,
 202   cd => 1,
 203   title => 'Insert or Update',
 204   last_updated_on => '1973-07-19 12:01:02'
 205 } );
 206 $new->update_or_insert;
 207 ok($new->in_storage, 'update_or_insert insert ok');
 208
 209 throws_ok (sub {
 210   $schema->class("Track")->load_components('DoesNotExist');
 211 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 212
 213 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 214
 215 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 216
 217 my $or_rs = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 218                                                   order_by => 'cdid' });
 219 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 220 is($or_rs->count, 5, 'Search count with OR ok');
 221
 222 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 223 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 224 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 225
 226 # make sure sure distinct on a grouped rs is warned about
 227 {
 228   my $cd_rs = $schema->resultset ('CD')
 229                 ->search ({}, { distinct => 1, group_by => 'title' });
 230   warnings_exist (sub {
 231     $cd_rs->next;
 232   }, qr/Useless use of distinct/, 'UUoD warning');
 233 }
 234
 235 {
 236   my $tcount = $schema->resultset('Track')->search(
 237     {},
 238     {
 239       select => [ qw/position title/ ],
 240       distinct => 1,
 241     }
 242   );
 243   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 244
 245   $tcount = $schema->resultset('Track')->search(
 246     {},
 247     {
 248       columns => [ qw/position title/ ],
 249       distinct => 1,
 250     }
 251   );
 252   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 253
 254   $tcount = $schema->resultset('Track')->search(
 255     {},
 256     {
 257        group_by => [ qw/position title/ ]
 258     }
 259   );
 260   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 261 }
 262
 263 my $tag_rs = $schema->resultset('Tag')->search(
 264                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 265
 266 my $rel_rs = $tag_rs->search_related('cd', {}, { order_by => 'cd.cdid'} );
 267
 268 is($rel_rs->count, 5, 'Related search ok');
 269
 270 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 271 $or_rs->reset;
 272 $rel_rs->reset;
 273
 274 # at this point there should be no active statements
 275 # (finish() was called everywhere, either explicitly via
 276 # reset() or on DESTROY)
 277 for (keys %{$schema->storage->dbh->{CachedKids}}) {
 278   fail("Unreachable cached statement still active: $_")
 279     if $schema->storage->dbh->{CachedKids}{$_}->FETCH('Active');
 280 }
 281
 282 my $tag = $schema->resultset('Tag')->search(
 283   [ { 'me.tag' => 'Blue' } ],
 284   { columns => 'tagid' }
 285 )->next;
 286
 287 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 288 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 289
 290 ok($schema->storage(), 'Storage available');
 291
 292 {
 293   my $rs = $schema->resultset("Artist")->search({
 294     -and => [
 295       artistid => { '>=', 1 },
 296       artistid => { '<', 3 }
 297     ]
 298   });
 299
 300   $rs->update({ rank => 6134 });
 301
 302   my $art;
 303
 304   $art = $schema->resultset("Artist")->find(1);
 305   is($art->rank, 6134, 'updated first artist rank');
 306
 307   $art = $schema->resultset("Artist")->find(2);
 308   is($art->rank, 6134, 'updated second artist rank');
 309 }
 310
 311 # test source_name
 312 {
 313   # source_name should be set for normal modules
 314   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 315
 316   # test the result source that sets source_name explictly
 317   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 318
 319   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 320   is(@artsn, 4, "Four artists returned");
 321
 322   # make sure subclasses that don't set source_name are ok
 323   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 324 }
 325
 326 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 327
 328 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 329
 330 # test cascade_delete through many_to_many relations
 331 {
 332   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 333   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 334   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 335   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 336 }
 337
 338 # test column_info
 339 {
 340   $schema->source("Artist")->{_columns}{'artistid'} = {};
 341   $schema->source("Artist")->column_info_from_storage(1);
 342
 343   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 344   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 345   $schema->source("Artist")->column_info('artistid');
 346   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 347 }
 348
 349 # test columns_info
 350 {
 351   $schema->source("Artist")->{_columns}{'artistid'} = {};
 352   $schema->source("Artist")->column_info_from_storage(1);
 353   $schema->source("Artist")->{_columns_info_loaded} = 0;
 354
 355   my @undef_default = DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
 356     ? ()
 357     : ( default_value => undef )
 358   ;
 359
 360   is_deeply (
 361     $schema->source('Artist')->columns_info,
 362     {
 363       artistid => {
 364         data_type => "INTEGER",
 365         @undef_default,
 366         is_nullable => 0,
 367         size => undef
 368       },
 369       charfield => {
 370         data_type => "char",
 371         @undef_default,
 372         is_nullable => 1,
 373         size => 10
 374       },
 375       name => {
 376         data_type => "varchar",
 377         @undef_default,
 378         is_nullable => 1,
 379         is_numeric => 0,
 380         size => 100
 381       },
 382       rank => {
 383         data_type => "integer",
 384         default_value => 13,
 385         is_nullable => 0,
 386         size => undef
 387       },
 388     },
 389     'columns_info works',
 390   );
 391
 392   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 393
 394   is_deeply (
 395     $schema->source('Artist')->columns_info([qw/artistid rank/]),
 396     {
 397       artistid => {
 398         data_type => "INTEGER",
 399         @undef_default,
 400         is_nullable => 0,
 401         size => undef
 402       },
 403       rank => {
 404         data_type => "integer",
 405         default_value => 13,
 406         is_nullable => 0,
 407         size => undef
 408       },
 409     },
 410     'limited columns_info works',
 411   );
 412 }
 413
 414 # test source_info
 415 {
 416   my $expected = {
 417     "source_info_key_A" => "source_info_value_A",
 418     "source_info_key_B" => "source_info_value_B",
 419     "source_info_key_C" => "source_info_value_C",
 420   };
 421
 422   my $sinfo = $schema->source("Artist")->source_info;
 423
 424   is_deeply($sinfo, $expected, 'source_info data works');
 425 }
 426
 427 # test remove_columns
 428 {
 429   is_deeply(
 430     [$schema->source('CD')->columns],
 431     [qw/cdid artist title year genreid single_track/],
 432     'initial columns',
 433   );
 434
 435   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 436   is_deeply(
 437     [$schema->source('CD')->columns],
 438     [qw/cdid artist title year genreid single_track/],
 439     'nothing removed when removing a non-existent column',
 440   );
 441
 442   $schema->source('CD')->remove_columns('genreid', 'year');
 443   is_deeply(
 444     [$schema->source('CD')->columns],
 445     [qw/cdid artist title single_track/],
 446     'removed two columns',
 447   );
 448
 449   my $priv_columns = $schema->source('CD')->_columns;
 450   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 451   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 452 }
 453
 454 # test resultsource->table return value when setting
 455 {
 456     my $class = $schema->class('Event');
 457     my $table = $class->table($class->table);
 458     is($table, $class->table, '->table($table) returns $table');
 459 }
 460
 461 #make sure insert doesn't use set_column
 462 {
 463   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 464   is($en_row->encoded, 'amliw', 'new encodes');
 465   $en_row->insert;
 466   is($en_row->encoded, 'amliw', 'insert does not encode again');
 467 }
 468
 469 #make sure multicreate encoding still works
 470 {
 471   my $empl_rs = $schema->resultset('Employee');
 472
 473   my $empl = $empl_rs->create ({
 474     name => 'Secret holder',
 475     secretkey => {
 476       encoded => 'CAN HAZ',
 477     },
 478   });
 479   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 480
 481   my $empl2 = $empl_rs->create ({
 482     name => 'Same secret holder',
 483     secretkey => {
 484       encoded => 'CAN HAZ',
 485     },
 486   });
 487   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 488
 489   $empl_rs->create ({
 490     name => 'cat1',
 491     secretkey => {
 492       encoded => 'CHEEZBURGER',
 493       keyholders => [
 494         {
 495           name => 'cat2',
 496         },
 497         {
 498           name => 'cat3',
 499         },
 500       ],
 501     },
 502   });
 503
 504   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 505   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 506   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 507
 508 }
 509
 510 # make sure that obsolete handle-based source tracking continues to work for the time being
 511 {
 512   my $handle = $schema->source('Artist')->handle;
 513
 514   my $rowdata = { $schema->resultset('Artist')->next->get_columns };
 515
 516   my $rs = DBIx::Class::ResultSet->new($handle);
 517   my $rs_result = $rs->next;
 518   isa_ok( $rs_result, 'DBICTest::Artist' );
 519   is_deeply (
 520     { $rs_result->get_columns },
 521     $rowdata,
 522     'Correct columns retrieved (rset/source link healthy)'
 523   );
 524
 525   my $row = DBICTest::Artist->new({ -source_handle => $handle });
 526   is_deeply(
 527     { $row->get_columns },
 528     {},
 529     'No columns yet'
 530   );
 531
 532   # store_column to fool the _orig_ident tracker
 533   $row->store_column('artistid', $rowdata->{artistid});
 534   $row->in_storage(1);
 535
 536   $row->discard_changes;
 537   is_deeply(
 538     { $row->get_columns },
 539     $rowdata,
 540     'Storage refetch successful'
 541   );
 542 }
 543
 544 # test to make sure that calling ->new() on a resultset object gives
 545 # us a row object
 546 {
 547     my $new_artist = $schema->resultset('Artist')->new({});
 548     isa_ok( $new_artist, 'DBIx::Class::Row', '$rs->new gives a row object' );
 549 }
 550
 551
 552 # make sure we got rid of the compat shims
 553 SKIP: {
 554     my $remove_version = 0.083;
 555     skip "Remove in $remove_version", 3 if $DBIx::Class::VERSION < $remove_version;
 556
 557     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 558       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource, removed before $remove_version");
 559     }
 560 }
 561
 562 #------------------------------
 563 # READ THIS BEFORE "FIXING"
 564 #------------------------------
 565 #
 566 # make sure we got rid of discard_changes mess - this is a mess and a source
 567 # of great confusion. Here I simply die if the methods are available, which
 568 # is wrong on its own (we *have* to provide some sort of back-compat, even
 569 # if with warnings). Here is how I envision things should actually be. Also
 570 # note that a lot of the deprecation can be started today (i.e. the switch
 571 # from get_from_storage to copy_from_storage). So:
 572 #
 573 # $row->discard_changes =>
 574 #   warning, and delegation to reload_from_storage
 575 #
 576 # $row->reload_from_storage =>
 577 #   does what discard changes did in 0.08 - issues a query to the db
 578 #   and repopulates all column slots, regardless of dirty states etc.
 579 #
 580 # $row->revert_changes =>
 581 #   does what discard_changes should have done initially (before it became
 582 #   a dual-purpose call). In order to make this work we will have to
 583 #   augment $row to carry its own initial-state, much like svn has a
 584 #   copy of the current checkout in contrast to cvs.
 585 #
 586 # my $db_row = $row->get_from_storage =>
 587 #   warns and delegates to an improved name copy_from_storage, with the
 588 #   same semantics
 589 #
 590 # my $db_row = $row->copy_from_storage =>
 591 #   a much better/descriptive name than get_from_storage
 592 #
 593 #------------------------------
 594 # READ THIS BEFORE "FIXING"
 595 #------------------------------
 596 #
 597 SKIP: {
 598     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 599
 600     my $row = $schema->resultset ('Artist')->next;
 601
 602     for (qw/discard_changes get_from_storage/) {
 603       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 604     }
 605 }
 606
 607 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 608
 609 throws_ok { $schema->source('Artist')->result_class->new( 'bugger' ) } qr/must be a hashref/;
 610
 611 done_testing;