lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 our ($DEBUG, $VERSION, @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use DBIx::Class::Carp qw/^SQL::Translator|^DBIx::Class|^Try::Tiny/;
  18 use DBIx::Class::Exception;
  19 use Scalar::Util qw/weaken blessed/;
  20 use Try::Tiny;
  21 use namespace::clean;
  22
  23 use base qw(Exporter);
  24
  25 @EXPORT_OK = qw(parse);
  26
  27 # -------------------------------------------------------------------
  28 # parse($tr, $data)
  29 #
  30 # setting parser_args => { add_fk_index => 0 } will prevent
  31 # the auto-generation of an index for each FK.
  32 #
  33 # Note that $data, in the case of this parser, is not useful.
  34 # We're working with DBIx::Class Schemas, not data streams.
  35 # -------------------------------------------------------------------
  36 sub parse {
  37     my ($tr, $data)   = @_;
  38     my $args          = $tr->parser_args;
  39     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  40     $dbicschema     ||= $args->{'package'};
  41     my $limit_sources = $args->{'sources'};
  42
  43     # this is a hack to prevent schema leaks due to a retarded SQLT implementation
  44     # DO NOT REMOVE (until SQLT2 is out, the all of this will be rewritten anyway)
  45     ref $_ and weaken $_
  46       for $_[1], $dbicschema, @{$args}{qw/DBIx::Schema DBIx::Class::Schema package/};
  47
  48     DBIx::Class::Exception->throw('No DBIx::Class::Schema') unless ($dbicschema);
  49     if (!ref $dbicschema) {
  50       eval "require $dbicschema"
  51         or DBIx::Class::Exception->throw("Can't load $dbicschema: $@");
  52     }
  53
  54     my $schema      = $tr->schema;
  55     my $table_no    = 0;
  56
  57     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  58       unless ($schema->name);
  59
  60     my @monikers = sort $dbicschema->sources;
  61     if ($limit_sources) {
  62         my $ref = ref $limit_sources || '';
  63         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  64           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  65
  66         # limit monikers to those specified in
  67         my $sources;
  68         if ($ref eq 'ARRAY') {
  69             $sources->{$_} = 1 for (@$limit_sources);
  70         } else {
  71             $sources = $limit_sources;
  72         }
  73         @monikers = grep { $sources->{$_} } @monikers;
  74     }
  75
  76
  77     my(%table_monikers, %view_monikers);
  78     for my $moniker (@monikers){
  79       my $source = $dbicschema->source($moniker);
  80        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  81          $table_monikers{$moniker}++;
  82       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  83           next if $source->is_virtual;
  84          $view_monikers{$moniker}++;
  85       }
  86     }
  87
  88     my %tables;
  89     foreach my $moniker (sort keys %table_monikers)
  90     {
  91         my $source = $dbicschema->source($moniker);
  92         my $table_name = $source->name;
  93
  94         # FIXME - this isn't the right way to do it, but sqlt does not
  95         # support quoting properly to be signaled about this
  96         $table_name = $$table_name if ref $table_name eq 'SCALAR';
  97
  98         # It's possible to have multiple DBIC sources using the same table
  99         next if $tables{$table_name};
 100
 101         $tables{$table_name}{source} = $source;
 102         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
 103                                        name => $table_name,
 104                                        type => 'TABLE',
 105                                        );
 106         foreach my $col ($source->columns)
 107         {
 108             # assuming column_info in dbic is the same as DBI (?)
 109             # data_type is a number, column_type is text?
 110             my %colinfo = (
 111               name => $col,
 112               size => 0,
 113               is_auto_increment => 0,
 114               is_foreign_key => 0,
 115               is_nullable => 0,
 116               %{$source->column_info($col)}
 117             );
 118             if ($colinfo{is_nullable}) {
 119               $colinfo{default} = '' unless exists $colinfo{default};
 120             }
 121             my $f = $table->add_field(%colinfo)
 122               || $dbicschema->throw_exception ($table->error);
 123         }
 124
 125         my @primary = $source->primary_columns;
 126
 127         $table->primary_key(@primary) if @primary;
 128
 129         my %unique_constraints = $source->unique_constraints;
 130         foreach my $uniq (sort keys %unique_constraints) {
 131             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 132                 $table->add_constraint(
 133                             type             => 'unique',
 134                             name             => $uniq,
 135                             fields           => $unique_constraints{$uniq}
 136                 );
 137             }
 138         }
 139
 140         my @rels = $source->relationships();
 141
 142         my %created_FK_rels;
 143
 144         # global add_fk_index set in parser_args
 145         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 146
 147         foreach my $rel (sort @rels)
 148         {
 149
 150             my $rel_info = $source->relationship_info($rel);
 151
 152             # Ignore any rel cond that isn't a straight hash
 153             next unless ref $rel_info->{cond} eq 'HASH';
 154
 155             my $relsource = try { $source->related_source($rel) };
 156             unless ($relsource) {
 157               carp "Ignoring relationship '$rel' - related resultsource '$rel_info->{class}' is not registered with this schema\n";
 158               next;
 159             };
 160
 161             # related sources might be excluded via a {sources} filter or might be views
 162             next unless exists $table_monikers{$relsource->source_name};
 163
 164             my $rel_table = $relsource->name;
 165
 166             # FIXME - this isn't the right way to do it, but sqlt does not
 167             # support quoting properly to be signaled about this
 168             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 169
 170             my $reverse_rels = $source->reverse_relationship_info($rel);
 171             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 172
 173             # Force the order of @cond to match the order of ->add_columns
 174             my $idx;
 175             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 176             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 177
 178             # Get the key information, mapping off the foreign/self markers
 179             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 180             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 181
 182             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 183             my $fk_constraint;
 184
 185             #first it can be specified explicitly
 186             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 187                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 188             }
 189             # it can not be multi
 190             elsif ( $rel_info->{attrs}{accessor}
 191                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 192                 $fk_constraint = 0;
 193             }
 194             # if indeed single, check if all self.columns are our primary keys.
 195             # this is supposed to indicate a has_one/might_have...
 196             # where's the introspection!!?? :)
 197             else {
 198                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 199             }
 200
 201             my $cascade;
 202             for my $c (qw/delete update/) {
 203                 if (exists $rel_info->{attrs}{"on_$c"}) {
 204                     if ($fk_constraint) {
 205                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 206                     }
 207                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 208                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 209                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 210                     }
 211                 }
 212                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 213                     $cascade->{$c} = 'CASCADE';
 214                 }
 215             }
 216
 217             if($rel_table) {
 218                 # Constraints are added only if applicable
 219                 next unless $fk_constraint;
 220
 221                 # Make sure we dont create the same foreign key constraint twice
 222                 my $key_test = join("\x00", sort @keys);
 223                 next if $created_FK_rels{$rel_table}->{$key_test};
 224
 225                 if (scalar(@keys)) {
 226                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 227
 228                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 229
 230                   # calculate dependencies: do not consider deferrable constraints and
 231                   # self-references for dependency calculations
 232                   if (! $is_deferrable and $rel_table ne $table_name) {
 233                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 234                   }
 235
 236                   $table->add_constraint(
 237                     type             => 'foreign_key',
 238                     name             => join('_', $table_name, 'fk', @keys),
 239                     fields           => \@keys,
 240                     reference_fields => \@refkeys,
 241                     reference_table  => $rel_table,
 242                     on_delete        => uc ($cascade->{delete} || ''),
 243                     on_update        => uc ($cascade->{update} || ''),
 244                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 245                   );
 246
 247                   # global parser_args add_fk_index param can be overridden on the rel def
 248                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 249
 250                   # Check that we do not create an index identical to the PK index
 251                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 252                   # NOTE: we do not sort the key columns because the order of
 253                   # columns is important for indexes and two indexes with the
 254                   # same cols but different order are allowed and sometimes
 255                   # needed
 256                   next if join("\x00", @keys) eq join("\x00", @primary);
 257
 258                   if ($add_fk_index_rel) {
 259                       my $index = $table->add_index(
 260                           name   => join('_', $table_name, 'idx', @keys),
 261                           fields => \@keys,
 262                           type   => 'NORMAL',
 263                       );
 264                   }
 265               }
 266             }
 267         }
 268
 269     }
 270
 271     # attach the tables to the schema in dependency order
 272     my $dependencies = {
 273       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 274     };
 275
 276     for my $table (sort
 277       {
 278         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 279           ||
 280         $a cmp $b
 281       }
 282       (keys %tables)
 283     ) {
 284       $schema->add_table ($tables{$table}{object});
 285       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 286
 287       # the hook might have already removed the table
 288       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 289         carp <<'EOW';
 290
 291 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 292 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 293 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 294
 295 EOW
 296
 297         # remove the table as there is no way someone might want to
 298         # actually deploy this
 299         $schema->drop_table ($table);
 300       }
 301     }
 302
 303     my %views;
 304     my @views = map { $dbicschema->source($_) } keys %view_monikers;
 305
 306     my $view_dependencies = {
 307         map {
 308             $_ => _resolve_deps( $dbicschema->source($_), \%view_monikers )
 309           } ( keys %view_monikers )
 310     };
 311
 312     my @view_sources =
 313       sort {
 314         keys %{ $view_dependencies->{ $a->source_name }   || {} } <=>
 315           keys %{ $view_dependencies->{ $b->source_name } || {} }
 316           || $a->source_name cmp $b->source_name
 317       }
 318       map { $dbicschema->source($_) }
 319       keys %view_monikers;
 320
 321     foreach my $source (@view_sources)
 322     {
 323         my $view_name = $source->name;
 324
 325         # FIXME - this isn't the right way to do it, but sqlt does not
 326         # support quoting properly to be signaled about this
 327         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 328
 329         # Skip custom query sources
 330         next if ref $view_name;
 331
 332         # Its possible to have multiple DBIC source using same table
 333         next if $views{$view_name}++;
 334
 335         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 336             unless $source->view_definition;
 337
 338         my $view = $schema->add_view (
 339           name => $view_name,
 340           fields => [ $source->columns ],
 341           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 342         ) || $dbicschema->throw_exception ($schema->error);
 343
 344         $source->_invoke_sqlt_deploy_hook($view);
 345     }
 346
 347
 348     if ($dbicschema->can('sqlt_deploy_hook')) {
 349       $dbicschema->sqlt_deploy_hook($schema);
 350     }
 351
 352     return 1;
 353 }
 354
 355 #
 356 # Quick and dirty dependency graph calculator
 357 #
 358 sub _resolve_deps {
 359     my ( $question, $answers, $seen ) = @_;
 360     my $ret = {};
 361     $seen ||= {};
 362     my @deps;
 363
 364     # copy and bump all deps by one (so we can reconstruct the chain)
 365     my %seen = map { $_ => $seen->{$_} + 1 } ( keys %$seen );
 366     if ( blessed($question)
 367         && $question->isa('DBIx::Class::ResultSource::View') )
 368     {
 369         $seen{ $question->result_class } = 1;
 370         @deps = keys %{ $question->{deploy_depends_on} };
 371     }
 372     else {
 373         $seen{$question} = 1;
 374         @deps = keys %{ $answers->{$question}{foreign_table_deps} };
 375     }
 376
 377     for my $dep (@deps) {
 378         if ( $seen->{$dep} ) {
 379             return {};
 380         }
 381         my $next_dep;
 382
 383         if ( blessed($question)
 384             && $question->isa('DBIx::Class::ResultSource::View') )
 385         {
 386             no warnings 'uninitialized';
 387             my ($next_dep_source_name) =
 388               grep {
 389                 $question->schema->source($_)->result_class eq $dep
 390                   && !( $question->schema->source($_)
 391                     ->isa('DBIx::Class::ResultSource::Table') )
 392               } @{ [ $question->schema->sources ] };
 393             return {} unless $next_dep_source_name;
 394             $next_dep = $question->schema->source($next_dep_source_name);
 395         }
 396         else {
 397             $next_dep = $dep;
 398         }
 399         my $subdeps = _resolve_deps( $next_dep, $answers, \%seen );
 400         $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 401         ++$ret->{$dep};
 402     }
 403     return $ret;
 404 }
 405
 406 1;
 407
 408 =head1 NAME
 409
 410 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 411 from a DBIx::Class::Schema instance
 412
 413 =head1 SYNOPSIS
 414
 415  ## Via DBIx::Class
 416  use MyApp::Schema;
 417  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 418  $schema->create_ddl_dir();
 419  ## or
 420  $schema->deploy();
 421
 422  ## Standalone
 423  use MyApp::Schema;
 424  use SQL::Translator;
 425
 426  my $schema = MyApp::Schema->connect;
 427  my $trans  = SQL::Translator->new (
 428       parser      => 'SQL::Translator::Parser::DBIx::Class',
 429       parser_args => {
 430           package => $schema,
 431           add_fk_index => 0,
 432           sources => [qw/
 433             Artist
 434             CD
 435           /],
 436       },
 437       producer    => 'SQLite',
 438      ) or die SQL::Translator->error;
 439  my $out = $trans->translate() or die $trans->error;
 440
 441 =head1 DESCRIPTION
 442
 443 This class requires L<SQL::Translator> installed to work.
 444
 445 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 446 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 447
 448 Its primary use is in deploying database layouts described as a set
 449 of L<DBIx::Class> classes, to a database. To do this, see
 450 L<DBIx::Class::Schema/deploy>.
 451
 452 This can also be achieved by having DBIx::Class export the schema as a
 453 set of SQL files ready for import into your database, or passed to
 454 other machines that need to have your application installed but don't
 455 have SQL::Translator installed. To do this see
 456 L<DBIx::Class::Schema/create_ddl_dir>.
 457
 458 =head1 PARSER OPTIONS
 459
 460 =head2 add_fk_index
 461
 462 Create an index for each foreign key.
 463 Enabled by default, as having indexed foreign key columns is normally the
 464 sensible thing to do.
 465
 466 =head2 sources
 467
 468 =over 4
 469
 470 =item Arguments: \@class_names
 471
 472 =back
 473
 474 Limit the amount of parsed sources by supplying an explicit list of source names.
 475
 476 =head1 SEE ALSO
 477
 478 L<SQL::Translator>, L<DBIx::Class::Schema>
 479
 480 =head1 AUTHORS
 481
 482 See L<DBIx::Class/CONTRIBUTORS>.
 483
 484 =head1 LICENSE
 485
 486 You may distribute this code under the same terms as Perl itself.
 487
 488 =cut