lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package # hide from PAUSE
   2     SQL::Translator::Parser::DBIx::Class;
   3
   4 # AUTHOR: Jess Robinson
   5
   6 # Some mistakes the fault of Matt S Trout
   7
   8 # Others the fault of Ash Berlin
   9
  10 use strict;
  11 use warnings;
  12 use vars qw($DEBUG @EXPORT_OK);
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use Data::Dumper;
  17 use SQL::Translator::Utils qw(debug normalize_name);
  18
  19 use base qw(Exporter);
  20
  21 @EXPORT_OK = qw(parse);
  22
  23 # -------------------------------------------------------------------
  24 # parse($tr, $data)
  25 #
  26 # setting parser_args => { add_fk_index => 0 } will prevent
  27 # the auto-generation of an index for each FK.
  28 #
  29 # Note that $data, in the case of this parser, is not useful.
  30 # We're working with DBIx::Class Schemas, not data streams.
  31 # -------------------------------------------------------------------
  32 sub parse {
  33     my ($tr, $data)   = @_;
  34     my $args          = $tr->parser_args;
  35     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  36     $dbicschema     ||= $args->{'package'};
  37     my $limit_sources = $args->{'sources'};
  38
  39     die 'No DBIx::Class::Schema' unless ($dbicschema);
  40     if (!ref $dbicschema) {
  41       eval "use $dbicschema;";
  42       die "Can't load $dbicschema ($@)" if($@);
  43     }
  44
  45     my $schema      = $tr->schema;
  46     my $table_no    = 0;
  47
  48     $schema->name( ref($dbicschema) . " v" . ($dbicschema->VERSION || '1.x'))
  49       unless ($schema->name);
  50
  51     my %seen_tables;
  52
  53     my @monikers = sort $dbicschema->sources;
  54     if ($limit_sources) {
  55         my $ref = ref $limit_sources || '';
  56         die "'sources' parameter must be an array or hash ref" unless $ref eq 'ARRAY' || ref eq 'HASH';
  57
  58         # limit monikers to those specified in
  59         my $sources;
  60         if ($ref eq 'ARRAY') {
  61             $sources->{$_} = 1 for (@$limit_sources);
  62         } else {
  63             $sources = $limit_sources;
  64         }
  65         @monikers = grep { $sources->{$_} } @monikers;
  66     }
  67
  68
  69     foreach my $moniker (sort @monikers)
  70     {
  71         my $source = $dbicschema->source($moniker);
  72
  73         # Skip custom query sources
  74         next if ref($source->name);
  75
  76         # Its possible to have multiple DBIC source using same table
  77         next if $seen_tables{$source->name}++;
  78
  79         my $table = $schema->add_table(
  80                                        name => $source->name,
  81                                        type => 'TABLE',
  82                                        ) || die $schema->error;
  83         my $colcount = 0;
  84         foreach my $col ($source->columns)
  85         {
  86             # assuming column_info in dbic is the same as DBI (?)
  87             # data_type is a number, column_type is text?
  88             my %colinfo = (
  89               name => $col,
  90               size => 0,
  91               is_auto_increment => 0,
  92               is_foreign_key => 0,
  93               is_nullable => 0,
  94               %{$source->column_info($col)}
  95             );
  96             if ($colinfo{is_nullable}) {
  97               $colinfo{default} = '' unless exists $colinfo{default};
  98             }
  99             my $f = $table->add_field(%colinfo) || die $table->error;
 100         }
 101         $table->primary_key($source->primary_columns);
 102
 103         my @primary = $source->primary_columns;
 104         my %unique_constraints = $source->unique_constraints;
 105         foreach my $uniq (sort keys %unique_constraints) {
 106             if (!$source->compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 107                 $table->add_constraint(
 108                             type             => 'unique',
 109                             name             => $uniq,
 110                             fields           => $unique_constraints{$uniq}
 111                 );
 112             }
 113         }
 114
 115         my @rels = $source->relationships();
 116
 117         my %created_FK_rels;
 118
 119         # global add_fk_index set in parser_args
 120         my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
 121
 122         foreach my $rel (sort @rels)
 123         {
 124             my $rel_info = $source->relationship_info($rel);
 125
 126             # Ignore any rel cond that isn't a straight hash
 127             next unless ref $rel_info->{cond} eq 'HASH';
 128
 129             my $othertable = $source->related_source($rel);
 130             my $rel_table = $othertable->name;
 131
 132             # Force the order of @cond to match the order of ->add_columns
 133             my $idx;
 134             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
 135             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 136
 137             # Get the key information, mapping off the foreign/self markers
 138             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 139             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 140
 141             if($rel_table)
 142             {
 143                 my $reverse_rels = $source->reverse_relationship_info($rel);
 144                 my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 145
 146                 my $on_delete = '';
 147                 my $on_update = '';
 148
 149                 if (defined $otherrelationship) {
 150                     $on_delete = $otherrelationship->{'attrs'}->{cascade_delete} ? 'CASCADE' : '';
 151                     $on_update = $otherrelationship->{'attrs'}->{cascade_copy} ? 'CASCADE' : '';
 152                 }
 153
 154                 my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 155
 156                 # global parser_args add_fk_index param can be overridden on the rel def
 157                 my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 158
 159                 # Make sure we dont create the same foreign key constraint twice
 160                 my $key_test = join("\x00", @keys);
 161
 162                 #Decide if this is a foreign key based on whether the self
 163                 #items are our primary columns.
 164
 165                 # If the sets are different, then we assume it's a foreign key from
 166                 # us to another table.
 167                 # OR: If is_foreign_key_constraint attr is explicity set (or set to false) on the relation
 168                 next if ( exists $created_FK_rels{$rel_table}->{$key_test} );
 169                 if ( exists $rel_info->{attrs}{is_foreign_key_constraint}) {
 170                   # not is this attr set to 0 but definitely if set to 1
 171                   next unless ($rel_info->{attrs}{is_foreign_key_constraint});
 172                 } else {
 173                   # not if might have
 174                   # next if ($rel_info->{attrs}{accessor} eq 'single' && exists $rel_info->{attrs}{join_type} && uc($rel_info->{attrs}{join_type}) eq 'LEFT');
 175                   # not sure about this one
 176                   next if $source->compare_relationship_keys(\@keys, \@primary);
 177                 }
 178
 179                 $created_FK_rels{$rel_table}->{$key_test} = 1;
 180                 if (scalar(@keys)) {
 181                   $table->add_constraint(
 182                                     type             => 'foreign_key',
 183                                     name             => join('_', $table->name, 'fk', @keys),
 184                                     fields           => \@keys,
 185                                     reference_fields => \@refkeys,
 186                                     reference_table  => $rel_table,
 187                                     on_delete        => $on_delete,
 188                                     on_update        => $on_update,
 189                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 190                   );
 191
 192                   if ($add_fk_index_rel) {
 193                       my $index = $table->add_index(
 194                                                     name   => join('_', $table->name, 'idx', @keys),
 195                                                     fields => \@keys,
 196                                                     type   => 'NORMAL',
 197                                                     );
 198                   }
 199               }
 200             }
 201         }
 202
 203         if ($source->result_class->can('sqlt_deploy_hook')) {
 204           $source->result_class->sqlt_deploy_hook($table);
 205         }
 206     }
 207
 208     if ($dbicschema->can('sqlt_deploy_hook')) {
 209       $dbicschema->sqlt_deploy_hook($schema);
 210     }
 211
 212     return 1;
 213 }
 214
 215 1;