t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 use lib qw(t/lib);
  25 use DBICTest::RunMode;
  26
  27 plan skip_all => "Temporarily no smoke testing of Test::More 1.3xx alphas" if (
  28   DBICTest::RunMode->is_smoker
  29     and
  30   eval { Test::More->VERSION("1.300") }
  31     and
  32   require ExtUtils::MakeMaker
  33     and
  34   MM->parse_version($INC{"Test/Builder.pm"}) =~ / ^ 1 \. 3.. ... \_ /x
  35 );
  36
  37 my $TB = Test::More->builder;
  38 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  39   # without this explicit close older TBs warn in END after a ->reset
  40   if ($TB->VERSION < 1.005) {
  41     close ($TB->$_) for (qw/output failure_output todo_output/);
  42   }
  43
  44   # if I do not do this, I get happy sigpipes on new TB, no idea why
  45   # (the above close-and-forget doesn't work - new TB does *not* reopen
  46   # its handles automatically anymore)
  47   else {
  48     for (qw/failure_output todo_output/) {
  49       close $TB->$_;
  50       open ($TB->$_, '>&', *STDERR);
  51     }
  52
  53     close $TB->output;
  54     open ($TB->output, '>&', *STDOUT);
  55   }
  56
  57   # so done_testing can work on every persistent pass
  58   $TB->reset;
  59 }
  60
  61 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  62 use Scalar::Util qw(weaken blessed reftype);
  63 use DBIx::Class;
  64 use DBIx::Class::_Util qw(hrefaddr sigwarn_silencer);
  65 BEGIN {
  66   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  67     if DBIx::Class::_ENV_::PEEPEENESS;
  68 }
  69
  70 # this is what holds all weakened refs to be checked for leakage
  71 my $weak_registry = {};
  72
  73 # whether or to invoke IC::DT
  74 my $has_dt;
  75
  76 # Skip the heavy-duty leak tracing when just doing an install
  77 unless (DBICTest::RunMode->is_plain) {
  78
  79   # redefine the bless override so that we can catch each and every object created
  80   no warnings qw/redefine once/;
  81   no strict qw/refs/;
  82
  83   $bless_override = sub {
  84
  85     my $obj = CORE::bless(
  86       $_[0], (@_ > 1) ? $_[1] : do {
  87         my ($class, $fn, $line) = caller();
  88         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  89           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  90         $class;
  91       }
  92     );
  93
  94     # unicode is tricky, and now we happen to invoke it early via a
  95     # regex in connection()
  96     return $obj if (ref $obj) =~ /^utf8/;
  97
  98     # Test Builder is now making a new object for every pass/fail (que bloat?)
  99     # and as such we can't really store any of its objects (since it will
 100     # re-populate the registry while checking it, ewwww!)
 101     return $obj if (ref $obj) =~ /^TB2::/;
 102
 103     # populate immediately to avoid weird side effects
 104     return populate_weakregistry ($weak_registry, $obj );
 105   };
 106
 107   require Try::Tiny;
 108   for my $func (qw/try catch finally/) {
 109     my $orig = \&{"Try::Tiny::$func"};
 110     *{"Try::Tiny::$func"} = sub (&;@) {
 111       populate_weakregistry( $weak_registry, $_[0] );
 112       goto $orig;
 113     }
 114   }
 115
 116   # Some modules are known to install singletons on-load
 117   # Load them and empty the registry
 118
 119   # this loads the DT armada
 120   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 121
 122   require Errno;
 123   require DBI;
 124   require DBD::SQLite;
 125   require FileHandle;
 126   require Moo;
 127
 128   %$weak_registry = ();
 129 }
 130
 131 {
 132   use_ok ('DBICTest');
 133
 134   my $schema = DBICTest->init_schema;
 135   my $rs = $schema->resultset ('Artist');
 136   my $storage = $schema->storage;
 137
 138   ok ($storage->connected, 'we are connected');
 139
 140   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 141   ok ($row_obj, 'row from db');
 142
 143   # txn_do to invoke more codepaths
 144   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 145
 146     my $artist = $schema->resultset('Artist')->create ({
 147       name => 'foo artist',
 148       cds => [{
 149         title => 'foo cd',
 150         year => 1984,
 151         tracks => [
 152           { title => 't1' },
 153           { title => 't2' },
 154         ],
 155         genre => { name => 'mauve' },
 156       }],
 157     });
 158
 159     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 160
 161     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 162
 163     return ($artist, $pg, $pg_wcount);
 164   });
 165
 166   # more codepaths - error handling in txn_do
 167   {
 168     eval { $schema->txn_do ( sub {
 169       $storage->_dbh->begin_work;
 170       fail ('how did we get so far?!');
 171     } ) };
 172
 173     eval { $schema->txn_do ( sub {
 174       $schema->txn_do ( sub {
 175         die "It's called EXCEPTION";
 176         fail ('how did we get so far?!');
 177       } );
 178       fail ('how did we get so far?!');
 179     } ) };
 180     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 181   }
 182
 183   # dbh_do codepath
 184   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 185     my $row = $_[0]->schema->resultset('Artist')->new({});
 186     my $rs = $_[0]->schema->resultset('Artist')->search({
 187       name => $row,  # this is deliberately bogus, see FIXME below!
 188     });
 189     return ($rs, $row);
 190   });
 191
 192   is ($pager->next_page, 3, 'There is one more page available');
 193
 194   # based on 66 per 10 pages
 195   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 196
 197   # do some population (invokes some extra codepaths)
 198   # also exercise the guard code and the manual txn control
 199   {
 200     my $guard = $schema->txn_scope_guard;
 201     # populate with bindvars
 202     $rs->populate([{ name => 'James Bound' }]);
 203     $guard->commit;
 204
 205     $schema->txn_begin;
 206     # populate mixed
 207     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 208     $schema->txn_commit;
 209
 210     $schema->txn_begin;
 211     # and without bindvars
 212     $rs->populate([{ name => \ '"James Unbound"' }]);
 213     $schema->txn_rollback;
 214   }
 215
 216   # prefetching
 217   my $cds_rs = $schema->resultset('CD');
 218   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 219   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 220   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 221
 222   # implicit pref
 223   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 224
 225   # get_column
 226   my $getcol_rs = $cds_rs->get_column('me.cdid');
 227   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 228
 229   my $base_collection = {
 230     resultset => $rs,
 231
 232     pref_precursor => $cds_rs,
 233
 234     pref_rs_single => $cds_with_artist,
 235     pref_rs_multi => $cds_with_tracks,
 236     pref_rs_nested => $cds_with_stuff,
 237
 238     pref_rs_implicit => $cds_with_impl_artist,
 239
 240     pref_row_single => $cds_with_artist->next,
 241     pref_row_multi => $cds_with_tracks->next,
 242     pref_row_nested => $cds_with_stuff->next,
 243
 244     # even though this does not leak Storable croaks on it :(((
 245     #pref_row_implicit => $cds_with_impl_artist->next,
 246
 247     get_column_rs_plain => $getcol_rs,
 248     get_column_rs_pref => $pref_getcol_rs,
 249
 250     # twice so that we make sure only one H::M object spawned
 251     chained_resultset => $rs->search_rs ({}, { '+columns' => { foo => 'artistid' } } ),
 252     chained_resultset2 => $rs->search_rs ({}, { '+columns' => { bar => 'artistid' } } ),
 253
 254     row_object => $row_obj,
 255
 256     mc_row_object => $mc_row_obj,
 257
 258     result_source => $rs->result_source,
 259
 260     result_source_handle => $rs->result_source->handle,
 261
 262     pager_explicit_count => $pager_explicit_count,
 263
 264     leaky_resultset => $rs_bind_circref,
 265     leaky_resultset_cond => $cond_rowobj,
 266   };
 267
 268   # fire all resultsets multiple times, once here, more below
 269   # some of these can't find anything (notably leaky_resultset)
 270   my @rsets = grep {
 271     blessed $_
 272       and
 273     (
 274       $_->isa('DBIx::Class::ResultSet')
 275         or
 276       $_->isa('DBIx::Class::ResultSetColumn')
 277     )
 278   } values %$base_collection;
 279
 280
 281   my $fire_resultsets = sub {
 282     local $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS} = 1;
 283     local $SIG{__WARN__} = sigwarn_silencer(
 284       qr/Unable to deflate 'filter'-type relationship 'artist'.+related object primary key not retrieved/
 285     );
 286
 287     map
 288       { $_, (blessed($_) ? { $_->get_columns } : ()) }
 289       map
 290         { $_->all }
 291         @rsets
 292     ;
 293   };
 294
 295   push @{$base_collection->{random_results}}, $fire_resultsets->();
 296
 297   # FIXME - something throws a Storable for a spin if we keep
 298   # the results in-collection. The same problem is seen above,
 299   # swept under the rug back in 0a03206a, damned lazy ribantainer
 300 {
 301   local $base_collection->{random_results};
 302
 303   require Storable;
 304   %$base_collection = (
 305     %$base_collection,
 306     refrozen => Storable::dclone( $base_collection ),
 307     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 308     pref_row_implicit => $cds_with_impl_artist->next,
 309     schema => $schema,
 310     storage => $storage,
 311     sql_maker => $storage->sql_maker,
 312     dbh => $storage->_dbh,
 313     fresh_pager => $rs->page(5)->pager,
 314     pager => $pager,
 315   );
 316 }
 317
 318   # FIXME - ideally this kind of collector ought to be global, but attempts
 319   # with an invasive debugger-based tracer did not quite work out... yet
 320   # Manually scan the innards of everything we have in the base collection
 321   # we assembled so far (skip the DT madness below) *recursively*
 322   #
 323   # Only do this when we do have the bits to look inside CVs properly,
 324   # without it we are liable to pick up object defaults that are locked
 325   # in method closures
 326   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 327     visit_refs(
 328       refs => [ $base_collection ],
 329       action => sub {
 330         populate_weakregistry ($weak_registry, $_[0]);
 331         1;  # true means "keep descending"
 332       },
 333     );
 334
 335     # do a heavy-duty fire-and-compare loop on all resultsets
 336     # this is expensive - not running on install
 337     my $typecounts = {};
 338     if (
 339       ! DBICTest::RunMode->is_plain
 340         and
 341       ! $ENV{DBICTEST_IN_PERSISTENT_ENV}
 342     ) {
 343
 344       # FIXME - ideally we should be able to just populate an alternative
 345       # registry, subtract everything from the main one, and arrive at
 346       # an "empty" resulting hash
 347       # However due to gross inefficiencies in the ::ResultSet code we
 348       # end up recalculating a new set of aliasmaps which could have very
 349       # well been cached if it wasn't for... anyhow
 350       # What we do here for the time being is similar to the lazy approach
 351       # of Devel::LeakTrace - we just make sure we do not end up with more
 352       # reftypes than when we started. At least we are not blanket-counting
 353       # SVs like D::LT does, but going by reftype... sigh...
 354
 355       for (values %$weak_registry) {
 356         if ( my $r = reftype($_->{weakref}) ) {
 357           $typecounts->{$r}--;
 358         }
 359       }
 360
 361       # For now we can only reuse the same registry, see FIXME above/below
 362       #for my $interim_wr ({}, {}) {
 363       for my $interim_wr ( ($weak_registry) x 4 ) {
 364
 365         visit_refs(
 366           refs => [ $fire_resultsets->(), @rsets ],
 367           action => sub {
 368             populate_weakregistry ($interim_wr, $_[0]);
 369             1;  # true means "keep descending"
 370           },
 371         );
 372
 373         # FIXME - this is what *should* be here
 374         #
 375         ## anything we have seen so far is cool
 376         #delete @{$interim_wr}{keys %$weak_registry};
 377         #
 378         ## moment of truth - the rest ought to be gone
 379         #assert_empty_weakregistry($interim_wr);
 380       }
 381
 382       for (values %$weak_registry) {
 383         if ( my $r = reftype($_->{weakref}) ) {
 384           $typecounts->{$r}++;
 385         }
 386       }
 387     }
 388
 389     for (keys %$typecounts) {
 390       fail ("Amount of $_ refs changed by $typecounts->{$_} during resultset mass-execution")
 391         if ( abs ($typecounts->{$_}) > 1 ); # there is a pad caught somewhere, the +1/-1 can be ignored
 392     }
 393   }
 394
 395   if ($has_dt) {
 396     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 397
 398     my $now = DateTime->now;
 399     for (1..5) {
 400       $base_collection->{"icdt_row_$_"} = $rs->create({
 401         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 402         starts_at => $now->clone->add(days => $_),
 403       });
 404     }
 405
 406     # re-search
 407     my @dummy = $rs->all;
 408   }
 409
 410   # dbh's are created in XS space, so pull them separately
 411   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 412     $base_collection->{"DBI handle $_"} = $_;
 413   }
 414
 415   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 416     for keys %$base_collection;
 417 }
 418
 419 # check that "phantom-chaining" works - we never lose track of the original $schema
 420 # and have access to the entire tree without leaking anything
 421 {
 422   my $phantom;
 423   for (
 424     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 425     sub { shift->source('Artist') },
 426     sub { shift->resultset },
 427     sub { shift->result_source },
 428     sub { shift->schema },
 429     sub { shift->resultset('Artist') },
 430     sub { shift->find_or_create({ name => 'detachable' }) },
 431     sub { shift->result_source },
 432     sub { shift->schema },
 433     sub { shift->clone },
 434     sub { shift->resultset('CD') },
 435     sub { shift->next },
 436     sub { shift->artist },
 437     sub { shift->search_related('cds') },
 438     sub { shift->next },
 439     sub { shift->search_related('artist') },
 440     sub { shift->result_source },
 441     sub { shift->resultset },
 442     sub { shift->create({ name => 'detached' }) },
 443     sub { shift->update({ name => 'reattached' }) },
 444     sub { shift->discard_changes },
 445     sub { shift->delete },
 446     sub { shift->insert },
 447   ) {
 448     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 449   }
 450
 451   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 452   is( $phantom->name, 'reattached', 'Still correct name' );
 453 }
 454
 455 # Naturally we have some exceptions
 456 my $cleared;
 457 for my $addr (keys %$weak_registry) {
 458   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 459
 460   if ($names =~ /^Test::Builder/m) {
 461     # T::B 2.0 has result objects and other fancyness
 462     delete $weak_registry->{$addr};
 463   }
 464   elsif ($names =~ /^Hash::Merge/m) {
 465     # only clear one object of a specific behavior - more would indicate trouble
 466     delete $weak_registry->{$addr}
 467       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 468   }
 469   elsif (
 470 #    # if we can look at closed over pieces - we will register it as a global
 471 #    !DBICTest::Util::LeakTracer::CV_TRACING
 472 #      and
 473     $names =~ /^SQL::Translator::Generator::DDL::SQLite/m
 474   ) {
 475     # SQLT::Producer::SQLite keeps global generators around for quoted
 476     # and non-quoted DDL, allow one for each quoting style
 477     delete $weak_registry->{$addr}
 478       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$addr}{weakref}->quote_chars}}++;
 479   }
 480 }
 481
 482 # FIXME !!!
 483 # There is an actual strong circular reference taking place here, but because
 484 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 485 # (our tracker does not yet do it, but it'd be nice)
 486 # The problem is:
 487 #
 488 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 489 #          ^                                                           /
 490 #           \-------- bound value on prepared/cached STH  <-----------/
 491 #
 492 {
 493   my @circreffed;
 494
 495   for my $r (map
 496     { $_->{weakref} }
 497     grep
 498       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 499       values %$weak_registry
 500   ) {
 501     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 502     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 503       or push @circreffed, $r;
 504   }
 505
 506   if (@circreffed) {
 507     is (scalar @circreffed, 1, 'One resultset expected to leak');
 508
 509     # this is useless on its own, it is to showcase the circref-diag
 510     # and eventually test it when it is operational
 511     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 512     while (@circreffed) {
 513       weaken (my $r = shift @circreffed);
 514
 515       populate_weakregistry( (my $mini_registry = {}), $r );
 516       assert_empty_weakregistry( $mini_registry );
 517
 518       $r->result_source(undef);
 519     }
 520   }
 521 }
 522
 523 assert_empty_weakregistry ($weak_registry);
 524
 525 # we got so far without a failure - this is a good thing
 526 # now let's try to rerun this script under a "persistent" environment
 527 # this is ugly and dirty but we do not yet have a Test::Embedded or
 528 # similar
 529
 530 # set up -I
 531 require Config;
 532 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 533 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 534
 535
 536 my $persistence_tests;
 537 SKIP: {
 538   skip 'Test already in a persistent loop', 1
 539     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 540
 541   skip 'Main test failed - skipping persistent env tests', 1
 542     unless $TB->is_passing;
 543
 544   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 545
 546   $persistence_tests = {
 547     PPerl => {
 548       cmd => [qw/pperl --prefork=1/, __FILE__],
 549     },
 550     'CGI::SpeedyCGI' => {
 551       cmd => [qw/speedy -- -t5/, __FILE__],
 552     },
 553   };
 554
 555   # scgi is smart and will auto-reap after -t amount of seconds
 556   # pperl needs an actual killer :(
 557   $persistence_tests->{PPerl}{termcmd} = [
 558     $persistence_tests->{PPerl}{cmd}[0],
 559     '--kill',
 560     @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 561   ];
 562
 563   require IPC::Open2;
 564
 565   for my $type (keys %$persistence_tests) { SKIP: {
 566     unless (eval "require $type") {
 567       # Don't terminate what we didn't start
 568       delete $persistence_tests->{$type}{termcmd};
 569       skip "$type module not found", 1;
 570     }
 571
 572     my @cmd = @{$persistence_tests->{$type}{cmd}};
 573
 574     # since PPerl is racy and sucks - just prime the "server"
 575     {
 576       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 577       system(@cmd);
 578       sleep 1;
 579
 580       # see if the thing actually runs, if not - might as well bail now
 581       skip "Something is wrong with $type ($!)", 1
 582         if system(@cmd);
 583     }
 584
 585     for (1,2,3) {
 586       note ("Starting run in persistent env ($type pass $_)");
 587       IPC::Open2::open2(my $out, undef, @cmd);
 588       my @out_lines;
 589       while (my $ln = <$out>) {
 590         next if $ln =~ /^\s*$/;
 591         push @out_lines, "   $ln";
 592         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 593       }
 594       print $_ for @out_lines;
 595       close $out;
 596       wait;
 597       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 598       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 599     }
 600
 601     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 602       if $persistence_tests->{$type}{termcmd};
 603   }}
 604 }
 605
 606 done_testing;
 607
 608 # just an extra precaution in case we blew away from the SKIP - since there are no
 609 # PID files to go by (man does pperl really suck :(
 610 END {
 611   if ($persistence_tests->{PPerl}{termcmd}) {
 612     local $?; # otherwise test will inherit $? of the system()
 613     require IPC::Open3;
 614     open my $null, ">", File::Spec->devnull;
 615     waitpid(
 616       IPC::Open3::open3(undef, $null, $null, @{$persistence_tests->{PPerl}{termcmd}}),
 617       0,
 618     );
 619   }
 620 }