t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 use lib qw(t/lib);
  25 use DBICTest::RunMode;
  26 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  27 use Scalar::Util qw(weaken blessed reftype);
  28 use DBIx::Class::_Util qw(hrefaddr sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt);
  29 BEGIN {
  30   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  31     if DBIx::Class::_ENV_::PEEPEENESS;
  32 }
  33
  34
  35 my $TB = Test::More->builder;
  36 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  37   # without this explicit close TB warns in END after a ->reset
  38   close ($TB->$_) for qw(output failure_output todo_output);
  39
  40   # newer TB does not auto-reopen handles
  41   if ( modver_gt_or_eq( 'Test::More', '1.200' ) ) {
  42     open ($TB->$_, '>&', *STDERR)
  43       for qw( failure_output todo_output );
  44     open ($TB->output, '>&', *STDOUT);
  45   }
  46
  47   # so done_testing can work on every persistent pass
  48   $TB->reset;
  49 }
  50
  51 # this is what holds all weakened refs to be checked for leakage
  52 my $weak_registry = {};
  53
  54 # whether or to invoke IC::DT
  55 my $has_dt;
  56
  57 # Skip the heavy-duty leak tracing when just doing an install
  58 unless (DBICTest::RunMode->is_plain) {
  59
  60   # redefine the bless override so that we can catch each and every object created
  61   no warnings qw/redefine once/;
  62   no strict qw/refs/;
  63
  64   $bless_override = sub {
  65
  66     my $obj = CORE::bless(
  67       $_[0], (@_ > 1) ? $_[1] : do {
  68         my ($class, $fn, $line) = caller();
  69         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  70           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  71         $class;
  72       }
  73     );
  74
  75     # unicode is tricky, and now we happen to invoke it early via a
  76     # regex in connection()
  77     return $obj if (ref $obj) =~ /^utf8/;
  78
  79     # Test Builder is now making a new object for every pass/fail (que bloat?)
  80     # and as such we can't really store any of its objects (since it will
  81     # re-populate the registry while checking it, ewwww!)
  82     return $obj if (ref $obj) =~ /^TB2::|^Test::Stream/;
  83
  84     # populate immediately to avoid weird side effects
  85     return populate_weakregistry ($weak_registry, $obj );
  86   };
  87
  88   require Try::Tiny;
  89   for my $func (qw/try catch finally/) {
  90     my $orig = \&{"Try::Tiny::$func"};
  91     *{"Try::Tiny::$func"} = sub (&;@) {
  92       populate_weakregistry( $weak_registry, $_[0] );
  93       goto $orig;
  94     }
  95   }
  96
  97   # Some modules are known to install singletons on-load
  98   # Load them and empty the registry
  99
 100   # this loads the DT armada
 101   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 102
 103   require Errno;
 104   require DBI;
 105   require DBD::SQLite;
 106   require FileHandle;
 107   require Moo;
 108
 109   %$weak_registry = ();
 110 }
 111
 112 {
 113   use_ok ('DBICTest');
 114
 115   my $schema = DBICTest->init_schema;
 116   my $rs = $schema->resultset ('Artist');
 117   my $storage = $schema->storage;
 118
 119   ok ($storage->connected, 'we are connected');
 120
 121   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 122   ok ($row_obj, 'row from db');
 123
 124   # txn_do to invoke more codepaths
 125   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 126
 127     my $artist = $schema->resultset('Artist')->create ({
 128       name => 'foo artist',
 129       cds => [{
 130         title => 'foo cd',
 131         year => 1984,
 132         tracks => [
 133           { title => 't1' },
 134           { title => 't2' },
 135         ],
 136         genre => { name => 'mauve' },
 137       }],
 138     });
 139
 140     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 141
 142     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 143
 144     return ($artist, $pg, $pg_wcount);
 145   });
 146
 147   # more codepaths - error handling in txn_do
 148   {
 149     eval { $schema->txn_do ( sub {
 150       $storage->_dbh->begin_work;
 151       fail ('how did we get so far?!');
 152     } ) };
 153
 154     eval { $schema->txn_do ( sub {
 155       $schema->txn_do ( sub {
 156         die "It's called EXCEPTION";
 157         fail ('how did we get so far?!');
 158       } );
 159       fail ('how did we get so far?!');
 160     } ) };
 161     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 162   }
 163
 164   # dbh_do codepath
 165   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 166     my $row = $_[0]->schema->resultset('Artist')->new({});
 167     my $rs = $_[0]->schema->resultset('Artist')->search({
 168       name => $row,  # this is deliberately bogus, see FIXME below!
 169     });
 170     return ($rs, $row);
 171   });
 172
 173   is ($pager->next_page, 3, 'There is one more page available');
 174
 175   # based on 66 per 10 pages
 176   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 177
 178   # do some population (invokes some extra codepaths)
 179   # also exercise the guard code and the manual txn control
 180   {
 181     my $guard = $schema->txn_scope_guard;
 182     # populate with bindvars
 183     $rs->populate([{ name => 'James Bound' }]);
 184     $guard->commit;
 185
 186     $schema->txn_begin;
 187     # populate mixed
 188     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 189     $schema->txn_commit;
 190
 191     $schema->txn_begin;
 192     # and without bindvars
 193     $rs->populate([{ name => \ '"James Unbound"' }]);
 194     $schema->txn_rollback;
 195   }
 196
 197   # prefetching
 198   my $cds_rs = $schema->resultset('CD');
 199   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 200   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 201   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 202
 203   # implicit pref
 204   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 205
 206   # get_column
 207   my $getcol_rs = $cds_rs->get_column('me.cdid');
 208   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 209
 210   my $base_collection = {
 211     resultset => $rs,
 212
 213     pref_precursor => $cds_rs,
 214
 215     pref_rs_single => $cds_with_artist,
 216     pref_rs_multi => $cds_with_tracks,
 217     pref_rs_nested => $cds_with_stuff,
 218
 219     pref_rs_implicit => $cds_with_impl_artist,
 220
 221     pref_row_single => $cds_with_artist->next,
 222     pref_row_multi => $cds_with_tracks->next,
 223     pref_row_nested => $cds_with_stuff->next,
 224
 225     # even though this does not leak Storable croaks on it :(((
 226     #pref_row_implicit => $cds_with_impl_artist->next,
 227
 228     get_column_rs_plain => $getcol_rs,
 229     get_column_rs_pref => $pref_getcol_rs,
 230
 231     # twice so that we make sure only one H::M object spawned
 232     chained_resultset => $rs->search_rs ({}, { '+columns' => { foo => 'artistid' } } ),
 233     chained_resultset2 => $rs->search_rs ({}, { '+columns' => { bar => 'artistid' } } ),
 234
 235     row_object => $row_obj,
 236
 237     mc_row_object => $mc_row_obj,
 238
 239     result_source => $rs->result_source,
 240
 241     result_source_handle => $rs->result_source->handle,
 242
 243     pager_explicit_count => $pager_explicit_count,
 244
 245     leaky_resultset => $rs_bind_circref,
 246     leaky_resultset_cond => $cond_rowobj,
 247   };
 248
 249   # fire all resultsets multiple times, once here, more below
 250   # some of these can't find anything (notably leaky_resultset)
 251   my @rsets = grep {
 252     blessed $_
 253       and
 254     (
 255       $_->isa('DBIx::Class::ResultSet')
 256         or
 257       $_->isa('DBIx::Class::ResultSetColumn')
 258     )
 259   } values %$base_collection;
 260
 261
 262   my $fire_resultsets = sub {
 263     local $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS} = 1;
 264     local $SIG{__WARN__} = sigwarn_silencer(
 265       qr/Unable to deflate 'filter'-type relationship 'artist'.+related object primary key not retrieved/
 266     );
 267
 268     map
 269       { $_, (blessed($_) ? { $_->get_columns } : ()) }
 270       map
 271         { $_->all }
 272         @rsets
 273     ;
 274   };
 275
 276   push @{$base_collection->{random_results}}, $fire_resultsets->();
 277
 278   # FIXME - something throws a Storable for a spin if we keep
 279   # the results in-collection. The same problem is seen above,
 280   # swept under the rug back in 0a03206a, damned lazy ribantainer
 281 {
 282   local $base_collection->{random_results};
 283
 284   require Storable;
 285   %$base_collection = (
 286     %$base_collection,
 287     refrozen => Storable::dclone( $base_collection ),
 288     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 289     pref_row_implicit => $cds_with_impl_artist->next,
 290     schema => $schema,
 291     storage => $storage,
 292     sql_maker => $storage->sql_maker,
 293     dbh => $storage->_dbh,
 294     fresh_pager => $rs->page(5)->pager,
 295     pager => $pager,
 296   );
 297 }
 298
 299   # FIXME - ideally this kind of collector ought to be global, but attempts
 300   # with an invasive debugger-based tracer did not quite work out... yet
 301   # Manually scan the innards of everything we have in the base collection
 302   # we assembled so far (skip the DT madness below) *recursively*
 303   #
 304   # Only do this when we do have the bits to look inside CVs properly,
 305   # without it we are liable to pick up object defaults that are locked
 306   # in method closures
 307   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 308     visit_refs(
 309       refs => [ $base_collection ],
 310       action => sub {
 311         populate_weakregistry ($weak_registry, $_[0]);
 312         1;  # true means "keep descending"
 313       },
 314     );
 315
 316     # do a heavy-duty fire-and-compare loop on all resultsets
 317     # this is expensive - not running on install
 318     my $typecounts = {};
 319     if (
 320       ! DBICTest::RunMode->is_plain
 321         and
 322       ! $ENV{DBICTEST_IN_PERSISTENT_ENV}
 323     ) {
 324
 325       # FIXME - ideally we should be able to just populate an alternative
 326       # registry, subtract everything from the main one, and arrive at
 327       # an "empty" resulting hash
 328       # However due to gross inefficiencies in the ::ResultSet code we
 329       # end up recalculating a new set of aliasmaps which could have very
 330       # well been cached if it wasn't for... anyhow
 331       # What we do here for the time being is similar to the lazy approach
 332       # of Devel::LeakTrace - we just make sure we do not end up with more
 333       # reftypes than when we started. At least we are not blanket-counting
 334       # SVs like D::LT does, but going by reftype... sigh...
 335
 336       for (values %$weak_registry) {
 337         if ( my $r = reftype($_->{weakref}) ) {
 338           $typecounts->{$r}--;
 339         }
 340       }
 341
 342       # For now we can only reuse the same registry, see FIXME above/below
 343       #for my $interim_wr ({}, {}) {
 344       for my $interim_wr ( ($weak_registry) x 4 ) {
 345
 346         visit_refs(
 347           refs => [ $fire_resultsets->(), @rsets ],
 348           action => sub {
 349             populate_weakregistry ($interim_wr, $_[0]);
 350             1;  # true means "keep descending"
 351           },
 352         );
 353
 354         # FIXME - this is what *should* be here
 355         #
 356         ## anything we have seen so far is cool
 357         #delete @{$interim_wr}{keys %$weak_registry};
 358         #
 359         ## moment of truth - the rest ought to be gone
 360         #assert_empty_weakregistry($interim_wr);
 361       }
 362
 363       for (values %$weak_registry) {
 364         if ( my $r = reftype($_->{weakref}) ) {
 365           $typecounts->{$r}++;
 366         }
 367       }
 368     }
 369
 370     for (keys %$typecounts) {
 371       fail ("Amount of $_ refs changed by $typecounts->{$_} during resultset mass-execution")
 372         if ( abs ($typecounts->{$_}) > 1 ); # there is a pad caught somewhere, the +1/-1 can be ignored
 373     }
 374   }
 375
 376   if ($has_dt) {
 377     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 378
 379     my $now = DateTime->now;
 380     for (1..5) {
 381       $base_collection->{"icdt_row_$_"} = $rs->create({
 382         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 383         starts_at => $now->clone->add(days => $_),
 384       });
 385     }
 386
 387     # re-search
 388     my @dummy = $rs->all;
 389   }
 390
 391   # dbh's are created in XS space, so pull them separately
 392   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 393     $base_collection->{"DBI handle $_"} = $_;
 394   }
 395
 396   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 397     for keys %$base_collection;
 398 }
 399
 400 # check that "phantom-chaining" works - we never lose track of the original $schema
 401 # and have access to the entire tree without leaking anything
 402 {
 403   my $phantom;
 404   for (
 405     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 406     sub { shift->source('Artist') },
 407     sub { shift->resultset },
 408     sub { shift->result_source },
 409     sub { shift->schema },
 410     sub { shift->resultset('Artist') },
 411     sub { shift->find_or_create({ name => 'detachable' }) },
 412     sub { shift->result_source },
 413     sub { shift->schema },
 414     sub { shift->clone },
 415     sub { shift->resultset('CD') },
 416     sub { shift->next },
 417     sub { shift->artist },
 418     sub { shift->search_related('cds') },
 419     sub { shift->next },
 420     sub { shift->search_related('artist') },
 421     sub { shift->result_source },
 422     sub { shift->resultset },
 423     sub { shift->create({ name => 'detached' }) },
 424     sub { shift->update({ name => 'reattached' }) },
 425     sub { shift->discard_changes },
 426     sub { shift->delete },
 427     sub { shift->insert },
 428   ) {
 429     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 430   }
 431
 432   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 433   is( $phantom->name, 'reattached', 'Still correct name' );
 434 }
 435
 436 # Naturally we have some exceptions
 437 my $cleared;
 438 for my $addr (keys %$weak_registry) {
 439   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 440
 441   if ($names =~ /^Test::Builder/m) {
 442     # T::B 2.0 has result objects and other fancyness
 443     delete $weak_registry->{$addr};
 444   }
 445   elsif ($names =~ /^Hash::Merge/m) {
 446     # only clear one object of a specific behavior - more would indicate trouble
 447     delete $weak_registry->{$addr}
 448       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 449   }
 450   elsif ($names =~ /^DateTime::TimeZone::UTC/m) {
 451     # DT is going through a refactor it seems - let it leak zones for now
 452     delete $weak_registry->{$addr};
 453   }
 454   elsif (
 455 #    # if we can look at closed over pieces - we will register it as a global
 456 #    !DBICTest::Util::LeakTracer::CV_TRACING
 457 #      and
 458     $names =~ /^SQL::Translator::Generator::DDL::SQLite/m
 459   ) {
 460     # SQLT::Producer::SQLite keeps global generators around for quoted
 461     # and non-quoted DDL, allow one for each quoting style
 462     delete $weak_registry->{$addr}
 463       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$addr}{weakref}->quote_chars}}++;
 464   }
 465 }
 466
 467 # FIXME !!!
 468 # There is an actual strong circular reference taking place here, but because
 469 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 470 # (our tracker does not yet do it, but it'd be nice)
 471 # The problem is:
 472 #
 473 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 474 #          ^                                                           /
 475 #           \-------- bound value on prepared/cached STH  <-----------/
 476 #
 477 {
 478   my @circreffed;
 479
 480   for my $r (map
 481     { $_->{weakref} }
 482     grep
 483       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 484       values %$weak_registry
 485   ) {
 486     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 487     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 488       or push @circreffed, $r;
 489   }
 490
 491   if (@circreffed) {
 492     is (scalar @circreffed, 1, 'One resultset expected to leak');
 493
 494     # this is useless on its own, it is to showcase the circref-diag
 495     # and eventually test it when it is operational
 496     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 497     while (@circreffed) {
 498       weaken (my $r = shift @circreffed);
 499
 500       populate_weakregistry( (my $mini_registry = {}), $r );
 501       assert_empty_weakregistry( $mini_registry );
 502
 503       $r->result_source(undef);
 504     }
 505   }
 506 }
 507
 508 assert_empty_weakregistry ($weak_registry);
 509
 510 # we got so far without a failure - this is a good thing
 511 # now let's try to rerun this script under a "persistent" environment
 512 # this is ugly and dirty but we do not yet have a Test::Embedded or
 513 # similar
 514
 515 # set up -I
 516 require Config;
 517 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 518 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 519
 520
 521 my $persistence_tests;
 522 SKIP: {
 523   skip 'Test already in a persistent loop', 1
 524     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 525
 526   skip 'Main test failed - skipping persistent env tests', 1
 527     unless $TB->is_passing;
 528
 529   skip "Test::Builder\@@{[ Test::Builder->VERSION ]} known to break persistence tests", 1
 530     if modver_gt_or_eq_and_lt( 'Test::More', '1.200', '1.301001_099' );
 531
 532   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 533
 534   $persistence_tests = {
 535     PPerl => {
 536       cmd => [qw/pperl --prefork=1/, __FILE__],
 537     },
 538     'CGI::SpeedyCGI' => {
 539       cmd => [qw/speedy -- -t5/, __FILE__],
 540     },
 541   };
 542
 543   # scgi is smart and will auto-reap after -t amount of seconds
 544   # pperl needs an actual killer :(
 545   $persistence_tests->{PPerl}{termcmd} = [
 546     $persistence_tests->{PPerl}{cmd}[0],
 547     '--kill',
 548     @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 549   ];
 550
 551   require IPC::Open2;
 552
 553   for my $type (keys %$persistence_tests) { SKIP: {
 554     unless (eval "require $type") {
 555       # Don't terminate what we didn't start
 556       delete $persistence_tests->{$type}{termcmd};
 557       skip "$type module not found", 1;
 558     }
 559
 560     my @cmd = @{$persistence_tests->{$type}{cmd}};
 561
 562     # since PPerl is racy and sucks - just prime the "server"
 563     {
 564       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 565       system(@cmd);
 566       sleep 1;
 567
 568       # see if the thing actually runs, if not - might as well bail now
 569       skip "Something is wrong with $type ($!)", 1
 570         if system(@cmd);
 571     }
 572
 573     for (1,2,3) {
 574       note ("Starting run in persistent env ($type pass $_)");
 575       IPC::Open2::open2(my $out, undef, @cmd);
 576       my @out_lines;
 577       while (my $ln = <$out>) {
 578         next if $ln =~ /^\s*$/;
 579         push @out_lines, "   $ln";
 580         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 581       }
 582       print $_ for @out_lines;
 583       close $out;
 584       wait;
 585       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 586       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 587     }
 588
 589     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 590       if $persistence_tests->{$type}{termcmd};
 591   }}
 592 }
 593
 594 done_testing;
 595
 596 # just an extra precaution in case we blew away from the SKIP - since there are no
 597 # PID files to go by (man does pperl really suck :(
 598 END {
 599   if ($persistence_tests->{PPerl}{termcmd}) {
 600     local $?; # otherwise test will inherit $? of the system()
 601     require IPC::Open3;
 602     open my $null, ">", File::Spec->devnull;
 603     waitpid(
 604       IPC::Open3::open3(undef, $null, $null, @{$persistence_tests->{PPerl}{termcmd}}),
 605       0,
 606     );
 607   }
 608 }