t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 use lib qw(t/lib);
  25 use DBICTest::RunMode;
  26 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  27 use Scalar::Util qw(weaken blessed reftype);
  28 use DBIx::Class::_Util qw(hrefaddr sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt);
  29 BEGIN {
  30   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  31     if DBIx::Class::_ENV_::PEEPEENESS;
  32 }
  33
  34
  35 my $TB = Test::More->builder;
  36 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  37   # without this explicit close TB warns in END after a ->reset
  38   close ($TB->$_) for qw(output failure_output todo_output);
  39
  40   # newer TB does not auto-reopen handles
  41   if ( modver_gt_or_eq( 'Test::More', '1.200' ) ) {
  42     open ($TB->$_, '>&', *STDERR)
  43       for qw( failure_output todo_output );
  44     open ($TB->output, '>&', *STDOUT);
  45   }
  46
  47   # so done_testing can work on every persistent pass
  48   $TB->reset;
  49 }
  50
  51 # this is what holds all weakened refs to be checked for leakage
  52 my $weak_registry = {};
  53
  54 # whether or to invoke IC::DT
  55 my $has_dt;
  56
  57 # Skip the heavy-duty leak tracing when just doing an install
  58 # or when having Moose crap all over everything
  59 if ( !$ENV{DBICTEST_VIA_REPLICATED} and !DBICTest::RunMode->is_plain ) {
  60
  61   # redefine the bless override so that we can catch each and every object created
  62   no warnings qw/redefine once/;
  63   no strict qw/refs/;
  64
  65   $bless_override = sub {
  66
  67     my $obj = CORE::bless(
  68       $_[0], (@_ > 1) ? $_[1] : do {
  69         my ($class, $fn, $line) = caller();
  70         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  71           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  72         $class;
  73       }
  74     );
  75
  76     # unicode is tricky, and now we happen to invoke it early via a
  77     # regex in connection()
  78     return $obj if (ref $obj) =~ /^utf8/;
  79
  80     # Test Builder is now making a new object for every pass/fail (que bloat?)
  81     # and as such we can't really store any of its objects (since it will
  82     # re-populate the registry while checking it, ewwww!)
  83     return $obj if (ref $obj) =~ /^TB2::|^Test::Stream/;
  84
  85     # populate immediately to avoid weird side effects
  86     return populate_weakregistry ($weak_registry, $obj );
  87   };
  88
  89   require Try::Tiny;
  90   for my $func (qw/try catch finally/) {
  91     my $orig = \&{"Try::Tiny::$func"};
  92     *{"Try::Tiny::$func"} = sub (&;@) {
  93       populate_weakregistry( $weak_registry, $_[0] );
  94       goto $orig;
  95     }
  96   }
  97
  98   # Some modules are known to install singletons on-load
  99   # Load them and empty the registry
 100
 101   # this loads the DT armada
 102   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for([qw( test_rdbms_sqlite ic_dt )]);
 103
 104   require Errno;
 105   require DBI;
 106   require DBD::SQLite;
 107   require FileHandle;
 108   require Moo;
 109
 110   %$weak_registry = ();
 111 }
 112
 113 {
 114   use_ok ('DBICTest');
 115
 116   my $schema = DBICTest->init_schema;
 117   my $rs = $schema->resultset ('Artist');
 118   my $storage = $schema->storage;
 119
 120   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 121   ok ($row_obj, 'row from db');
 122
 123   # txn_do to invoke more codepaths
 124   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 125
 126     my $artist = $schema->resultset('Artist')->create ({
 127       name => 'foo artist',
 128       cds => [{
 129         title => 'foo cd',
 130         year => 1984,
 131         tracks => [
 132           { title => 't1' },
 133           { title => 't2' },
 134         ],
 135         genre => { name => 'mauve' },
 136       }],
 137     });
 138
 139     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 140
 141     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 142
 143     return ($artist, $pg, $pg_wcount);
 144   });
 145
 146   # more codepaths - error handling in txn_do
 147   {
 148     eval { $schema->txn_do ( sub {
 149       $storage->_dbh->begin_work;
 150       fail ('how did we get so far?!');
 151     } ) };
 152
 153     eval { $schema->txn_do ( sub {
 154       $schema->txn_do ( sub {
 155         die "It's called EXCEPTION";
 156         fail ('how did we get so far?!');
 157       } );
 158       fail ('how did we get so far?!');
 159     } ) };
 160     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 161   }
 162
 163   # dbh_do codepath
 164   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 165     my $row = $_[0]->schema->resultset('Artist')->new({});
 166     my $rs = $_[0]->schema->resultset('Artist')->search({
 167       name => $row,  # this is deliberately bogus, see FIXME below!
 168     });
 169     return ($rs, $row);
 170   });
 171
 172   is ($pager->next_page, 3, 'There is one more page available');
 173
 174   # based on 66 per 10 pages
 175   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 176
 177   # do some population (invokes some extra codepaths)
 178   # also exercise the guard code and the manual txn control
 179   {
 180     my $guard = $schema->txn_scope_guard;
 181     # populate with bindvars
 182     $rs->populate([{ name => 'James Bound' }]);
 183     $guard->commit;
 184
 185     $schema->txn_begin;
 186     # populate mixed
 187     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 188     $schema->txn_commit;
 189
 190     $schema->txn_begin;
 191     # and without bindvars
 192     $rs->populate([{ name => \ '"James Unbound"' }]);
 193     $schema->txn_rollback;
 194   }
 195
 196   # prefetching
 197   my $cds_rs = $schema->resultset('CD');
 198   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 199   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 200   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 201
 202   # implicit pref
 203   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 204
 205   # get_column
 206   my $getcol_rs = $cds_rs->get_column('me.cdid');
 207   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 208
 209   my $base_collection = {
 210     resultset => $rs,
 211
 212     pref_precursor => $cds_rs,
 213
 214     pref_rs_single => $cds_with_artist,
 215     pref_rs_multi => $cds_with_tracks,
 216     pref_rs_nested => $cds_with_stuff,
 217
 218     pref_rs_implicit => $cds_with_impl_artist,
 219
 220     pref_row_single => $cds_with_artist->next,
 221     pref_row_multi => $cds_with_tracks->next,
 222     pref_row_nested => $cds_with_stuff->next,
 223
 224     # even though this does not leak Storable croaks on it :(((
 225     #pref_row_implicit => $cds_with_impl_artist->next,
 226
 227     get_column_rs_plain => $getcol_rs,
 228     get_column_rs_pref => $pref_getcol_rs,
 229
 230     # twice so that we make sure only one H::M object spawned
 231     chained_resultset => $rs->search_rs ({}, { '+columns' => { foo => 'artistid' } } ),
 232     chained_resultset2 => $rs->search_rs ({}, { '+columns' => { bar => 'artistid' } } ),
 233
 234     row_object => $row_obj,
 235
 236     mc_row_object => $mc_row_obj,
 237
 238     result_source => $rs->result_source,
 239
 240     result_source_handle => $rs->result_source->handle,
 241
 242     pager_explicit_count => $pager_explicit_count,
 243
 244     leaky_resultset => $rs_bind_circref,
 245     leaky_resultset_cond => $cond_rowobj,
 246   };
 247
 248   # fire all resultsets multiple times, once here, more below
 249   # some of these can't find anything (notably leaky_resultset)
 250   my @rsets = grep {
 251     blessed $_
 252       and
 253     (
 254       $_->isa('DBIx::Class::ResultSet')
 255         or
 256       $_->isa('DBIx::Class::ResultSetColumn')
 257     )
 258   } values %$base_collection;
 259
 260
 261   my $fire_resultsets = sub {
 262     local $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS} = 1;
 263     local $SIG{__WARN__} = sigwarn_silencer(
 264       qr/Unable to deflate 'filter'-type relationship 'artist'.+related object primary key not retrieved/
 265     );
 266
 267     map
 268       { $_, (blessed($_) ? { $_->get_columns } : ()) }
 269       map
 270         { $_->all }
 271         @rsets
 272     ;
 273   };
 274
 275   push @{$base_collection->{random_results}}, $fire_resultsets->();
 276
 277   # FIXME - something throws a Storable for a spin if we keep
 278   # the results in-collection. The same problem is seen above,
 279   # swept under the rug back in 0a03206a, damned lazy ribantainer
 280 {
 281   local $base_collection->{random_results};
 282
 283   require Storable;
 284   %$base_collection = (
 285     %$base_collection,
 286     refrozen => Storable::dclone( $base_collection ),
 287     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 288     pref_row_implicit => $cds_with_impl_artist->next,
 289     schema => $schema,
 290     storage => $storage,
 291     sql_maker => $storage->sql_maker,
 292     dbh => $storage->_dbh,
 293     fresh_pager => $rs->page(5)->pager,
 294     pager => $pager,
 295   );
 296 }
 297
 298   # FIXME - ideally this kind of collector ought to be global, but attempts
 299   # with an invasive debugger-based tracer did not quite work out... yet
 300   # Manually scan the innards of everything we have in the base collection
 301   # we assembled so far (skip the DT madness below) *recursively*
 302   #
 303   # Only do this when we do have the bits to look inside CVs properly,
 304   # without it we are liable to pick up object defaults that are locked
 305   # in method closures
 306   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 307     visit_refs(
 308       refs => [ $base_collection ],
 309       action => sub {
 310         populate_weakregistry ($weak_registry, $_[0]);
 311         1;  # true means "keep descending"
 312       },
 313     );
 314
 315     # do a heavy-duty fire-and-compare loop on all resultsets
 316     # this is expensive - not running on install
 317     my $typecounts = {};
 318     if (
 319       ! DBICTest::RunMode->is_plain
 320         and
 321       ! $ENV{DBICTEST_IN_PERSISTENT_ENV}
 322     ) {
 323
 324       # FIXME - ideally we should be able to just populate an alternative
 325       # registry, subtract everything from the main one, and arrive at
 326       # an "empty" resulting hash
 327       # However due to gross inefficiencies in the ::ResultSet code we
 328       # end up recalculating a new set of aliasmaps which could have very
 329       # well been cached if it wasn't for... anyhow
 330       # What we do here for the time being is similar to the lazy approach
 331       # of Devel::LeakTrace - we just make sure we do not end up with more
 332       # reftypes than when we started. At least we are not blanket-counting
 333       # SVs like D::LT does, but going by reftype... sigh...
 334
 335       for (values %$weak_registry) {
 336         if ( my $r = reftype($_->{weakref}) ) {
 337           $typecounts->{$r}--;
 338         }
 339       }
 340
 341       # For now we can only reuse the same registry, see FIXME above/below
 342       #for my $interim_wr ({}, {}) {
 343       for my $interim_wr ( ($weak_registry) x 4 ) {
 344
 345         visit_refs(
 346           refs => [ $fire_resultsets->(), @rsets ],
 347           action => sub {
 348             populate_weakregistry ($interim_wr, $_[0]);
 349             1;  # true means "keep descending"
 350           },
 351         );
 352
 353         # FIXME - this is what *should* be here
 354         #
 355         ## anything we have seen so far is cool
 356         #delete @{$interim_wr}{keys %$weak_registry};
 357         #
 358         ## moment of truth - the rest ought to be gone
 359         #assert_empty_weakregistry($interim_wr);
 360       }
 361
 362       for (values %$weak_registry) {
 363         if ( my $r = reftype($_->{weakref}) ) {
 364           $typecounts->{$r}++;
 365         }
 366       }
 367     }
 368
 369     for (keys %$typecounts) {
 370       fail ("Amount of $_ refs changed by $typecounts->{$_} during resultset mass-execution")
 371         if ( abs ($typecounts->{$_}) > 1 ); # there is a pad caught somewhere, the +1/-1 can be ignored
 372     }
 373   }
 374
 375   if ($has_dt) {
 376     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 377
 378     my $now = DateTime->now;
 379     for (1..5) {
 380       $base_collection->{"icdt_row_$_"} = $rs->create({
 381         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 382         starts_at => $now->clone->add(days => $_),
 383       });
 384     }
 385
 386     # re-search
 387     my @dummy = $rs->all;
 388   }
 389
 390   # dbh's are created in XS space, so pull them separately
 391   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 392     $base_collection->{"DBI handle $_"} = $_;
 393   }
 394
 395   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 396     for keys %$base_collection;
 397 }
 398
 399 # check that "phantom-chaining" works - we never lose track of the original $schema
 400 # and have access to the entire tree without leaking anything
 401 {
 402   my $phantom;
 403   for (
 404     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 405     sub { shift->source('Artist') },
 406     sub { shift->resultset },
 407     sub { shift->result_source },
 408     sub { shift->schema },
 409     sub { shift->resultset('Artist') },
 410     sub { shift->find_or_create({ name => 'detachable' }) },
 411     sub { shift->result_source },
 412     sub { shift->schema },
 413     sub { shift->clone },
 414     sub { shift->resultset('CD') },
 415     sub { shift->next },
 416     sub { shift->artist },
 417     sub { shift->search_related('cds') },
 418     sub { shift->next },
 419     sub { shift->search_related('artist') },
 420     sub { shift->result_source },
 421     sub { shift->resultset },
 422     sub { shift->create({ name => 'detached' }) },
 423     sub { shift->update({ name => 'reattached' }) },
 424     sub { shift->discard_changes },
 425     sub { shift->delete },
 426     sub { shift->insert },
 427   ) {
 428     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 429   }
 430
 431   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 432   is( $phantom->name, 'reattached', 'Still correct name' );
 433 }
 434
 435 # Naturally we have some exceptions
 436 my $cleared;
 437 for my $addr (keys %$weak_registry) {
 438   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 439
 440   if ($names =~ /^Test::Builder/m) {
 441     # T::B 2.0 has result objects and other fancyness
 442     delete $weak_registry->{$addr};
 443   }
 444   elsif ($names =~ /^Hash::Merge/m) {
 445     # only clear one object of a specific behavior - more would indicate trouble
 446     delete $weak_registry->{$addr}
 447       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 448   }
 449   elsif ($names =~ /^DateTime::TimeZone::UTC/m) {
 450     # DT is going through a refactor it seems - let it leak zones for now
 451     delete $weak_registry->{$addr};
 452   }
 453   elsif (
 454 #    # if we can look at closed over pieces - we will register it as a global
 455 #    !DBICTest::Util::LeakTracer::CV_TRACING
 456 #      and
 457     $names =~ /^SQL::Translator::Generator::DDL::SQLite/m
 458   ) {
 459     # SQLT::Producer::SQLite keeps global generators around for quoted
 460     # and non-quoted DDL, allow one for each quoting style
 461     delete $weak_registry->{$addr}
 462       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$addr}{weakref}->quote_chars}}++;
 463   }
 464 }
 465
 466 # FIXME !!!
 467 # There is an actual strong circular reference taking place here, but because
 468 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 469 # (our tracker does not yet do it, but it'd be nice)
 470 # The problem is:
 471 #
 472 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 473 #          ^                                                           /
 474 #           \-------- bound value on prepared/cached STH  <-----------/
 475 #
 476 {
 477   my @circreffed;
 478
 479   for my $r (map
 480     { $_->{weakref} }
 481     grep
 482       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 483       values %$weak_registry
 484   ) {
 485     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 486     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 487       or push @circreffed, $r;
 488   }
 489
 490   if (@circreffed) {
 491     is (scalar @circreffed, 1, 'One resultset expected to leak');
 492
 493     # this is useless on its own, it is to showcase the circref-diag
 494     # and eventually test it when it is operational
 495     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 496     while (@circreffed) {
 497       weaken (my $r = shift @circreffed);
 498
 499       populate_weakregistry( (my $mini_registry = {}), $r );
 500       assert_empty_weakregistry( $mini_registry );
 501
 502       $r->result_source(undef);
 503     }
 504   }
 505 }
 506
 507 assert_empty_weakregistry ($weak_registry);
 508
 509 # we got so far without a failure - this is a good thing
 510 # now let's try to rerun this script under a "persistent" environment
 511 # this is ugly and dirty but we do not yet have a Test::Embedded or
 512 # similar
 513
 514 # set up -I
 515 require Config;
 516 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 517 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 518
 519
 520 my $persistence_tests;
 521 SKIP: {
 522   skip 'Test already in a persistent loop', 1
 523     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 524
 525   skip 'Main test failed - skipping persistent env tests', 1
 526     unless $TB->is_passing;
 527
 528   skip "Test::Builder\@@{[ Test::Builder->VERSION ]} known to break persistence tests", 1
 529     if modver_gt_or_eq_and_lt( 'Test::More', '1.200', '1.301001_099' );
 530
 531   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 532
 533   $persistence_tests = {
 534     PPerl => {
 535       cmd => [qw/pperl --prefork=1/, __FILE__],
 536     },
 537     'CGI::SpeedyCGI' => {
 538       cmd => [qw/speedy -- -t5/, __FILE__],
 539     },
 540   };
 541
 542   # scgi is smart and will auto-reap after -t amount of seconds
 543   # pperl needs an actual killer :(
 544   $persistence_tests->{PPerl}{termcmd} = [
 545     $persistence_tests->{PPerl}{cmd}[0],
 546     '--kill',
 547     @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 548   ];
 549
 550   require IPC::Open2;
 551
 552   for my $type (keys %$persistence_tests) { SKIP: {
 553     unless (eval "require $type") {
 554       # Don't terminate what we didn't start
 555       delete $persistence_tests->{$type}{termcmd};
 556       skip "$type module not found", 1;
 557     }
 558
 559     my @cmd = @{$persistence_tests->{$type}{cmd}};
 560
 561     # since PPerl is racy and sucks - just prime the "server"
 562     {
 563       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 564       system(@cmd);
 565       sleep 1;
 566
 567       # see if the thing actually runs, if not - might as well bail now
 568       skip "Something is wrong with $type ($!)", 1
 569         if system(@cmd);
 570     }
 571
 572     for (1,2,3) {
 573       note ("Starting run in persistent env ($type pass $_)");
 574       IPC::Open2::open2(my $out, undef, @cmd);
 575       my @out_lines;
 576       while (my $ln = <$out>) {
 577         next if $ln =~ /^\s*$/;
 578         push @out_lines, "   $ln";
 579         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 580       }
 581       print $_ for @out_lines;
 582       close $out;
 583       wait;
 584       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 585       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 586     }
 587
 588     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 589       if $persistence_tests->{$type}{termcmd};
 590   }}
 591 }
 592
 593 done_testing;
 594
 595 # just an extra precaution in case we blew away from the SKIP - since there are no
 596 # PID files to go by (man does pperl really suck :(
 597 END {
 598   if ($persistence_tests->{PPerl}{termcmd}) {
 599     local $?; # otherwise test will inherit $? of the system()
 600     require IPC::Open3;
 601     open my $null, ">", File::Spec->devnull;
 602     waitpid(
 603       IPC::Open3::open3(undef, $null, $null, @{$persistence_tests->{PPerl}{termcmd}}),
 604       0,
 605     );
 606   }
 607 }