t/51threads.t

   1 use Config;
   2 BEGIN {
   3   unless ($Config{useithreads}) {
   4     print "1..0 # SKIP your perl does not support ithreads\n";
   5     exit 0;
   6   }
   7 }
   8 use threads;
   9
  10 use strict;
  11 use warnings;
  12
  13 use Test::More;
  14 use Test::Exception;
  15
  16 plan skip_all => 'DBIC does not actively support threads before perl 5.8.5'
  17   if $] < '5.008005';
  18
  19 use DBIx::Class::Optional::Dependencies ();
  20 use lib qw(t/lib);
  21 use DBICTest;
  22
  23 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('rdbms_pg')
  24   unless DBIx::Class::Optional::Dependencies->req_ok_for ('rdbms_pg');
  25
  26 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  27 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  28       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  29
  30 # README: If you set the env var to a number greater than 10,
  31 #   we will use that many children
  32 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  33 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  34    $num_children = 10;
  35 }
  36
  37 use_ok('DBICTest::Schema');
  38
  39 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  40
  41 my $parent_rs;
  42
  43 lives_ok (sub {
  44     my $dbh = $schema->storage->dbh;
  45
  46     {
  47         local $SIG{__WARN__} = sub {};
  48         eval { $dbh->do("DROP TABLE cd") };
  49         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  50     }
  51
  52     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  53     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  54
  55     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  56     $parent_rs->next;
  57 }, 'populate successfull');
  58
  59 my @children;
  60 while(@children < $num_children) {
  61
  62     my $newthread = async {
  63         my $tid = threads->tid;
  64
  65         my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  66         my $row = $parent_rs->next;
  67         if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  68             $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  69         }
  70         sleep(1); # tasty crashes without this
  71     };
  72     die "Thread creation failed: $! $@" if !defined $newthread;
  73     push(@children, $newthread);
  74 }
  75
  76 ok(1, "past spawning");
  77
  78 {
  79     $_->join for(@children);
  80 }
  81
  82 ok(1, "past joining");
  83
  84 while(@children) {
  85     my $child = pop(@children);
  86     my $tid = $child->tid;
  87     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  88     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  89 }
  90
  91 ok(1, "Made it to the end");
  92
  93 $schema->storage->dbh->do("DROP TABLE cd");
  94
  95 done_testing;