t/51threadtxn.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 # README: If you set the env var to a number greater than 5,
   4 #   we will use that many children
   5
   6 use Config;
   7 BEGIN {
   8   unless ($Config{useithreads}) {
   9     print "1..0 # SKIP your perl does not support ithreads\n";
  10     exit 0;
  11   }
  12
  13   if ($INC{'Devel/Cover.pm'}) {
  14     print "1..0 # SKIP Devel::Cover does not work with threads yet\n";
  15     exit 0;
  16   }
  17 }
  18 use threads;
  19
  20 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
  21
  22 use strict;
  23 use warnings;
  24
  25 use Test::More;
  26
  27 plan skip_all => 'DBIC does not actively support threads before perl 5.8.5'
  28   if "$]" < 5.008005;
  29
  30 use Scalar::Util 'weaken';
  31 use Time::HiRes qw(time sleep);
  32
  33 use DBICTest;
  34
  35 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  36 if($num_children !~ /^[0-9]+$/ || $num_children < 5) {
  37    $num_children = 5;
  38 }
  39
  40 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  41
  42 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  43
  44 my $parent_rs;
  45
  46 eval {
  47     my $dbh = $schema->storage->dbh;
  48
  49     {
  50         local $SIG{__WARN__} = sub {};
  51         eval { $dbh->do("DROP TABLE cd") };
  52         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  53     }
  54
  55     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  56     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  57
  58     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  59     is ($parent_rs->count, 2);
  60 };
  61 ok(!$@) or diag "Creation eval failed: $@";
  62
  63 # sleep until this spot so everything starts simultaneously
  64 # add "until turn of second" for prettier display
  65 my $t = int( time() ) + 4;
  66
  67 my @children;
  68 while(@children < $num_children) {
  69
  70     my $newthread = async {
  71         my $tid = threads->tid;
  72
  73         sleep ($t - time);
  74
  75         # FIXME if we do not stagger the threads, sparks fly due to CXSA
  76         sleep ( $tid / 10 ) if "$]" < 5.012;
  77
  78         note ("Thread $tid starting work at " . time() );
  79
  80         weaken(my $weak_schema = $schema);
  81         weaken(my $weak_parent_rs = $parent_rs);
  82         $schema->txn_do(sub {
  83             my $child_rs = $weak_schema->resultset('CD')->search({ year => 1901 });
  84             my $row = $weak_parent_rs->next;
  85             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  86                 $weak_schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  87             }
  88         });
  89
  90         sleep (0.2); # without this many tasty crashes even on latest perls
  91     };
  92     die "Thread creation failed: $! $@" if !defined $newthread;
  93     push(@children, $newthread);
  94 }
  95
  96 ok(1, "past spawning");
  97
  98 {
  99     $_->join for(@children);
 100 }
 101
 102 ok(1, "past joining");
 103
 104 while(@children) {
 105     my $child = pop(@children);
 106     my $tid = $child->tid;
 107     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
 108     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
 109 }
 110
 111 ok(1, "Made it to the end");
 112
 113 $schema->storage->dbh->do("DROP TABLE cd");
 114
 115 # Too many threading bugs on exit, none of which have anything to do with
 116 # the actual stuff we test
 117 $ENV{DBICTEST_DIRTY_EXIT} = 1
 118   if "$]" < 5.012;
 119
 120 done_testing;