t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 my $TB = Test::More->builder;
  25 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  26   # without this explicit close older TBs warn in END after a ->reset
  27   if ($TB->VERSION < 1.005) {
  28     close ($TB->$_) for (qw/output failure_output todo_output/);
  29   }
  30
  31   # if I do not do this, I get happy sigpipes on new TB, no idea why
  32   # (the above close-and-forget doesn't work - new TB does *not* reopen
  33   # its handles automatically anymore)
  34   else {
  35     for (qw/failure_output todo_output/) {
  36       close $TB->$_;
  37       open ($TB->$_, '>&', *STDERR);
  38     }
  39
  40     close $TB->output;
  41     open ($TB->output, '>&', *STDOUT);
  42   }
  43
  44   # so done_testing can work on every persistent pass
  45   $TB->reset;
  46 }
  47
  48 use lib qw(t/lib);
  49 use DBICTest::RunMode;
  50 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  51 use Scalar::Util qw(weaken blessed reftype);
  52 use DBIx::Class;
  53 use DBIx::Class::_Util qw(hrefaddr sigwarn_silencer);
  54 BEGIN {
  55   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  56     if DBIx::Class::_ENV_::PEEPEENESS;
  57 }
  58
  59 # this is what holds all weakened refs to be checked for leakage
  60 my $weak_registry = {};
  61
  62 # whether or to invoke IC::DT
  63 my $has_dt;
  64
  65 # Skip the heavy-duty leak tracing when just doing an install
  66 unless (DBICTest::RunMode->is_plain) {
  67
  68   # redefine the bless override so that we can catch each and every object created
  69   no warnings qw/redefine once/;
  70   no strict qw/refs/;
  71
  72   $bless_override = sub {
  73
  74     my $obj = CORE::bless(
  75       $_[0], (@_ > 1) ? $_[1] : do {
  76         my ($class, $fn, $line) = caller();
  77         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  78           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  79         $class;
  80       }
  81     );
  82
  83     # unicode is tricky, and now we happen to invoke it early via a
  84     # regex in connection()
  85     return $obj if (ref $obj) =~ /^utf8/;
  86
  87     # Test Builder is now making a new object for every pass/fail (que bloat?)
  88     # and as such we can't really store any of its objects (since it will
  89     # re-populate the registry while checking it, ewwww!)
  90     return $obj if (ref $obj) =~ /^TB2::/;
  91
  92     # populate immediately to avoid weird side effects
  93     return populate_weakregistry ($weak_registry, $obj );
  94   };
  95
  96   require Try::Tiny;
  97   for my $func (qw/try catch finally/) {
  98     my $orig = \&{"Try::Tiny::$func"};
  99     *{"Try::Tiny::$func"} = sub (&;@) {
 100       populate_weakregistry( $weak_registry, $_[0] );
 101       goto $orig;
 102     }
 103   }
 104
 105   # Some modules are known to install singletons on-load
 106   # Load them and empty the registry
 107
 108   # this loads the DT armada
 109   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 110
 111   require Errno;
 112   require DBI;
 113   require DBD::SQLite;
 114   require FileHandle;
 115   require Moo;
 116
 117   %$weak_registry = ();
 118 }
 119
 120 {
 121   use_ok ('DBICTest');
 122
 123   my $schema = DBICTest->init_schema;
 124   my $rs = $schema->resultset ('Artist');
 125   my $storage = $schema->storage;
 126
 127   ok ($storage->connected, 'we are connected');
 128
 129   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 130   ok ($row_obj, 'row from db');
 131
 132   # txn_do to invoke more codepaths
 133   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 134
 135     my $artist = $schema->resultset('Artist')->create ({
 136       name => 'foo artist',
 137       cds => [{
 138         title => 'foo cd',
 139         year => 1984,
 140         tracks => [
 141           { title => 't1' },
 142           { title => 't2' },
 143         ],
 144         genre => { name => 'mauve' },
 145       }],
 146     });
 147
 148     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 149
 150     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 151
 152     return ($artist, $pg, $pg_wcount);
 153   });
 154
 155   # more codepaths - error handling in txn_do
 156   {
 157     eval { $schema->txn_do ( sub {
 158       $storage->_dbh->begin_work;
 159       fail ('how did we get so far?!');
 160     } ) };
 161
 162     eval { $schema->txn_do ( sub {
 163       $schema->txn_do ( sub {
 164         die "It's called EXCEPTION";
 165         fail ('how did we get so far?!');
 166       } );
 167       fail ('how did we get so far?!');
 168     } ) };
 169     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 170   }
 171
 172   # dbh_do codepath
 173   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 174     my $row = $_[0]->schema->resultset('Artist')->new({});
 175     my $rs = $_[0]->schema->resultset('Artist')->search({
 176       name => $row,  # this is deliberately bogus, see FIXME below!
 177     });
 178     return ($rs, $row);
 179   });
 180
 181   is ($pager->next_page, 3, 'There is one more page available');
 182
 183   # based on 66 per 10 pages
 184   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 185
 186   # do some population (invokes some extra codepaths)
 187   # also exercise the guard code and the manual txn control
 188   {
 189     my $guard = $schema->txn_scope_guard;
 190     # populate with bindvars
 191     $rs->populate([{ name => 'James Bound' }]);
 192     $guard->commit;
 193
 194     $schema->txn_begin;
 195     # populate mixed
 196     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 197     $schema->txn_commit;
 198
 199     $schema->txn_begin;
 200     # and without bindvars
 201     $rs->populate([{ name => \ '"James Unbound"' }]);
 202     $schema->txn_rollback;
 203   }
 204
 205   # prefetching
 206   my $cds_rs = $schema->resultset('CD');
 207   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 208   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 209   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 210
 211   # implicit pref
 212   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 213
 214   # get_column
 215   my $getcol_rs = $cds_rs->get_column('me.cdid');
 216   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 217
 218   my $base_collection = {
 219     resultset => $rs,
 220
 221     pref_precursor => $cds_rs,
 222
 223     pref_rs_single => $cds_with_artist,
 224     pref_rs_multi => $cds_with_tracks,
 225     pref_rs_nested => $cds_with_stuff,
 226
 227     pref_rs_implicit => $cds_with_impl_artist,
 228
 229     pref_row_single => $cds_with_artist->next,
 230     pref_row_multi => $cds_with_tracks->next,
 231     pref_row_nested => $cds_with_stuff->next,
 232
 233     # even though this does not leak Storable croaks on it :(((
 234     #pref_row_implicit => $cds_with_impl_artist->next,
 235
 236     get_column_rs_plain => $getcol_rs,
 237     get_column_rs_pref => $pref_getcol_rs,
 238
 239     # twice so that we make sure only one H::M object spawned
 240     chained_resultset => $rs->search_rs ({}, { '+columns' => { foo => 'artistid' } } ),
 241     chained_resultset2 => $rs->search_rs ({}, { '+columns' => { bar => 'artistid' } } ),
 242
 243     row_object => $row_obj,
 244
 245     mc_row_object => $mc_row_obj,
 246
 247     result_source => $rs->result_source,
 248
 249     result_source_handle => $rs->result_source->handle,
 250
 251     pager_explicit_count => $pager_explicit_count,
 252
 253     leaky_resultset => $rs_bind_circref,
 254     leaky_resultset_cond => $cond_rowobj,
 255   };
 256
 257   # fire all resultsets multiple times, once here, more below
 258   # some of these can't find anything (notably leaky_resultset)
 259   my @rsets = grep {
 260     blessed $_
 261       and
 262     (
 263       $_->isa('DBIx::Class::ResultSet')
 264         or
 265       $_->isa('DBIx::Class::ResultSetColumn')
 266     )
 267   } values %$base_collection;
 268
 269
 270   my $fire_resultsets = sub {
 271     local $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS} = 1;
 272     local $SIG{__WARN__} = sigwarn_silencer(
 273       qr/Unable to deflate 'filter'-type relationship 'artist'.+related object primary key not retrieved/
 274     );
 275
 276     map
 277       { $_, (blessed($_) ? { $_->get_columns } : ()) }
 278       map
 279         { $_->all }
 280         @rsets
 281     ;
 282   };
 283
 284   push @{$base_collection->{random_results}}, $fire_resultsets->();
 285
 286   # FIXME - something throws a Storable for a spin if we keep
 287   # the results in-collection. The same problem is seen above,
 288   # swept under the rug back in 0a03206a, damned lazy ribantainer
 289 {
 290   local $base_collection->{random_results};
 291
 292   require Storable;
 293   %$base_collection = (
 294     %$base_collection,
 295     refrozen => Storable::dclone( $base_collection ),
 296     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 297     pref_row_implicit => $cds_with_impl_artist->next,
 298     schema => $schema,
 299     storage => $storage,
 300     sql_maker => $storage->sql_maker,
 301     dbh => $storage->_dbh,
 302     fresh_pager => $rs->page(5)->pager,
 303     pager => $pager,
 304   );
 305 }
 306
 307   # FIXME - ideally this kind of collector ought to be global, but attempts
 308   # with an invasive debugger-based tracer did not quite work out... yet
 309   # Manually scan the innards of everything we have in the base collection
 310   # we assembled so far (skip the DT madness below) *recursively*
 311   #
 312   # Only do this when we do have the bits to look inside CVs properly,
 313   # without it we are liable to pick up object defaults that are locked
 314   # in method closures
 315   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 316     visit_refs(
 317       refs => [ $base_collection ],
 318       action => sub {
 319         populate_weakregistry ($weak_registry, $_[0]);
 320         1;  # true means "keep descending"
 321       },
 322     );
 323
 324     # do a heavy-duty fire-and-compare loop on all resultsets
 325     # this is expensive - not running on install
 326     my $typecounts = {};
 327     if (
 328       ! DBICTest::RunMode->is_plain
 329         and
 330       ! $ENV{DBICTEST_IN_PERSISTENT_ENV}
 331         and
 332       # FIXME - investigate wtf is going on with 5.18
 333       ! ( $] > 5.017 and $ENV{DBIC_TRACE_PROFILE} )
 334     ) {
 335
 336       # FIXME - ideally we should be able to just populate an alternative
 337       # registry, subtract everything from the main one, and arrive at
 338       # an "empty" resulting hash
 339       # However due to gross inefficiencies in the ::ResultSet code we
 340       # end up recalculating a new set of aliasmaps which could have very
 341       # well been cached if it wasn't for... anyhow
 342       # What we do here for the time being is similar to the lazy approach
 343       # of Devel::LeakTrace - we just make sure we do not end up with more
 344       # reftypes than when we started. At least we are not blanket-counting
 345       # SVs like D::LT does, but going by reftype... sigh...
 346
 347       for (values %$weak_registry) {
 348         if ( my $r = reftype($_->{weakref}) ) {
 349           $typecounts->{$r}--;
 350         }
 351       }
 352
 353       # For now we can only reuse the same registry, see FIXME above/below
 354       #for my $interim_wr ({}, {}) {
 355       for my $interim_wr ( ($weak_registry) x 4 ) {
 356
 357         visit_refs(
 358           refs => [ $fire_resultsets->(), @rsets ],
 359           action => sub {
 360             populate_weakregistry ($interim_wr, $_[0]);
 361             1;  # true means "keep descending"
 362           },
 363         );
 364
 365         # FIXME - this is what *should* be here
 366         #
 367         ## anything we have seen so far is cool
 368         #delete @{$interim_wr}{keys %$weak_registry};
 369         #
 370         ## moment of truth - the rest ought to be gone
 371         #assert_empty_weakregistry($interim_wr);
 372       }
 373
 374       for (values %$weak_registry) {
 375         if ( my $r = reftype($_->{weakref}) ) {
 376           $typecounts->{$r}++;
 377         }
 378       }
 379     }
 380
 381     for (keys %$typecounts) {
 382       fail ("Amount of $_ refs changed by $typecounts->{$_} during resultset mass-execution")
 383         if ( abs ($typecounts->{$_}) > 1 ); # there is a pad caught somewhere, the +1/-1 can be ignored
 384     }
 385   }
 386
 387   if ($has_dt) {
 388     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 389
 390     my $now = DateTime->now;
 391     for (1..5) {
 392       $base_collection->{"icdt_row_$_"} = $rs->create({
 393         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 394         starts_at => $now->clone->add(days => $_),
 395       });
 396     }
 397
 398     # re-search
 399     my @dummy = $rs->all;
 400   }
 401
 402   # dbh's are created in XS space, so pull them separately
 403   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 404     $base_collection->{"DBI handle $_"} = $_;
 405   }
 406
 407   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 408     for keys %$base_collection;
 409 }
 410
 411 # check that "phantom-chaining" works - we never lose track of the original $schema
 412 # and have access to the entire tree without leaking anything
 413 {
 414   my $phantom;
 415   for (
 416     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 417     sub { shift->source('Artist') },
 418     sub { shift->resultset },
 419     sub { shift->result_source },
 420     sub { shift->schema },
 421     sub { shift->resultset('Artist') },
 422     sub { shift->find_or_create({ name => 'detachable' }) },
 423     sub { shift->result_source },
 424     sub { shift->schema },
 425     sub { shift->clone },
 426     sub { shift->resultset('CD') },
 427     sub { shift->next },
 428     sub { shift->artist },
 429     sub { shift->search_related('cds') },
 430     sub { shift->next },
 431     sub { shift->search_related('artist') },
 432     sub { shift->result_source },
 433     sub { shift->resultset },
 434     sub { shift->create({ name => 'detached' }) },
 435     sub { shift->update({ name => 'reattached' }) },
 436     sub { shift->discard_changes },
 437     sub { shift->delete },
 438     sub { shift->insert },
 439   ) {
 440     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 441   }
 442
 443   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 444   is( $phantom->name, 'reattached', 'Still correct name' );
 445 }
 446
 447 # Naturally we have some exceptions
 448 my $cleared;
 449 for my $addr (keys %$weak_registry) {
 450   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 451
 452   if ($names =~ /^Test::Builder/m) {
 453     # T::B 2.0 has result objects and other fancyness
 454     delete $weak_registry->{$addr};
 455   }
 456   elsif ($names =~ /^Hash::Merge/m) {
 457     # only clear one object of a specific behavior - more would indicate trouble
 458     delete $weak_registry->{$addr}
 459       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 460   }
 461   elsif (
 462 #    # if we can look at closed over pieces - we will register it as a global
 463 #    !DBICTest::Util::LeakTracer::CV_TRACING
 464 #      and
 465     $names =~ /^SQL::Translator::Generator::DDL::SQLite/m
 466   ) {
 467     # SQLT::Producer::SQLite keeps global generators around for quoted
 468     # and non-quoted DDL, allow one for each quoting style
 469     delete $weak_registry->{$addr}
 470       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$addr}{weakref}->quote_chars}}++;
 471   }
 472 }
 473
 474 # FIXME !!!
 475 # There is an actual strong circular reference taking place here, but because
 476 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 477 # (our tracker does not yet do it, but it'd be nice)
 478 # The problem is:
 479 #
 480 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 481 #          ^                                                           /
 482 #           \-------- bound value on prepared/cached STH  <-----------/
 483 #
 484 {
 485   my @circreffed;
 486
 487   for my $r (map
 488     { $_->{weakref} }
 489     grep
 490       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 491       values %$weak_registry
 492   ) {
 493     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 494     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 495       or push @circreffed, $r;
 496   }
 497
 498   if (@circreffed) {
 499     is (scalar @circreffed, 1, 'One resultset expected to leak');
 500
 501     # this is useless on its own, it is to showcase the circref-diag
 502     # and eventually test it when it is operational
 503     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 504     while (@circreffed) {
 505       weaken (my $r = shift @circreffed);
 506
 507       populate_weakregistry( (my $mini_registry = {}), $r );
 508       assert_empty_weakregistry( $mini_registry );
 509
 510       $r->result_source(undef);
 511     }
 512   }
 513 }
 514
 515 assert_empty_weakregistry ($weak_registry);
 516
 517 # we got so far without a failure - this is a good thing
 518 # now let's try to rerun this script under a "persistent" environment
 519 # this is ugly and dirty but we do not yet have a Test::Embedded or
 520 # similar
 521
 522 # set up -I
 523 require Config;
 524 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 525 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 526
 527
 528 my $persistence_tests = {
 529   PPerl => {
 530     cmd => [qw/pperl --prefork=1/, __FILE__],
 531   },
 532   'CGI::SpeedyCGI' => {
 533     cmd => [qw/speedy -- -t5/, __FILE__],
 534   },
 535 };
 536
 537 # scgi is smart and will auto-reap after -t amount of seconds
 538 # pperl needs an actual killer :(
 539 $persistence_tests->{PPerl}{termcmd} = [
 540   $persistence_tests->{PPerl}{cmd}[0],
 541   '--kill',
 542   @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 543 ];
 544
 545 SKIP: {
 546   skip 'Test already in a persistent loop', 1
 547     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 548
 549   skip 'Main test failed - skipping persistent env tests', 1
 550     unless $TB->is_passing;
 551
 552   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 553
 554   require IPC::Open2;
 555
 556   for my $type (keys %$persistence_tests) { SKIP: {
 557     unless (eval "require $type") {
 558       # Don't terminate what we didn't start
 559       delete $persistence_tests->{$type}{termcmd};
 560       skip "$type module not found", 1;
 561     }
 562
 563     my @cmd = @{$persistence_tests->{$type}{cmd}};
 564
 565     # since PPerl is racy and sucks - just prime the "server"
 566     {
 567       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 568       system(@cmd);
 569       sleep 1;
 570
 571       # see if the thing actually runs, if not - might as well bail now
 572       skip "Something is wrong with $type ($!)", 1
 573         if system(@cmd);
 574     }
 575
 576     for (1,2,3) {
 577       note ("Starting run in persistent env ($type pass $_)");
 578       IPC::Open2::open2(my $out, undef, @cmd);
 579       my @out_lines;
 580       while (my $ln = <$out>) {
 581         next if $ln =~ /^\s*$/;
 582         push @out_lines, "   $ln";
 583         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 584       }
 585       print $_ for @out_lines;
 586       close $out;
 587       wait;
 588       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 589       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 590     }
 591
 592     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 593       if $persistence_tests->{$type}{termcmd};
 594   }}
 595 }
 596
 597 done_testing;
 598
 599 # just an extra precaution in case we blew away from the SKIP - since there are no
 600 # PID files to go by (man does pperl really suck :(
 601 END {
 602   unless ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
 603     close $_ for (*STDIN, *STDOUT, *STDERR);
 604     local $?; # otherwise test will inherit $? of the system()
 605     system (@{$persistence_tests->{PPerl}{termcmd}})
 606       if $persistence_tests->{PPerl}{termcmd};
 607   }
 608 }