t/51threadtxn.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 # README: If you set the env var to a number greater than 10,
   4 #   we will use that many children
   5
   6 use Config;
   7 BEGIN {
   8   unless ($Config{useithreads}) {
   9     print "1..0 # SKIP your perl does not support ithreads\n";
  10     exit 0;
  11   }
  12
  13   if ($INC{'Devel/Cover.pm'}) {
  14     print "1..0 # SKIP Devel::Cover does not work with threads yet\n";
  15     exit 0;
  16   }
  17 }
  18 use threads;
  19
  20 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
  21
  22 use strict;
  23 use warnings;
  24
  25 use Test::More;
  26
  27 plan skip_all => 'DBIC does not actively support threads before perl 5.8.5'
  28   if "$]" < 5.008005;
  29
  30 use Scalar::Util 'weaken';
  31
  32 use DBICTest;
  33
  34 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  35 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  36    $num_children = 10;
  37 }
  38
  39 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  40
  41 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  42
  43 my $parent_rs;
  44
  45 eval {
  46     my $dbh = $schema->storage->dbh;
  47
  48     {
  49         local $SIG{__WARN__} = sub {};
  50         eval { $dbh->do("DROP TABLE cd") };
  51         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  52     }
  53
  54     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  55     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  56
  57     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  58     is ($parent_rs->count, 2);
  59 };
  60 ok(!$@) or diag "Creation eval failed: $@";
  61
  62 my @children;
  63 while(@children < $num_children) {
  64
  65     my $newthread = async {
  66         my $tid = threads->tid;
  67         weaken(my $weak_schema = $schema);
  68         weaken(my $weak_parent_rs = $parent_rs);
  69         $schema->txn_do(sub {
  70             my $child_rs = $weak_schema->resultset('CD')->search({ year => 1901 });
  71             my $row = $weak_parent_rs->next;
  72             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  73                 $weak_schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  74             }
  75         });
  76         sleep(1);  # tasty crashes without this
  77     };
  78     die "Thread creation failed: $! $@" if !defined $newthread;
  79     push(@children, $newthread);
  80 }
  81
  82 ok(1, "past spawning");
  83
  84 {
  85     $_->join for(@children);
  86 }
  87
  88 ok(1, "past joining");
  89
  90 while(@children) {
  91     my $child = pop(@children);
  92     my $tid = $child->tid;
  93     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  94     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  95 }
  96
  97 ok(1, "Made it to the end");
  98
  99 $schema->storage->dbh->do("DROP TABLE cd");
 100
 101 done_testing;