t/51threadtxn.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Config;
   5
   6 # README: If you set the env var to a number greater than 10,
   7 #   we will use that many children
   8
   9 BEGIN {
  10     plan skip_all => 'Your perl does not support ithreads'
  11         if !$Config{useithreads};
  12 }
  13
  14 use threads;
  15 use lib qw(t/lib);
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  18 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  19       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  20
  21
  22 my $num_children = $ENV{DBICTEST_THREAD_STRESS};
  23 plan skip_all => 'Set $ENV{DBICTEST_THREAD_STRESS} to run this test'
  24     unless $num_children;
  25
  26 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  27    $num_children = 10;
  28 }
  29
  30 use_ok('DBICTest::Schema');
  31
  32 diag "\n\nIt is ok if you see series of 'Attempt to free unreferenced scalar: ...' warnings during this test\n "
  33   if $] < '5.008005';
  34
  35 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  36
  37 my $parent_rs;
  38
  39 eval {
  40     my $dbh = $schema->storage->dbh;
  41
  42     {
  43         local $SIG{__WARN__} = sub {};
  44         eval { $dbh->do("DROP TABLE cd") };
  45         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  46     }
  47
  48     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  49     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  50
  51     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  52     $parent_rs->next;
  53 };
  54 ok(!$@) or diag "Creation eval failed: $@";
  55
  56 my @children;
  57 while(@children < $num_children) {
  58
  59     my $newthread = async {
  60         my $tid = threads->tid;
  61         # my $dbh = $schema->storage->dbh;
  62
  63         $schema->txn_do(sub {
  64             my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  65             my $row = $parent_rs->next;
  66             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  67                 $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  68             }
  69         });
  70         sleep(3);
  71     };
  72     die "Thread creation failed: $! $@" if !defined $newthread;
  73     push(@children, $newthread);
  74 }
  75
  76 ok(1, "past spawning");
  77
  78 {
  79     $_->join for(@children);
  80 }
  81
  82 ok(1, "past joining");
  83
  84 while(@children) {
  85     my $child = pop(@children);
  86     my $tid = $child->tid;
  87     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  88     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  89 }
  90
  91 ok(1, "Made it to the end");
  92
  93 $schema->storage->dbh->do("DROP TABLE cd");
  94
  95 done_testing;