maint/Makefile.PL.inc/50_redefine_makefile_flow.pl

   1 # Split create_distdir into several subtargets, allowing us to generate
   2 # stuff, inject it into lib/, manifest it, and then clean all of it up
   3 {
   4   package MY;
   5   sub distdir {
   6     (my $snippet = shift->SUPER::distdir(@_)) =~ s/^create_distdir :/create_distdir_copy_manifested :/;
   7     return <<"EOM";
   8 $snippet
   9
  10 create_distdir : check_create_distdir_prereqs clonedir_generate_files clonedir_post_generate_files fresh_manifest create_distdir_copy_manifested clonedir_cleanup_generated_files
  11 \t\$(NOECHO) \$(NOOP)
  12
  13 clonedir_generate_files :
  14 \t\$(NOECHO) \$(NOOP)
  15
  16 clonedir_post_generate_files :
  17 \t\$(NOECHO) \$(NOOP)
  18
  19 clonedir_cleanup_generated_files :
  20 \t\$(NOECHO) \$(NOOP)
  21
  22 check_create_distdir_prereqs :
  23 \t\$(NOECHO) @{[
  24   $mm_proto->oneliner("DBIx::Class::Optional::Dependencies->die_unless_req_ok_for(q(dist_dir))", [qw/-Ilib -MDBIx::Class::Optional::Dependencies/])
  25 ]}
  26
  27 EOM
  28   }
  29 }
  30
  31 # M::I inserts its own default postamble, so we can't easily override upload
  32 # but we can still hook postamble in EU::MM
  33 {
  34   package MY;
  35
  36   sub postamble {
  37     my $snippet = shift->SUPER::postamble(@_);
  38     return <<"EOM";
  39 $snippet
  40
  41 upload :: check_create_distdir_prereqs check_upload_dist_prereqs
  42
  43 check_upload_dist_prereqs :
  44 \t\$(NOECHO) @{[
  45   $mm_proto->oneliner("DBIx::Class::Optional::Dependencies->die_unless_req_ok_for(q(dist_upload))", [qw/-Ilib -MDBIx::Class::Optional::Dependencies/])
  46 ]}
  47
  48 EOM
  49   }
  50 }
  51
  52 # EU::MM BUG - workaround
  53 # somehow the init_PM of EUMM (in MM_Unix) interprets ResultClass.pod.proto
  54 # as a valid ResultClass.pod. While this has no effect on dist-building
  55 # it royally screws up the local Makefile.PL $TO_INST_PM and friends,
  56 # making it impossible to make/make test from a checkout
  57 # just rip it out here (remember - this is only executed under author mode)
  58 {
  59   package MY;
  60   sub init_PM {
  61     my $self = shift;
  62     my $rv = $self->SUPER::init_PM(@_);
  63     delete @{$self->{PM}}{qw(lib/DBIx/Class/Manual/ResultClass.pod lib/DBIx/Class/Manual/ResultClass.pod.proto)};
  64     $rv
  65   }
  66 }
  67
  68 # make the install (and friends) target a noop - instead of
  69 # doing a perl Makefile.PL && make && make install (which will leave pod
  70 # behind), one ought to assemble a distdir first
  71
  72 {
  73   package MY;
  74   sub install {
  75     (my $snippet = shift->SUPER::install(@_))
  76       =~ s/^( (?: install [^\:]+ | \w+_install \s) \:+ )/$1 block_install_from_checkout/mxg;
  77     return <<"EOM";
  78 $snippet
  79
  80 block_install_from_checkout :
  81 \t\$(NOECHO) \$(ECHO) Installation directly from a checkout is not possible. You need to prepare a distdir, enter it, and run the installation from within.
  82 \t\$(NOECHO) \$(FALSE)
  83
  84 EOM
  85   }
  86 }
  87
  88 # keep the Makefile.PL eval happy
  89 1;