lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 use vars qw($DEBUG $VERSION @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
  18 use Scalar::Util ();
  19 use base qw(Exporter);
  20
  21 @EXPORT_OK = qw(parse);
  22
  23 # -------------------------------------------------------------------
  24 # parse($tr, $data)
  25 #
  26 # setting parser_args => { add_fk_index => 0 } will prevent
  27 # the auto-generation of an index for each FK.
  28 #
  29 # Note that $data, in the case of this parser, is not useful.
  30 # We're working with DBIx::Class Schemas, not data streams.
  31 # -------------------------------------------------------------------
  32 sub parse {
  33     # this is a hack to prevent schema leaks due to a retarded SQLT implementation
  34     # DO NOT REMOVE (until SQLT2 is out, the all of this will be rewritten anyway)
  35     Scalar::Util::weaken ($_[1]) if ref ($_[1]);
  36
  37     my ($tr, $data)   = @_;
  38     my $args          = $tr->parser_args;
  39     my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
  40     $dbicschema     ||= $args->{'package'};
  41     my $limit_sources = $args->{'sources'};
  42
  43     croak 'No DBIx::Class::Schema' unless ($dbicschema);
  44     if (!ref $dbicschema) {
  45       eval "use $dbicschema;";
  46       croak "Can't load $dbicschema ($@)" if($@);
  47     }
  48
  49     my $schema      = $tr->schema;
  50     my $table_no    = 0;
  51
  52     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  53       unless ($schema->name);
  54
  55     my @monikers = sort $dbicschema->sources;
  56     if ($limit_sources) {
  57         my $ref = ref $limit_sources || '';
  58         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  59           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  60
  61         # limit monikers to those specified in
  62         my $sources;
  63         if ($ref eq 'ARRAY') {
  64             $sources->{$_} = 1 for (@$limit_sources);
  65         } else {
  66             $sources = $limit_sources;
  67         }
  68         @monikers = grep { $sources->{$_} } @monikers;
  69     }
  70
  71
  72     my(%table_monikers, %view_monikers);
  73     for my $moniker (@monikers){
  74       my $source = $dbicschema->source($moniker);
  75        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
  76          $table_monikers{$moniker}++;
  77       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
  78           next if $source->is_virtual;
  79          $view_monikers{$moniker}++;
  80       }
  81     }
  82
  83     my %tables;
  84     foreach my $moniker (sort keys %table_monikers)
  85     {
  86         my $source = $dbicschema->source($moniker);
  87         my $table_name = $source->name;
  88
  89         # FIXME - this isn't the right way to do it, but sqlt does not
  90         # support quoting properly to be signaled about this
  91         $table_name = $$table_name if ref $table_name eq 'SCALAR';
  92
  93         # It's possible to have multiple DBIC sources using the same table
  94         next if $tables{$table_name};
  95
  96         $tables{$table_name}{source} = $source;
  97         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
  98                                        name => $table_name,
  99                                        type => 'TABLE',
 100                                        );
 101         foreach my $col ($source->columns)
 102         {
 103             # assuming column_info in dbic is the same as DBI (?)
 104             # data_type is a number, column_type is text?
 105             my %colinfo = (
 106               name => $col,
 107               size => 0,
 108               is_auto_increment => 0,
 109               is_foreign_key => 0,
 110               is_nullable => 0,
 111               %{$source->column_info($col)}
 112             );
 113             if ($colinfo{is_nullable}) {
 114               $colinfo{default} = '' unless exists $colinfo{default};
 115             }
 116             my $f = $table->add_field(%colinfo)
 117               || $dbicschema->throw_exception ($table->error);
 118         }
 119
 120         my @primary = $source->primary_columns;
 121
 122         $table->primary_key(@primary) if @primary;
 123
 124         my %unique_constraints = $source->unique_constraints;
 125         foreach my $uniq (sort keys %unique_constraints) {
 126             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 127                 $table->add_constraint(
 128                             type             => 'unique',
 129                             name             => $uniq,
 130                             fields           => $unique_constraints{$uniq}
 131                 );
 132             }
 133         }
 134
 135         my @rels = $source->relationships();
 136
 137         my %created_FK_rels;
 138
 139         # global add_fk_index set in parser_args
 140         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 141
 142         foreach my $rel (sort @rels)
 143         {
 144
 145             my $rel_info = $source->relationship_info($rel);
 146
 147             # Ignore any rel cond that isn't a straight hash
 148             next unless ref $rel_info->{cond} eq 'HASH';
 149
 150             my $relsource = $source->related_source($rel);
 151
 152             # related sources might be excluded via a {sources} filter or might be views
 153             next unless exists $table_monikers{$relsource->source_name};
 154
 155             my $rel_table = $relsource->name;
 156
 157             # FIXME - this isn't the right way to do it, but sqlt does not
 158             # support quoting properly to be signaled about this
 159             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 160
 161             my $reverse_rels = $source->reverse_relationship_info($rel);
 162             my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
 163
 164             # Force the order of @cond to match the order of ->add_columns
 165             my $idx;
 166             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 167             my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 168
 169             # Get the key information, mapping off the foreign/self markers
 170             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 171             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 172
 173             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 174             my $fk_constraint;
 175
 176             #first it can be specified explicitly
 177             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 178                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 179             }
 180             # it can not be multi
 181             elsif ( $rel_info->{attrs}{accessor}
 182                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 183                 $fk_constraint = 0;
 184             }
 185             # if indeed single, check if all self.columns are our primary keys.
 186             # this is supposed to indicate a has_one/might_have...
 187             # where's the introspection!!?? :)
 188             else {
 189                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 190             }
 191
 192             my $cascade;
 193             for my $c (qw/delete update/) {
 194                 if (exists $rel_info->{attrs}{"on_$c"}) {
 195                     if ($fk_constraint) {
 196                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 197                     }
 198                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 199                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 200                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 201                     }
 202                 }
 203                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 204                     $cascade->{$c} = 'CASCADE';
 205                 }
 206             }
 207
 208             if($rel_table) {
 209                 # Constraints are added only if applicable
 210                 next unless $fk_constraint;
 211
 212                 # Make sure we dont create the same foreign key constraint twice
 213                 my $key_test = join("\x00", sort @keys);
 214                 next if $created_FK_rels{$rel_table}->{$key_test};
 215
 216                 if (scalar(@keys)) {
 217                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 218
 219                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 220
 221                   # calculate dependencies: do not consider deferrable constraints and
 222                   # self-references for dependency calculations
 223                   if (! $is_deferrable and $rel_table ne $table_name) {
 224                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 225                   }
 226
 227                   $table->add_constraint(
 228                     type             => 'foreign_key',
 229                     name             => join('_', $table_name, 'fk', @keys),
 230                     fields           => \@keys,
 231                     reference_fields => \@refkeys,
 232                     reference_table  => $rel_table,
 233                     on_delete        => uc ($cascade->{delete} || ''),
 234                     on_update        => uc ($cascade->{update} || ''),
 235                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 236                   );
 237
 238                   # global parser_args add_fk_index param can be overridden on the rel def
 239                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 240
 241                   # Check that we do not create an index identical to the PK index
 242                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 243                   # NOTE: we do not sort the key columns because the order of
 244                   # columns is important for indexes and two indexes with the
 245                   # same cols but different order are allowed and sometimes
 246                   # needed
 247                   next if join("\x00", @keys) eq join("\x00", @primary);
 248
 249                   if ($add_fk_index_rel) {
 250                       my $index = $table->add_index(
 251                           name   => join('_', $table_name, 'idx', @keys),
 252                           fields => \@keys,
 253                           type   => 'NORMAL',
 254                       );
 255                   }
 256               }
 257             }
 258         }
 259
 260     }
 261
 262     # attach the tables to the schema in dependency order
 263     my $dependencies = {
 264       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 265     };
 266
 267     for my $table (sort
 268       {
 269         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 270           ||
 271         $a cmp $b
 272       }
 273       (keys %tables)
 274     ) {
 275       $schema->add_table ($tables{$table}{object});
 276       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 277
 278       # the hook might have already removed the table
 279       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 280         warn <<'EOW';
 281
 282 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 283 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 284 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 285
 286 EOW
 287
 288         # remove the table as there is no way someone might want to
 289         # actually deploy this
 290         $schema->drop_table ($table);
 291       }
 292     }
 293
 294     my %views;
 295
 296     my @view_sources =
 297     sort {
 298         keys %{ $dependencies->{$a} || {} }
 299         <=>
 300         keys %{ $dependencies->{$b} || {} }
 301         ||
 302         $a cmp $b
 303     }
 304     map { $dbicschema->source($_) }
 305     keys %view_monikers;
 306
 307     foreach my $source (@view_sources)
 308     {
 309         my $view_name = $source->name;
 310
 311         # FIXME - this isn't the right way to do it, but sqlt does not
 312         # support quoting properly to be signaled about this
 313         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 314
 315         # Skip custom query sources
 316         next if ref $view_name;
 317
 318         # Its possible to have multiple DBIC source using same table
 319         next if $views{$view_name}++;
 320
 321         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 322             unless $source->view_definition;
 323
 324         my $view = $schema->add_view (
 325           name => $view_name,
 326           fields => [ $source->columns ],
 327           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 328         ) || $dbicschema->throw_exception ($schema->error);
 329
 330         $source->_invoke_sqlt_deploy_hook($view);
 331     }
 332
 333
 334     if ($dbicschema->can('sqlt_deploy_hook')) {
 335       $dbicschema->sqlt_deploy_hook($schema);
 336     }
 337
 338     return 1;
 339 }
 340
 341 #
 342 # Quick and dirty dependency graph calculator
 343 #
 344 sub _resolve_deps {
 345   my ($table, $tables, $seen) = @_;
 346
 347   my $ret = {};
 348   $seen ||= {};
 349
 350   # copy and bump all deps by one (so we can reconstruct the chain)
 351   my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
 352   $seen{$table} = 1;
 353
 354   for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
 355
 356     if ($seen->{$dep}) {
 357
 358       # warn and remove the circular constraint so we don't get flooded with the same warning over and over
 359       #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
 360       #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
 361       #);
 362       #delete $tables->{$table}{foreign_table_deps}{$dep};
 363
 364       return {};
 365     }
 366
 367     my $subdeps = _resolve_deps ($dep, $tables, \%seen);
 368     $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 369
 370     ++$ret->{$dep};
 371   }
 372
 373   return $ret;
 374 }
 375
 376 1;
 377
 378 =head1 NAME
 379
 380 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 381 from a DBIx::Class::Schema instance
 382
 383 =head1 SYNOPSIS
 384
 385  ## Via DBIx::Class
 386  use MyApp::Schema;
 387  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 388  $schema->create_ddl_dir();
 389  ## or
 390  $schema->deploy();
 391
 392  ## Standalone
 393  use MyApp::Schema;
 394  use SQL::Translator;
 395
 396  my $schema = MyApp::Schema->connect;
 397  my $trans  = SQL::Translator->new (
 398       parser      => 'SQL::Translator::Parser::DBIx::Class',
 399       parser_args => {
 400           package => $schema,
 401           add_fk_index => 0,
 402           sources => [qw/
 403             Artist
 404             CD
 405           /],
 406       },
 407       producer    => 'SQLite',
 408      ) or die SQL::Translator->error;
 409  my $out = $trans->translate() or die $trans->error;
 410
 411 =head1 DESCRIPTION
 412
 413 This class requires L<SQL::Translator> installed to work.
 414
 415 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 416 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 417
 418 Its primary use is in deploying database layouts described as a set
 419 of L<DBIx::Class> classes, to a database. To do this, see
 420 L<DBIx::Class::Schema/deploy>.
 421
 422 This can also be achieved by having DBIx::Class export the schema as a
 423 set of SQL files ready for import into your database, or passed to
 424 other machines that need to have your application installed but don't
 425 have SQL::Translator installed. To do this see
 426 L<DBIx::Class::Schema/create_ddl_dir>.
 427
 428 =head1 PARSER OPTIONS
 429
 430 =head2 add_fk_index
 431
 432 Create an index for each foreign key.
 433 Enabled by default, as having indexed foreign key columns is normally the
 434 sensible thing to do.
 435
 436 =head2 sources
 437
 438 =over 4
 439
 440 =item Arguments: \@class_names
 441
 442 =back
 443
 444 Limit the amount of parsed sources by supplying an explicit list of source names.
 445
 446 =head1 SEE ALSO
 447
 448 L<SQL::Translator>, L<DBIx::Class::Schema>
 449
 450 =head1 AUTHORS
 451
 452 See L<DBIx::Class/CONTRIBUTORS>.
 453
 454 =head1 LICENSE
 455
 456 You may distribute this code under the same terms as Perl itself.
 457
 458 =cut