lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
  18
  19 use base qw(Exporter);
  20
  21 @EXPORT_OK = qw(parse);
  22
  23 # -------------------------------------------------------------------
  24 # parse($tr, $data)
  25 #
  26 # setting parser_args => { add_fk_index => 0 } will prevent
  27 # the auto-generation of an index for each FK.
  28 #
  29 # Note that $data, in the case of this parser, is not useful.
  30 # We're working with DBIx::Class Schemas, not data streams.
  31 # -------------------------------------------------------------------
  32 sub parse {
  33     my ($tr, $data)   = @_;
  34     my $args          = $tr->parser_args;
  35     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  36     $dbicschema     ||= $args->{'package'};
  37     my $limit_sources = $args->{'sources'};
  38
  39     die 'No DBIx::Class::Schema' unless ($dbicschema);
  40     if (!ref $dbicschema) {
  41       eval "use $dbicschema;";
  42       die "Can't load $dbicschema ($@)" if($@);
  43     }
  44
  45     my $schema      = $tr->schema;
  46     my $table_no    = 0;
  47
  48     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  49       unless ($schema->name);
  50
  51     my @monikers = sort $dbicschema->sources;
  52     if ($limit_sources) {
  53         my $ref = ref $limit_sources || '';
  54         die "'sources' parameter must be an array or hash ref" unless $ref eq 'ARRAY' || ref eq 'HASH';
  55
  56         # limit monikers to those specified in
  57         my $sources;
  58         if ($ref eq 'ARRAY') {
  59             $sources->{$_} = 1 for (@$limit_sources);
  60         } else {
  61             $sources = $limit_sources;
  62         }
  63         @monikers = grep { $sources->{$_} } @monikers;
  64     }
  65
  66
  67     my(@table_monikers, @view_monikers);
  68     for my $moniker (@monikers){
  69       my $source = $dbicschema->source($moniker);
  70        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  71          push(@table_monikers, $moniker);
  72       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  73           next if $source->is_virtual;
  74          push(@view_monikers, $moniker);
  75       }
  76     }
  77
  78     my %tables;
  79     foreach my $moniker (sort @table_monikers)
  80     {
  81         my $source = $dbicschema->source($moniker);
  82         my $table_name = $source->name;
  83
  84         # Skip custom query sources
  85         next if ref $table_name;
  86
  87         # Its possible to have multiple DBIC sources using the same table
  88         next if $tables{$table_name};
  89
  90         $tables{$table_name}{source} = $source;
  91         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
  92                                        name => $table_name,
  93                                        type => 'TABLE',
  94                                        );
  95         foreach my $col ($source->columns)
  96         {
  97             # assuming column_info in dbic is the same as DBI (?)
  98             # data_type is a number, column_type is text?
  99             my %colinfo = (
 100               name => $col,
 101               size => 0,
 102               is_auto_increment => 0,
 103               is_foreign_key => 0,
 104               is_nullable => 0,
 105               %{$source->column_info($col)}
 106             );
 107             if ($colinfo{is_nullable}) {
 108               $colinfo{default} = '' unless exists $colinfo{default};
 109             }
 110             my $f = $table->add_field(%colinfo) || die $table->error;
 111         }
 112         $table->primary_key($source->primary_columns);
 113
 114         my @primary = $source->primary_columns;
 115         my %unique_constraints = $source->unique_constraints;
 116         foreach my $uniq (sort keys %unique_constraints) {
 117             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 118                 $table->add_constraint(
 119                             type             => 'unique',
 120                             name             => $uniq,
 121                             fields           => $unique_constraints{$uniq}
 122                 );
 123             }
 124         }
 125
 126         my @rels = $source->relationships();
 127
 128         my %created_FK_rels;
 129
 130         # global add_fk_index set in parser_args
 131         my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
 132
 133         foreach my $rel (sort @rels)
 134         {
 135             my $rel_info = $source->relationship_info($rel);
 136
 137             # Ignore any rel cond that isn't a straight hash
 138             next unless ref $rel_info->{cond} eq 'HASH';
 139
 140             my $othertable = $source->related_source($rel);
 141             my $rel_table = $othertable->name;
 142
 143             my $reverse_rels = $source->reverse_relationship_info($rel);
 144             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 145
 146             # Force the order of @cond to match the order of ->add_columns
 147             my $idx;
 148             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
 149             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 150
 151             # Get the key information, mapping off the foreign/self markers
 152             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 153             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 154
 155             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 156             my $fk_constraint;
 157
 158             #first it can be specified explicitly
 159             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 160                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 161             }
 162             # it can not be multi
 163             elsif ( $rel_info->{attrs}{accessor}
 164                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 165                 $fk_constraint = 0;
 166             }
 167             # if indeed single, check if all self.columns are our primary keys.
 168             # this is supposed to indicate a has_one/might_have...
 169             # where's the introspection!!?? :)
 170             else {
 171                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 172             }
 173
 174             my $cascade;
 175             for my $c (qw/delete update/) {
 176                 if (exists $rel_info->{attrs}{"on_$c"}) {
 177                     if ($fk_constraint) {
 178                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 179                     }
 180                     else {
 181                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 182                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 183                     }
 184                 }
 185                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 186                     $cascade->{$c} = 'CASCADE';
 187                 }
 188             }
 189
 190             if($rel_table)
 191             {
 192                 # Constraints are added only if applicable
 193                 next unless $fk_constraint;
 194
 195                 # Make sure we dont create the same foreign key constraint twice
 196                 my $key_test = join("\x00", @keys);
 197                 next if $created_FK_rels{$rel_table}->{$key_test};
 198
 199                 if (scalar(@keys)) {
 200
 201                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 202
 203                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 204
 205                   # do not consider deferrable constraints and self-references
 206                   # for dependency calculations
 207                   if (! $is_deferrable and $rel_table ne $table_name) {
 208                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 209                   }
 210
 211                   $table->add_constraint(
 212                                     type             => 'foreign_key',
 213                                     name             => join('_', $table_name, 'fk', @keys),
 214                                     fields           => \@keys,
 215                                     reference_fields => \@refkeys,
 216                                     reference_table  => $rel_table,
 217                                     on_delete        => uc ($cascade->{delete} || ''),
 218                                     on_update        => uc ($cascade->{update} || ''),
 219                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 220                   );
 221
 222                   # global parser_args add_fk_index param can be overridden on the rel def
 223                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 224
 225                   if ($add_fk_index_rel) {
 226                       my $index = $table->add_index(
 227                                                     name   => join('_', $table_name, 'idx', @keys),
 228                                                     fields => \@keys,
 229                                                     type   => 'NORMAL',
 230                                                     );
 231                   }
 232               }
 233             }
 234         }
 235
 236     }
 237
 238     # attach the tables to the schema in dependency order
 239     my $dependencies = {
 240       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 241     };
 242     for my $table (sort
 243       {
 244         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 245           ||
 246         $a cmp $b
 247       }
 248       (keys %tables)
 249     ) {
 250       $schema->add_table ($tables{$table}{object});
 251       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 252     }
 253
 254
 255     my %views;
 256     foreach my $moniker (sort @view_monikers)
 257     {
 258         my $source = $dbicschema->source($moniker);
 259         my $view_name = $source->name;
 260
 261         # Skip custom query sources
 262         next if ref $view_name;
 263
 264         # Its possible to have multiple DBIC source using same table
 265         next if $views{$view_name}++;
 266
 267         my $view = $schema->add_view (
 268           name => $view_name,
 269           fields => [ $source->columns ],
 270           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 271         ) || die $schema->error;
 272
 273         $source->_invoke_sqlt_deploy_hook($view);
 274     }
 275
 276
 277     if ($dbicschema->can('sqlt_deploy_hook')) {
 278       $dbicschema->sqlt_deploy_hook($schema);
 279     }
 280
 281     return 1;
 282 }
 283
 284 #
 285 # Quick and dirty dependency graph calculator
 286 #
 287 sub _resolve_deps {
 288   my ($table, $tables, $seen) = @_;
 289
 290   my $ret = {};
 291   $seen ||= {};
 292
 293   # copy and bump all deps by one (so we can reconstruct the chain)
 294   my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
 295   $seen{$table} = 1;
 296
 297   for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
 298
 299     if ($seen->{$dep}) {
 300
 301       # warn and remove the circular constraint so we don't get flooded with the same warning over and over
 302       #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
 303       #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
 304       #);
 305       #delete $tables->{$table}{foreign_table_deps}{$dep};
 306
 307       return {};
 308     }
 309
 310     my $subdeps = _resolve_deps ($dep, $tables, \%seen);
 311     $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 312
 313     ++$ret->{$dep};
 314   }
 315
 316   return $ret;
 317 }
 318
 319 1;
 320
 321 =head1 NAME
 322
 323 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 324 from a DBIx::Class::Schema instance
 325
 326 =head1 SYNOPSIS
 327
 328  ## Via DBIx::Class
 329  use MyApp::Schema;
 330  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 331  $schema->create_ddl_dir();
 332  ## or
 333  $schema->deploy();
 334
 335  ## Standalone
 336  use MyApp::Schema;
 337  use SQL::Translator;
 338
 339  my $schema = MyApp::Schema->connect;
 340  my $trans  = SQL::Translator->new (
 341       parser      => 'SQL::Translator::Parser::DBIx::Class',
 342       parser_args => { package => $schema },
 343       producer    => 'SQLite',
 344      ) or die SQL::Translator->error;
 345  my $out = $trans->translate() or die $trans->error;
 346
 347 =head1 DESCRIPTION
 348
 349 This class requires L<SQL::Translator> installed to work.
 350
 351 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 352 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 353
 354 It's primary use is in deploying database layouts described as a set
 355 of L<DBIx::Class> classes, to a database. To do this, see
 356 L<DBIx::Class::Schema/deploy>.
 357
 358 This can also be achieved by having DBIx::Class export the schema as a
 359 set of SQL files ready for import into your database, or passed to
 360 other machines that need to have your application installed but don't
 361 have SQL::Translator installed. To do this see
 362 L<DBIx::Class::Schema/create_ddl_dir>.
 363
 364 =head1 SEE ALSO
 365
 366 L<SQL::Translator>, L<DBIx::Class::Schema>
 367
 368 =head1 AUTHORS
 369
 370 Jess Robinson
 371
 372 Matt S Trout
 373
 374 Ash Berlin