lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17
  18 use base qw(Exporter);
  19
  20 @EXPORT_OK = qw(parse);
  21
  22 # -------------------------------------------------------------------
  23 # parse($tr, $data)
  24 #
  25 # setting parser_args => { add_fk_index => 0 } will prevent
  26 # the auto-generation of an index for each FK.
  27 #
  28 # Note that $data, in the case of this parser, is not useful.
  29 # We're working with DBIx::Class Schemas, not data streams.
  30 # -------------------------------------------------------------------
  31 sub parse {
  32     my ($tr, $data)   = @_;
  33     my $args          = $tr->parser_args;
  34     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  35     $dbicschema     ||= $args->{'package'};
  36     my $limit_sources = $args->{'sources'};
  37
  38     die 'No DBIx::Class::Schema' unless ($dbicschema);
  39     if (!ref $dbicschema) {
  40       eval "use $dbicschema;";
  41       die "Can't load $dbicschema ($@)" if($@);
  42     }
  43
  44     my $schema      = $tr->schema;
  45     my $table_no    = 0;
  46
  47     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  48       unless ($schema->name);
  49
  50     my %seen_tables;
  51
  52     my @monikers = sort $dbicschema->sources;
  53     if ($limit_sources) {
  54         my $ref = ref $limit_sources || '';
  55         die "'sources' parameter must be an array or hash ref" unless $ref eq 'ARRAY' || ref eq 'HASH';
  56
  57         # limit monikers to those specified in
  58         my $sources;
  59         if ($ref eq 'ARRAY') {
  60             $sources->{$_} = 1 for (@$limit_sources);
  61         } else {
  62             $sources = $limit_sources;
  63         }
  64         @monikers = grep { $sources->{$_} } @monikers;
  65     }
  66
  67
  68     my(@table_monikers, @view_monikers);
  69     for my $moniker (@monikers){
  70       my $source = $dbicschema->source($moniker);
  71        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  72          push(@table_monikers, $moniker);
  73       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  74           next if $source->is_virtual;
  75          push(@view_monikers, $moniker);
  76       }
  77     }
  78
  79     foreach my $moniker (sort @table_monikers)
  80     {
  81         my $source = $dbicschema->source($moniker);
  82
  83         # Skip custom query sources
  84         next if ref($source->name);
  85
  86         # Its possible to have multiple DBIC source using same table
  87         next if $seen_tables{$source->name}++;
  88
  89         my $table = $schema->add_table(
  90                                        name => $source->name,
  91                                        type => 'TABLE',
  92                                        ) || die $schema->error;
  93         my $colcount = 0;
  94         foreach my $col ($source->columns)
  95         {
  96             # assuming column_info in dbic is the same as DBI (?)
  97             # data_type is a number, column_type is text?
  98             my %colinfo = (
  99               name => $col,
 100               size => 0,
 101               is_auto_increment => 0,
 102               is_foreign_key => 0,
 103               is_nullable => 0,
 104               %{$source->column_info($col)}
 105             );
 106             if ($colinfo{is_nullable}) {
 107               $colinfo{default} = '' unless exists $colinfo{default};
 108             }
 109             my $f = $table->add_field(%colinfo) || die $table->error;
 110         }
 111         $table->primary_key($source->primary_columns);
 112
 113         my @primary = $source->primary_columns;
 114         my %unique_constraints = $source->unique_constraints;
 115         foreach my $uniq (sort keys %unique_constraints) {
 116             if (!$source->compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 117                 $table->add_constraint(
 118                             type             => 'unique',
 119                             name             => $uniq,
 120                             fields           => $unique_constraints{$uniq}
 121                 );
 122             }
 123         }
 124
 125         my @rels = $source->relationships();
 126
 127         my %created_FK_rels;
 128
 129         # global add_fk_index set in parser_args
 130         my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
 131
 132         foreach my $rel (sort @rels)
 133         {
 134             my $rel_info = $source->relationship_info($rel);
 135
 136             # Ignore any rel cond that isn't a straight hash
 137             next unless ref $rel_info->{cond} eq 'HASH';
 138
 139             my $othertable = $source->related_source($rel);
 140             my $rel_table = $othertable->name;
 141
 142             my $reverse_rels = $source->reverse_relationship_info($rel);
 143             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 144
 145             # Force the order of @cond to match the order of ->add_columns
 146             my $idx;
 147             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
 148             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 149
 150             # Get the key information, mapping off the foreign/self markers
 151             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 152             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 153
 154             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 155             my $fk_constraint;
 156
 157             #first it can be specified explicitly
 158             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 159                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 160             }
 161             # it can not be multi
 162             elsif ( $rel_info->{attrs}{accessor}
 163                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 164                 $fk_constraint = 0;
 165             }
 166             # if indeed single, check if all self.columns are our primary keys.
 167             # this is supposed to indicate a has_one/might_have...
 168             # where's the introspection!!?? :)
 169             else {
 170                 $fk_constraint = not $source->compare_relationship_keys(\@keys, \@primary);
 171             }
 172
 173             my $cascade;
 174             for my $c (qw/delete update/) {
 175                 if (exists $rel_info->{attrs}{"on_$c"}) {
 176                     if ($fk_constraint) {
 177                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 178                     }
 179                     else {
 180                         warn "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 181                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 182                     }
 183                 }
 184                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 185                     $cascade->{$c} = 'CASCADE';
 186                 }
 187             }
 188
 189             if($rel_table)
 190             {
 191                 # Constraints are added only if applicable
 192                 next unless $fk_constraint;
 193
 194                 # Make sure we dont create the same foreign key constraint twice
 195                 my $key_test = join("\x00", @keys);
 196                 next if $created_FK_rels{$rel_table}->{$key_test};
 197
 198                 my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 199
 200                 # global parser_args add_fk_index param can be overridden on the rel def
 201                 my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 202
 203
 204                 $created_FK_rels{$rel_table}->{$key_test} = 1;
 205                 if (scalar(@keys)) {
 206                   $table->add_constraint(
 207                                     type             => 'foreign_key',
 208                                     name             => join('_', $table->name, 'fk', @keys),
 209                                     fields           => \@keys,
 210                                     reference_fields => \@refkeys,
 211                                     reference_table  => $rel_table,
 212                                     on_delete        => uc ($cascade->{delete} || ''),
 213                                     on_update        => uc ($cascade->{update} || ''),
 214                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 215                   );
 216
 217                   if ($add_fk_index_rel) {
 218                       my $index = $table->add_index(
 219                                                     name   => join('_', $table->name, 'idx', @keys),
 220                                                     fields => \@keys,
 221                                                     type   => 'NORMAL',
 222                                                     );
 223                   }
 224               }
 225             }
 226         }
 227
 228         $source->_invoke_sqlt_deploy_hook($table);
 229     }
 230
 231     foreach my $moniker (sort @view_monikers)
 232     {
 233         my $source = $dbicschema->source($moniker);
 234         # Skip custom query sources
 235         next if ref($source->name);
 236
 237         # Its possible to have multiple DBIC source using same table
 238         next if $seen_tables{$source->name}++;
 239
 240         my $view = $schema->add_view(
 241           name => $source->name,
 242           fields => [ $source->columns ],
 243           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 244         );
 245         if ($source->result_class->can('sqlt_deploy_hook')) {
 246           $source->result_class->sqlt_deploy_hook($view);
 247         }
 248
 249         $source->_invoke_sqlt_deploy_hook($view);
 250     }
 251
 252     if ($dbicschema->can('sqlt_deploy_hook')) {
 253       $dbicschema->sqlt_deploy_hook($schema);
 254     }
 255
 256     return 1;
 257 }
 258
 259 1;
 260
 261 =head1 NAME
 262
 263 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 264 from a DBIx::Class::Schema instance
 265
 266 =head1 SYNOPSIS
 267
 268  ## Via DBIx::Class
 269  use MyApp::Schema;
 270  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 271  $schema->create_ddl_dir();
 272  ## or
 273  $schema->deploy();
 274
 275  ## Standalone
 276  use MyApp::Schema;
 277  use SQL::Translator;
 278
 279  my $schema = MyApp::Schema->connect;
 280  my $trans  = SQL::Translator->new (
 281       parser      => 'SQL::Translator::Parser::DBIx::Class',
 282       parser_args => { package => $schema },
 283       producer    => 'SQLite',
 284      ) or die SQL::Translator->error;
 285  my $out = $trans->translate() or die $trans->error;
 286
 287 =head1 DESCRIPTION
 288
 289 This class requires L<SQL::Translator> installed to work.
 290
 291 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 292 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 293
 294 It's primary use is in deploying database layouts described as a set
 295 of L<DBIx::Class> classes, to a database. To do this, see
 296 L<DBIx::Class::Schema/deploy>.
 297
 298 This can also be achieved by having DBIx::Class export the schema as a
 299 set of SQL files ready for import into your database, or passed to
 300 other machines that need to have your application installed but don't
 301 have SQL::Translator installed. To do this see
 302 L<DBIx::Class::Schema/create_ddl_dir>.
 303
 304 =head1 SEE ALSO
 305
 306 L<SQL::Translator>, L<DBIx::Class::Schema>
 307
 308 =head1 AUTHORS
 309
 310 Jess Robinson
 311
 312 Matt S Trout
 313
 314 Ash Berlin