t/53lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3
   4 my ($initial_inc_contents, $expected_dbic_deps, $require_sites);
   5 BEGIN {
   6   # these envvars *will* bring in more stuff than the baseline
   7   delete @ENV{qw(DBICTEST_SQLT_DEPLOY DBIC_TRACE)};
   8
   9   # make sure extras do not load even when this is set
  10   $ENV{PERL_STRICTURES_EXTRA} = 1;
  11
  12   unshift @INC, 't/lib';
  13   require DBICTest::Util::OverrideRequire;
  14
  15   DBICTest::Util::OverrideRequire::override_global_require( sub {
  16     my $res = $_[0]->();
  17
  18     my $req = $_[1];
  19     $req =~ s/\.pm$//;
  20     $req =~ s/\//::/g;
  21
  22     my $up = 0;
  23     my @caller;
  24     do { @caller = caller($up++) } while (
  25       @caller and (
  26         # exclude our test suite, known "module require-rs" and eval frames
  27         $caller[1] =~ /^ t [\/\\] /x
  28           or
  29         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  30           or
  31         $caller[3] eq '(eval)',
  32       )
  33     );
  34
  35     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  36       if @caller;
  37
  38     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  39
  40     # exclude everything where the current namespace does not match the called function
  41     # (this works around very weird XS-induced require callstack corruption)
  42     if (
  43       !$initial_inc_contents->{$req}
  44         and
  45       !$expected_dbic_deps->{$req}
  46         and
  47       @caller
  48         and
  49       $caller[0] =~ /^DBIx::Class/
  50         and
  51       (caller($up))[3] =~ /\Q$caller[0]/
  52     ) {
  53       CORE::require('Test/More.pm');
  54       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  55
  56       if ( $ENV{TEST_VERBOSE} or ! DBICTest::RunMode->is_plain ) {
  57         CORE::require('DBICTest/Util.pm');
  58         Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  59       }
  60     }
  61
  62     return $res;
  63   });
  64 }
  65
  66 use strict;
  67 use warnings;
  68 use Test::More;
  69
  70 BEGIN {
  71   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  72     if $ENV{PERL5OPT};
  73
  74   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  75     if $] < 5.010;
  76
  77   # add what we loaded so far
  78   for (keys %INC) {
  79     my $mod = $_;
  80     $mod =~ s/\.pm$//;
  81     $mod =~ s!\/!::!g;
  82     $initial_inc_contents->{$mod} = 1;
  83   }
  84 }
  85
  86 #######
  87 ### This is where the test starts
  88 #######
  89
  90 # checking base schema load, no storage no connection
  91 {
  92   register_lazy_loadable_requires(qw(
  93     B
  94     constant
  95     overload
  96
  97     base
  98     Devel::GlobalDestruction
  99     mro
 100
 101     Carp
 102     namespace::clean
 103     Try::Tiny
 104     Sub::Name
 105     strictures
 106     Sub::Defer
 107     Sub::Quote
 108
 109     Scalar::Util
 110     List::Util
 111
 112     Class::Accessor::Grouped
 113     Class::C3::Componentised
 114     SQL::Abstract
 115
 116     Module::Runtime
 117     File::Spec
 118   ));
 119
 120   require DBICTest::Schema;
 121   assert_no_missing_expected_requires();
 122 }
 123
 124 # check schema/storage instantiation with no connect
 125 {
 126   register_lazy_loadable_requires(qw(
 127     Moo
 128     Moo::Object
 129     Method::Generate::Accessor
 130     Method::Generate::Constructor
 131     Context::Preserve
 132   ));
 133
 134   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 135   ok (! $s->storage->connected, 'no connection');
 136   assert_no_missing_expected_requires();
 137 }
 138
 139 # do something (deploy, insert)
 140 {
 141   register_lazy_loadable_requires(qw(
 142     DBI
 143     Hash::Merge
 144   ));
 145
 146   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 147   $s->storage->dbh_do(sub {
 148     $_[1]->do('CREATE TABLE artist (
 149       "artistid" INTEGER PRIMARY KEY NOT NULL,
 150       "name" varchar(100),
 151       "rank" integer NOT NULL DEFAULT 13,
 152       "charfield" char(10)
 153     )');
 154   });
 155
 156   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 157   $art->discard_changes;
 158   $art->update({ rank => 69, name => 'foo' });
 159   assert_no_missing_expected_requires();
 160 }
 161
 162 # and do full populate() as well, just in case - shouldn't add new stuff
 163 {
 164   local $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 165   {
 166     # in general we do not want DBICTest to load before sqla, but it is
 167     # ok to cheat here
 168     local $INC{'SQL/Abstract.pm'};
 169     require DBICTest;
 170   }
 171   my $s = DBICTest->init_schema;
 172   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae');
 173   assert_no_missing_expected_requires();
 174 }
 175
 176 # make sure we never loaded any of the strictures XS bullshit
 177 {
 178   ok( ! exists $INC{ Module::Runtime::module_notional_filename($_) }, "$_ load never attempted" )
 179     for qw(indirect multidimensional bareword::filehandles);
 180 }
 181
 182 done_testing;
 183
 184 sub register_lazy_loadable_requires {
 185   local $Test::Builder::Level = $Test::Builder::Level + 1;
 186
 187   for my $mod (@_) {
 188     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 189     fail(join "\n",
 190       "Module $mod already loaded by require site(s):",
 191       (map { "\t$_" } @{$require_sites->{$mod}}),
 192       '',
 193     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 194
 195     $expected_dbic_deps->{$mod}++
 196   }
 197 }
 198
 199 # check if anything we were expecting didn't actually load
 200 sub assert_no_missing_expected_requires {
 201   my $nl;
 202   for my $mod (keys %$expected_dbic_deps) {
 203     (my $modfn = "$mod.pm") =~ s/::/\//g;
 204     unless ($INC{$modfn}) {
 205       my $err = sprintf "Expected DBIC core dependency '%s' never loaded - %s needs adjustment", $mod, __FILE__;
 206       if (DBICTest::RunMode->is_smoker or DBICTest::RunMode->is_author) {
 207         fail ($err)
 208       }
 209       else {
 210         diag "\n" unless $nl->{$mod}++;
 211         diag $err;
 212       }
 213     }
 214   }
 215   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 216     __FILE__,
 217     (caller(0))[2],
 218     join (', ', sort keys %$expected_dbic_deps ),
 219   ) unless $nl;
 220 }