lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
  18
  19 use base qw(Exporter);
  20
  21 @EXPORT_OK = qw(parse);
  22
  23 # -------------------------------------------------------------------
  24 # parse($tr, $data)
  25 #
  26 # setting parser_args => { add_fk_index => 0 } will prevent
  27 # the auto-generation of an index for each FK.
  28 #
  29 # Note that $data, in the case of this parser, is not useful.
  30 # We're working with DBIx::Class Schemas, not data streams.
  31 # -------------------------------------------------------------------
  32 sub parse {
  33     my ($tr, $data)   = @_;
  34     my $args          = $tr->parser_args;
  35     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  36     $dbicschema     ||= $args->{'package'};
  37     my $limit_sources = $args->{'sources'};
  38
  39     croak 'No DBIx::Class::Schema' unless ($dbicschema);
  40     if (!ref $dbicschema) {
  41       eval "use $dbicschema;";
  42       croak "Can't load $dbicschema ($@)" if($@);
  43     }
  44
  45     my $schema      = $tr->schema;
  46     my $table_no    = 0;
  47
  48     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  49       unless ($schema->name);
  50
  51     my @monikers = sort $dbicschema->sources;
  52     if ($limit_sources) {
  53         my $ref = ref $limit_sources || '';
  54         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  55           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  56
  57         # limit monikers to those specified in
  58         my $sources;
  59         if ($ref eq 'ARRAY') {
  60             $sources->{$_} = 1 for (@$limit_sources);
  61         } else {
  62             $sources = $limit_sources;
  63         }
  64         @monikers = grep { $sources->{$_} } @monikers;
  65     }
  66
  67
  68     my(@table_monikers, @view_monikers);
  69     for my $moniker (@monikers){
  70       my $source = $dbicschema->source($moniker);
  71        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  72          push(@table_monikers, $moniker);
  73       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  74           next if $source->is_virtual;
  75          push(@view_monikers, $moniker);
  76       }
  77     }
  78
  79     my %tables;
  80     foreach my $moniker (sort @table_monikers)
  81     {
  82         my $source = $dbicschema->source($moniker);
  83         my $table_name = $source->name;
  84
  85         # Skip custom query sources
  86         next if ref $table_name;
  87
  88         # Its possible to have multiple DBIC sources using the same table
  89         next if $tables{$table_name};
  90
  91         $tables{$table_name}{source} = $source;
  92         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
  93                                        name => $table_name,
  94                                        type => 'TABLE',
  95                                        );
  96         foreach my $col ($source->columns)
  97         {
  98             # assuming column_info in dbic is the same as DBI (?)
  99             # data_type is a number, column_type is text?
 100             my %colinfo = (
 101               name => $col,
 102               size => 0,
 103               is_auto_increment => 0,
 104               is_foreign_key => 0,
 105               is_nullable => 0,
 106               %{$source->column_info($col)}
 107             );
 108             if ($colinfo{is_nullable}) {
 109               $colinfo{default} = '' unless exists $colinfo{default};
 110             }
 111             my $f = $table->add_field(%colinfo)
 112               || $dbicschema->throw_exception ($table->error);
 113         }
 114         $table->primary_key($source->primary_columns);
 115
 116         my @primary = $source->primary_columns;
 117         my %unique_constraints = $source->unique_constraints;
 118         foreach my $uniq (sort keys %unique_constraints) {
 119             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 120                 $table->add_constraint(
 121                             type             => 'unique',
 122                             name             => $uniq,
 123                             fields           => $unique_constraints{$uniq}
 124                 );
 125             }
 126         }
 127
 128         my @rels = $source->relationships();
 129
 130         my %created_FK_rels;
 131
 132         # global add_fk_index set in parser_args
 133         my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
 134
 135         foreach my $rel (sort @rels)
 136         {
 137             my $rel_info = $source->relationship_info($rel);
 138
 139             # Ignore any rel cond that isn't a straight hash
 140             next unless ref $rel_info->{cond} eq 'HASH';
 141
 142             my $othertable = $source->related_source($rel);
 143             my $rel_table = $othertable->name;
 144
 145             my $reverse_rels = $source->reverse_relationship_info($rel);
 146             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 147
 148             # Force the order of @cond to match the order of ->add_columns
 149             my $idx;
 150             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
 151             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 152
 153             # Get the key information, mapping off the foreign/self markers
 154             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 155             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 156
 157             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 158             my $fk_constraint;
 159
 160             #first it can be specified explicitly
 161             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 162                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 163             }
 164             # it can not be multi
 165             elsif ( $rel_info->{attrs}{accessor}
 166                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 167                 $fk_constraint = 0;
 168             }
 169             # if indeed single, check if all self.columns are our primary keys.
 170             # this is supposed to indicate a has_one/might_have...
 171             # where's the introspection!!?? :)
 172             else {
 173                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 174             }
 175
 176             my $cascade;
 177             for my $c (qw/delete update/) {
 178                 if (exists $rel_info->{attrs}{"on_$c"}) {
 179                     if ($fk_constraint) {
 180                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 181                     }
 182                     else {
 183                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 184                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 185                     }
 186                 }
 187                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 188                     $cascade->{$c} = 'CASCADE';
 189                 }
 190             }
 191
 192             if($rel_table)
 193             {
 194                 # Constraints are added only if applicable
 195                 next unless $fk_constraint;
 196
 197                 # Make sure we dont create the same foreign key constraint twice
 198                 my $key_test = join("\x00", @keys);
 199                 next if $created_FK_rels{$rel_table}->{$key_test};
 200
 201                 if (scalar(@keys)) {
 202
 203                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 204
 205                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 206
 207                   # do not consider deferrable constraints and self-references
 208                   # for dependency calculations
 209                   if (! $is_deferrable and $rel_table ne $table_name) {
 210                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 211                   }
 212
 213                   $table->add_constraint(
 214                                     type             => 'foreign_key',
 215                                     name             => join('_', $table_name, 'fk', @keys),
 216                                     fields           => \@keys,
 217                                     reference_fields => \@refkeys,
 218                                     reference_table  => $rel_table,
 219                                     on_delete        => uc ($cascade->{delete} || ''),
 220                                     on_update        => uc ($cascade->{update} || ''),
 221                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 222                   );
 223
 224                   # global parser_args add_fk_index param can be overridden on the rel def
 225                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 226
 227                   if ($add_fk_index_rel) {
 228                       my $index = $table->add_index(
 229                                                     name   => join('_', $table_name, 'idx', @keys),
 230                                                     fields => \@keys,
 231                                                     type   => 'NORMAL',
 232                                                     );
 233                   }
 234               }
 235             }
 236         }
 237
 238     }
 239
 240     # attach the tables to the schema in dependency order
 241     my $dependencies = {
 242       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 243     };
 244     for my $table (sort
 245       {
 246         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 247           ||
 248         $a cmp $b
 249       }
 250       (keys %tables)
 251     ) {
 252       $schema->add_table ($tables{$table}{object});
 253       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 254     }
 255
 256
 257     my %views;
 258     foreach my $moniker (sort @view_monikers)
 259     {
 260         my $source = $dbicschema->source($moniker);
 261         my $view_name = $source->name;
 262
 263         # Skip custom query sources
 264         next if ref $view_name;
 265
 266         # Its possible to have multiple DBIC source using same table
 267         next if $views{$view_name}++;
 268
 269         my $view = $schema->add_view (
 270           name => $view_name,
 271           fields => [ $source->columns ],
 272           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 273         ) || $dbicschema->throw_exception ($schema->error);
 274
 275         $source->_invoke_sqlt_deploy_hook($view);
 276     }
 277
 278
 279     if ($dbicschema->can('sqlt_deploy_hook')) {
 280       $dbicschema->sqlt_deploy_hook($schema);
 281     }
 282
 283     return 1;
 284 }
 285
 286 #
 287 # Quick and dirty dependency graph calculator
 288 #
 289 sub _resolve_deps {
 290   my ($table, $tables, $seen) = @_;
 291
 292   my $ret = {};
 293   $seen ||= {};
 294
 295   # copy and bump all deps by one (so we can reconstruct the chain)
 296   my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
 297   $seen{$table} = 1;
 298
 299   for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
 300
 301     if ($seen->{$dep}) {
 302
 303       # warn and remove the circular constraint so we don't get flooded with the same warning over and over
 304       #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
 305       #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
 306       #);
 307       #delete $tables->{$table}{foreign_table_deps}{$dep};
 308
 309       return {};
 310     }
 311
 312     my $subdeps = _resolve_deps ($dep, $tables, \%seen);
 313     $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 314
 315     ++$ret->{$dep};
 316   }
 317
 318   return $ret;
 319 }
 320
 321 1;
 322
 323 =head1 NAME
 324
 325 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 326 from a DBIx::Class::Schema instance
 327
 328 =head1 SYNOPSIS
 329
 330  ## Via DBIx::Class
 331  use MyApp::Schema;
 332  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 333  $schema->create_ddl_dir();
 334  ## or
 335  $schema->deploy();
 336
 337  ## Standalone
 338  use MyApp::Schema;
 339  use SQL::Translator;
 340
 341  my $schema = MyApp::Schema->connect;
 342  my $trans  = SQL::Translator->new (
 343       parser      => 'SQL::Translator::Parser::DBIx::Class',
 344       parser_args => { package => $schema },
 345       producer    => 'SQLite',
 346      ) or die SQL::Translator->error;
 347  my $out = $trans->translate() or die $trans->error;
 348
 349 =head1 DESCRIPTION
 350
 351 This class requires L<SQL::Translator> installed to work.
 352
 353 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 354 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 355
 356 It's primary use is in deploying database layouts described as a set
 357 of L<DBIx::Class> classes, to a database. To do this, see
 358 L<DBIx::Class::Schema/deploy>.
 359
 360 This can also be achieved by having DBIx::Class export the schema as a
 361 set of SQL files ready for import into your database, or passed to
 362 other machines that need to have your application installed but don't
 363 have SQL::Translator installed. To do this see
 364 L<DBIx::Class::Schema/create_ddl_dir>.
 365
 366 =head1 SEE ALSO
 367
 368 L<SQL::Translator>, L<DBIx::Class::Schema>
 369
 370 =head1 AUTHORS
 371
 372 Jess Robinson
 373
 374 Matt S Trout
 375
 376 Ash Berlin