t/60core.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8 use Test::Warn;
   9
  10 use DBICTest ':DiffSQL';
  11
  12 my $schema = DBICTest->init_schema();
  13
  14 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  15
  16 is(@art, 3, "Three artists returned");
  17
  18 my $art = $art[0];
  19
  20 is($art->name, 'We Are Goth', "Correct order too");
  21
  22 $art->name('We Are In Rehab');
  23
  24 is($art->name, 'We Are In Rehab', "Accessor update ok");
  25
  26 my %dirty = $art->get_dirty_columns();
  27 is(scalar(keys(%dirty)), 1, '1 dirty column');
  28 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  29
  30 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  31
  32 ok($art->update, 'Update run');
  33
  34 my %not_dirty = $art->get_dirty_columns();
  35 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  36
  37 throws_ok ( sub {
  38   my $ret = $art->make_column_dirty('name2');
  39 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  40
  41 $art->make_column_dirty('name');
  42 my %fake_dirty = $art->get_dirty_columns();
  43 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  44 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  45
  46 ok($art->update, 'Update run');
  47
  48 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  49
  50 ok($record_jp, "prefetch on same rel okay");
  51
  52 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  53
  54 ok($record_fn, "funny join is okay");
  55
  56 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  57
  58 is(@art, 1, "Changed artist returned by search");
  59
  60 is($art[0]->artistid, 3,'Correct artist too');
  61
  62 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  63
  64 @art = $schema->resultset("Artist")->search({ });
  65
  66 is(@art, 2, 'And then there were two');
  67
  68 is($art->in_storage, 0, "It knows it's dead");
  69
  70 lives_ok { $art->update } 'No changes so update should be OK';
  71
  72 dies_ok ( sub { $art->delete }, "Can't delete twice");
  73
  74 is($art->name, 'We Are In Rehab', 'But the object is still live');
  75
  76 $art->insert;
  77
  78 ok($art->in_storage, "Re-created");
  79
  80 @art = $schema->resultset("Artist")->search({ });
  81
  82 is(@art, 3, 'And now there are three again');
  83
  84 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  85
  86 is($new->artistid, 4, 'Create produced record ok');
  87
  88 @art = $schema->resultset("Artist")->search({ });
  89
  90 is(@art, 4, "Oh my god! There's four of them!");
  91
  92 $new->set_column('name' => 'Man With A Fork');
  93
  94 is($new->name, 'Man With A Fork', 'set_column ok');
  95
  96 $new->discard_changes;
  97
  98 ok(!defined $new->name, 'Discard ok');
  99
 100 $new->name('Man With A Spoon');
 101
 102 $new->update;
 103
 104 my $new_again = $schema->resultset("Artist")->find(4);
 105
 106 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 107
 108 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 109
 110 # test that store_column is called once for create() for non sequence columns
 111 {
 112   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 113   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 114
 115   # call store_column even though the column doesn't seem to be dirty
 116   $artist->name($artist->name);
 117   is($artist->name, 'X X store_column test');
 118   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 119
 120   $artist->delete;
 121 }
 122
 123 # deprecation of rolled-out search
 124 warnings_exist {
 125   $schema->resultset('Artist')->search_rs(id => 4)
 126 } qr/\Qsearch( %condition ) is deprecated/, 'Deprecation warning on ->search( %condition )';
 127
 128 is($schema->resultset("Artist")->count, 4, 'count ok');
 129
 130
 131 # test find_or_new
 132 {
 133   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 134     artistid => 4,
 135   });
 136
 137   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 138   ok($existing_obj->in_storage, 'existing artist is in storage');
 139
 140   my $new_obj = $schema->resultset('Artist')->find_or_new({
 141     artistid => 5,
 142     name     => 'find_or_new',
 143   });
 144
 145   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 146   is($new_obj->in_storage, 0, 'new artist is not in storage');
 147 }
 148
 149 my $cd = $schema->resultset("CD")->find(1);
 150 my %cols = $cd->get_columns;
 151
 152 is(keys %cols, 6, 'get_columns number of columns ok');
 153
 154 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 155
 156 %cols = ( title => 'Forkful of bees', year => 2005);
 157 $cd->set_columns(\%cols);
 158
 159 is($cd->title, 'Forkful of bees', 'set_columns ok');
 160
 161 is($cd->year, 2005, 'set_columns ok');
 162
 163 $cd->discard_changes;
 164
 165 # check whether ResultSource->columns returns columns in order originally supplied
 166 my @cd = $schema->source("CD")->columns;
 167
 168 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 169
 170 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 171 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 172
 173 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 174
 175 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 176 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 177
 178 # check if new syntax +columns also works for this
 179 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 180
 181 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 182 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 183
 184 # check if new syntax for +columns select specifiers works for this
 185 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 186
 187 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 188 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 189
 190 # update_or_insert
 191 $new = $schema->resultset("Track")->new( {
 192   trackid => 100,
 193   cd => 1,
 194   title => 'Insert or Update',
 195   last_updated_on => '1973-07-19 12:01:02'
 196 } );
 197 $new->update_or_insert;
 198 ok($new->in_storage, 'update_or_insert insert ok');
 199
 200 throws_ok (sub {
 201   $schema->class("Track")->load_components('DoesNotExist');
 202 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 203
 204 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 205
 206 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 207
 208 my $or_rs = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 209                                                   order_by => 'cdid' });
 210 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 211 is($or_rs->count, 5, 'Search count with OR ok');
 212
 213 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 214 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 215 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 216
 217 # make sure sure distinct on a grouped rs is warned about
 218 {
 219   my $cd_rs = $schema->resultset ('CD')
 220                 ->search ({}, { distinct => 1, group_by => 'title' });
 221   warnings_exist (sub {
 222     $cd_rs->next;
 223   }, qr/Useless use of distinct/, 'UUoD warning');
 224 }
 225
 226 {
 227   my $tcount = $schema->resultset('Track')->search(
 228     {},
 229     {
 230       select => [ qw/position title/ ],
 231       distinct => 1,
 232     }
 233   );
 234   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 235
 236   $tcount = $schema->resultset('Track')->search(
 237     {},
 238     {
 239       columns => [ qw/position title/ ],
 240       distinct => 1,
 241     }
 242   );
 243   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 244
 245   $tcount = $schema->resultset('Track')->search(
 246     {},
 247     {
 248        group_by => [ qw/position title/ ]
 249     }
 250   );
 251   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 252 }
 253
 254 my $tag_rs = $schema->resultset('Tag')->search(
 255                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 256
 257 my $rel_rs = $tag_rs->search_related('cd', {}, { order_by => 'cd.cdid'} );
 258
 259 is($rel_rs->count, 5, 'Related search ok');
 260
 261 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 262 $or_rs->reset;
 263 $rel_rs->reset;
 264
 265 # at this point there should be no active statements
 266 # (finish() was called everywhere, either explicitly via
 267 # reset() or on DESTROY)
 268 for (keys %{$schema->storage->dbh->{CachedKids}}) {
 269   fail("Unreachable cached statement still active: $_")
 270     if $schema->storage->dbh->{CachedKids}{$_}->FETCH('Active');
 271 }
 272
 273 my $tag = $schema->resultset('Tag')->search(
 274   [ { 'me.tag' => 'Blue' } ],
 275   { columns => 'tagid' }
 276 )->next;
 277
 278 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 279 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 280
 281 ok($schema->storage(), 'Storage available');
 282
 283 {
 284   my $rs = $schema->resultset("Artist")->search({
 285     -and => [
 286       artistid => { '>=', 1 },
 287       artistid => { '<', 3 }
 288     ]
 289   });
 290
 291   $rs->update({ rank => 6134 });
 292
 293   my $art;
 294
 295   $art = $schema->resultset("Artist")->find(1);
 296   is($art->rank, 6134, 'updated first artist rank');
 297
 298   $art = $schema->resultset("Artist")->find(2);
 299   is($art->rank, 6134, 'updated second artist rank');
 300 }
 301
 302 # test source_name
 303 {
 304   # source_name should be set for normal modules
 305   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 306
 307   # test the result source that sets source_name explictly
 308   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 309
 310   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 311   is(@artsn, 4, "Four artists returned");
 312
 313   # make sure subclasses that don't set source_name are ok
 314   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 315 }
 316
 317 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 318
 319 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 320
 321 # test cascade_delete through many_to_many relations
 322 {
 323   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 324   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 325   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 326   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 327 }
 328
 329 # test column_info
 330 {
 331   $schema->source("Artist")->{_columns}{'artistid'} = {};
 332   $schema->source("Artist")->column_info_from_storage(1);
 333
 334   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 335   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 336   $schema->source("Artist")->column_info('artistid');
 337   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 338 }
 339
 340 # test columns_info
 341 {
 342   $schema->source("Artist")->{_columns}{'artistid'} = {};
 343   $schema->source("Artist")->column_info_from_storage(1);
 344   $schema->source("Artist")->{_columns_info_loaded} = 0;
 345
 346   my @undef_default = DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
 347     ? ()
 348     : ( default_value => undef )
 349   ;
 350
 351   is_deeply (
 352     $schema->source('Artist')->columns_info,
 353     {
 354       artistid => {
 355         data_type => "INTEGER",
 356         @undef_default,
 357         is_nullable => 0,
 358         size => undef
 359       },
 360       charfield => {
 361         data_type => "char",
 362         @undef_default,
 363         is_nullable => 1,
 364         size => 10
 365       },
 366       name => {
 367         data_type => "varchar",
 368         @undef_default,
 369         is_nullable => 1,
 370         is_numeric => 0,
 371         size => 100
 372       },
 373       rank => {
 374         data_type => "integer",
 375         default_value => 13,
 376         is_nullable => 0,
 377         size => undef
 378       },
 379     },
 380     'columns_info works',
 381   );
 382
 383   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 384
 385   is_deeply (
 386     $schema->source('Artist')->columns_info([qw/artistid rank/]),
 387     {
 388       artistid => {
 389         data_type => "INTEGER",
 390         @undef_default,
 391         is_nullable => 0,
 392         size => undef
 393       },
 394       rank => {
 395         data_type => "integer",
 396         default_value => 13,
 397         is_nullable => 0,
 398         size => undef
 399       },
 400     },
 401     'limited columns_info works',
 402   );
 403 }
 404
 405 # test source_info
 406 {
 407   my $expected = {
 408     "source_info_key_A" => "source_info_value_A",
 409     "source_info_key_B" => "source_info_value_B",
 410     "source_info_key_C" => "source_info_value_C",
 411   };
 412
 413   my $sinfo = $schema->source("Artist")->source_info;
 414
 415   is_deeply($sinfo, $expected, 'source_info data works');
 416 }
 417
 418 # test remove_columns
 419 {
 420   is_deeply(
 421     [$schema->source('CD')->columns],
 422     [qw/cdid artist title year genreid single_track/],
 423     'initial columns',
 424   );
 425
 426   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 427   is_deeply(
 428     [$schema->source('CD')->columns],
 429     [qw/cdid artist title year genreid single_track/],
 430     'nothing removed when removing a non-existent column',
 431   );
 432
 433   $schema->source('CD')->remove_columns('genreid', 'year');
 434   is_deeply(
 435     [$schema->source('CD')->columns],
 436     [qw/cdid artist title single_track/],
 437     'removed two columns',
 438   );
 439
 440   my $priv_columns = $schema->source('CD')->_columns;
 441   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 442   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 443 }
 444
 445 # test resultsource->table return value when setting
 446 {
 447     my $class = $schema->class('Event');
 448     my $table = $class->table($class->table);
 449     is($table, $class->table, '->table($table) returns $table');
 450 }
 451
 452 #make sure insert doesn't use set_column
 453 {
 454   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 455   is($en_row->encoded, 'amliw', 'new encodes');
 456   $en_row->insert;
 457   is($en_row->encoded, 'amliw', 'insert does not encode again');
 458 }
 459
 460 #make sure multicreate encoding still works
 461 {
 462   my $empl_rs = $schema->resultset('Employee');
 463
 464   my $empl = $empl_rs->create ({
 465     name => 'Secret holder',
 466     secretkey => {
 467       encoded => 'CAN HAZ',
 468     },
 469   });
 470   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 471
 472   my $empl2 = $empl_rs->create ({
 473     name => 'Same secret holder',
 474     secretkey => {
 475       encoded => 'CAN HAZ',
 476     },
 477   });
 478   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 479
 480   $empl_rs->create ({
 481     name => 'cat1',
 482     secretkey => {
 483       encoded => 'CHEEZBURGER',
 484       keyholders => [
 485         {
 486           name => 'cat2',
 487         },
 488         {
 489           name => 'cat3',
 490         },
 491       ],
 492     },
 493   });
 494
 495   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 496   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 497   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 498
 499 }
 500
 501 # make sure that obsolete handle-based source tracking continues to work for the time being
 502 {
 503   my $handle = $schema->source('Artist')->handle;
 504
 505   my $rowdata = { $schema->resultset('Artist')->next->get_columns };
 506
 507   my $rs = DBIx::Class::ResultSet->new($handle);
 508   my $rs_result = $rs->next;
 509   isa_ok( $rs_result, 'DBICTest::Artist' );
 510   is_deeply (
 511     { $rs_result->get_columns },
 512     $rowdata,
 513     'Correct columns retrieved (rset/source link healthy)'
 514   );
 515
 516   my $row = DBICTest::Artist->new({ -source_handle => $handle });
 517   is_deeply(
 518     { $row->get_columns },
 519     {},
 520     'No columns yet'
 521   );
 522
 523   # store_column to fool the _orig_ident tracker
 524   $row->store_column('artistid', $rowdata->{artistid});
 525   $row->in_storage(1);
 526
 527   $row->discard_changes;
 528   is_deeply(
 529     { $row->get_columns },
 530     $rowdata,
 531     'Storage refetch successful'
 532   );
 533 }
 534
 535 # test to make sure that calling ->new() on a resultset object gives
 536 # us a row object
 537 {
 538     my $new_artist = $schema->resultset('Artist')->new({});
 539     isa_ok( $new_artist, 'DBIx::Class::Row', '$rs->new gives a row object' );
 540 }
 541
 542
 543 # make sure we got rid of the compat shims
 544 SKIP: {
 545     my $remove_version = 0.083;
 546     skip "Remove in $remove_version", 3 if $DBIx::Class::VERSION < $remove_version;
 547
 548     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 549       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource, removed before $remove_version");
 550     }
 551 }
 552
 553 #------------------------------
 554 # READ THIS BEFORE "FIXING"
 555 #------------------------------
 556 #
 557 # make sure we got rid of discard_changes mess - this is a mess and a source
 558 # of great confusion. Here I simply die if the methods are available, which
 559 # is wrong on its own (we *have* to provide some sort of back-compat, even
 560 # if with warnings). Here is how I envision things should actually be. Also
 561 # note that a lot of the deprecation can be started today (i.e. the switch
 562 # from get_from_storage to copy_from_storage). So:
 563 #
 564 # $row->discard_changes =>
 565 #   warning, and delegation to reload_from_storage
 566 #
 567 # $row->reload_from_storage =>
 568 #   does what discard changes did in 0.08 - issues a query to the db
 569 #   and repopulates all column slots, regardless of dirty states etc.
 570 #
 571 # $row->revert_changes =>
 572 #   does what discard_changes should have done initially (before it became
 573 #   a dual-purpose call). In order to make this work we will have to
 574 #   augment $row to carry its own initial-state, much like svn has a
 575 #   copy of the current checkout in contrast to cvs.
 576 #
 577 # my $db_row = $row->get_from_storage =>
 578 #   warns and delegates to an improved name copy_from_storage, with the
 579 #   same semantics
 580 #
 581 # my $db_row = $row->copy_from_storage =>
 582 #   a much better/descriptive name than get_from_storage
 583 #
 584 #------------------------------
 585 # READ THIS BEFORE "FIXING"
 586 #------------------------------
 587 #
 588 SKIP: {
 589     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 590
 591     my $row = $schema->resultset ('Artist')->next;
 592
 593     for (qw/discard_changes get_from_storage/) {
 594       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 595     }
 596 }
 597
 598 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 599
 600 throws_ok { $schema->source('Artist')->result_class->new( 'bugger' ) } qr/must be a hashref/;
 601
 602 done_testing;