lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
  18 use Scalar::Util ();
  19
  20 use base qw(Exporter);
  21
  22 @EXPORT_OK = qw(parse);
  23
  24 # -------------------------------------------------------------------
  25 # parse($tr, $data)
  26 #
  27 # setting parser_args => { add_fk_index => 0 } will prevent
  28 # the auto-generation of an index for each FK.
  29 #
  30 # Note that $data, in the case of this parser, is not useful.
  31 # We're working with DBIx::Class Schemas, not data streams.
  32 # -------------------------------------------------------------------
  33 sub parse {
  34     # this is a hack to prevent schema leaks due to a retarded SQLT implementation
  35     # DO NOT REMOVE (until SQLT2 is out, the all of this will be rewritten anyway)
  36     Scalar::Util::weaken ($_[1]);
  37
  38     my ($tr, $data)   = @_;
  39     my $args          = $tr->parser_args;
  40     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  41     $dbicschema     ||= $args->{'package'};
  42     my $limit_sources = $args->{'sources'};
  43
  44     croak 'No DBIx::Class::Schema' unless ($dbicschema);
  45     if (!ref $dbicschema) {
  46       eval "use $dbicschema;";
  47       croak "Can't load $dbicschema ($@)" if($@);
  48     }
  49
  50     my $schema      = $tr->schema;
  51     my $table_no    = 0;
  52
  53     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  54       unless ($schema->name);
  55
  56     my @monikers = sort $dbicschema->sources;
  57     if ($limit_sources) {
  58         my $ref = ref $limit_sources || '';
  59         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  60           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  61
  62         # limit monikers to those specified in
  63         my $sources;
  64         if ($ref eq 'ARRAY') {
  65             $sources->{$_} = 1 for (@$limit_sources);
  66         } else {
  67             $sources = $limit_sources;
  68         }
  69         @monikers = grep { $sources->{$_} } @monikers;
  70     }
  71
  72
  73     my(%table_monikers, %view_monikers);
  74     for my $moniker (@monikers){
  75       my $source = $dbicschema->source($moniker);
  76        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  77          $table_monikers{$moniker}++;
  78       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  79           next if $source->is_virtual;
  80          $view_monikers{$moniker}++;
  81       }
  82     }
  83
  84     my %tables;
  85     foreach my $moniker (sort keys %table_monikers)
  86     {
  87         my $source = $dbicschema->source($moniker);
  88         my $table_name = $source->name;
  89
  90         # FIXME - this isn't the right way to do it, but sqlt does not
  91         # support quoting properly to be signaled about this
  92         $table_name = $$table_name if ref $table_name eq 'SCALAR';
  93
  94         # It's possible to have multiple DBIC sources using the same table
  95         next if $tables{$table_name};
  96
  97         $tables{$table_name}{source} = $source;
  98         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
  99                                        name => $table_name,
 100                                        type => 'TABLE',
 101                                        );
 102         foreach my $col ($source->columns)
 103         {
 104             # assuming column_info in dbic is the same as DBI (?)
 105             # data_type is a number, column_type is text?
 106             my %colinfo = (
 107               name => $col,
 108               size => 0,
 109               is_auto_increment => 0,
 110               is_foreign_key => 0,
 111               is_nullable => 0,
 112               %{$source->column_info($col)}
 113             );
 114             if ($colinfo{is_nullable}) {
 115               $colinfo{default} = '' unless exists $colinfo{default};
 116             }
 117             my $f = $table->add_field(%colinfo)
 118               || $dbicschema->throw_exception ($table->error);
 119         }
 120
 121         my @primary = $source->primary_columns;
 122
 123         $table->primary_key(@primary) if @primary;
 124
 125         my %unique_constraints = $source->unique_constraints;
 126         foreach my $uniq (sort keys %unique_constraints) {
 127             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 128                 $table->add_constraint(
 129                             type             => 'unique',
 130                             name             => $uniq,
 131                             fields           => $unique_constraints{$uniq}
 132                 );
 133             }
 134         }
 135
 136         my @rels = $source->relationships();
 137
 138         my %created_FK_rels;
 139
 140         # global add_fk_index set in parser_args
 141         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 142
 143         foreach my $rel (sort @rels)
 144         {
 145
 146             my $rel_info = $source->relationship_info($rel);
 147
 148             # Ignore any rel cond that isn't a straight hash
 149             next unless ref $rel_info->{cond} eq 'HASH';
 150
 151             my $relsource = $source->related_source($rel);
 152
 153             # related sources might be excluded via a {sources} filter or might be views
 154             next unless exists $table_monikers{$relsource->source_name};
 155
 156             my $rel_table = $relsource->name;
 157
 158             # FIXME - this isn't the right way to do it, but sqlt does not
 159             # support quoting properly to be signaled about this
 160             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 161
 162             my $reverse_rels = $source->reverse_relationship_info($rel);
 163             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 164
 165             # Force the order of @cond to match the order of ->add_columns
 166             my $idx;
 167             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 168             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 169
 170             # Get the key information, mapping off the foreign/self markers
 171             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 172             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 173
 174             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 175             my $fk_constraint;
 176
 177             #first it can be specified explicitly
 178             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 179                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 180             }
 181             # it can not be multi
 182             elsif ( $rel_info->{attrs}{accessor}
 183                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 184                 $fk_constraint = 0;
 185             }
 186             # if indeed single, check if all self.columns are our primary keys.
 187             # this is supposed to indicate a has_one/might_have...
 188             # where's the introspection!!?? :)
 189             else {
 190                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 191             }
 192
 193             my $cascade;
 194             for my $c (qw/delete update/) {
 195                 if (exists $rel_info->{attrs}{"on_$c"}) {
 196                     if ($fk_constraint) {
 197                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 198                     }
 199                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 200                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 201                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 202                     }
 203                 }
 204                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 205                     $cascade->{$c} = 'CASCADE';
 206                 }
 207             }
 208
 209             if($rel_table) {
 210                 # Constraints are added only if applicable
 211                 next unless $fk_constraint;
 212
 213                 # Make sure we dont create the same foreign key constraint twice
 214                 my $key_test = join("\x00", sort @keys);
 215                 next if $created_FK_rels{$rel_table}->{$key_test};
 216
 217                 if (scalar(@keys)) {
 218                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 219
 220                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 221
 222                   # calculate dependencies: do not consider deferrable constraints and
 223                   # self-references for dependency calculations
 224                   if (! $is_deferrable and $rel_table ne $table_name) {
 225                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 226                   }
 227
 228                   $table->add_constraint(
 229                     type             => 'foreign_key',
 230                     name             => join('_', $table_name, 'fk', @keys),
 231                     fields           => \@keys,
 232                     reference_fields => \@refkeys,
 233                     reference_table  => $rel_table,
 234                     on_delete        => uc ($cascade->{delete} || ''),
 235                     on_update        => uc ($cascade->{update} || ''),
 236                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 237                   );
 238
 239                   # global parser_args add_fk_index param can be overridden on the rel def
 240                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 241                   # Make sure we don't create another index with the same
 242                   # order of columns twice
 243
 244                   # WARNING: don't sort the key columns because the order of
 245                   # columns is important for indexes and two indexes with the
 246                   # same cols but different order are allowed and sometimes
 247                   # needed
 248                   my $key_idx_test = join("\x00", @keys);
 249                   my $pk_idx_test  = join("\x00", @primary);
 250                   next if $key_idx_test eq $pk_idx_test;
 251
 252                   if ($add_fk_index_rel) {
 253                       my $index = $table->add_index(
 254                           name   => join('_', $table_name, 'idx', @keys),
 255                           fields => \@keys,
 256                           type   => 'NORMAL',
 257                       );
 258                   }
 259               }
 260             }
 261         }
 262
 263     }
 264
 265     # attach the tables to the schema in dependency order
 266     my $dependencies = {
 267       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 268     };
 269     for my $table (sort
 270       {
 271         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 272           ||
 273         $a cmp $b
 274       }
 275       (keys %tables)
 276     ) {
 277       $schema->add_table ($tables{$table}{object});
 278       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 279
 280       # the hook might have already removed the table
 281       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 282         warn <<'EOW';
 283
 284 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 285 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 286 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 287
 288 EOW
 289
 290         # remove the table as there is no way someone might want to
 291         # actually deploy this
 292         $schema->drop_table ($table);
 293       }
 294     }
 295
 296     my %views;
 297     foreach my $moniker (sort keys %view_monikers)
 298     {
 299         my $source = $dbicschema->source($moniker);
 300         my $view_name = $source->name;
 301
 302         # FIXME - this isn't the right way to do it, but sqlt does not
 303         # support quoting properly to be signaled about this
 304         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 305
 306         # Skip custom query sources
 307         next if ref $view_name;
 308
 309         # Its possible to have multiple DBIC source using same table
 310         next if $views{$view_name}++;
 311
 312         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 313             unless $source->view_definition;
 314
 315         my $view = $schema->add_view (
 316           name => $view_name,
 317           fields => [ $source->columns ],
 318           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 319         ) || $dbicschema->throw_exception ($schema->error);
 320
 321         $source->_invoke_sqlt_deploy_hook($view);
 322     }
 323
 324
 325     if ($dbicschema->can('sqlt_deploy_hook')) {
 326       $dbicschema->sqlt_deploy_hook($schema);
 327     }
 328
 329     return 1;
 330 }
 331
 332 #
 333 # Quick and dirty dependency graph calculator
 334 #
 335 sub _resolve_deps {
 336   my ($table, $tables, $seen) = @_;
 337
 338   my $ret = {};
 339   $seen ||= {};
 340
 341   # copy and bump all deps by one (so we can reconstruct the chain)
 342   my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
 343   $seen{$table} = 1;
 344
 345   for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
 346
 347     if ($seen->{$dep}) {
 348
 349       # warn and remove the circular constraint so we don't get flooded with the same warning over and over
 350       #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
 351       #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
 352       #);
 353       #delete $tables->{$table}{foreign_table_deps}{$dep};
 354
 355       return {};
 356     }
 357
 358     my $subdeps = _resolve_deps ($dep, $tables, \%seen);
 359     $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 360
 361     ++$ret->{$dep};
 362   }
 363
 364   return $ret;
 365 }
 366
 367 1;
 368
 369 =head1 NAME
 370
 371 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 372 from a DBIx::Class::Schema instance
 373
 374 =head1 SYNOPSIS
 375
 376  ## Via DBIx::Class
 377  use MyApp::Schema;
 378  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 379  $schema->create_ddl_dir();
 380  ## or
 381  $schema->deploy();
 382
 383  ## Standalone
 384  use MyApp::Schema;
 385  use SQL::Translator;
 386
 387  my $schema = MyApp::Schema->connect;
 388  my $trans  = SQL::Translator->new (
 389       parser      => 'SQL::Translator::Parser::DBIx::Class',
 390       parser_args => {
 391           package => $schema,
 392           add_fk_index => 0,
 393           sources => [qw/
 394             Artist
 395             CD
 396           /],
 397       },
 398       producer    => 'SQLite',
 399      ) or die SQL::Translator->error;
 400  my $out = $trans->translate() or die $trans->error;
 401
 402 =head1 DESCRIPTION
 403
 404 This class requires L<SQL::Translator> installed to work.
 405
 406 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 407 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 408
 409 Its primary use is in deploying database layouts described as a set
 410 of L<DBIx::Class> classes, to a database. To do this, see
 411 L<DBIx::Class::Schema/deploy>.
 412
 413 This can also be achieved by having DBIx::Class export the schema as a
 414 set of SQL files ready for import into your database, or passed to
 415 other machines that need to have your application installed but don't
 416 have SQL::Translator installed. To do this see
 417 L<DBIx::Class::Schema/create_ddl_dir>.
 418
 419 =head1 PARSER OPTIONS
 420
 421 =head2 add_fk_index
 422
 423 Create an index for each foreign key.
 424 It defaults to enabled because this is a sensible default which accelerates most rdbms.
 425
 426 =head2 sources
 427
 428 =over 4
 429
 430 =item Arguments: @classes
 431
 432 =back
 433
 434 To explicitly specify which ResultSources should be parsed.
 435
 436 =head1 SEE ALSO
 437
 438 L<SQL::Translator>, L<DBIx::Class::Schema>
 439
 440 =head1 AUTHORS
 441
 442 Jess Robinson
 443
 444 Matt S Trout
 445
 446 Ash Berlin
 447
 448 Alexander Hartmaier