lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 our ($DEBUG, $VERSION, @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use DBIx::Class::Carp qw/^SQL::Translator|^DBIx::Class|^Try::Tiny/;
  18 use DBIx::Class::Exception;
  19 use Class::C3::Componentised;
  20 use Scalar::Util 'blessed';
  21 use Try::Tiny;
  22 use namespace::clean;
  23
  24 use base qw(Exporter);
  25
  26 @EXPORT_OK = qw(parse);
  27
  28 # -------------------------------------------------------------------
  29 # parse($tr, $data)
  30 #
  31 # setting parser_args => { add_fk_index => 0 } will prevent
  32 # the auto-generation of an index for each FK.
  33 #
  34 # Note that $data, in the case of this parser, is not useful.
  35 # We're working with DBIx::Class Schemas, not data streams.
  36 # -------------------------------------------------------------------
  37 sub parse {
  38     my ($tr, $data)   = @_;
  39     my $args          = $tr->parser_args;
  40
  41     my $dbicschema = $data || $args->{dbic_schema};
  42
  43     for (qw(DBIx::Class::Schema DBIx::Schema package)) {
  44       if (defined (my $s = delete $args->{$_} )) {
  45         carp_unique("Supplying a schema via  ... parser_args => { '$_' => \$schema } is deprecated. Please use parser_args => { dbic_schema => \$schema } instead");
  46
  47         # move it from the deprecated to the proper $args slot
  48         unless ($dbicschema) {
  49           $args->{dbic_schema} = $dbicschema = $s;
  50         }
  51       }
  52     }
  53
  54     DBIx::Class::Exception->throw('No DBIx::Class::Schema') unless ($dbicschema);
  55
  56     if (!ref $dbicschema) {
  57       try {
  58         Class::C3::Componentised->ensure_class_loaded($dbicschema)
  59       } catch {
  60         DBIx::Class::Exception->throw("Can't load $dbicschema: $_");
  61       }
  62     }
  63
  64     if (
  65       ref $args->{dbic_schema}
  66         and
  67       $args->{dbic_schema}->storage
  68     ) {
  69       # we have a storage-holding $schema instance in $args
  70       # we need to dissociate it from that $storage
  71       # otherwise SQLT insanity may ensue due to how some
  72       # serializing producers treat $args (crazy crazy shit)
  73       local $args->{dbic_schema}{storage};
  74       $args->{dbic_schema} = $args->{dbic_schema}->clone;
  75     }
  76
  77     my $schema      = $tr->schema;
  78     my $table_no    = 0;
  79
  80     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  81       unless ($schema->name);
  82
  83     my @monikers = sort $dbicschema->sources;
  84     if (my $limit_sources = $args->{'sources'}) {
  85         my $ref = ref $limit_sources || '';
  86         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  87           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  88
  89         # limit monikers to those specified in
  90         my $sources;
  91         if ($ref eq 'ARRAY') {
  92             $sources->{$_} = 1 for (@$limit_sources);
  93         } else {
  94             $sources = $limit_sources;
  95         }
  96         @monikers = grep { $sources->{$_} } @monikers;
  97     }
  98
  99
 100     my(%table_monikers, %view_monikers);
 101     for my $moniker (@monikers){
 102       my $source = $dbicschema->source($moniker);
 103        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
 104          $table_monikers{$moniker}++;
 105       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
 106           next if $source->is_virtual;
 107          $view_monikers{$moniker}++;
 108       }
 109     }
 110
 111     my %tables;
 112     foreach my $moniker (sort keys %table_monikers)
 113     {
 114         my $source = $dbicschema->source($moniker);
 115         my $table_name = $source->name;
 116
 117         # FIXME - this isn't the right way to do it, but sqlt does not
 118         # support quoting properly to be signaled about this
 119         $table_name = $$table_name if ref $table_name eq 'SCALAR';
 120
 121         # It's possible to have multiple DBIC sources using the same table
 122         next if $tables{$table_name};
 123
 124         $tables{$table_name}{source} = $source;
 125         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
 126                                        name => $table_name,
 127                                        type => 'TABLE',
 128                                        );
 129         foreach my $col ($source->columns)
 130         {
 131             # assuming column_info in dbic is the same as DBI (?)
 132             # data_type is a number, column_type is text?
 133             my %colinfo = (
 134               name => $col,
 135               size => 0,
 136               is_auto_increment => 0,
 137               is_foreign_key => 0,
 138               is_nullable => 0,
 139               %{$source->column_info($col)}
 140             );
 141             if ($colinfo{is_nullable}) {
 142               $colinfo{default} = '' unless exists $colinfo{default};
 143             }
 144             my $f = $table->add_field(%colinfo)
 145               || $dbicschema->throw_exception ($table->error);
 146         }
 147
 148         my @primary = $source->primary_columns;
 149
 150         $table->primary_key(@primary) if @primary;
 151
 152         my %unique_constraints = $source->unique_constraints;
 153         foreach my $uniq (sort keys %unique_constraints) {
 154             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 155                 $table->add_constraint(
 156                             type             => 'unique',
 157                             name             => $uniq,
 158                             fields           => $unique_constraints{$uniq}
 159                 );
 160             }
 161         }
 162
 163         my @rels = $source->relationships();
 164
 165         my %created_FK_rels;
 166
 167         # global add_fk_index set in parser_args
 168         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 169
 170         REL:
 171         foreach my $rel (sort @rels) {
 172
 173             my $rel_info = $source->relationship_info($rel);
 174
 175             # Ignore any rel cond that isn't a straight hash
 176             next unless ref $rel_info->{cond} eq 'HASH';
 177
 178             my $relsource = try { $source->related_source($rel) };
 179             unless ($relsource) {
 180               carp "Ignoring relationship '$rel' on '$moniker' - related resultsource '$rel_info->{class}' is not registered with this schema\n";
 181               next;
 182             };
 183
 184             # related sources might be excluded via a {sources} filter or might be views
 185             next unless exists $table_monikers{$relsource->source_name};
 186
 187             my $rel_table = $relsource->name;
 188
 189             # FIXME - this isn't the right way to do it, but sqlt does not
 190             # support quoting properly to be signaled about this
 191             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 192
 193             # Force the order of @cond to match the order of ->add_columns
 194             my $idx;
 195             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 196
 197             for ( keys %{$rel_info->{cond}} ) {
 198               unless (exists $other_columns_idx{$_}) {
 199                 carp "Ignoring relationship '$rel' on '$moniker' - related resultsource '@{[ $relsource->source_name ]}' does not contain one of the specified columns: '$_'\n";
 200                 next REL;
 201               }
 202             }
 203
 204             my @cond = sort { $other_columns_idx{$a} <=> $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 205
 206             # Get the key information, mapping off the foreign/self markers
 207             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 208             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 209
 210             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 211             my $fk_constraint;
 212
 213             #first it can be specified explicitly
 214             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 215                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 216             }
 217             # it can not be multi
 218             elsif ( $rel_info->{attrs}{accessor}
 219                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 220                 $fk_constraint = 0;
 221             }
 222             # if indeed single, check if all self.columns are our primary keys.
 223             # this is supposed to indicate a has_one/might_have...
 224             # where's the introspection!!?? :)
 225             else {
 226                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 227             }
 228
 229             my ($otherrelname, $otherrelationship) = %{ $source->reverse_relationship_info($rel) };
 230
 231             my $cascade;
 232             for my $c (qw/delete update/) {
 233                 if (exists $rel_info->{attrs}{"on_$c"}) {
 234                     if ($fk_constraint) {
 235                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 236                     }
 237                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 238                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 239                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 240                     }
 241                 }
 242                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 243                     $cascade->{$c} = 'CASCADE';
 244                 }
 245             }
 246
 247             if($rel_table) {
 248                 # Constraints are added only if applicable
 249                 next unless $fk_constraint;
 250
 251                 # Make sure we don't create the same foreign key constraint twice
 252                 my $key_test = join("\x00", sort @keys);
 253                 next if $created_FK_rels{$rel_table}->{$key_test};
 254
 255                 if (scalar(@keys)) {
 256                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 257
 258                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 259
 260                   # calculate dependencies: do not consider deferrable constraints and
 261                   # self-references for dependency calculations
 262                   if (! $is_deferrable and $rel_table ne $table_name) {
 263                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 264                   }
 265
 266                   # trim schema before generating constraint/index names
 267                   (my $table_abbrev = $table_name) =~ s/ ^ [^\.]+ \. //x;
 268
 269                   $table->add_constraint(
 270                     type             => 'foreign_key',
 271                     name             => join('_', $table_abbrev, 'fk', @keys),
 272                     fields           => \@keys,
 273                     reference_fields => \@refkeys,
 274                     reference_table  => $rel_table,
 275                     on_delete        => uc ($cascade->{delete} || ''),
 276                     on_update        => uc ($cascade->{update} || ''),
 277                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 278                   );
 279
 280                   # global parser_args add_fk_index param can be overridden on the rel def
 281                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 282
 283                   # Check that we do not create an index identical to the PK index
 284                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 285                   # NOTE: we do not sort the key columns because the order of
 286                   # columns is important for indexes and two indexes with the
 287                   # same cols but different order are allowed and sometimes
 288                   # needed
 289                   next if join("\x00", @keys) eq join("\x00", @primary);
 290
 291                   if ($add_fk_index_rel) {
 292                       (my $idx_name = $table_name) =~ s/ ^ [^\.]+ \. //x;
 293                       my $index = $table->add_index(
 294                           name   => join('_', $table_abbrev, 'idx', @keys),
 295                           fields => \@keys,
 296                           type   => 'NORMAL',
 297                       );
 298                   }
 299               }
 300             }
 301         }
 302
 303     }
 304
 305     # attach the tables to the schema in dependency order
 306     my $dependencies = {
 307       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 308     };
 309
 310     for my $table (sort
 311       {
 312         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 313           ||
 314         $a cmp $b
 315       }
 316       (keys %tables)
 317     ) {
 318       $schema->add_table ($tables{$table}{object});
 319       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 320
 321       # the hook might have already removed the table
 322       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 323         carp <<'EOW';
 324
 325 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 326 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 327 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 328
 329 EOW
 330
 331         # remove the table as there is no way someone might want to
 332         # actually deploy this
 333         $schema->drop_table ($table);
 334       }
 335     }
 336
 337     my %views;
 338     my @views = map { $dbicschema->source($_) } keys %view_monikers;
 339
 340     my $view_dependencies = {
 341         map {
 342             $_ => _resolve_deps( $dbicschema->source($_), \%view_monikers )
 343           } ( keys %view_monikers )
 344     };
 345
 346     my @view_sources =
 347       sort {
 348         keys %{ $view_dependencies->{ $a->source_name }   || {} } <=>
 349           keys %{ $view_dependencies->{ $b->source_name } || {} }
 350           || $a->source_name cmp $b->source_name
 351       }
 352       map { $dbicschema->source($_) }
 353       keys %view_monikers;
 354
 355     foreach my $source (@view_sources)
 356     {
 357         my $view_name = $source->name;
 358
 359         # FIXME - this isn't the right way to do it, but sqlt does not
 360         # support quoting properly to be signaled about this
 361         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 362
 363         # Skip custom query sources
 364         next if ref $view_name;
 365
 366         # Its possible to have multiple DBIC source using same table
 367         next if $views{$view_name}++;
 368
 369         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 370             unless $source->view_definition;
 371
 372         my $view = $schema->add_view (
 373           name => $view_name,
 374           fields => [ $source->columns ],
 375           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 376         ) || $dbicschema->throw_exception ($schema->error);
 377
 378         $source->_invoke_sqlt_deploy_hook($view);
 379     }
 380
 381
 382     if ($dbicschema->can('sqlt_deploy_hook')) {
 383       $dbicschema->sqlt_deploy_hook($schema);
 384     }
 385
 386     return 1;
 387 }
 388
 389 #
 390 # Quick and dirty dependency graph calculator
 391 #
 392 sub _resolve_deps {
 393     my ( $question, $answers, $seen ) = @_;
 394     my $ret = {};
 395     $seen ||= {};
 396     my @deps;
 397
 398     # copy and bump all deps by one (so we can reconstruct the chain)
 399     my %seen = map { $_ => $seen->{$_} + 1 } ( keys %$seen );
 400     if ( blessed($question)
 401         && $question->isa('DBIx::Class::ResultSource::View') )
 402     {
 403         $seen{ $question->result_class } = 1;
 404         @deps = keys %{ $question->{deploy_depends_on} };
 405     }
 406     else {
 407         $seen{$question} = 1;
 408         @deps = keys %{ $answers->{$question}{foreign_table_deps} };
 409     }
 410
 411     for my $dep (@deps) {
 412         if ( $seen->{$dep} ) {
 413             return {};
 414         }
 415         my $next_dep;
 416
 417         if ( blessed($question)
 418             && $question->isa('DBIx::Class::ResultSource::View') )
 419         {
 420             no warnings 'uninitialized';
 421             my ($next_dep_source_name) =
 422               grep {
 423                 $question->schema->source($_)->result_class eq $dep
 424                   && !( $question->schema->source($_)
 425                     ->isa('DBIx::Class::ResultSource::Table') )
 426               } @{ [ $question->schema->sources ] };
 427             return {} unless $next_dep_source_name;
 428             $next_dep = $question->schema->source($next_dep_source_name);
 429         }
 430         else {
 431             $next_dep = $dep;
 432         }
 433         my $subdeps = _resolve_deps( $next_dep, $answers, \%seen );
 434         $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 435         ++$ret->{$dep};
 436     }
 437     return $ret;
 438 }
 439
 440 1;
 441
 442 =head1 NAME
 443
 444 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 445 from a DBIx::Class::Schema instance
 446
 447 =head1 SYNOPSIS
 448
 449  ## Via DBIx::Class
 450  use MyApp::Schema;
 451  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 452  $schema->create_ddl_dir();
 453  ## or
 454  $schema->deploy();
 455
 456  ## Standalone
 457  use MyApp::Schema;
 458  use SQL::Translator;
 459
 460  my $schema = MyApp::Schema->connect;
 461  my $trans  = SQL::Translator->new (
 462       parser      => 'SQL::Translator::Parser::DBIx::Class',
 463       parser_args => {
 464           dbic_schema => $schema,
 465           add_fk_index => 0,
 466           sources => [qw/
 467             Artist
 468             CD
 469           /],
 470       },
 471       producer    => 'SQLite',
 472      ) or die SQL::Translator->error;
 473  my $out = $trans->translate() or die $trans->error;
 474
 475 =head1 DESCRIPTION
 476
 477 This class requires L<SQL::Translator> installed to work.
 478
 479 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 480 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 481
 482 Its primary use is in deploying database layouts described as a set
 483 of L<DBIx::Class> classes, to a database. To do this, see
 484 L<DBIx::Class::Schema/deploy>.
 485
 486 This can also be achieved by having DBIx::Class export the schema as a
 487 set of SQL files ready for import into your database, or passed to
 488 other machines that need to have your application installed but don't
 489 have SQL::Translator installed. To do this see
 490 L<DBIx::Class::Schema/create_ddl_dir>.
 491
 492 =head1 PARSER OPTIONS
 493
 494 =head2 dbic_schema
 495
 496 The DBIx::Class schema (either an instance or a class name) to be parsed.
 497 This argument is in fact optional - instead one can supply it later at
 498 translation time as an argument to L<SQL::Translator/translate>. In
 499 other words both of the following invocations are valid and will produce
 500 conceptually identical output:
 501
 502   my $yaml = SQL::Translator->new(
 503     parser => 'SQL::Translator::Parser::DBIx::Class',
 504     parser_args => {
 505       dbic_schema => $schema,
 506     },
 507     producer => 'SQL::Translator::Producer::YAML',
 508   )->translate;
 509
 510   my $yaml = SQL::Translator->new(
 511     parser => 'SQL::Translator::Parser::DBIx::Class',
 512     producer => 'SQL::Translator::Producer::YAML',
 513   )->translate(data => $schema);
 514
 515 =head2 add_fk_index
 516
 517 Create an index for each foreign key.
 518 Enabled by default, as having indexed foreign key columns is normally the
 519 sensible thing to do.
 520
 521 =head2 sources
 522
 523 =over 4
 524
 525 =item Arguments: \@class_names
 526
 527 =back
 528
 529 Limit the amount of parsed sources by supplying an explicit list of source names.
 530
 531 =head1 SEE ALSO
 532
 533 L<SQL::Translator>, L<DBIx::Class::Schema>
 534
 535 =head1 FURTHER QUESTIONS?
 536
 537 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 538
 539 =head1 COPYRIGHT AND LICENSE
 540
 541 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 542 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 543 redistribute it and/or modify it under the same terms as the
 544 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.