lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
  18
  19 use base qw(Exporter);
  20
  21 @EXPORT_OK = qw(parse);
  22
  23 # -------------------------------------------------------------------
  24 # parse($tr, $data)
  25 #
  26 # setting parser_args => { add_fk_index => 0 } will prevent
  27 # the auto-generation of an index for each FK.
  28 #
  29 # Note that $data, in the case of this parser, is not useful.
  30 # We're working with DBIx::Class Schemas, not data streams.
  31 # -------------------------------------------------------------------
  32 sub parse {
  33     my ($tr, $data)   = @_;
  34     my $args          = $tr->parser_args;
  35     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  36     $dbicschema     ||= $args->{'package'};
  37     my $limit_sources = $args->{'sources'};
  38
  39     croak 'No DBIx::Class::Schema' unless ($dbicschema);
  40     if (!ref $dbicschema) {
  41       eval "use $dbicschema;";
  42       croak "Can't load $dbicschema ($@)" if($@);
  43     }
  44
  45     my $schema      = $tr->schema;
  46     my $table_no    = 0;
  47
  48     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  49       unless ($schema->name);
  50
  51     my @monikers = sort $dbicschema->sources;
  52     if ($limit_sources) {
  53         my $ref = ref $limit_sources || '';
  54         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  55           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  56
  57         # limit monikers to those specified in
  58         my $sources;
  59         if ($ref eq 'ARRAY') {
  60             $sources->{$_} = 1 for (@$limit_sources);
  61         } else {
  62             $sources = $limit_sources;
  63         }
  64         @monikers = grep { $sources->{$_} } @monikers;
  65     }
  66
  67
  68     my(@table_monikers, @view_monikers);
  69     for my $moniker (@monikers){
  70       my $source = $dbicschema->source($moniker);
  71        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  72          push(@table_monikers, $moniker);
  73       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  74           next if $source->is_virtual;
  75          push(@view_monikers, $moniker);
  76       }
  77     }
  78
  79     my %tables;
  80     foreach my $moniker (sort @table_monikers)
  81     {
  82         my $source = $dbicschema->source($moniker);
  83         my $table_name = $source->name;
  84
  85         # sqlt currently does not do quoting right anyway
  86         $table_name = $$table_name if ref $table_name eq 'SCALAR';
  87
  88         # Its possible to have multiple DBIC sources using the same table
  89         next if $tables{$table_name};
  90
  91         $tables{$table_name}{source} = $source;
  92         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
  93                                        name => $table_name,
  94                                        type => 'TABLE',
  95                                        );
  96         foreach my $col ($source->columns)
  97         {
  98             # assuming column_info in dbic is the same as DBI (?)
  99             # data_type is a number, column_type is text?
 100             my %colinfo = (
 101               name => $col,
 102               size => 0,
 103               is_auto_increment => 0,
 104               is_foreign_key => 0,
 105               is_nullable => 0,
 106               %{$source->column_info($col)}
 107             );
 108             if ($colinfo{is_nullable}) {
 109               $colinfo{default} = '' unless exists $colinfo{default};
 110             }
 111             my $f = $table->add_field(%colinfo)
 112               || $dbicschema->throw_exception ($table->error);
 113         }
 114         $table->primary_key($source->primary_columns);
 115
 116         my @primary = $source->primary_columns;
 117         my %unique_constraints = $source->unique_constraints;
 118         foreach my $uniq (sort keys %unique_constraints) {
 119             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 120                 $table->add_constraint(
 121                             type             => 'unique',
 122                             name             => $uniq,
 123                             fields           => $unique_constraints{$uniq}
 124                 );
 125             }
 126         }
 127
 128         my @rels = $source->relationships();
 129
 130         my %created_FK_rels;
 131
 132         # global add_fk_index set in parser_args
 133         my $add_fk_index = (exists $args->{add_fk_index} && ($args->{add_fk_index} == 0)) ? 0 : 1;
 134
 135         foreach my $rel (sort @rels)
 136         {
 137             my $rel_info = $source->relationship_info($rel);
 138
 139             # Ignore any rel cond that isn't a straight hash
 140             next unless ref $rel_info->{cond} eq 'HASH';
 141
 142             my $othertable = $source->related_source($rel);
 143             my $rel_table = $othertable->name;
 144             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';  #sqlt currently does not do quoting right anyway
 145
 146             my $reverse_rels = $source->reverse_relationship_info($rel);
 147             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 148
 149             # Force the order of @cond to match the order of ->add_columns
 150             my $idx;
 151             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $othertable->columns;
 152             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 153
 154             # Get the key information, mapping off the foreign/self markers
 155             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 156             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 157
 158             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 159             my $fk_constraint;
 160
 161             #first it can be specified explicitly
 162             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 163                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 164             }
 165             # it can not be multi
 166             elsif ( $rel_info->{attrs}{accessor}
 167                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 168                 $fk_constraint = 0;
 169             }
 170             # if indeed single, check if all self.columns are our primary keys.
 171             # this is supposed to indicate a has_one/might_have...
 172             # where's the introspection!!?? :)
 173             else {
 174                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 175             }
 176
 177             my $cascade;
 178             for my $c (qw/delete update/) {
 179                 if (exists $rel_info->{attrs}{"on_$c"}) {
 180                     if ($fk_constraint) {
 181                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 182                     }
 183                     else {
 184                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 185                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 186                     }
 187                 }
 188                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 189                     $cascade->{$c} = 'CASCADE';
 190                 }
 191             }
 192
 193             if($rel_table)
 194             {
 195                 # Constraints are added only if applicable
 196                 next unless $fk_constraint;
 197
 198                 # Make sure we dont create the same foreign key constraint twice
 199                 my $key_test = join("\x00", @keys);
 200                 next if $created_FK_rels{$rel_table}->{$key_test};
 201
 202                 if (scalar(@keys)) {
 203
 204                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 205
 206                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 207
 208                   # do not consider deferrable constraints and self-references
 209                   # for dependency calculations
 210                   if (! $is_deferrable and $rel_table ne $table_name) {
 211                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 212                   }
 213
 214                   $table->add_constraint(
 215                                     type             => 'foreign_key',
 216                                     name             => join('_', $table_name, 'fk', @keys),
 217                                     fields           => \@keys,
 218                                     reference_fields => \@refkeys,
 219                                     reference_table  => $rel_table,
 220                                     on_delete        => uc ($cascade->{delete} || ''),
 221                                     on_update        => uc ($cascade->{update} || ''),
 222                                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 223                   );
 224
 225                   # global parser_args add_fk_index param can be overridden on the rel def
 226                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 227
 228                   if ($add_fk_index_rel) {
 229                       my $index = $table->add_index(
 230                                                     name   => join('_', $table_name, 'idx', @keys),
 231                                                     fields => \@keys,
 232                                                     type   => 'NORMAL',
 233                                                     );
 234                   }
 235               }
 236             }
 237         }
 238
 239     }
 240
 241     # attach the tables to the schema in dependency order
 242     my $dependencies = {
 243       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 244     };
 245     for my $table (sort
 246       {
 247         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 248           ||
 249         $a cmp $b
 250       }
 251       (keys %tables)
 252     ) {
 253       $schema->add_table ($tables{$table}{object});
 254       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 255
 256       if ($schema->get_table($table) && $table =~ /SELECT \s+/ix) {
 257         warn <<'EOF';
 258
 259 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, see the "Arbitrary
 260 SQL" entry in:
 261
 262   perldoc DBIx::Class::Manual::Cookbook
 263
 264 for the current method of doing this.
 265
 266 EOF
 267       }
 268     }
 269
 270     my %views;
 271     foreach my $moniker (sort @view_monikers)
 272     {
 273         my $source = $dbicschema->source($moniker);
 274         my $view_name = $source->name;
 275         $view_name = $$view_name if ref $view_name eq 'SCALAR';  #sqlt currently does not do quoting right anyway
 276
 277         # Skip custom query sources
 278         next if ref $view_name;
 279
 280         # Its possible to have multiple DBIC source using same table
 281         next if $views{$view_name}++;
 282
 283         my $view = $schema->add_view (
 284           name => $view_name,
 285           fields => [ $source->columns ],
 286           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 287         ) || $dbicschema->throw_exception ($schema->error);
 288
 289         $source->_invoke_sqlt_deploy_hook($view);
 290     }
 291
 292
 293     if ($dbicschema->can('sqlt_deploy_hook')) {
 294       $dbicschema->sqlt_deploy_hook($schema);
 295     }
 296
 297     return 1;
 298 }
 299
 300 #
 301 # Quick and dirty dependency graph calculator
 302 #
 303 sub _resolve_deps {
 304   my ($table, $tables, $seen) = @_;
 305
 306   my $ret = {};
 307   $seen ||= {};
 308
 309   # copy and bump all deps by one (so we can reconstruct the chain)
 310   my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
 311   $seen{$table} = 1;
 312
 313   for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
 314
 315     if ($seen->{$dep}) {
 316
 317       # warn and remove the circular constraint so we don't get flooded with the same warning over and over
 318       #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
 319       #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
 320       #);
 321       #delete $tables->{$table}{foreign_table_deps}{$dep};
 322
 323       return {};
 324     }
 325
 326     my $subdeps = _resolve_deps ($dep, $tables, \%seen);
 327     $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 328
 329     ++$ret->{$dep};
 330   }
 331
 332   return $ret;
 333 }
 334
 335 1;
 336
 337 =head1 NAME
 338
 339 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 340 from a DBIx::Class::Schema instance
 341
 342 =head1 SYNOPSIS
 343
 344  ## Via DBIx::Class
 345  use MyApp::Schema;
 346  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 347  $schema->create_ddl_dir();
 348  ## or
 349  $schema->deploy();
 350
 351  ## Standalone
 352  use MyApp::Schema;
 353  use SQL::Translator;
 354
 355  my $schema = MyApp::Schema->connect;
 356  my $trans  = SQL::Translator->new (
 357       parser      => 'SQL::Translator::Parser::DBIx::Class',
 358       parser_args => { package => $schema },
 359       producer    => 'SQLite',
 360      ) or die SQL::Translator->error;
 361  my $out = $trans->translate() or die $trans->error;
 362
 363 =head1 DESCRIPTION
 364
 365 This class requires L<SQL::Translator> installed to work.
 366
 367 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 368 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 369
 370 Its primary use is in deploying database layouts described as a set
 371 of L<DBIx::Class> classes, to a database. To do this, see
 372 L<DBIx::Class::Schema/deploy>.
 373
 374 This can also be achieved by having DBIx::Class export the schema as a
 375 set of SQL files ready for import into your database, or passed to
 376 other machines that need to have your application installed but don't
 377 have SQL::Translator installed. To do this see
 378 L<DBIx::Class::Schema/create_ddl_dir>.
 379
 380 =head1 SEE ALSO
 381
 382 L<SQL::Translator>, L<DBIx::Class::Schema>
 383
 384 =head1 AUTHORS
 385
 386 Jess Robinson
 387
 388 Matt S Trout
 389
 390 Ash Berlin