t/52leaks.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 # work around brain damage in PPerl (yes, it has to be a global)
   4 $SIG{__WARN__} = sub {
   5   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   6 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   7
   8 # the persistent environments run with this flag first to see if
   9 # we will run at all (e.g. it will fail if $^X doesn't match)
  10 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
  11
  12 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  13 # We will replace $bless_override only if we are in author mode
  14 my $bless_override;
  15 BEGIN {
  16   $bless_override = sub {
  17     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  18   };
  19   *CORE::GLOBAL::bless = sub { goto $bless_override };
  20 }
  21
  22 use strict;
  23 use warnings;
  24 use Test::More;
  25
  26 BEGIN {
  27   require DBICTest::Util;
  28   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  29     if DBICTest::Util::PEEPEENESS();
  30 }
  31
  32 use DBICTest::RunMode;
  33 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  34 use Scalar::Util qw(weaken blessed reftype);
  35 use DBIx::Class::_Util qw(hrefaddr sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt);
  36
  37 my $TB = Test::More->builder;
  38 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  39   # without this explicit close TB warns in END after a ->reset
  40   close ($TB->$_) for qw(output failure_output todo_output);
  41
  42   # newer TB does not auto-reopen handles
  43   if ( modver_gt_or_eq( 'Test::More', '1.200' ) ) {
  44     open ($TB->$_, '>&', *STDERR)
  45       for qw( failure_output todo_output );
  46     open ($TB->output, '>&', *STDOUT);
  47   }
  48
  49   # so done_testing can work on every persistent pass
  50   $TB->reset;
  51 }
  52
  53 # this is what holds all weakened refs to be checked for leakage
  54 my $weak_registry = {};
  55
  56 # whether or to invoke IC::DT
  57 my $has_dt;
  58
  59 # Skip the heavy-duty leak tracing when just doing an install
  60 # or when having Moose crap all over everything
  61 if ( !$ENV{DBICTEST_VIA_REPLICATED} and !DBICTest::RunMode->is_plain ) {
  62
  63   # redefine the bless override so that we can catch each and every object created
  64   no warnings qw/redefine once/;
  65   no strict qw/refs/;
  66
  67   $bless_override = sub {
  68
  69     my $obj = CORE::bless(
  70       $_[0], (@_ > 1) ? $_[1] : do {
  71         my ($class, $fn, $line) = caller();
  72         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  73           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  74         $class;
  75       }
  76     );
  77
  78     # unicode is tricky, and now we happen to invoke it early via a
  79     # regex in connection()
  80     return $obj if (ref $obj) =~ /^utf8/;
  81
  82     # Test Builder is now making a new object for every pass/fail (que bloat?)
  83     # and as such we can't really store any of its objects (since it will
  84     # re-populate the registry while checking it, ewwww!)
  85     return $obj if (ref $obj) =~ /^TB2::|^Test::Stream/;
  86
  87     # populate immediately to avoid weird side effects
  88     return populate_weakregistry ($weak_registry, $obj );
  89   };
  90
  91   require Try::Tiny;
  92   for my $func (qw/try catch finally/) {
  93     my $orig = \&{"Try::Tiny::$func"};
  94     *{"Try::Tiny::$func"} = sub (&;@) {
  95       populate_weakregistry( $weak_registry, $_[0] );
  96       goto $orig;
  97     }
  98   }
  99
 100   # Some modules are known to install singletons on-load
 101   # Load them and empty the registry
 102
 103   # this loads the DT armada
 104   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for([qw( test_rdbms_sqlite ic_dt )]);
 105
 106   require Errno;
 107   require DBI;
 108   require DBD::SQLite;
 109   require FileHandle;
 110   require Moo;
 111
 112   %$weak_registry = ();
 113 }
 114
 115 {
 116   use_ok ('DBICTest');
 117
 118   my $schema = DBICTest->init_schema;
 119   my $rs = $schema->resultset ('Artist');
 120   my $storage = $schema->storage;
 121
 122   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 123   ok ($row_obj, 'row from db');
 124
 125   # txn_do to invoke more codepaths
 126   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 127
 128     my $artist = $schema->resultset('Artist')->create ({
 129       name => 'foo artist',
 130       cds => [{
 131         title => 'foo cd',
 132         year => 1984,
 133         tracks => [
 134           { title => 't1' },
 135           { title => 't2' },
 136         ],
 137         genre => { name => 'mauve' },
 138       }],
 139     });
 140
 141     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 142
 143     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 144
 145     return ($artist, $pg, $pg_wcount);
 146   });
 147
 148   # more codepaths - error handling in txn_do
 149   {
 150     eval { $schema->txn_do ( sub {
 151       $storage->_dbh->begin_work;
 152       fail ('how did we get so far?!');
 153     } ) };
 154
 155     eval { $schema->txn_do ( sub {
 156       $schema->txn_do ( sub {
 157         die "It's called EXCEPTION";
 158         fail ('how did we get so far?!');
 159       } );
 160       fail ('how did we get so far?!');
 161     } ) };
 162     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 163   }
 164
 165   # dbh_do codepath
 166   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 167     my $row = $_[0]->schema->resultset('Artist')->new({});
 168     my $rs = $_[0]->schema->resultset('Artist')->search({
 169       name => $row,  # this is deliberately bogus, see FIXME below!
 170     });
 171     return ($rs, $row);
 172   });
 173
 174   is ($pager->next_page, 3, 'There is one more page available');
 175
 176   # based on 66 per 10 pages
 177   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 178
 179   # do some population (invokes some extra codepaths)
 180   # also exercise the guard code and the manual txn control
 181   {
 182     my $guard = $schema->txn_scope_guard;
 183     # populate with bindvars
 184     $rs->populate([{ name => 'James Bound' }]);
 185     $guard->commit;
 186
 187     $schema->txn_begin;
 188     # populate mixed
 189     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 190     $schema->txn_commit;
 191
 192     $schema->txn_begin;
 193     # and without bindvars
 194     $rs->populate([{ name => \ '"James Unbound"' }]);
 195     $schema->txn_rollback;
 196   }
 197
 198   # prefetching
 199   my $cds_rs = $schema->resultset('CD');
 200   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 201   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 202   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 203
 204   # implicit pref
 205   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 206
 207   # get_column
 208   my $getcol_rs = $cds_rs->get_column('me.cdid');
 209   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 210
 211   my $base_collection = {
 212     resultset => $rs,
 213
 214     pref_precursor => $cds_rs,
 215
 216     pref_rs_single => $cds_with_artist,
 217     pref_rs_multi => $cds_with_tracks,
 218     pref_rs_nested => $cds_with_stuff,
 219
 220     pref_rs_implicit => $cds_with_impl_artist,
 221
 222     pref_row_single => $cds_with_artist->next,
 223     pref_row_multi => $cds_with_tracks->next,
 224     pref_row_nested => $cds_with_stuff->next,
 225
 226     # even though this does not leak Storable croaks on it :(((
 227     #pref_row_implicit => $cds_with_impl_artist->next,
 228
 229     get_column_rs_plain => $getcol_rs,
 230     get_column_rs_pref => $pref_getcol_rs,
 231
 232     # twice so that we make sure only one H::M object spawned
 233     chained_resultset => $rs->search_rs ({}, { '+columns' => { foo => 'artistid' } } ),
 234     chained_resultset2 => $rs->search_rs ({}, { '+columns' => { bar => 'artistid' } } ),
 235
 236     row_object => $row_obj,
 237
 238     mc_row_object => $mc_row_obj,
 239
 240     result_source => $rs->result_source,
 241
 242     result_source_handle => $rs->result_source->handle,
 243
 244     pager_explicit_count => $pager_explicit_count,
 245
 246     leaky_resultset => $rs_bind_circref,
 247     leaky_resultset_cond => $cond_rowobj,
 248   };
 249
 250   # fire all resultsets multiple times, once here, more below
 251   # some of these can't find anything (notably leaky_resultset)
 252   my @rsets = grep {
 253     blessed $_
 254       and
 255     (
 256       $_->isa('DBIx::Class::ResultSet')
 257         or
 258       $_->isa('DBIx::Class::ResultSetColumn')
 259     )
 260   } values %$base_collection;
 261
 262
 263   my $fire_resultsets = sub {
 264     local $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS} = 1;
 265     local $SIG{__WARN__} = sigwarn_silencer(
 266       qr/Unable to deflate 'filter'-type relationship 'artist'.+related object primary key not retrieved/
 267     );
 268
 269     map
 270       { $_, (blessed($_) ? { $_->get_columns } : ()) }
 271       map
 272         { $_->all }
 273         @rsets
 274     ;
 275   };
 276
 277   push @{$base_collection->{random_results}}, $fire_resultsets->();
 278
 279   # FIXME - something throws a Storable for a spin if we keep
 280   # the results in-collection. The same problem is seen above,
 281   # swept under the rug back in 0a03206a, damned lazy ribantainer
 282 {
 283   local $base_collection->{random_results};
 284
 285   require Storable;
 286   %$base_collection = (
 287     %$base_collection,
 288     refrozen => Storable::dclone( $base_collection ),
 289     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 290     pref_row_implicit => $cds_with_impl_artist->next,
 291     schema => $schema,
 292     storage => $storage,
 293     sql_maker => $storage->sql_maker,
 294     dbh => $storage->_dbh,
 295     fresh_pager => $rs->page(5)->pager,
 296     pager => $pager,
 297   );
 298 }
 299
 300   # FIXME - ideally this kind of collector ought to be global, but attempts
 301   # with an invasive debugger-based tracer did not quite work out... yet
 302   # Manually scan the innards of everything we have in the base collection
 303   # we assembled so far (skip the DT madness below) *recursively*
 304   #
 305   # Only do this when we do have the bits to look inside CVs properly,
 306   # without it we are liable to pick up object defaults that are locked
 307   # in method closures
 308   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 309     visit_refs(
 310       refs => [ $base_collection ],
 311       action => sub {
 312         populate_weakregistry ($weak_registry, $_[0]);
 313         1;  # true means "keep descending"
 314       },
 315     );
 316
 317     # do a heavy-duty fire-and-compare loop on all resultsets
 318     # this is expensive - not running on install
 319     my $typecounts = {};
 320     if (
 321       ! DBICTest::RunMode->is_plain
 322         and
 323       ! $ENV{DBICTEST_IN_PERSISTENT_ENV}
 324     ) {
 325
 326       # FIXME - ideally we should be able to just populate an alternative
 327       # registry, subtract everything from the main one, and arrive at
 328       # an "empty" resulting hash
 329       # However due to gross inefficiencies in the ::ResultSet code we
 330       # end up recalculating a new set of aliasmaps which could have very
 331       # well been cached if it wasn't for... anyhow
 332       # What we do here for the time being is similar to the lazy approach
 333       # of Devel::LeakTrace - we just make sure we do not end up with more
 334       # reftypes than when we started. At least we are not blanket-counting
 335       # SVs like D::LT does, but going by reftype... sigh...
 336
 337       for (values %$weak_registry) {
 338         if ( my $r = reftype($_->{weakref}) ) {
 339           $typecounts->{$r}--;
 340         }
 341       }
 342
 343       # For now we can only reuse the same registry, see FIXME above/below
 344       #for my $interim_wr ({}, {}) {
 345       for my $interim_wr ( ($weak_registry) x 4 ) {
 346
 347         visit_refs(
 348           refs => [ $fire_resultsets->(), @rsets ],
 349           action => sub {
 350             populate_weakregistry ($interim_wr, $_[0]);
 351             1;  # true means "keep descending"
 352           },
 353         );
 354
 355         # FIXME - this is what *should* be here
 356         #
 357         ## anything we have seen so far is cool
 358         #delete @{$interim_wr}{keys %$weak_registry};
 359         #
 360         ## moment of truth - the rest ought to be gone
 361         #assert_empty_weakregistry($interim_wr);
 362       }
 363
 364       for (values %$weak_registry) {
 365         if ( my $r = reftype($_->{weakref}) ) {
 366           $typecounts->{$r}++;
 367         }
 368       }
 369     }
 370
 371     for (keys %$typecounts) {
 372       fail ("Amount of $_ refs changed by $typecounts->{$_} during resultset mass-execution")
 373         if ( abs ($typecounts->{$_}) > 1 ); # there is a pad caught somewhere, the +1/-1 can be ignored
 374     }
 375   }
 376
 377   if ($has_dt) {
 378     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 379
 380     my $now = DateTime->now;
 381     for (1..5) {
 382       $base_collection->{"icdt_row_$_"} = $rs->create({
 383         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 384         starts_at => $now->clone->add(days => $_),
 385       });
 386     }
 387
 388     # re-search
 389     my @dummy = $rs->all;
 390   }
 391
 392   # dbh's are created in XS space, so pull them separately
 393   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 394     $base_collection->{"DBI handle $_"} = $_;
 395   }
 396
 397   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 398     for keys %$base_collection;
 399 }
 400
 401 # check that "phantom-chaining" works - we never lose track of the original $schema
 402 # and have access to the entire tree without leaking anything
 403 {
 404   my $phantom;
 405   for (
 406     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 407     sub { shift->source('Artist') },
 408     sub { shift->resultset },
 409     sub { shift->result_source },
 410     sub { shift->schema },
 411     sub { shift->resultset('Artist') },
 412     sub { shift->find_or_create({ name => 'detachable' }) },
 413     sub { shift->result_source },
 414     sub { shift->schema },
 415     sub { shift->clone },
 416     sub { shift->resultset('CD') },
 417     sub { shift->next },
 418     sub { shift->artist },
 419     sub { shift->search_related('cds') },
 420     sub { shift->next },
 421     sub { shift->search_related('artist') },
 422     sub { shift->result_source },
 423     sub { shift->resultset },
 424     sub { shift->create({ name => 'detached' }) },
 425     sub { shift->update({ name => 'reattached' }) },
 426     sub { shift->discard_changes },
 427     sub { shift->delete },
 428     sub { shift->insert },
 429   ) {
 430     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 431   }
 432
 433   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 434   is( $phantom->name, 'reattached', 'Still correct name' );
 435 }
 436
 437 # Naturally we have some exceptions
 438 my $cleared;
 439 for my $addr (keys %$weak_registry) {
 440   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 441
 442   if ($names =~ /^Test::Builder/m) {
 443     # T::B 2.0 has result objects and other fancyness
 444     delete $weak_registry->{$addr};
 445   }
 446   elsif ($names =~ /^Class::Struct/m) {
 447     # remove this when Path::Class is gone, what a crock of shit
 448     delete $weak_registry->{$addr};
 449   }
 450   elsif ($names =~ /^Hash::Merge/m) {
 451     # only clear one object of a specific behavior - more would indicate trouble
 452     delete $weak_registry->{$addr}
 453       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 454   }
 455   elsif ($names =~ /^B::Hooks::EndOfScope::PP::_TieHintHashFieldHash/m) {
 456     # there is one tied lexical which stays alive until GC time
 457     # https://metacpan.org/source/ETHER/B-Hooks-EndOfScope-0.15/lib/B/Hooks/EndOfScope/PP/FieldHash.pm#L24
 458     # simply ignore it here, instead of teaching the leaktracer to examine ties
 459     # the latter is possible yet terrible: https://github.com/dbsrgits/dbix-class/blob/v0.082820/t/lib/DBICTest/Util/LeakTracer.pm#L113-L117
 460     delete $weak_registry->{$addr}
 461       unless $cleared->{bheos_pptiehinthashfieldhash}++;
 462   }
 463   elsif ($names =~ /^DateTime::TimeZone::UTC/m) {
 464     # DT is going through a refactor it seems - let it leak zones for now
 465     delete $weak_registry->{$addr};
 466   }
 467   elsif (
 468 #    # if we can look at closed over pieces - we will register it as a global
 469 #    !DBICTest::Util::LeakTracer::CV_TRACING
 470 #      and
 471     $names =~ /^SQL::Translator::Generator::DDL::SQLite/m
 472   ) {
 473     # SQLT::Producer::SQLite keeps global generators around for quoted
 474     # and non-quoted DDL, allow one for each quoting style
 475     delete $weak_registry->{$addr}
 476       unless $cleared->{sqlt_ddl_sqlite}->{@{$weak_registry->{$addr}{weakref}->quote_chars}}++;
 477   }
 478 }
 479
 480 # FIXME !!!
 481 # There is an actual strong circular reference taking place here, but because
 482 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 483 # (our tracker does not yet do it, but it'd be nice)
 484 # The problem is:
 485 #
 486 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 487 #          ^                                                           /
 488 #           \-------- bound value on prepared/cached STH  <-----------/
 489 #
 490 {
 491   my @circreffed;
 492
 493   for my $r (map
 494     { $_->{weakref} }
 495     grep
 496       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 497       values %$weak_registry
 498   ) {
 499     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 500     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 501       or push @circreffed, $r;
 502   }
 503
 504   if (@circreffed) {
 505     is (scalar @circreffed, 1, 'One resultset expected to leak');
 506
 507     # this is useless on its own, it is to showcase the circref-diag
 508     # and eventually test it when it is operational
 509     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 510     while (@circreffed) {
 511       weaken (my $r = shift @circreffed);
 512
 513       populate_weakregistry( (my $mini_registry = {}), $r );
 514       assert_empty_weakregistry( $mini_registry );
 515
 516       $r->result_source(undef);
 517     }
 518   }
 519 }
 520
 521 assert_empty_weakregistry ($weak_registry);
 522
 523 # we got so far without a failure - this is a good thing
 524 # now let's try to rerun this script under a "persistent" environment
 525 # this is ugly and dirty but we do not yet have a Test::Embedded or
 526 # similar
 527
 528 my $persistence_tests;
 529 SKIP: {
 530   skip 'Test already in a persistent loop', 1
 531     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 532
 533   skip 'Main test failed - skipping persistent env tests', 1
 534     unless $TB->is_passing;
 535
 536   skip "Test::Builder\@@{[ Test::Builder->VERSION ]} known to break persistence tests", 1
 537     if modver_gt_or_eq_and_lt( 'Test::More', '1.200', '1.301001_099' );
 538
 539   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 540
 541   require File::Spec;
 542
 543   $persistence_tests = {
 544     PPerl => {
 545       cmd => [qw/pperl --prefork=1/, __FILE__],
 546     },
 547     'CGI::SpeedyCGI' => {
 548       cmd => [qw/speedy -- -t5/, __FILE__],
 549     },
 550   };
 551
 552   # scgi is smart and will auto-reap after -t amount of seconds
 553   # pperl needs an actual killer :(
 554   $persistence_tests->{PPerl}{termcmd} = [
 555     $persistence_tests->{PPerl}{cmd}[0],
 556     '--kill',
 557     @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 558   ];
 559
 560   # set up -I
 561   require Config;
 562   $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 563
 564   # adjust PATH for -T
 565   if (length $ENV{PATH}) {
 566     ( $ENV{PATH} ) = join ( $Config::Config{path_sep},
 567       map { length($_) ? File::Spec->rel2abs($_) : () }
 568         split /\Q$Config::Config{path_sep}/, $ENV{PATH}
 569     ) =~ /\A(.+)\z/;
 570   }
 571
 572   for my $type (keys %$persistence_tests) { SKIP: {
 573     unless (eval "require $type") {
 574       # Don't terminate what we didn't start
 575       delete $persistence_tests->{$type}{termcmd};
 576       skip "$type module not found", 1;
 577     }
 578
 579     my @cmd = @{$persistence_tests->{$type}{cmd}};
 580
 581     # since PPerl is racy and sucks - just prime the "server"
 582     {
 583       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 584       system(@cmd);
 585       sleep 1;
 586
 587       # see if the thing actually runs, if not - might as well bail now
 588       skip "Something is wrong with $type ($!)", 1
 589         if system(@cmd);
 590     }
 591
 592     require IPC::Open2;
 593
 594     for (1,2,3) {
 595       note ("Starting run in persistent env ($type pass $_)");
 596       IPC::Open2::open2(my $out, undef, @cmd);
 597       my @out_lines;
 598       while (my $ln = <$out>) {
 599         next if $ln =~ /^\s*$/;
 600         push @out_lines, "   $ln";
 601         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 602       }
 603       print $_ for @out_lines;
 604       close $out;
 605       wait;
 606       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 607       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 608     }
 609
 610     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 611       if $persistence_tests->{$type}{termcmd};
 612   }}
 613 }
 614
 615 done_testing;
 616
 617 # just an extra precaution in case we blew away from the SKIP - since there are no
 618 # PID files to go by (man does pperl really suck :(
 619 END {
 620   if ($persistence_tests->{PPerl}{termcmd}) {
 621     local $?; # otherwise test will inherit $? of the system()
 622     require IPC::Open3;
 623     open my $null, ">", File::Spec->devnull;
 624     waitpid(
 625       IPC::Open3::open3(undef, $null, $null, @{$persistence_tests->{PPerl}{termcmd}}),
 626       0,
 627     );
 628   }
 629 }