maint/Makefile.PL.inc/53_autogen_pod.pl

   1 use File::Path();
   2 use File::Glob();
   3
   4 # leftovers in old checkouts
   5 unlink 'lib/DBIx/Class/Optional/Dependencies.pod'
   6   if -f 'lib/DBIx/Class/Optional/Dependencies.pod';
   7 File::Path::rmtree([ '.generated_pod' ])
   8   if -d '.generated_pod';
   9
  10 my $pod_dir = 'maint/.Generated_Pod';
  11 my $ver = Meta->version;
  12
  13 # cleanup the generated pod dir (again - kill leftovers from old checkouts)
  14 if (-d $pod_dir) {
  15   File::Path::rmtree([ File::Glob::bsd_glob("$pod_dir/*") ]);
  16 }
  17 else {
  18   mkdir $pod_dir or die "Unable to create $pod_dir: $!";
  19 }
  20
  21 # generate the OptDeps pod both in the clone-dir and during the makefile distdir
  22 {
  23   print "Regenerating Optional/Dependencies.pod\n";
  24
  25   # this should always succeed - hence no error checking
  26   # if someone breaks OptDeps - travis should catch it
  27   require DBIx::Class::Optional::Dependencies;
  28   DBIx::Class::Optional::Dependencies->_gen_pod ($ver, "$pod_dir/lib");
  29
  30   postamble <<"EOP";
  31
  32 clonedir_generate_files : dbic_clonedir_gen_optdeps_pod
  33
  34 dbic_clonedir_gen_optdeps_pod :
  35 \t@{[
  36   $mm_proto->oneliner("DBIx::Class::Optional::Dependencies->_gen_pod(q($ver), q($pod_dir/lib))", [qw/-Ilib -MDBIx::Class::Optional::Dependencies/])
  37 ]}
  38
  39 EOP
  40 }
  41
  42
  43 # generate the script/dbicadmin pod
  44 {
  45   print "Regenerating script/dbicadmin.pod\n";
  46
  47   # generating it in the root of $pod_dir
  48   # it will *not* be copied over due to not being listed at the top
  49   # of MANIFEST.SKIP - this is a *good* thing
  50   # we only want to ship a script/dbicadmin, with the POD appended
  51   # (see inject_dbicadmin_pod.pl), but still want to spellcheck and
  52   # whatnot the intermediate step
  53   my $pod_fn = "$pod_dir/dbicadmin.pod";
  54
  55   # if the author doesn't have the prereqs, don't fail the initial "perl Makefile.pl" step
  56   my $great_success;
  57   {
  58     local @ARGV = ('--documentation-as-pod', $pod_fn);
  59     local $0 = 'dbicadmin';
  60     local *CORE::GLOBAL::exit = sub { $great_success++; die; };
  61     do 'script/dbicadmin';
  62   }
  63   if (!$great_success and ($@ || $!) ) {
  64     printf ("FAILED!!! Subsequent `make dist` will fail. %s\n",
  65       $ENV{DBICDIST_DEBUG}
  66         ? 'Full error: ' . ($@ || $!)
  67         : 'Re-run with $ENV{DBICDIST_DEBUG} set for more info'
  68     );
  69   }
  70
  71   postamble <<"EOP";
  72
  73 clonedir_generate_files : dbic_clonedir_gen_dbicadmin_pod
  74
  75 dbic_clonedir_gen_dbicadmin_pod :
  76 \t\$(ABSPERLRUN) -Ilib -- script/dbicadmin --documentation-as-pod @{[ $mm_proto->quote_literal($pod_fn) ]}
  77
  78 EOP
  79 }
  80
  81
  82 # generate the inherit pods only during distbuilding phase
  83 # it is too slow to do at regular Makefile.PL
  84 {
  85   postamble <<"EOP";
  86
  87 clonedir_generate_files : dbic_clonedir_gen_inherit_pods
  88
  89 dbic_clonedir_gen_inherit_pods :
  90 \t\$(ABSPERLRUN) -Ilib maint/gen_pod_inherit
  91
  92 EOP
  93 }
  94
  95
  96 # generate the DBIx/Class.pod only during distdir
  97 {
  98   my $dist_pod_fn = "$pod_dir/lib/DBIx/Class.pod";
  99
 100   postamble <<"EOP";
 101
 102 clonedir_generate_files : dbic_distdir_gen_dbic_pod
 103
 104 dbic_distdir_gen_dbic_pod :
 105
 106 \tperldoc -u lib/DBIx/Class.pm > $dist_pod_fn
 107 \t@{[ $mm_proto->oneliner(
 108   "s!^.*?this line is replaced with the author list.*! qq{List of the awesome contributors who made DBIC v$ver possible\\n\\n} . qx(\$^X -Ilib maint/gen_pod_authors)!me",
 109   [qw( -0777 -p -i.arghwin32 )]
 110 ) ]} $dist_pod_fn
 111 \t\$(RM_F) $dist_pod_fn.arghwin32
 112
 113 create_distdir : dbic_distdir_defang_authors
 114
 115 # Remove the maintainer-only warning (be nice ;)
 116 dbic_distdir_defang_authors :
 117 \t@{[ $mm_proto->oneliner('s/ ^ \s* \# \s* \*\*\* .+ \n ( ^ \s* \# \s*? \n )? //xmg', [qw( -0777 -p -i.arghwin32 )] ) ]} \$(DISTVNAME)/AUTHORS
 118 @{[ $crlf_fixup->( '$(DISTVNAME)/AUTHORS' ) ]}
 119 \t\$(RM_F) \$(DISTVNAME)/AUTHORS.arghwin32
 120
 121 EOP
 122 }
 123
 124
 125 # on some OSes generated files may have an incorrect \n - fix it
 126 # so that the xt tests pass on a fresh checkout (also shipping a
 127 # dist with CRLFs is beyond obnoxious)
 128 if ($^O eq 'MSWin32' or $^O eq 'cygwin') {
 129   {
 130     local $ENV{PERLIO} = 'unix';
 131     system( $^X, qw( -MExtUtils::Command -e dos2unix -- ), $pod_dir );
 132   }
 133
 134   postamble <<"EOP";
 135
 136 clonedir_post_generate_files : pod_crlf_fixup
 137
 138 pod_crlf_fixup :
 139 @{[ $crlf_fixup->($pod_dir) ]}
 140
 141 EOP
 142 }
 143
 144 {
 145   postamble <<"EOP";
 146
 147 clonedir_post_generate_files : dbic_clonedir_copy_generated_pod
 148
 149 dbic_clonedir_copy_generated_pod :
 150 \t\$(RM_F) $pod_dir.packlist
 151 \t@{[
 152   $mm_proto->oneliner("install([ from_to => {q($pod_dir) => './', write => q($pod_dir.packlist)}, verbose => 0, uninstall_shadows => 0, skip => [] ])", ['-MExtUtils::Install'])
 153 ]}
 154
 155 EOP
 156 }
 157
 158
 159 # everything that came from $pod_dir, needs to be removed from the workdir
 160 {
 161   postamble <<"EOP";
 162
 163 clonedir_cleanup_generated_files : dbic_clonedir_cleanup_generated_pod_copies
 164
 165 dbic_clonedir_cleanup_generated_pod_copies :
 166 \t@{[ $mm_proto->oneliner('chomp && unlink || die', ['-n']) ]} $pod_dir.packlist
 167 \t\$(RM_F) $pod_dir.packlist
 168
 169 EOP
 170 }
 171
 172 # keep the Makefile.PL eval happy
 173 1;