t/55namespaces_cleaned.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5
   6 use File::Find;
   7 use File::Spec;
   8 use B qw/svref_2object/;
   9
  10 # makes sure we can load at least something
  11 use DBIx::Class;
  12
  13 my @modules = grep {
  14   my $mod = $_;
  15
  16   # trap deprecation warnings and whatnot
  17   local $SIG{__WARN__} = sub {};
  18
  19   # not all modules are loadable at all times
  20   eval "require $mod" ? $mod : do {
  21     SKIP: { skip "Failed require of $mod: $@", 1 }A
  22     ();
  23   };
  24
  25
  26 } find_modules();
  27
  28 # have an exception table for old and/or weird code we are not sure
  29 # we *want* to clean in the first place
  30 my $skip_idx = { map { $_ => 1 } (
  31   (grep { /^DBIx::Class::CDBICompat/ } @modules), # too crufty to touch
  32   'SQL::Translator::Producer::DBIx::Class::File', # ditto
  33
  34   # not sure how to handle type libraries
  35   'DBIx::Class::Storage::DBI::Replicated::Types',
  36   'DBIx::Class::Admin::Types',
  37
  38   # G::L::D is unclean, but we never inherit from it
  39   'DBIx::Class::Admin::Descriptive',
  40   'DBIx::Class::Admin::Usage',
  41 ) };
  42
  43 my $has_cmop = eval { require Class::MOP };
  44
  45 # can't use Class::Inspector for the mundane parts as it does not
  46 # distinguish imports from anything else, what a crock of...
  47 # Class::MOP is not always available either - hence just do it ourselves
  48
  49 my $seen; #inheritance means we will see the same method multiple times
  50
  51 for my $mod (@modules) {
  52   SKIP: {
  53     skip "$mod exempt from namespace checks",1 if $skip_idx->{$mod};
  54
  55     my %all_method_like = do {
  56       no strict 'refs';
  57       map {
  58         my $m = $_;
  59         map
  60           { *{"${m}::$_"}{CODE} ? ( $_ => *{"${m}::$_"}{CODE} ) : () }
  61           keys %{"${m}::"}
  62       } (reverse @{mro::get_linear_isa($mod)});
  63     };
  64
  65     my %parents = map { $_ => 1 } @{mro::get_linear_isa($mod)};
  66
  67     my %roles;
  68     if ($has_cmop and my $mc = Class::MOP::class_of($mod)) {
  69       if ($mc->can('calculate_all_roles_with_inheritance')) {
  70         $roles{$_->name} = 1 for ($mc->calculate_all_roles_with_inheritance);
  71       }
  72     }
  73
  74     for my $name (keys %all_method_like) {
  75
  76       # overload is a funky thing - it is neither cleaned, and its imports are named funny
  77       next if $name =~ /^\(/;
  78
  79       my $gv = svref_2object($all_method_like{$name})->GV;
  80       my $origin = $gv->STASH->NAME;
  81
  82       next if $seen->{"${origin}:${name}"}++;
  83
  84       TODO: {
  85         local $TODO = 'CAG does not clean its BEGIN constants' if $name =~ /^__CAG_/;
  86         is ($gv->NAME, $name, "Properly named $name method at $origin");
  87       }
  88
  89       if ($origin eq $mod) {
  90         pass ("$name is a native $mod method");
  91       }
  92       elsif ($roles{$origin}) {
  93         pass ("${mod}::${name} came from consumption of role $origin");
  94       }
  95       elsif ($parents{$origin}) {
  96         pass ("${mod}::${name} came from proper parent-class $origin");
  97       }
  98       else {
  99         my $via;
 100         for (reverse @{mro::get_linear_isa($mod)} ) {
 101           if ( ($_->can($name)||'') eq $all_method_like{$name} ) {
 102             $via = $_;
 103             last;
 104           }
 105         }
 106         fail ("${mod}::${name} appears to have entered inheritance chain by import into "
 107             . ($via || 'UNKNOWN')
 108         );
 109       }
 110     }
 111   }
 112 }
 113
 114 sub find_modules {
 115   my @modules;
 116
 117   find({
 118     wanted => sub {
 119       -f $_ or return;
 120       s/\.pm$// or return;
 121       s/^ (?: lib | blib . (?:lib|arch) ) . //x;
 122       push @modules, join ('::', File::Spec->splitdir($_));
 123     },
 124     no_chdir => 1,
 125   }, (-e 'blib' ? 'blib' : 'lib') );
 126
 127   return sort @modules;
 128 }
 129
 130
 131 done_testing;