lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 our ($DEBUG, $VERSION, @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use DBIx::Class::Carp qw/^SQL::Translator|^DBIx::Class|^Try::Tiny/;
  18 use DBIx::Class::Exception;
  19 use Scalar::Util 'blessed';
  20 use Try::Tiny;
  21 use namespace::clean;
  22
  23 use base qw(Exporter);
  24
  25 @EXPORT_OK = qw(parse);
  26
  27 # -------------------------------------------------------------------
  28 # parse($tr, $data)
  29 #
  30 # setting parser_args => { add_fk_index => 0 } will prevent
  31 # the auto-generation of an index for each FK.
  32 #
  33 # Note that $data, in the case of this parser, is not useful.
  34 # We're working with DBIx::Class Schemas, not data streams.
  35 # -------------------------------------------------------------------
  36 sub parse {
  37     my ($tr, $data)   = @_;
  38     my $args          = $tr->parser_args;
  39
  40     my $dbicschema = $data || $args->{dbic_schema};
  41
  42     for (qw(DBIx::Class::Schema DBIx::Schema package)) {
  43       if (defined (my $s = delete $args->{$_} )) {
  44         carp_unique("Supplying a schema via  ... parser_args => { '$_' => \$schema } is deprecated. Please use parser_args => { dbic_schema => \$schema } instead");
  45
  46         # move it from the deprecated to the proper $args slot
  47         unless ($dbicschema) {
  48           $args->{dbic_schema} = $dbicschema = $s;
  49         }
  50       }
  51     }
  52
  53     DBIx::Class::Exception->throw('No DBIx::Class::Schema') unless ($dbicschema);
  54
  55     if (!ref $dbicschema) {
  56       eval "require $dbicschema"
  57         or DBIx::Class::Exception->throw("Can't load $dbicschema: $@");
  58     }
  59
  60     if (
  61       ref $args->{dbic_schema}
  62         and
  63       $args->{dbic_schema}->storage
  64     ) {
  65       # we have a storage-holding $schema instance in $args
  66       # we need to dissociate it from that $storage
  67       # otherwise SQLT insanity may ensue due to how some
  68       # serializing producers treat $args (crazy crazy shit)
  69       local $args->{dbic_schema}{storage};
  70       $args->{dbic_schema} = $args->{dbic_schema}->clone;
  71     }
  72
  73     my $schema      = $tr->schema;
  74     my $table_no    = 0;
  75
  76     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  77       unless ($schema->name);
  78
  79     my @monikers = sort $dbicschema->sources;
  80     if (my $limit_sources = $args->{'sources'}) {
  81         my $ref = ref $limit_sources || '';
  82         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  83           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  84
  85         # limit monikers to those specified in
  86         my $sources;
  87         if ($ref eq 'ARRAY') {
  88             $sources->{$_} = 1 for (@$limit_sources);
  89         } else {
  90             $sources = $limit_sources;
  91         }
  92         @monikers = grep { $sources->{$_} } @monikers;
  93     }
  94
  95
  96     my(%table_monikers, %view_monikers);
  97     for my $moniker (@monikers){
  98       my $source = $dbicschema->source($moniker);
  99        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
 100          $table_monikers{$moniker}++;
 101       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
 102           next if $source->is_virtual;
 103          $view_monikers{$moniker}++;
 104       }
 105     }
 106
 107     my %tables;
 108     foreach my $moniker (sort keys %table_monikers)
 109     {
 110         my $source = $dbicschema->source($moniker);
 111         my $table_name = $source->name;
 112
 113         # FIXME - this isn't the right way to do it, but sqlt does not
 114         # support quoting properly to be signaled about this
 115         $table_name = $$table_name if ref $table_name eq 'SCALAR';
 116
 117         # It's possible to have multiple DBIC sources using the same table
 118         next if $tables{$table_name};
 119
 120         $tables{$table_name}{source} = $source;
 121         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
 122                                        name => $table_name,
 123                                        type => 'TABLE',
 124                                        );
 125         foreach my $col ($source->columns)
 126         {
 127             # assuming column_info in dbic is the same as DBI (?)
 128             # data_type is a number, column_type is text?
 129             my %colinfo = (
 130               name => $col,
 131               size => 0,
 132               is_auto_increment => 0,
 133               is_foreign_key => 0,
 134               is_nullable => 0,
 135               %{$source->column_info($col)}
 136             );
 137             if ($colinfo{is_nullable}) {
 138               $colinfo{default} = '' unless exists $colinfo{default};
 139             }
 140             my $f = $table->add_field(%colinfo)
 141               || $dbicschema->throw_exception ($table->error);
 142         }
 143
 144         my @primary = $source->primary_columns;
 145
 146         $table->primary_key(@primary) if @primary;
 147
 148         my %unique_constraints = $source->unique_constraints;
 149         foreach my $uniq (sort keys %unique_constraints) {
 150             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 151                 $table->add_constraint(
 152                             type             => 'unique',
 153                             name             => $uniq,
 154                             fields           => $unique_constraints{$uniq}
 155                 );
 156             }
 157         }
 158
 159         my @rels = $source->relationships();
 160
 161         my %created_FK_rels;
 162
 163         # global add_fk_index set in parser_args
 164         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 165
 166         foreach my $rel (sort @rels)
 167         {
 168
 169             my $rel_info = $source->relationship_info($rel);
 170
 171             # Ignore any rel cond that isn't a straight hash
 172             next unless ref $rel_info->{cond} eq 'HASH';
 173
 174             my $relsource = try { $source->related_source($rel) };
 175             unless ($relsource) {
 176               carp "Ignoring relationship '$rel' - related resultsource '$rel_info->{class}' is not registered with this schema\n";
 177               next;
 178             };
 179
 180             # related sources might be excluded via a {sources} filter or might be views
 181             next unless exists $table_monikers{$relsource->source_name};
 182
 183             my $rel_table = $relsource->name;
 184
 185             # FIXME - this isn't the right way to do it, but sqlt does not
 186             # support quoting properly to be signaled about this
 187             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 188
 189             # Force the order of @cond to match the order of ->add_columns
 190             my $idx;
 191             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 192             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 193
 194             # Get the key information, mapping off the foreign/self markers
 195             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 196             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 197
 198             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 199             my $fk_constraint;
 200
 201             #first it can be specified explicitly
 202             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 203                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 204             }
 205             # it can not be multi
 206             elsif ( $rel_info->{attrs}{accessor}
 207                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 208                 $fk_constraint = 0;
 209             }
 210             # if indeed single, check if all self.columns are our primary keys.
 211             # this is supposed to indicate a has_one/might_have...
 212             # where's the introspection!!?? :)
 213             else {
 214                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 215             }
 216
 217             my ($otherrelname, $otherrelationship) = %{ $source->reverse_relationship_info($rel) };
 218
 219             my $cascade;
 220             for my $c (qw/delete update/) {
 221                 if (exists $rel_info->{attrs}{"on_$c"}) {
 222                     if ($fk_constraint) {
 223                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 224                     }
 225                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 226                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 227                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 228                     }
 229                 }
 230                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 231                     $cascade->{$c} = 'CASCADE';
 232                 }
 233             }
 234
 235             if($rel_table) {
 236                 # Constraints are added only if applicable
 237                 next unless $fk_constraint;
 238
 239                 # Make sure we don't create the same foreign key constraint twice
 240                 my $key_test = join("\x00", sort @keys);
 241                 next if $created_FK_rels{$rel_table}->{$key_test};
 242
 243                 if (scalar(@keys)) {
 244                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 245
 246                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 247
 248                   # calculate dependencies: do not consider deferrable constraints and
 249                   # self-references for dependency calculations
 250                   if (! $is_deferrable and $rel_table ne $table_name) {
 251                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 252                   }
 253
 254                   # trim schema before generating constraint/index names
 255                   (my $table_abbrev = $table_name) =~ s/ ^ [^\.]+ \. //x;
 256
 257                   $table->add_constraint(
 258                     type             => 'foreign_key',
 259                     name             => join('_', $table_abbrev, 'fk', @keys),
 260                     fields           => \@keys,
 261                     reference_fields => \@refkeys,
 262                     reference_table  => $rel_table,
 263                     on_delete        => uc ($cascade->{delete} || ''),
 264                     on_update        => uc ($cascade->{update} || ''),
 265                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 266                   );
 267
 268                   # global parser_args add_fk_index param can be overridden on the rel def
 269                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 270
 271                   # Check that we do not create an index identical to the PK index
 272                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 273                   # NOTE: we do not sort the key columns because the order of
 274                   # columns is important for indexes and two indexes with the
 275                   # same cols but different order are allowed and sometimes
 276                   # needed
 277                   next if join("\x00", @keys) eq join("\x00", @primary);
 278
 279                   if ($add_fk_index_rel) {
 280                       (my $idx_name = $table_name) =~ s/ ^ [^\.]+ \. //x;
 281                       my $index = $table->add_index(
 282                           name   => join('_', $table_abbrev, 'idx', @keys),
 283                           fields => \@keys,
 284                           type   => 'NORMAL',
 285                       );
 286                   }
 287               }
 288             }
 289         }
 290
 291     }
 292
 293     # attach the tables to the schema in dependency order
 294     my $dependencies = {
 295       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 296     };
 297
 298     for my $table (sort
 299       {
 300         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 301           ||
 302         $a cmp $b
 303       }
 304       (keys %tables)
 305     ) {
 306       $schema->add_table ($tables{$table}{object});
 307       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 308
 309       # the hook might have already removed the table
 310       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 311         carp <<'EOW';
 312
 313 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 314 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 315 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 316
 317 EOW
 318
 319         # remove the table as there is no way someone might want to
 320         # actually deploy this
 321         $schema->drop_table ($table);
 322       }
 323     }
 324
 325     my %views;
 326     my @views = map { $dbicschema->source($_) } keys %view_monikers;
 327
 328     my $view_dependencies = {
 329         map {
 330             $_ => _resolve_deps( $dbicschema->source($_), \%view_monikers )
 331           } ( keys %view_monikers )
 332     };
 333
 334     my @view_sources =
 335       sort {
 336         keys %{ $view_dependencies->{ $a->source_name }   || {} } <=>
 337           keys %{ $view_dependencies->{ $b->source_name } || {} }
 338           || $a->source_name cmp $b->source_name
 339       }
 340       map { $dbicschema->source($_) }
 341       keys %view_monikers;
 342
 343     foreach my $source (@view_sources)
 344     {
 345         my $view_name = $source->name;
 346
 347         # FIXME - this isn't the right way to do it, but sqlt does not
 348         # support quoting properly to be signaled about this
 349         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 350
 351         # Skip custom query sources
 352         next if ref $view_name;
 353
 354         # Its possible to have multiple DBIC source using same table
 355         next if $views{$view_name}++;
 356
 357         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 358             unless $source->view_definition;
 359
 360         my $view = $schema->add_view (
 361           name => $view_name,
 362           fields => [ $source->columns ],
 363           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 364         ) || $dbicschema->throw_exception ($schema->error);
 365
 366         $source->_invoke_sqlt_deploy_hook($view);
 367     }
 368
 369
 370     if ($dbicschema->can('sqlt_deploy_hook')) {
 371       $dbicschema->sqlt_deploy_hook($schema);
 372     }
 373
 374     return 1;
 375 }
 376
 377 #
 378 # Quick and dirty dependency graph calculator
 379 #
 380 sub _resolve_deps {
 381     my ( $question, $answers, $seen ) = @_;
 382     my $ret = {};
 383     $seen ||= {};
 384     my @deps;
 385
 386     # copy and bump all deps by one (so we can reconstruct the chain)
 387     my %seen = map { $_ => $seen->{$_} + 1 } ( keys %$seen );
 388     if ( blessed($question)
 389         && $question->isa('DBIx::Class::ResultSource::View') )
 390     {
 391         $seen{ $question->result_class } = 1;
 392         @deps = keys %{ $question->{deploy_depends_on} };
 393     }
 394     else {
 395         $seen{$question} = 1;
 396         @deps = keys %{ $answers->{$question}{foreign_table_deps} };
 397     }
 398
 399     for my $dep (@deps) {
 400         if ( $seen->{$dep} ) {
 401             return {};
 402         }
 403         my $next_dep;
 404
 405         if ( blessed($question)
 406             && $question->isa('DBIx::Class::ResultSource::View') )
 407         {
 408             no warnings 'uninitialized';
 409             my ($next_dep_source_name) =
 410               grep {
 411                 $question->schema->source($_)->result_class eq $dep
 412                   && !( $question->schema->source($_)
 413                     ->isa('DBIx::Class::ResultSource::Table') )
 414               } @{ [ $question->schema->sources ] };
 415             return {} unless $next_dep_source_name;
 416             $next_dep = $question->schema->source($next_dep_source_name);
 417         }
 418         else {
 419             $next_dep = $dep;
 420         }
 421         my $subdeps = _resolve_deps( $next_dep, $answers, \%seen );
 422         $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 423         ++$ret->{$dep};
 424     }
 425     return $ret;
 426 }
 427
 428 1;
 429
 430 =head1 NAME
 431
 432 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 433 from a DBIx::Class::Schema instance
 434
 435 =head1 SYNOPSIS
 436
 437  ## Via DBIx::Class
 438  use MyApp::Schema;
 439  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 440  $schema->create_ddl_dir();
 441  ## or
 442  $schema->deploy();
 443
 444  ## Standalone
 445  use MyApp::Schema;
 446  use SQL::Translator;
 447
 448  my $schema = MyApp::Schema->connect;
 449  my $trans  = SQL::Translator->new (
 450       parser      => 'SQL::Translator::Parser::DBIx::Class',
 451       parser_args => {
 452           dbic_schema => $schema,
 453           add_fk_index => 0,
 454           sources => [qw/
 455             Artist
 456             CD
 457           /],
 458       },
 459       producer    => 'SQLite',
 460      ) or die SQL::Translator->error;
 461  my $out = $trans->translate() or die $trans->error;
 462
 463 =head1 DESCRIPTION
 464
 465 This class requires L<SQL::Translator> installed to work.
 466
 467 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 468 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 469
 470 Its primary use is in deploying database layouts described as a set
 471 of L<DBIx::Class> classes, to a database. To do this, see
 472 L<DBIx::Class::Schema/deploy>.
 473
 474 This can also be achieved by having DBIx::Class export the schema as a
 475 set of SQL files ready for import into your database, or passed to
 476 other machines that need to have your application installed but don't
 477 have SQL::Translator installed. To do this see
 478 L<DBIx::Class::Schema/create_ddl_dir>.
 479
 480 =head1 PARSER OPTIONS
 481
 482 =head2 dbic_schema
 483
 484 The DBIx::Class schema (either an instance or a class name) to be parsed.
 485 This argument is in fact optional - instead one can supply it later at
 486 translation time as an argument to L<SQL::Translator/translate>. In
 487 other words both of the following invocations are valid and will produce
 488 conceptually identical output:
 489
 490   my $yaml = SQL::Translator->new(
 491     parser => 'SQL::Translator::Parser::DBIx::Class',
 492     parser_args => {
 493       dbic_schema => $schema,
 494     },
 495     producer => 'SQL::Translator::Producer::YAML',
 496   )->translate;
 497
 498   my $yaml = SQL::Translator->new(
 499     parser => 'SQL::Translator::Parser::DBIx::Class',
 500     producer => 'SQL::Translator::Producer::YAML',
 501   )->translate(data => $schema);
 502
 503 =head2 add_fk_index
 504
 505 Create an index for each foreign key.
 506 Enabled by default, as having indexed foreign key columns is normally the
 507 sensible thing to do.
 508
 509 =head2 sources
 510
 511 =over 4
 512
 513 =item Arguments: \@class_names
 514
 515 =back
 516
 517 Limit the amount of parsed sources by supplying an explicit list of source names.
 518
 519 =head1 SEE ALSO
 520
 521 L<SQL::Translator>, L<DBIx::Class::Schema>
 522
 523 =head1 AUTHORS
 524
 525 See L<DBIx::Class/CONTRIBUTORS>.
 526
 527 =head1 LICENSE
 528
 529 You may distribute this code under the same terms as Perl itself.
 530
 531 =cut