lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 our ($DEBUG, $VERSION, @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use DBIx::Class::Carp qw/^SQL::Translator|^DBIx::Class|^Try::Tiny/;
  18 use DBIx::Class::Exception;
  19 use Scalar::Util 'blessed';
  20 use Try::Tiny;
  21 use namespace::clean;
  22
  23 use base qw(Exporter);
  24
  25 @EXPORT_OK = qw(parse);
  26
  27 # -------------------------------------------------------------------
  28 # parse($tr, $data)
  29 #
  30 # setting parser_args => { add_fk_index => 0 } will prevent
  31 # the auto-generation of an index for each FK.
  32 #
  33 # Note that $data, in the case of this parser, is not useful.
  34 # We're working with DBIx::Class Schemas, not data streams.
  35 # -------------------------------------------------------------------
  36 sub parse {
  37     my ($tr, $data)   = @_;
  38     my $args          = $tr->parser_args;
  39
  40     my $dbicschema = $data || $args->{dbic_schema};
  41
  42     for (qw(DBIx::Class::Schema DBIx::Schema package)) {
  43       if (defined (my $s = delete $args->{$_} )) {
  44         carp_unique("Supplying a schema via  ... parser_args => { '$_' => \$schema } is deprecated. Please use parser_args => { dbic_schema => \$schema } instead");
  45
  46         # move it from the deprecated to the proper $args slot
  47         unless ($dbicschema) {
  48           $args->{dbic_schema} = $dbicschema = $s;
  49         }
  50       }
  51     }
  52
  53     DBIx::Class::Exception->throw('No DBIx::Class::Schema') unless ($dbicschema);
  54
  55     if (!ref $dbicschema) {
  56       eval "require $dbicschema"
  57         or DBIx::Class::Exception->throw("Can't load $dbicschema: $@");
  58     }
  59
  60     if (
  61       ref $args->{dbic_schema}
  62         and
  63       $args->{dbic_schema}->storage
  64     ) {
  65       # we have a storage-holding $schema instance in $args
  66       # we need to dissociate it from that $storage
  67       # otherwise SQLT insanity may ensue due to how some
  68       # serializing producers treat $args (crazy crazy shit)
  69       local $args->{dbic_schema}{storage};
  70       $args->{dbic_schema} = $args->{dbic_schema}->clone;
  71     }
  72
  73     my $schema      = $tr->schema;
  74     my $table_no    = 0;
  75
  76     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  77       unless ($schema->name);
  78
  79     my @monikers = sort $dbicschema->sources;
  80     if (my $limit_sources = $args->{'sources'}) {
  81         my $ref = ref $limit_sources || '';
  82         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  83           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  84
  85         # limit monikers to those specified in
  86         my $sources;
  87         if ($ref eq 'ARRAY') {
  88             $sources->{$_} = 1 for (@$limit_sources);
  89         } else {
  90             $sources = $limit_sources;
  91         }
  92         @monikers = grep { $sources->{$_} } @monikers;
  93     }
  94
  95
  96     my(%table_monikers, %view_monikers);
  97     for my $moniker (@monikers){
  98       my $source = $dbicschema->source($moniker);
  99        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
 100          $table_monikers{$moniker}++;
 101       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
 102           next if $source->is_virtual;
 103          $view_monikers{$moniker}++;
 104       }
 105     }
 106
 107     my %tables;
 108     foreach my $moniker (sort keys %table_monikers)
 109     {
 110         my $source = $dbicschema->source($moniker);
 111         my $table_name = $source->name;
 112
 113         # FIXME - this isn't the right way to do it, but sqlt does not
 114         # support quoting properly to be signaled about this
 115         $table_name = $$table_name if ref $table_name eq 'SCALAR';
 116
 117         # It's possible to have multiple DBIC sources using the same table
 118         next if $tables{$table_name};
 119
 120         $tables{$table_name}{source} = $source;
 121         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
 122                                        name => $table_name,
 123                                        type => 'TABLE',
 124                                        );
 125         foreach my $col ($source->columns)
 126         {
 127             # assuming column_info in dbic is the same as DBI (?)
 128             # data_type is a number, column_type is text?
 129             my %colinfo = (
 130               name => $col,
 131               size => 0,
 132               is_auto_increment => 0,
 133               is_foreign_key => 0,
 134               is_nullable => 0,
 135               %{$source->column_info($col)}
 136             );
 137             if ($colinfo{is_nullable}) {
 138               $colinfo{default} = '' unless exists $colinfo{default};
 139             }
 140             my $f = $table->add_field(%colinfo)
 141               || $dbicschema->throw_exception ($table->error);
 142         }
 143
 144         my @primary = $source->primary_columns;
 145
 146         $table->primary_key(@primary) if @primary;
 147
 148         my %unique_constraints = $source->unique_constraints;
 149         foreach my $uniq (sort keys %unique_constraints) {
 150             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 151                 $table->add_constraint(
 152                             type             => 'unique',
 153                             name             => $uniq,
 154                             fields           => $unique_constraints{$uniq}
 155                 );
 156             }
 157         }
 158
 159         my @rels = $source->relationships();
 160
 161         my %created_FK_rels;
 162
 163         # global add_fk_index set in parser_args
 164         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 165
 166         foreach my $rel (sort @rels)
 167         {
 168
 169             my $rel_info = $source->relationship_info($rel);
 170
 171             # Ignore any rel cond that isn't a straight hash
 172             next unless ref $rel_info->{cond} eq 'HASH';
 173
 174             my $relsource = try { $source->related_source($rel) };
 175             unless ($relsource) {
 176               carp "Ignoring relationship '$rel' - related resultsource '$rel_info->{class}' is not registered with this schema\n";
 177               next;
 178             };
 179
 180             # related sources might be excluded via a {sources} filter or might be views
 181             next unless exists $table_monikers{$relsource->source_name};
 182
 183             my $rel_table = $relsource->name;
 184
 185             # FIXME - this isn't the right way to do it, but sqlt does not
 186             # support quoting properly to be signaled about this
 187             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 188
 189             my $reverse_rels = $source->reverse_relationship_info($rel);
 190             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 191
 192             # Force the order of @cond to match the order of ->add_columns
 193             my $idx;
 194             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 195             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 196
 197             # Get the key information, mapping off the foreign/self markers
 198             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 199             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 200
 201             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 202             my $fk_constraint;
 203
 204             #first it can be specified explicitly
 205             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 206                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 207             }
 208             # it can not be multi
 209             elsif ( $rel_info->{attrs}{accessor}
 210                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 211                 $fk_constraint = 0;
 212             }
 213             # if indeed single, check if all self.columns are our primary keys.
 214             # this is supposed to indicate a has_one/might_have...
 215             # where's the introspection!!?? :)
 216             else {
 217                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 218             }
 219
 220             my $cascade;
 221             for my $c (qw/delete update/) {
 222                 if (exists $rel_info->{attrs}{"on_$c"}) {
 223                     if ($fk_constraint) {
 224                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 225                     }
 226                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 227                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 228                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 229                     }
 230                 }
 231                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 232                     $cascade->{$c} = 'CASCADE';
 233                 }
 234             }
 235
 236             if($rel_table) {
 237                 # Constraints are added only if applicable
 238                 next unless $fk_constraint;
 239
 240                 # Make sure we don't create the same foreign key constraint twice
 241                 my $key_test = join("\x00", sort @keys);
 242                 next if $created_FK_rels{$rel_table}->{$key_test};
 243
 244                 if (scalar(@keys)) {
 245                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 246
 247                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 248
 249                   # calculate dependencies: do not consider deferrable constraints and
 250                   # self-references for dependency calculations
 251                   if (! $is_deferrable and $rel_table ne $table_name) {
 252                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 253                   }
 254
 255                   $table->add_constraint(
 256                     type             => 'foreign_key',
 257                     name             => join('_', $table_name, 'fk', @keys),
 258                     fields           => \@keys,
 259                     reference_fields => \@refkeys,
 260                     reference_table  => $rel_table,
 261                     on_delete        => uc ($cascade->{delete} || ''),
 262                     on_update        => uc ($cascade->{update} || ''),
 263                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 264                   );
 265
 266                   # global parser_args add_fk_index param can be overridden on the rel def
 267                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 268
 269                   # Check that we do not create an index identical to the PK index
 270                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 271                   # NOTE: we do not sort the key columns because the order of
 272                   # columns is important for indexes and two indexes with the
 273                   # same cols but different order are allowed and sometimes
 274                   # needed
 275                   next if join("\x00", @keys) eq join("\x00", @primary);
 276
 277                   if ($add_fk_index_rel) {
 278                       my $index = $table->add_index(
 279                           name   => join('_', $table_name, 'idx', @keys),
 280                           fields => \@keys,
 281                           type   => 'NORMAL',
 282                       );
 283                   }
 284               }
 285             }
 286         }
 287
 288     }
 289
 290     # attach the tables to the schema in dependency order
 291     my $dependencies = {
 292       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 293     };
 294
 295     for my $table (sort
 296       {
 297         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 298           ||
 299         $a cmp $b
 300       }
 301       (keys %tables)
 302     ) {
 303       $schema->add_table ($tables{$table}{object});
 304       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 305
 306       # the hook might have already removed the table
 307       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 308         carp <<'EOW';
 309
 310 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 311 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 312 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 313
 314 EOW
 315
 316         # remove the table as there is no way someone might want to
 317         # actually deploy this
 318         $schema->drop_table ($table);
 319       }
 320     }
 321
 322     my %views;
 323     my @views = map { $dbicschema->source($_) } keys %view_monikers;
 324
 325     my $view_dependencies = {
 326         map {
 327             $_ => _resolve_deps( $dbicschema->source($_), \%view_monikers )
 328           } ( keys %view_monikers )
 329     };
 330
 331     my @view_sources =
 332       sort {
 333         keys %{ $view_dependencies->{ $a->source_name }   || {} } <=>
 334           keys %{ $view_dependencies->{ $b->source_name } || {} }
 335           || $a->source_name cmp $b->source_name
 336       }
 337       map { $dbicschema->source($_) }
 338       keys %view_monikers;
 339
 340     foreach my $source (@view_sources)
 341     {
 342         my $view_name = $source->name;
 343
 344         # FIXME - this isn't the right way to do it, but sqlt does not
 345         # support quoting properly to be signaled about this
 346         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 347
 348         # Skip custom query sources
 349         next if ref $view_name;
 350
 351         # Its possible to have multiple DBIC source using same table
 352         next if $views{$view_name}++;
 353
 354         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 355             unless $source->view_definition;
 356
 357         my $view = $schema->add_view (
 358           name => $view_name,
 359           fields => [ $source->columns ],
 360           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 361         ) || $dbicschema->throw_exception ($schema->error);
 362
 363         $source->_invoke_sqlt_deploy_hook($view);
 364     }
 365
 366
 367     if ($dbicschema->can('sqlt_deploy_hook')) {
 368       $dbicschema->sqlt_deploy_hook($schema);
 369     }
 370
 371     return 1;
 372 }
 373
 374 #
 375 # Quick and dirty dependency graph calculator
 376 #
 377 sub _resolve_deps {
 378     my ( $question, $answers, $seen ) = @_;
 379     my $ret = {};
 380     $seen ||= {};
 381     my @deps;
 382
 383     # copy and bump all deps by one (so we can reconstruct the chain)
 384     my %seen = map { $_ => $seen->{$_} + 1 } ( keys %$seen );
 385     if ( blessed($question)
 386         && $question->isa('DBIx::Class::ResultSource::View') )
 387     {
 388         $seen{ $question->result_class } = 1;
 389         @deps = keys %{ $question->{deploy_depends_on} };
 390     }
 391     else {
 392         $seen{$question} = 1;
 393         @deps = keys %{ $answers->{$question}{foreign_table_deps} };
 394     }
 395
 396     for my $dep (@deps) {
 397         if ( $seen->{$dep} ) {
 398             return {};
 399         }
 400         my $next_dep;
 401
 402         if ( blessed($question)
 403             && $question->isa('DBIx::Class::ResultSource::View') )
 404         {
 405             no warnings 'uninitialized';
 406             my ($next_dep_source_name) =
 407               grep {
 408                 $question->schema->source($_)->result_class eq $dep
 409                   && !( $question->schema->source($_)
 410                     ->isa('DBIx::Class::ResultSource::Table') )
 411               } @{ [ $question->schema->sources ] };
 412             return {} unless $next_dep_source_name;
 413             $next_dep = $question->schema->source($next_dep_source_name);
 414         }
 415         else {
 416             $next_dep = $dep;
 417         }
 418         my $subdeps = _resolve_deps( $next_dep, $answers, \%seen );
 419         $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 420         ++$ret->{$dep};
 421     }
 422     return $ret;
 423 }
 424
 425 1;
 426
 427 =head1 NAME
 428
 429 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 430 from a DBIx::Class::Schema instance
 431
 432 =head1 SYNOPSIS
 433
 434  ## Via DBIx::Class
 435  use MyApp::Schema;
 436  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 437  $schema->create_ddl_dir();
 438  ## or
 439  $schema->deploy();
 440
 441  ## Standalone
 442  use MyApp::Schema;
 443  use SQL::Translator;
 444
 445  my $schema = MyApp::Schema->connect;
 446  my $trans  = SQL::Translator->new (
 447       parser      => 'SQL::Translator::Parser::DBIx::Class',
 448       parser_args => {
 449           dbic_schema => $schema,
 450           add_fk_index => 0,
 451           sources => [qw/
 452             Artist
 453             CD
 454           /],
 455       },
 456       producer    => 'SQLite',
 457      ) or die SQL::Translator->error;
 458  my $out = $trans->translate() or die $trans->error;
 459
 460 =head1 DESCRIPTION
 461
 462 This class requires L<SQL::Translator> installed to work.
 463
 464 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 465 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 466
 467 Its primary use is in deploying database layouts described as a set
 468 of L<DBIx::Class> classes, to a database. To do this, see
 469 L<DBIx::Class::Schema/deploy>.
 470
 471 This can also be achieved by having DBIx::Class export the schema as a
 472 set of SQL files ready for import into your database, or passed to
 473 other machines that need to have your application installed but don't
 474 have SQL::Translator installed. To do this see
 475 L<DBIx::Class::Schema/create_ddl_dir>.
 476
 477 =head1 PARSER OPTIONS
 478
 479 =head2 dbic_schema
 480
 481 The DBIx::Class schema (either an instance or a class name) to be parsed.
 482 This argument is in fact optional - instead one can supply it later at
 483 translation time as an argument to L<SQL::Translator/translate>. In
 484 other words both of the following invocations are valid and will produce
 485 conceptually identical output:
 486
 487   my $yaml = SQL::Translator->new(
 488     parser => 'SQL::Translator::Parser::DBIx::Class',
 489     parser_args => {
 490       dbic_schema => $schema,
 491     },
 492     producer => 'SQL::Translator::Producer::YAML',
 493   )->translate;
 494
 495   my $yaml = SQL::Translator->new(
 496     parser => 'SQL::Translator::Parser::DBIx::Class',
 497     producer => 'SQL::Translator::Producer::YAML',
 498   )->translate(data => $schema);
 499
 500 =head2 add_fk_index
 501
 502 Create an index for each foreign key.
 503 Enabled by default, as having indexed foreign key columns is normally the
 504 sensible thing to do.
 505
 506 =head2 sources
 507
 508 =over 4
 509
 510 =item Arguments: \@class_names
 511
 512 =back
 513
 514 Limit the amount of parsed sources by supplying an explicit list of source names.
 515
 516 =head1 SEE ALSO
 517
 518 L<SQL::Translator>, L<DBIx::Class::Schema>
 519
 520 =head1 AUTHORS
 521
 522 See L<DBIx::Class/CONTRIBUTORS>.
 523
 524 =head1 LICENSE
 525
 526 You may distribute this code under the same terms as Perl itself.
 527
 528 =cut