t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 my $TB = Test::More->builder;
  25 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  26   # without this explicit close older TBs warn in END after a ->reset
  27   if ($TB->VERSION < 1.005) {
  28     close ($TB->$_) for (qw/output failure_output todo_output/);
  29   }
  30
  31   # if I do not do this, I get happy sigpipes on new TB, no idea why
  32   # (the above close-and-forget doesn't work - new TB does *not* reopen
  33   # its handles automatically anymore)
  34   else {
  35     for (qw/failure_output todo_output/) {
  36       close $TB->$_;
  37       open ($TB->$_, '>&', *STDERR);
  38     }
  39
  40     close $TB->output;
  41     open ($TB->output, '>&', *STDOUT);
  42   }
  43
  44   # so done_testing can work on every persistent pass
  45   $TB->reset;
  46 }
  47
  48 use lib qw(t/lib);
  49 use DBICTest::RunMode;
  50 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  51 use Scalar::Util 'refaddr';
  52 use DBIx::Class;
  53 use B 'svref_2object';
  54 BEGIN {
  55   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  56     if DBIx::Class::_ENV_::PEEPEENESS;
  57 }
  58
  59 # this is what holds all weakened refs to be checked for leakage
  60 my $weak_registry = {};
  61
  62 # whether or to invoke IC::DT
  63 my $has_dt;
  64
  65 # Skip the heavy-duty leak tracing when just doing an install
  66 unless (DBICTest::RunMode->is_plain) {
  67
  68   # redefine the bless override so that we can catch each and every object created
  69   no warnings qw/redefine once/;
  70   no strict qw/refs/;
  71
  72   $bless_override = sub {
  73
  74     my $obj = CORE::bless(
  75       $_[0], (@_ > 1) ? $_[1] : do {
  76         my ($class, $fn, $line) = caller();
  77         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  78           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  79         $class;
  80       }
  81     );
  82
  83     # unicode is tricky, and now we happen to invoke it early via a
  84     # regex in connection()
  85     return $obj if (ref $obj) =~ /^utf8/;
  86
  87     # Test Builder is now making a new object for every pass/fail (que bloat?)
  88     # and as such we can't really store any of its objects (since it will
  89     # re-populate the registry while checking it, ewwww!)
  90     return $obj if (ref $obj) =~ /^TB2::/;
  91
  92     # weaken immediately to avoid weird side effects
  93     return populate_weakregistry ($weak_registry, $obj );
  94   };
  95
  96   require Try::Tiny;
  97   for my $func (qw/try catch finally/) {
  98     my $orig = \&{"Try::Tiny::$func"};
  99     *{"Try::Tiny::$func"} = sub (&;@) {
 100       populate_weakregistry( $weak_registry, $_[0] );
 101       goto $orig;
 102     }
 103   }
 104
 105   # Some modules are known to install singletons on-load
 106   # Load them and empty the registry
 107
 108   # this loads the DT armada
 109   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 110
 111   require Errno;
 112   require DBI;
 113   require DBD::SQLite;
 114   require FileHandle;
 115   require Moo;
 116
 117   %$weak_registry = ();
 118 }
 119
 120 my @compose_ns_classes;
 121 {
 122   use_ok ('DBICTest');
 123
 124   my $schema = DBICTest->init_schema;
 125   my $rs = $schema->resultset ('Artist');
 126   my $storage = $schema->storage;
 127
 128   @compose_ns_classes = map { "DBICTest::${_}" } keys %{$schema->source_registrations};
 129
 130   ok ($storage->connected, 'we are connected');
 131
 132   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 133   ok ($row_obj, 'row from db');
 134
 135   # txn_do to invoke more codepaths
 136   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 137
 138     my $artist = $schema->resultset('Artist')->create ({
 139       name => 'foo artist',
 140       cds => [{
 141         title => 'foo cd',
 142         year => 1984,
 143         tracks => [
 144           { title => 't1' },
 145           { title => 't2' },
 146         ],
 147         genre => { name => 'mauve' },
 148       }],
 149     });
 150
 151     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 152
 153     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 154
 155     return ($artist, $pg, $pg_wcount);
 156   });
 157
 158   # more codepaths - error handling in txn_do
 159   {
 160     eval { $schema->txn_do ( sub {
 161       $storage->_dbh->begin_work;
 162       fail ('how did we get so far?!');
 163     } ) };
 164
 165     eval { $schema->txn_do ( sub {
 166       $schema->txn_do ( sub {
 167         die "It's called EXCEPTION";
 168         fail ('how did we get so far?!');
 169       } );
 170       fail ('how did we get so far?!');
 171     } ) };
 172     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 173   }
 174
 175   # dbh_do codepath
 176   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 177     my $row = $_[0]->schema->resultset('Artist')->new({});
 178     my $rs = $_[0]->schema->resultset('Artist')->search({
 179       name => $row,  # this is deliberately bogus, see FIXME below!
 180     });
 181     return ($rs, $row);
 182   });
 183
 184   is ($pager->next_page, 3, 'There is one more page available');
 185
 186   # based on 66 per 10 pages
 187   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 188
 189   # do some population (invokes some extra codepaths)
 190   # also exercise the guard code and the manual txn control
 191   {
 192     my $guard = $schema->txn_scope_guard;
 193     # populate with bindvars
 194     $rs->populate([{ name => 'James Bound' }]);
 195     $guard->commit;
 196
 197     $schema->txn_begin;
 198     # populate mixed
 199     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 200     $schema->txn_commit;
 201
 202     $schema->txn_begin;
 203     # and without bindvars
 204     $rs->populate([{ name => \ '"James Unbound"' }]);
 205     $schema->txn_rollback;
 206   }
 207
 208   # prefetching
 209   my $cds_rs = $schema->resultset('CD');
 210   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 211   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 212   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 213
 214   # implicit pref
 215   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 216
 217   # get_column
 218   my $getcol_rs = $cds_rs->get_column('me.cdid');
 219   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 220
 221   # fire the column getters
 222   my @throwaway = $pref_getcol_rs->all;
 223
 224   my $base_collection = {
 225     resultset => $rs,
 226
 227     pref_precursor => $cds_rs,
 228
 229     pref_rs_single => $cds_with_artist,
 230     pref_rs_multi => $cds_with_tracks,
 231     pref_rs_nested => $cds_with_stuff,
 232
 233     pref_rs_implicit => $cds_with_impl_artist,
 234
 235     pref_row_single => $cds_with_artist->next,
 236     pref_row_multi => $cds_with_tracks->next,
 237     pref_row_nested => $cds_with_stuff->next,
 238
 239     # even though this does not leak Storable croaks on it :(((
 240     #pref_row_implicit => $cds_with_impl_artist->next,
 241
 242     get_column_rs_plain => $getcol_rs,
 243     get_column_rs_pref => $pref_getcol_rs,
 244
 245     # twice so that we make sure only one H::M object spawned
 246     chained_resultset => $rs->search_rs ({}, { '+columns' => [ 'foo' ] } ),
 247     chained_resultset2 => $rs->search_rs ({}, { '+columns' => [ 'bar' ] } ),
 248
 249     row_object => $row_obj,
 250
 251     mc_row_object => $mc_row_obj,
 252
 253     result_source => $rs->result_source,
 254
 255     result_source_handle => $rs->result_source->handle,
 256
 257     pager_explicit_count => $pager_explicit_count,
 258
 259     leaky_resultset => $rs_bind_circref,
 260     leaky_resultset_cond => $cond_rowobj,
 261   };
 262
 263   # this needs to fire, even if it can't find anything
 264   # see FIXME below
 265   # we run this only on smokers - trying to establish a pattern
 266   $rs_bind_circref->next
 267     if ( ($ENV{TRAVIS}||'') ne 'true' and DBICTest::RunMode->is_smoker);
 268
 269   require Storable;
 270   %$base_collection = (
 271     %$base_collection,
 272     refrozen => Storable::dclone( $base_collection ),
 273     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 274     pref_row_implicit => $cds_with_impl_artist->next,
 275     schema => $schema,
 276     storage => $storage,
 277     sql_maker => $storage->sql_maker,
 278     dbh => $storage->_dbh,
 279     fresh_pager => $rs->page(5)->pager,
 280     pager => $pager,
 281   );
 282
 283   if ($has_dt) {
 284     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 285
 286     my $now = DateTime->now;
 287     for (1..5) {
 288       $base_collection->{"icdt_row_$_"} = $rs->create({
 289         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 290         starts_at => $now->clone->add(days => $_),
 291       });
 292     }
 293
 294     # re-search
 295     my @dummy = $rs->all;
 296   }
 297
 298   # dbh's are created in XS space, so pull them separately
 299   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 300     $base_collection->{"DBI handle $_"} = $_;
 301   }
 302
 303   SKIP: {
 304     if ( DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks') ) {
 305       Test::Memory::Cycle::memory_cycle_ok ($base_collection, 'No cycles in the object collection')
 306     }
 307     else {
 308       skip 'Circular ref test needs ' .  DBIx::Class::Optional::Dependencies->req_missing_for ('test_leaks'), 1;
 309     }
 310   }
 311
 312   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 313     for keys %$base_collection;
 314 }
 315
 316 # check that "phantom-chaining" works - we never lose track of the original $schema
 317 # and have access to the entire tree without leaking anything
 318 {
 319   my $phantom;
 320   for (
 321     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 322     sub { shift->source('Artist') },
 323     sub { shift->resultset },
 324     sub { shift->result_source },
 325     sub { shift->schema },
 326     sub { shift->resultset('Artist') },
 327     sub { shift->find_or_create({ name => 'detachable' }) },
 328     sub { shift->result_source },
 329     sub { shift->schema },
 330     sub { shift->clone },
 331     sub { shift->resultset('CD') },
 332     sub { shift->next },
 333     sub { shift->artist },
 334     sub { shift->search_related('cds') },
 335     sub { shift->next },
 336     sub { shift->search_related('artist') },
 337     sub { shift->result_source },
 338     sub { shift->resultset },
 339     sub { shift->create({ name => 'detached' }) },
 340     sub { shift->update({ name => 'reattached' }) },
 341     sub { shift->discard_changes },
 342     sub { shift->delete },
 343     sub { shift->insert },
 344   ) {
 345     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 346   }
 347
 348   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 349   is( $phantom->name, 'reattached', 'Still correct name' );
 350 }
 351
 352 # Naturally we have some exceptions
 353 my $cleared;
 354 for my $slot (keys %$weak_registry) {
 355   if ($slot =~ /^Test::Builder/) {
 356     # T::B 2.0 has result objects and other fancyness
 357     delete $weak_registry->{$slot};
 358   }
 359   elsif ($slot =~ /^Method::Generate::(?:Accessor|Constructor)/) {
 360     # Moo keeps globals around, this is normal
 361     delete $weak_registry->{$slot};
 362   }
 363   elsif ($slot =~ /^SQL::Translator::Generator::DDL::SQLite/) {
 364     # SQLT::Producer::SQLite keeps global generators around for quoted
 365     # and non-quoted DDL, allow one for each quoting style
 366     delete $weak_registry->{$slot}
 367       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$slot}{weakref}->quote_chars}}++;
 368   }
 369   elsif ($slot =~ /^Hash::Merge/) {
 370     # only clear one object of a specific behavior - more would indicate trouble
 371     delete $weak_registry->{$slot}
 372       unless $cleared->{hash_merge_singleton}{$weak_registry->{$slot}{weakref}{behavior}}++;
 373   }
 374   elsif ($slot =~ /^DateTime::TimeZone/) {
 375     # DT is going through a refactor it seems - let it leak zones for now
 376     delete $weak_registry->{$slot};
 377   }
 378 }
 379
 380 # every result class has a result source instance as classdata
 381 # make sure these are all present and distinct before ignoring
 382 # (distinct means only 1 reference)
 383 for my $rs_class (
 384   'DBICTest::BaseResult',
 385   @compose_ns_classes,
 386   map { DBICTest::Schema->class ($_) } DBICTest::Schema->sources
 387 ) {
 388   # need to store the SVref and examine it separately, to push the rsrc instance off the pad
 389   my $SV = svref_2object($rs_class->result_source_instance);
 390   is( $SV->REFCNT, 1, "Source instance of $rs_class referenced exactly once" );
 391
 392   # ignore it
 393   delete $weak_registry->{$rs_class->result_source_instance};
 394 }
 395
 396 # Schema classes also hold sources, but these are clones, since
 397 # each source contains the schema (or schema class name in this case)
 398 # Hence the clone so that the same source can be registered with
 399 # multiple schemas
 400 for my $moniker ( keys %{DBICTest::Schema->source_registrations || {}} ) {
 401
 402   my $SV = svref_2object(DBICTest::Schema->source($moniker));
 403   is( $SV->REFCNT, 1, "Source instance registered under DBICTest::Schema as $moniker referenced exactly once" );
 404
 405   delete $weak_registry->{DBICTest::Schema->source($moniker)};
 406 }
 407
 408 # FIXME !!!
 409 # There is an actual strong circular reference taking place here, but because
 410 # half of it is in XS no leaktracer sees it, and Devel::FindRef is equally
 411 # stumped when trying to trace the origin. The problem is:
 412 #
 413 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 414 #          ^                                                           /
 415 #           \-------- bound value on prepared/cached STH  <-----------/
 416 #
 417 {
 418   local $TODO = 'This fails intermittently - see RT#82942';
 419   if ( my $r = $weak_registry->{'basic leaky_resultset_cond'}{weakref} ) {
 420     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 421       or $r->result_source(undef);
 422   }
 423 }
 424
 425 assert_empty_weakregistry ($weak_registry);
 426
 427 # we got so far without a failure - this is a good thing
 428 # now let's try to rerun this script under a "persistent" environment
 429 # this is ugly and dirty but we do not yet have a Test::Embedded or
 430 # similar
 431
 432 # set up -I
 433 require Config;
 434 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 435 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 436
 437
 438 my $persistence_tests = {
 439   PPerl => {
 440     cmd => [qw/pperl --prefork=1/, __FILE__],
 441   },
 442   'CGI::SpeedyCGI' => {
 443     cmd => [qw/speedy -- -t5/, __FILE__],
 444   },
 445 };
 446
 447 # scgi is smart and will auto-reap after -t amount of seconds
 448 # pperl needs an actual killer :(
 449 $persistence_tests->{PPerl}{termcmd} = [
 450   $persistence_tests->{PPerl}{cmd}[0],
 451   '--kill',
 452   @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 453 ];
 454
 455 SKIP: {
 456   skip 'Test already in a persistent loop', 1
 457     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 458
 459   skip 'Main test failed - skipping persistent env tests', 1
 460     unless $TB->is_passing;
 461
 462   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 463
 464   require IPC::Open2;
 465
 466   for my $type (keys %$persistence_tests) { SKIP: {
 467       skip "$type module not found", 1
 468         unless eval "require $type";
 469
 470     my @cmd = @{$persistence_tests->{$type}{cmd}};
 471
 472     # since PPerl is racy and sucks - just prime the "server"
 473     {
 474       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 475       system(@cmd);
 476       sleep 1;
 477
 478       # see if the thing actually runs, if not - might as well bail now
 479       skip "Something is wrong with $type ($!)", 1
 480         if system(@cmd);
 481     }
 482
 483     for (1,2,3) {
 484       note ("Starting run in persistent env ($type pass $_)");
 485       IPC::Open2::open2(my $out, undef, @cmd);
 486       my @out_lines;
 487       while (my $ln = <$out>) {
 488         next if $ln =~ /^\s*$/;
 489         push @out_lines, "   $ln";
 490         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 491       }
 492       print $_ for @out_lines;
 493       close $out;
 494       wait;
 495       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 496       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 497     }
 498
 499     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 500       if $persistence_tests->{$type}{termcmd};
 501   }}
 502 }
 503
 504 done_testing;
 505
 506 # just an extra precaution in case we blew away from the SKIP - since there are no
 507 # PID files to go by (man does pperl really suck :(
 508 END {
 509   unless ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
 510     close $_ for (*STDIN, *STDOUT, *STDERR);
 511     local $?; # otherwise test will inherit $? of the system()
 512     system (@{$persistence_tests->{PPerl}{termcmd}});
 513   }
 514 }