t/50fork.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4
   5 # README: If you set the env var to a number greater than 10,
   6 #   we will use that many children
   7
   8 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
   9 my $num_children = $ENV{DBICTEST_FORK_STRESS};
  10
  11 plan skip_all => 'Set $ENV{DBICTEST_FORK_STRESS} to run this test'
  12     unless $num_children;
  13
  14 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  15       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  16
  17 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  18    $num_children = 10;
  19 }
  20
  21 plan tests => $num_children + 6;
  22
  23 use lib qw(t/lib);
  24
  25 use_ok('DBICTest::Schema');
  26
  27 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1 });
  28
  29 my $parent_rs;
  30
  31 eval {
  32     my $dbh = $schema->storage->dbh;
  33
  34     {
  35         local $SIG{__WARN__} = sub {};
  36         eval { $dbh->do("DROP TABLE cd") };
  37         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  38     }
  39
  40     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  41     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  42
  43     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  44     $parent_rs->next;
  45 };
  46 ok(!$@) or diag "Creation eval failed: $@";
  47
  48 {
  49     my $pid = fork;
  50     if(!defined $pid) {
  51         die "fork failed: $!";
  52     }
  53
  54     if (!$pid) {
  55         exit $schema->storage->connected ? 1 : 0;
  56     }
  57
  58     if (waitpid($pid, 0) == $pid) {
  59         my $ex = $? >> 8;
  60         ok($ex == 0, "storage->connected() returns false in child");
  61         exit $ex if $ex; # skip remaining tests
  62     }
  63 }
  64
  65 my @pids;
  66 while(@pids < $num_children) {
  67
  68     my $pid = fork;
  69     if(!defined $pid) {
  70         die "fork failed: $!";
  71     }
  72     elsif($pid) {
  73         push(@pids, $pid);
  74         next;
  75     }
  76
  77     $pid = $$;
  78
  79     my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  80     my $row = $parent_rs->next;
  81     if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  82         $schema->resultset('CD')->create({ title => "test success $pid", artist => $pid, year => scalar(@pids) });
  83     }
  84     sleep(3);
  85     exit;
  86 }
  87
  88 ok(1, "past forking");
  89
  90 waitpid($_,0) for(@pids);
  91
  92 ok(1, "past waiting");
  93
  94 while(@pids) {
  95     my $pid = pop(@pids);
  96     my $rs = $schema->resultset('CD')->search({ title => "test success $pid", artist => $pid, year => scalar(@pids) });
  97     is($rs->next->get_column('artist'), $pid, "Child $pid successful");
  98 }
  99
 100 ok(1, "Made it to the end");
 101
 102 $schema->storage->dbh->do("DROP TABLE cd");