t/55namespaces_cleaned.t

   1 BEGIN {
   2   if ($] < 5.010) {
   3
   4     # Pre-5.10 perls pollute %INC on unsuccesfull module
   5     # require, making it appear as if the module is already
   6     # loaded on subsequent require()s
   7     # Can't seem to find the exact RT/perldelta entry
   8     #
   9     # The reason we can't just use a sane, clean loader, is because
  10     # if a Module require()s another module the %INC will still
  11     # get filled with crap and we are back to square one. A global
  12     # fix is really the only way for this test, as we try to load
  13     # each available module separately, and have no control (nor
  14     # knowledge) over their common dependencies.
  15     #
  16     # we want to do this here, in the very beginning, before even
  17     # warnings/strict are loaded
  18
  19     unshift @INC, 't/lib';
  20     require DBICTest::Util::OverrideRequire;
  21
  22     DBICTest::Util::OverrideRequire::override_global_require( sub {
  23       my $res = eval { $_[0]->() };
  24       if ($@ ne '') {
  25         delete $INC{$_[1]};
  26         die $@;
  27       }
  28       return $res;
  29     } );
  30   }
  31 }
  32
  33 use strict;
  34 use warnings;
  35
  36 use Test::More;
  37
  38 use lib 't/lib';
  39
  40 BEGIN {
  41   require DBICTest::RunMode;
  42   plan( skip_all => "Skipping test on plain module install" )
  43     if DBICTest::RunMode->is_plain;
  44 }
  45
  46 use DBICTest;
  47 use File::Find;
  48 use File::Spec;
  49 use B qw/svref_2object/;
  50 use Package::Stash;
  51
  52 # makes sure we can load at least something
  53 use DBIx::Class;
  54 use DBIx::Class::Carp;
  55
  56 my @modules = grep {
  57   my ($mod) = $_ =~ /(.+)/;
  58
  59   # not all modules are loadable at all times
  60   do {
  61     # trap deprecation warnings and whatnot
  62     local $SIG{__WARN__} = sub {};
  63     eval "require $mod";
  64   } ? $mod : do {
  65     SKIP: { skip "Failed require of $mod: " . ($@ =~ /^(.+?)$/m)[0], 1 };
  66     (); # empty RV for @modules
  67   };
  68
  69 } find_modules();
  70
  71 # have an exception table for old and/or weird code we are not sure
  72 # we *want* to clean in the first place
  73 my $skip_idx = { map { $_ => 1 } (
  74   (grep { /^DBIx::Class::CDBICompat/ } @modules), # too crufty to touch
  75   'SQL::Translator::Producer::DBIx::Class::File', # ditto
  76
  77   # not sure how to handle type libraries
  78   'DBIx::Class::Storage::DBI::Replicated::Types',
  79   'DBIx::Class::Admin::Types',
  80
  81   # G::L::D is unclean, but we never inherit from it
  82   'DBIx::Class::Admin::Descriptive',
  83   'DBIx::Class::Admin::Usage',
  84
  85   # this subclass is expected to inherit whatever crap comes
  86   # from the parent
  87   'DBIx::Class::ResultSet::Pager',
  88
  89   # utility classes, not part of the inheritance chain
  90   'DBIx::Class::ResultSource::RowParser::Util',
  91   'DBIx::Class::_Util',
  92 ) };
  93
  94 my $has_moose = eval { require Moose::Util };
  95
  96 Sub::Defer::undefer_all();
  97
  98 # can't use Class::Inspector for the mundane parts as it does not
  99 # distinguish imports from anything else, what a crock of...
 100 # Moose is not always available either - hence just do it ourselves
 101
 102 my $seen; #inheritance means we will see the same method multiple times
 103
 104 for my $mod (@modules) {
 105   SKIP: {
 106     skip "$mod exempt from namespace checks",1 if $skip_idx->{$mod};
 107
 108     my %all_method_like = (map
 109       { %{Package::Stash->new($_)->get_all_symbols('CODE')} }
 110       (reverse @{mro::get_linear_isa($mod)})
 111     );
 112
 113     my %parents = map { $_ => 1 } @{mro::get_linear_isa($mod)};
 114
 115     my %roles;
 116     if ($has_moose and my $mc = Moose::Util::find_meta($mod)) {
 117       if ($mc->can('calculate_all_roles_with_inheritance')) {
 118         $roles{$_->name} = 1 for ($mc->calculate_all_roles_with_inheritance);
 119       }
 120     }
 121
 122     for my $name (keys %all_method_like) {
 123
 124       # overload is a funky thing - it is not cleaned, and its imports are named funny
 125       next if $name =~ /^\(/;
 126
 127       my $gv = svref_2object($all_method_like{$name})->GV;
 128       my $origin = $gv->STASH->NAME;
 129
 130       is ($gv->NAME, $name, "Properly named $name method at $origin" . ($origin eq $mod
 131         ? ''
 132         : " (inherited by $mod)"
 133       ));
 134
 135       next if $seen->{"${origin}:${name}"}++;
 136
 137       if ($origin eq $mod) {
 138         pass ("$name is a native $mod method");
 139       }
 140       elsif ($roles{$origin}) {
 141         pass ("${mod}::${name} came from consumption of role $origin");
 142       }
 143       elsif ($parents{$origin}) {
 144         pass ("${mod}::${name} came from proper parent-class $origin");
 145       }
 146       else {
 147         my $via;
 148         for (reverse @{mro::get_linear_isa($mod)} ) {
 149           if ( ($_->can($name)||'') eq $all_method_like{$name} ) {
 150             $via = $_;
 151             last;
 152           }
 153         }
 154
 155         # exception time
 156         if (
 157           ( $name eq 'import' and $via = 'Exporter' )
 158         ) {
 159           pass("${mod}::${name} is a valid uncleaned import from ${name}");
 160         }
 161         else {
 162           fail ("${mod}::${name} appears to have entered inheritance chain by import into "
 163               . ($via || 'UNKNOWN')
 164           );
 165         }
 166       }
 167     }
 168
 169     # some common import names (these should never ever be methods)
 170     for my $f (qw/carp carp_once carp_unique croak confess cluck try catch finally/) {
 171       if ($mod->can($f)) {
 172         my $via;
 173         for (reverse @{mro::get_linear_isa($mod)} ) {
 174           if ( ($_->can($f)||'') eq $all_method_like{$f} ) {
 175             $via = $_;
 176             last;
 177           }
 178         }
 179         fail ("Import $f leaked into method list of ${mod}, appears to have entered inheritance chain at "
 180             . ($via || 'UNKNOWN')
 181         );
 182       }
 183       else {
 184         pass ("Import $f not leaked into method list of $mod");
 185       }
 186     }
 187   }
 188 }
 189
 190 sub find_modules {
 191   my @modules;
 192
 193   find( {
 194     wanted => sub {
 195       -f $_ or return;
 196       s/\.pm$// or return;
 197       s/^ (?: lib | blib . (?:lib|arch) ) . //x;
 198       push @modules, join ('::', File::Spec->splitdir($_));
 199     },
 200     no_chdir => 1,
 201   }, (
 202     # find them in both lib and blib, duplicates are fine, since
 203     # @INC is preadjusted for us by the harness
 204     'lib',
 205     ( -e 'blib' ? 'blib' : () ),
 206   ));
 207
 208   return sort @modules;
 209 }
 210
 211 done_testing;