lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package # hide from PAUSE
   2     SQL::Translator::Parser::DBIx::Class;
   3
   4 # AUTHOR: Jess Robinson
   5
   6 # Some mistakes the fault of Matt S Trout
   7
   8 # Others the fault of Ash Berlin
   9
  10 use strict;
  11 use warnings;
  12 use vars qw($DEBUG @EXPORT_OK);
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use Data::Dumper;
  17 use Digest::SHA1 qw( sha1_hex );
  18 use SQL::Translator::Utils qw(debug normalize_name);
  19
  20 use base qw(Exporter);
  21
  22 @EXPORT_OK = qw(parse);
  23
  24 # -------------------------------------------------------------------
  25 # parse($tr, $data)
  26 #
  27 # Note that $data, in the case of this parser, is not useful.
  28 # We're working with DBIx::Class Schemas, not data streams.
  29 # -------------------------------------------------------------------
  30 sub parse {
  31     my ($tr, $data)   = @_;
  32     my $args          = $tr->parser_args;
  33     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  34     $dbicschema     ||= $args->{'package'};
  35     my $limit_sources = $args->{'sources'};
  36
  37     die 'No DBIx::Class::Schema' unless ($dbicschema);
  38     if (!ref $dbicschema) {
  39       eval "use $dbicschema;";
  40       die "Can't load $dbicschema ($@)" if($@);
  41     }
  42
  43     my $schema      = $tr->schema;
  44     my $table_no    = 0;
  45
  46     $schema->name( ref($dbicschema) . " v" . ($dbicschema->VERSION || '1.x'))
  47       unless ($schema->name);
  48
  49     my %seen_tables;
  50
  51     my @monikers = sort $dbicschema->sources;
  52     if ($limit_sources) {
  53         my $ref = ref $limit_sources || '';
  54         die "'sources' parameter must be an array or hash ref" unless $ref eq 'ARRAY' || ref eq 'HASH';
  55
  56         # limit monikers to those specified in
  57         my $sources;
  58         if ($ref eq 'ARRAY') {
  59             $sources->{$_} = 1 for (@$limit_sources);
  60         } else {
  61             $sources = $limit_sources;
  62         }
  63         @monikers = grep { $sources->{$_} } @monikers;
  64     }
  65
  66
  67     foreach my $moniker (sort @monikers)
  68     {
  69         my $source = $dbicschema->source($moniker);
  70
  71         # Its possible to have multiple DBIC source using same table
  72         next if $seen_tables{$source->name}++;
  73
  74         my $table = $schema->add_table(
  75                                        name => $source->name,
  76                                        type => 'TABLE',
  77                                        ) || die $schema->error;
  78         my $colcount = 0;
  79         foreach my $col ($source->columns)
  80         {
  81             # assuming column_info in dbic is the same as DBI (?)
  82             # data_type is a number, column_type is text?
  83             my %colinfo = (
  84               name => $col,
  85               size => 0,
  86               is_auto_increment => 0,
  87               is_foreign_key => 0,
  88               is_nullable => 0,
  89               %{$source->column_info($col)}
  90             );
  91             if ($colinfo{is_nullable}) {
  92               $colinfo{default} = '' unless exists $colinfo{default};
  93             }
  94             my $f = $table->add_field(%colinfo) || die $table->error;
  95         }
  96         $table->primary_key($source->primary_columns);
  97
  98         my @primary = $source->primary_columns;
  99         my %unique_constraints = $source->unique_constraints;
 100         foreach my $uniq (sort keys %unique_constraints) {
 101             if (!$source->compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 102                 $table->add_constraint(
 103                             type             => 'unique',
 104                             name             => _create_unique_symbol($uniq),
 105                             fields           => $unique_constraints{$uniq}
 106                 );
 107             }
 108         }
 109
 110         my @rels = $source->relationships();
 111
 112         my %created_FK_rels;
 113
 114         foreach my $rel (sort @rels)
 115         {
 116             my $rel_info = $source->relationship_info($rel);
 117
 118             # Ignore any rel cond that isn't a straight hash
 119             next unless ref $rel_info->{cond} eq 'HASH';
 120
 121             my $othertable = $source->related_source($rel);
 122             my $rel_table = $othertable->name;
 123
 124             # Get the key information, mapping off the foreign/self markers
 125             my @cond = keys(%{$rel_info->{cond}});
 126             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 127             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 128
 129             if($rel_table)
 130             {
 131                 my $reverse_rels = $source->reverse_relationship_info($rel);
 132                 my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 133
 134                 my $on_delete = '';
 135                 my $on_update = '';
 136
 137                 if (defined $otherrelationship) {
 138                     $on_delete = $otherrelationship->{'attrs'}->{cascade_delete} ? 'CASCADE' : '';
 139                     $on_update = $otherrelationship->{'attrs'}->{cascade_copy} ? 'CASCADE' : '';
 140                 }
 141
 142                 my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 143
 144                 # Make sure we dont create the same foreign key constraint twice
 145                 my $key_test = join("\x00", @keys);
 146
 147                 #Decide if this is a foreign key based on whether the self
 148                 #items are our primary columns.
 149
 150                 # If the sets are different, then we assume it's a foreign key from
 151                 # us to another table.
 152                 # OR: If is_foreign_key_constraint attr is explicity set (or set to false) on the relation
 153                 next if ( exists $created_FK_rels{$rel_table}->{$key_test} );
 154                 if ( exists $rel_info->{attrs}{is_foreign_key_constraint}) {
 155                   # not is this attr set to 0 but definitely if set to 1
 156                   next unless ($rel_info->{attrs}{is_foreign_key_constraint});
 157                 } else {
 158                   # not if might have
 159                   # next if ($rel_info->{attrs}{accessor} eq 'single' && exists $rel_info->{attrs}{join_type} && uc($rel_info->{attrs}{join_type}) eq 'LEFT');
 160                   # not sure about this one
 161                   next if $source->compare_relationship_keys(\@keys, \@primary);
 162                 }
 163
 164                 $created_FK_rels{$rel_table}->{$key_test} = 1;
 165                 if (scalar(@keys)) {
 166                   $table->add_constraint(
 167                                     type             => 'foreign_key',
 168                                     name             => _create_unique_symbol($table->name
 169                                                                             . '_fk_'
 170                                                                             . join('_', @keys)),
 171                                     fields           => \@keys,
 172                                     reference_fields => \@refkeys,
 173                                     reference_table  => $rel_table,
 174                                     on_delete        => $on_delete,
 175                                     on_update        => $on_update,
 176                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 177                   );
 178
 179                   my $index = $table->add_index(
 180                                     name   => _create_unique_symbol(join('_', $table->name, 'idx', @keys)),
 181                                     fields => \@keys,
 182                                     type   => 'NORMAL',
 183                   );
 184                 }
 185             }
 186         }
 187
 188         if ($source->result_class->can('sqlt_deploy_hook')) {
 189           $source->result_class->sqlt_deploy_hook($table);
 190         }
 191     }
 192
 193     if ($dbicschema->can('sqlt_deploy_hook')) {
 194       $dbicschema->sqlt_deploy_hook($schema);
 195     }
 196
 197     return 1;
 198 }
 199
 200 # TODO - is there a reasonable way to pass configuration?
 201 # Default of 64 comes from mysql's limit.
 202 our $MAX_SYMBOL_LENGTH    ||= 64;
 203 our $COLLISION_TAG_LENGTH ||= 8;
 204
 205 # -------------------------------------------------------------------
 206 # $resolved_name = _create_unique_symbol($desired_name)
 207 #
 208 # If desired_name is really long, it will be truncated in a way that
 209 # has a high probability of leaving it unique.
 210 # -------------------------------------------------------------------
 211 sub _create_unique_symbol {
 212     my $desired_name = shift;
 213     return $desired_name if length $desired_name <= $MAX_SYMBOL_LENGTH;
 214
 215     my $truncated_name = substr $desired_name, 0, $MAX_SYMBOL_LENGTH - $COLLISION_TAG_LENGTH - 1;
 216
 217     # Hex isn't the most space-efficient, but it skirts around allowed
 218     # charset issues
 219     my $digest = sha1_hex($desired_name);
 220     my $collision_tag = substr $digest, 0, $COLLISION_TAG_LENGTH;
 221
 222     return $truncated_name
 223          . '_'
 224          . $collision_tag;
 225 }
 226
 227 1;