maint/Makefile.PL.inc/50_redefine_makefile_flow.pl

   1 # Split create_distdir into several subtargets, allowing us to generate
   2 # stuff, inject it into lib/, manifest it, and then clean all of it up
   3 {
   4   package MY;
   5   sub distdir {
   6     (my $snippet = shift->SUPER::distdir(@_)) =~ s/^create_distdir :/create_distdir_copy_manifested :/;
   7     return <<"EOM";
   8 $snippet
   9
  10 create_distdir : check_create_distdir_prereqs clonedir_generate_files clonedir_post_generate_files fresh_manifest create_distdir_copy_manifested clonedir_cleanup_generated_files
  11 \t\$(NOECHO) \$(NOOP)
  12
  13 clonedir_generate_files :
  14 \t\$(NOECHO) \$(NOOP)
  15
  16 clonedir_post_generate_files :
  17 \t\$(NOECHO) \$(NOOP)
  18
  19 clonedir_cleanup_generated_files :
  20 \t\$(NOECHO) \$(NOOP)
  21
  22 check_create_distdir_prereqs :
  23 \t\$(NOECHO) @{[
  24   $mm_proto->oneliner("DBIx::Class::Optional::Dependencies->die_unless_req_ok_for(q(dist_dir))", [qw/-Ilib -MDBIx::Class::Optional::Dependencies/])
  25 ]}
  26
  27 upload :: check_create_distdir_prereqs check_upload_dist_prereqs
  28
  29 check_upload_dist_prereqs :
  30 \t\$(NOECHO) @{[
  31   $mm_proto->oneliner("DBIx::Class::Optional::Dependencies->die_unless_req_ok_for(q(dist_upload))", [qw/-Ilib -MDBIx::Class::Optional::Dependencies/])
  32 ]}
  33
  34 EOM
  35   }
  36 }
  37
  38 # EU::MM BUG - workaround
  39 # somehow the init_PM of EUMM (in MM_Unix) interprets ResultClass.pod.proto
  40 # as a valid ResultClass.pod. While this has no effect on dist-building
  41 # it royally screws up the local Makefile.PL $TO_INST_PM and friends,
  42 # making it impossible to make/make test from a checkout
  43 # just rip it out here (remember - this is only executed under author mode)
  44 {
  45   package MY;
  46   sub init_PM {
  47     my $self = shift;
  48     my $rv = $self->SUPER::init_PM(@_);
  49     delete @{$self->{PM}}{qw(lib/DBIx/Class/Manual/ResultClass.pod lib/DBIx/Class/Manual/ResultClass.pod.proto)};
  50     $rv
  51   }
  52 }
  53
  54 # make the install (and friends) target a noop - instead of
  55 # doing a perl Makefile.PL && make && make install (which will leave pod
  56 # behind), one ought to assemble a distdir first
  57
  58 {
  59   package MY;
  60   sub install {
  61     (my $snippet = shift->SUPER::install(@_))
  62       =~ s/^( (?: install [^\:]+ | \w+_install \s) \:+ )/$1 block_install_from_checkout/mxg;
  63     return <<"EOM";
  64 $snippet
  65
  66 block_install_from_checkout :
  67 \t\$(NOECHO) \$(ECHO) Installation directly from a checkout is not possible. You need to prepare a distdir, enter it, and run the installation from within.
  68 \t\$(NOECHO) \$(FALSE)
  69
  70 EOM
  71   }
  72 }
  73
  74 # keep the Makefile.PL eval happy
  75 1;