t/51threadtxn.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 # README: If you set the env var to a number greater than 5,
   4 #   we will use that many children
   5
   6 use Config;
   7 BEGIN {
   8   unless ($Config{useithreads}) {
   9     print "1..0 # SKIP your perl does not support ithreads\n";
  10     exit 0;
  11   }
  12
  13   if ($INC{'Devel/Cover.pm'}) {
  14     print "1..0 # SKIP Devel::Cover does not work with threads yet\n";
  15     exit 0;
  16   }
  17 }
  18 use threads;
  19
  20 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
  21
  22 use strict;
  23 use warnings;
  24
  25 use Test::More;
  26
  27 plan skip_all => 'DBIC does not actively support threads before perl 5.8.5'
  28   if "$]" < 5.008005;
  29
  30 use Scalar::Util 'weaken';
  31 use Time::HiRes qw(time sleep);
  32 use List::Util 'max';
  33
  34 use DBICTest;
  35
  36 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  37 if($num_children !~ /^[0-9]+$/ || $num_children < 5) {
  38    $num_children = 5;
  39 }
  40
  41 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  42
  43 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  44
  45 my $parent_rs;
  46
  47 eval {
  48     my $dbh = $schema->storage->dbh;
  49
  50     {
  51         local $SIG{__WARN__} = sub {};
  52         eval { $dbh->do("DROP TABLE cd") };
  53         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  54     }
  55
  56     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  57     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  58
  59     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  60     is ($parent_rs->count, 2);
  61 };
  62 ok(!$@) or diag "Creation eval failed: $@";
  63
  64 # sleep until this spot so everything starts simultaneously
  65 # add "until turn of second" for prettier display
  66 my $t = int( time() ) + 4;
  67
  68 my @children;
  69 while(@children < $num_children) {
  70
  71     my $newthread = async {
  72         my $tid = threads->tid;
  73
  74         sleep( max( 0.1, $t - time ) );
  75
  76         # FIXME if we do not stagger the threads, sparks fly due to CXSA
  77         sleep ( $tid / 10 ) if "$]" < 5.012;
  78
  79         note ("Thread $tid starting work at " . time() );
  80
  81         weaken(my $weak_schema = $schema);
  82         weaken(my $weak_parent_rs = $parent_rs);
  83         $schema->txn_do(sub {
  84             my $child_rs = $weak_schema->resultset('CD')->search({ year => 1901 });
  85             my $row = $weak_parent_rs->next;
  86             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  87                 $weak_schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  88             }
  89         });
  90
  91         sleep (0.2); # without this many tasty crashes even on latest perls
  92     };
  93     die "Thread creation failed: $! $@" if !defined $newthread;
  94     push(@children, $newthread);
  95 }
  96
  97 ok(1, "past spawning");
  98
  99 {
 100     $_->join for(@children);
 101 }
 102
 103 ok(1, "past joining");
 104
 105 while(@children) {
 106     my $child = pop(@children);
 107     my $tid = $child->tid;
 108     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
 109     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
 110 }
 111
 112 ok(1, "Made it to the end");
 113
 114 $schema->storage->dbh->do("DROP TABLE cd");
 115
 116 # Too many threading bugs on exit, none of which have anything to do with
 117 # the actual stuff we test
 118 $ENV{DBICTEST_DIRTY_EXIT} = 1
 119   if "$]" < 5.012;
 120
 121 done_testing;