lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 my $mro_recursor_stack;
  12
  13 BEGIN {
  14   package # hide from pause
  15     DBIx::Class::_ENV_;
  16
  17   use Config;
  18
  19   use constant {
  20
  21     # but of course
  22     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  23
  24     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  25
  26     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  27     BROKEN_WEAK_SCALARREF_VALUES => ( "$]" < 5.008003 ) ? 1 : 0,
  28
  29     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  30
  31     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  32
  33     ( map
  34       #
  35       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  36       # all envvars without further adjusting its scripts
  37       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  38       #
  39       { substr($_, 5) => !!( $ENV{$_} ) }
  40       qw(
  41         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  42         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  43         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  44         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  45         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  46       )
  47     ),
  48
  49     IV_SIZE => $Config{ivsize},
  50
  51     OS_NAME => $^O,
  52   };
  53
  54   if ( "$]" < 5.009_005) {
  55     require MRO::Compat;
  56     constant->import( OLD_MRO => 1 );
  57
  58     #
  59     # Yes, I know this is a rather PHP-ish name, but please first read
  60     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  61     #
  62     # Even if we are using Class::C3::XS it still won't work, as doing
  63     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  64     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  65     #
  66     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  67       require Digest::MD5;
  68       require Math::BigInt;
  69
  70       # the non-assign-unless-there-is-a-hash is deliberate
  71       ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{gen} ||= (
  72         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  73
  74           ( $mro_recursor_stack->{cache} || {} )->{$_}{methlist} ||= do {
  75
  76             my $class = $_;
  77             no strict 'refs';
  78
  79             # RV to be hashed up and turned into a number
  80             join "\0", (
  81               $class,
  82               map
  83                 {(
  84                   # stringification should be sufficient, ignore names/refaddr entirely
  85                   $_,
  86                   attributes::get( $_ ),
  87                 )}
  88                 map
  89                   {(
  90                     # skip dummy C::C3 helper crefs
  91                     ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
  92                       and
  93                     (
  94                       ref(\ "${class}::"->{$_} ) ne 'GLOB'
  95                         or
  96                       defined( *{ "${class}::"->{$_} }{CODE} )
  97                     )
  98                   )
  99                     ? ( \&{"${class}::$_"} )
 100                     : ()
 101                   }
 102                   keys %{ "${class}::" }
 103             );
 104           }
 105         } (
 106
 107           @{
 108             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{linear_isa}
 109               ||=
 110             mro::get_linear_isa($_[0])
 111           },
 112
 113           ((
 114             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{is_universal}
 115               ||=
 116             mro::is_universal($_[0])
 117           ) ? () : @{
 118             ( $mro_recursor_stack->{cache} || {} )->{UNIVERSAL}{linear_isa}
 119               ||=
 120             mro::get_linear_isa("UNIVERSAL")
 121           } ),
 122
 123         ) ) ) )
 124       );
 125     };
 126   }
 127   else {
 128     require mro;
 129     constant->import( OLD_MRO => 0 );
 130     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 131   }
 132
 133   # Both of these are no longer used for anything. However bring
 134   # them back after they were purged in 08a8d8f1, as there appear
 135   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 136   # in their production codebases. There is no point in breaking these
 137   # if whatever they used actually continues to work
 138   my $warned;
 139   my $sigh = sub {
 140
 141     require Carp;
 142     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
 143
 144     warn $cluck unless $warned->{$cluck}++;
 145
 146     0;
 147   };
 148   sub DBICTEST () { &$sigh }
 149   sub PEEPEENESS () { &$sigh }
 150 }
 151
 152 # FIXME - this is not supposed to be here
 153 # Carp::Skip to the rescue soon
 154 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 155
 156 use B ();
 157 use Carp 'croak';
 158 use Storable 'nfreeze';
 159 use Scalar::Util qw(weaken blessed reftype refaddr);
 160 use Sub::Quote qw(qsub);
 161 use Sub::Name ();
 162 use attributes ();
 163
 164 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 165 BEGIN { *deep_clone = \&Storable::dclone }
 166
 167 use base 'Exporter';
 168 our @EXPORT_OK = qw(
 169   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 170   fail_on_internal_wantarray fail_on_internal_call
 171   refdesc refcount hrefaddr set_subname describe_class_methods
 172   scope_guard detected_reinvoked_destructor
 173   is_exception dbic_internal_try visit_namespaces
 174   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 175   parent_dir mkdir_p
 176   UNRESOLVABLE_CONDITION
 177 );
 178
 179 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 180
 181 BEGIN {
 182   # add preliminary attribute support
 183   # FIXME FIXME FIXME
 184   # To be revisited when Moo with proper attr support ships
 185   Sub::Quote->VERSION(2.002);
 186 }
 187 # Override forcing no_defer, and adding naming consistency checks
 188 our %refs_closed_over_by_quote_sub_installed_crefs;
 189 sub quote_sub {
 190   Carp::confess( "Anonymous quoting not supported by the DBIC sub_quote override - supply a sub name" ) if
 191     @_ < 2
 192       or
 193     ! defined $_[1]
 194       or
 195     length ref $_[1]
 196   ;
 197
 198   Carp::confess( "The DBIC sub_quote override expects sub name '$_[0]' to be fully qualified" )
 199     unless $_[0] =~ /::/;
 200
 201   Carp::confess( "The DBIC sub_quote override expects the sub name '$_[0]' to match the supplied 'package' argument" ) if
 202     $_[3]
 203       and
 204     defined $_[3]->{package}
 205       and
 206     index( $_[0], $_[3]->{package} ) != 0
 207   ;
 208
 209   my @caller = caller(0);
 210   my $sq_opts = {
 211     package => $caller[0],
 212     hints => $caller[8],
 213     warning_bits => $caller[9],
 214     hintshash => $caller[10],
 215     %{ $_[3] || {} },
 216
 217     # explicitly forced for everything
 218     no_defer => 1,
 219   };
 220
 221   weaken (
 222     # just use a growing counter, no need to perform neither compaction
 223     # nor any special ithread-level handling
 224     $refs_closed_over_by_quote_sub_installed_crefs
 225      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 226       = $_
 227   ) for grep {
 228     length ref $_
 229       and
 230     (
 231       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 232         or
 233       ref $_ ne 'SCALAR'
 234     )
 235   } values %{ $_[2] || {} };
 236
 237   my $cref = Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 238
 239   # FIXME FIXME FIXME
 240   # To be revisited when Moo with proper attr support ships
 241   if(
 242     # external application does not work on things like :prototype(...), :lvalue, etc
 243     my @attrs = grep {
 244       $_ !~ /^[a-z]/
 245         or
 246       Carp::confess( "The DBIC sub_quote override does not support applying of reserved attribute '$_'" )
 247     } @{ $sq_opts->{attributes} || []}
 248   ) {
 249     Carp::confess( "The DBIC sub_quote override does not allow mixing 'attributes' with 'no_install'" )
 250       if $sq_opts->{no_install};
 251
 252     # might be different from $sq_opts->{package};
 253     my ($install_into) = $_[0] =~ /(.+)::[^:]+$/;
 254
 255     attributes->import( $install_into, $cref, @attrs );
 256   }
 257
 258   $cref;
 259 }
 260
 261 sub sigwarn_silencer ($) {
 262   my $pattern = shift;
 263
 264   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 265
 266   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 267
 268   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 269 }
 270
 271 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 272
 273 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 274
 275 sub refdesc ($) {
 276   croak "Expecting a reference" if ! length ref $_[0];
 277
 278   # be careful not to trigger stringification,
 279   # reuse @_ as a scratch-pad
 280   sprintf '%s%s(0x%x)',
 281     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 282     reftype $_[0],
 283     refaddr($_[0]),
 284   ;
 285 }
 286
 287 sub refcount ($) {
 288   croak "Expecting a reference" if ! length ref $_[0];
 289
 290   # No tempvars - must operate on $_[0], otherwise the pad
 291   # will count as an extra ref
 292   B::svref_2object($_[0])->REFCNT;
 293 }
 294
 295 sub visit_namespaces {
 296   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 297
 298   my $visited_count = 1;
 299
 300   # A package and a namespace are subtly different things
 301   $args->{package} ||= 'main';
 302   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 303   $args->{package} =~ s/^:://;
 304
 305   if ( $args->{action}->($args->{package}) ) {
 306     my $ns =
 307       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 308         .
 309       '::'
 310     ;
 311
 312     $visited_count += visit_namespaces( %$args, package => $_ ) for
 313       grep
 314         # this happens sometimes on %:: traversal
 315         { $_ ne '::main' }
 316         map
 317           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 318           do { no strict 'refs'; keys %$ns }
 319     ;
 320   }
 321
 322   $visited_count;
 323 }
 324
 325 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 326 sub set_subname ($$) {
 327
 328   # fully qualify name
 329   splice @_, 0, 1, caller(0) . "::$_[0]"
 330     if $_[0] !~ /::|'/;
 331
 332   &Sub::Name::subname;
 333 }
 334
 335 sub serialize ($) {
 336   local $Storable::canonical = 1;
 337   nfreeze($_[0]);
 338 }
 339
 340 sub uniq {
 341   my( %seen, $seen_undef, $numeric_preserving_copy );
 342   grep { not (
 343     defined $_
 344       ? $seen{ $numeric_preserving_copy = $_ }++
 345       : $seen_undef++
 346   ) } @_;
 347 }
 348
 349 my $dd_obj;
 350 sub dump_value ($) {
 351   local $Data::Dumper::Indent = 1
 352     unless defined $Data::Dumper::Indent;
 353
 354   my $dump_str = (
 355     $dd_obj
 356       ||=
 357     do {
 358       require Data::Dumper;
 359       my $d = Data::Dumper->new([])
 360         ->Purity(0)
 361         ->Pad('')
 362         ->Useqq(1)
 363         ->Terse(1)
 364         ->Freezer('')
 365         ->Quotekeys(0)
 366         ->Bless('bless')
 367         ->Pair(' => ')
 368         ->Sortkeys(1)
 369         ->Deparse(1)
 370       ;
 371
 372       $d->Sparseseen(1) if modver_gt_or_eq (
 373         'Data::Dumper', '2.136'
 374       );
 375
 376       $d;
 377     }
 378   )->Values([$_[0]])->Dump;
 379
 380   $dd_obj->Reset->Values([]);
 381
 382   $dump_str;
 383 }
 384
 385 sub scope_guard (&) {
 386   croak 'Calling scope_guard() in void context makes no sense'
 387     if ! defined wantarray;
 388
 389   # no direct blessing of coderefs - DESTROY is buggy on those
 390   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 391 }
 392 {
 393   package #
 394     DBIx::Class::_Util::ScopeGuard;
 395
 396   sub DESTROY {
 397     &DBIx::Class::_Util::detected_reinvoked_destructor;
 398
 399     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 400
 401     eval {
 402       $_[0]->[0]->();
 403       1;
 404     }
 405       or
 406     Carp::cluck(
 407       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 408     );
 409   }
 410 }
 411
 412
 413 sub is_exception ($) {
 414   my $e = $_[0];
 415
 416   # FIXME
 417   # this is not strictly correct - an eval setting $@ to undef
 418   # is *not* the same as an eval setting $@ to ''
 419   # but for the sake of simplicity assume the following for
 420   # the time being
 421   return 0 unless defined $e;
 422
 423   my ($not_blank, $suberror);
 424   {
 425     local $SIG{__DIE__} if $SIG{__DIE__};
 426     local $@;
 427     eval {
 428       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 429       # will entirely obviate the need for the encolsing eval{}, as the
 430       # condition we guard against is a missing fallback overload
 431       $not_blank = ( $e ne '' );
 432       1;
 433     } or $suberror = $@;
 434   }
 435
 436   if (defined $suberror) {
 437     if (length (my $class = blessed($e) )) {
 438       carp_unique( sprintf(
 439         'External exception class %s implements partial (broken) overloading '
 440       . 'preventing its instances from being used in simple ($x eq $y) '
 441       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 442       . 'handling this type of brokenness is extremely dangerous on '
 443       . 'exception objects, as it may (and often does) result in silent '
 444       . '"exception substitution". DBIx::Class tries to work around this '
 445       . 'as much as possible, but other parts of your software stack may '
 446       . 'not be even aware of this. Please submit a bugreport against the '
 447       . 'distribution containing %s and in the meantime apply a fix similar '
 448       . 'to the one shown at %s, in order to ensure your exception handling '
 449       . 'is saner application-wide. What follows is the actual error text '
 450       . "as generated by Perl itself:\n\n%s\n ",
 451         $class,
 452         $class,
 453         'http://v.gd/DBIC_overload_tempfix/',
 454         $suberror,
 455       ));
 456
 457       # workaround, keeps spice flowing
 458       $not_blank = !!( length $e );
 459     }
 460     else {
 461       # not blessed yet failed the 'ne'... this makes 0 sense...
 462       # just throw further
 463       die $suberror
 464     }
 465   }
 466   elsif (
 467     # a ref evaluating to '' is definitively a "null object"
 468     ( not $not_blank )
 469       and
 470     length( my $class = ref $e )
 471   ) {
 472     carp_unique( sprintf(
 473       "Objects of external exception class '%s' stringify to '' (the "
 474     . 'empty string), implementing the so called null-object-pattern. '
 475     . 'Given Perl\'s "globally cooperative" exception handling using this '
 476     . 'class of exceptions is extremely dangerous, as it may (and often '
 477     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 478     . 'work around this as much as possible, but other parts of your '
 479     . 'software stack may not be even aware of the problem. Please submit '
 480     . 'a bugreport against the distribution containing %s',
 481
 482       ($class) x 2,
 483     ));
 484
 485     $not_blank = 1;
 486   }
 487
 488   return $not_blank;
 489 }
 490
 491 {
 492   my $callstack_state;
 493
 494   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 495   #
 496   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 497   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 498   sub dbic_internal_try (&;@) {
 499
 500     my $try_cref = shift;
 501     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 502
 503     for my $arg (@_) {
 504
 505       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 506
 507         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 508           if $catch_cref;
 509
 510         $catch_cref = $$arg;
 511       }
 512       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 513         croak 'dbic_internal_try() does not support finally{}';
 514       }
 515       else {
 516         croak(
 517           'dbic_internal_try() encountered an unexpected argument '
 518         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 519         . 'a missing semi-colon before or ' # trailing space important
 520         );
 521       }
 522     }
 523
 524     my $wantarray = wantarray;
 525     my $preexisting_exception = $@;
 526
 527     my @ret;
 528     my $all_good = eval {
 529       $@ = $preexisting_exception;
 530
 531       local $callstack_state->{in_internal_try} = 1
 532         unless $callstack_state->{in_internal_try};
 533
 534       # always unset - someone may have snuck it in
 535       local $SIG{__DIE__} if $SIG{__DIE__};
 536
 537       if( $wantarray ) {
 538         @ret = $try_cref->();
 539       }
 540       elsif( defined $wantarray ) {
 541         $ret[0] = $try_cref->();
 542       }
 543       else {
 544         $try_cref->();
 545       }
 546
 547       1;
 548     };
 549
 550     my $exception = $@;
 551     $@ = $preexisting_exception;
 552
 553     if ( $all_good ) {
 554       return $wantarray ? @ret : $ret[0]
 555     }
 556     elsif ( $catch_cref ) {
 557       for ( $exception ) {
 558         return $catch_cref->($exception);
 559       }
 560     }
 561
 562     return;
 563   }
 564
 565   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 566 }
 567
 568 {
 569   my $destruction_registry = {};
 570
 571   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 572     %$destruction_registry = map {
 573       (defined $_)
 574         ? ( refaddr($_) => $_ )
 575         : ()
 576     } values %$destruction_registry;
 577
 578     weaken($_) for values %$destruction_registry;
 579
 580     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 581     # collected before leaving this scope. Depending on the code above, this
 582     # may very well be just a preventive measure guarding future modifications
 583     undef;
 584   }
 585
 586   # This is almost invariably invoked from within DESTROY
 587   # throwing exceptions won't work
 588   sub detected_reinvoked_destructor {
 589
 590     # quick "garbage collection" pass - prevents the registry
 591     # from slowly growing with a bunch of undef-valued keys
 592     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 593       for keys %$destruction_registry;
 594
 595     if (! length ref $_[0]) {
 596       printf STDERR '%s() expects a blessed reference %s',
 597         (caller(0))[3],
 598         Carp::longmess,
 599       ;
 600       return undef; # don't know wtf to do
 601     }
 602     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 603       weaken( $destruction_registry->{$addr} = $_[0] );
 604       return 0;
 605     }
 606     else {
 607       carp_unique ( sprintf (
 608         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 609       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 610       . 'application, affecting *ALL* classes without active protection against '
 611       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 612       refdesc $_[0],
 613         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 614           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 615           : ''
 616         )
 617       ));
 618
 619       return 1;
 620     }
 621   }
 622 }
 623
 624 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 625 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 626
 627 sub modver_gt_or_eq ($$) {
 628   my ($mod, $ver) = @_;
 629
 630   croak "Nonsensical module name supplied"
 631     if ! defined $mod or $mod !~ $module_name_rx;
 632
 633   croak "Nonsensical minimum version supplied"
 634     if ! defined $ver or $ver !~ $ver_rx;
 635
 636   no strict 'refs';
 637   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 638     ? {}
 639     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 640   );
 641
 642   ! defined $ver_cache->{$ver}
 643     and
 644   $ver_cache->{$ver} = do {
 645
 646     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 647       if SPURIOUS_VERSION_CHECK_WARNINGS;
 648
 649     local $SIG{__DIE__} if $SIG{__DIE__};
 650     local $@;
 651     eval { $mod->VERSION($ver) } ? 1 : 0;
 652   };
 653
 654   $ver_cache->{$ver};
 655 }
 656
 657 sub modver_gt_or_eq_and_lt ($$$) {
 658   my ($mod, $v_ge, $v_lt) = @_;
 659
 660   croak "Nonsensical maximum version supplied"
 661     if ! defined $v_lt or $v_lt !~ $ver_rx;
 662
 663   return (
 664     modver_gt_or_eq($mod, $v_ge)
 665       and
 666     ! modver_gt_or_eq($mod, $v_lt)
 667   ) ? 1 : 0;
 668 }
 669
 670 {
 671   # FIXME - should be a private my(), but I'm too uncertain whether
 672   # all bases are covered
 673   our $describe_class_query_cache;
 674
 675   sub describe_class_methods {
 676     my ($class, $requested_mro) = @_;
 677
 678     croak "Expecting a class name"
 679       if not defined $class or $class !~ $module_name_rx;
 680
 681     $requested_mro ||= mro::get_mro($class);
 682
 683     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 684     my $query_cache_key = "$class|$requested_mro";
 685
 686     my $stack_cache_key =
 687       ( mro::get_mro($class) eq $requested_mro )
 688         ? $class
 689         : $query_cache_key
 690     ;
 691
 692     # use a cache on old MRO, since while we are recursing in this function
 693     # nothing can possibly change (the speedup is immense)
 694     # (yes, people could be tie()ing the stash and adding methods on access
 695     # but there is a limit to how much crazy can be supported here)
 696     #
 697     # we use the cache for linear_isa lookups on new MRO as well - it adds
 698     # a *tiny* speedup, and simplifies the code a lot
 699     #
 700     local $mro_recursor_stack->{cache} = {}
 701       unless $mro_recursor_stack->{cache};
 702
 703     my $my_gen = 0;
 704
 705     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 706
 707       @{
 708         $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}
 709           ||=
 710         mro::get_linear_isa($class, $requested_mro)
 711       },
 712
 713       ((
 714         $mro_recursor_stack->{cache}{$class}{is_universal}
 715           ||=
 716         mro::is_universal($class)
 717       ) ? () : @{
 718         $mro_recursor_stack->{cache}{UNIVERSAL}{linear_isa}
 719           ||=
 720         mro::get_linear_isa("UNIVERSAL")
 721       }),
 722
 723     ));
 724
 725     my $slot = $describe_class_query_cache->{$query_cache_key} ||= {};
 726
 727     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 728
 729       # remove ourselves from ISA
 730       shift @full_ISA;
 731
 732       # reset
 733       %$slot = (
 734         class => $class,
 735         isa => [
 736           @{ $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa} }
 737             [ 1 .. $#{$mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}} ]
 738         ],
 739         mro => {
 740           type => $requested_mro,
 741           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 742         },
 743         cumulative_gen => $my_gen,
 744       );
 745
 746       # ensure the cache is populated for the parents, code below can then
 747       # efficiently operate over the query_cache directly
 748       describe_class_methods($_) for reverse @full_ISA;
 749
 750       no strict 'refs';
 751
 752       # combine full ISA-order inherited and local method list into a
 753       # "shadowing stack"
 754
 755       (
 756         unshift @{ $slot->{methods}{$_->{name}} }, $_
 757
 758           and
 759
 760         (
 761           $_->{via_class} ne $class
 762             or
 763           $slot->{methods_defined_in_class}{$_->{name}} = $_
 764         )
 765
 766           and
 767
 768         @{ $slot->{methods}{$_->{name}} } > 1
 769
 770           and
 771
 772         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 773
 774       ) for (
 775
 776         # what describe_class_methods for @full_ISA produced above
 777         ( map { values %{
 778           $describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 779         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 780
 781         # our own non-cleaned subs + their attributes
 782         ( map {
 783           (
 784             # need to account for dummy helper crefs under OLD_MRO
 785             (
 786               ! DBIx::Class::_ENV_::OLD_MRO
 787                 or
 788               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 789             )
 790               and
 791             # these 2 OR-ed checks are sufficient for 5.10+
 792             (
 793               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 794                 or
 795               defined( *{ "${class}::"->{$_} }{CODE} )
 796             )
 797           ) ? {
 798               via_class => $class,
 799               name => $_,
 800               attributes => {
 801                 map { $_ => 1 } attributes::get( \&{"${class}::${_}"} )
 802               },
 803             }
 804             : ()
 805         } keys %{"${class}::"} )
 806       );
 807
 808
 809       # recalculate the pkg_gen on newer perls under Taint mode,
 810       # because of shit like:
 811       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 812       #
 813       if (
 814         ! DBIx::Class::_ENV_::OLD_MRO
 815           and
 816         ${^TAINT}
 817       ) {
 818
 819         $slot->{cumulative_gen} = 0;
 820         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 821           for $class, @full_ISA;
 822       }
 823     }
 824
 825     # RV
 826     +{ %$slot };
 827   }
 828 }
 829
 830
 831 #
 832 # Why not just use some higher-level module or at least File::Spec here?
 833 # Because:
 834 # 1)  This is a *very* rarely used function, and the deptree is large
 835 #     enough already as it is
 836 #
 837 # 2)  (more importantly) Our tooling is utter shit in this area. There
 838 #     is no comprehensive support for UNC paths in PathTools and there
 839 #     are also various small bugs in representation across different
 840 #     path-manipulation CPAN offerings.
 841 #
 842 # Since this routine is strictly used for logical path processing (it
 843 # *must* be able to work with not-yet-existing paths), use this seemingly
 844 # simple but I *think* complete implementation to feed to other consumers
 845 #
 846 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 847 # the impulse to bring in an external dependency. During runtime there
 848 # is exactly one spot that could potentially maybe once in a blue moon
 849 # use this function. Keep it lean.
 850 #
 851 sub parent_dir ($) {
 852   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 853     ? (
 854       $_[0]
 855         .
 856       ( ( length($1) and ! length($2) ) ? '/' : '' )
 857         .
 858       '../'
 859     )
 860     : (
 861       require File::Spec
 862         and
 863       File::Spec->catpath (
 864         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 865         '/',
 866       )
 867     )
 868   ;
 869 }
 870
 871 sub mkdir_p ($) {
 872   require File::Path;
 873   # do not ask for a recent version, use 1.x API calls
 874   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 875 }
 876
 877
 878 {
 879   my $list_ctx_ok_stack_marker;
 880
 881   sub fail_on_internal_wantarray () {
 882     return if $list_ctx_ok_stack_marker;
 883
 884     if (! defined wantarray) {
 885       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 886     }
 887
 888     my $cf = 1;
 889     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 890
 891       # these are public API parts that alter behavior on wantarray
 892       search | search_related | slice | search_literal
 893
 894         |
 895
 896       # these are explicitly prefixed, since we only recognize them as valid
 897       # escapes when they come from the guts of CDBICompat
 898       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 899
 900     ) $/x ) {
 901       $cf++;
 902     }
 903
 904     my ($fr, $want, $argdesc);
 905     {
 906       package DB;
 907       $fr = [ CORE::caller($cf) ];
 908       $want = ( CORE::caller($cf-1) )[5];
 909       $argdesc = ref $DB::args[0]
 910         ? DBIx::Class::_Util::refdesc($DB::args[0])
 911         : 'non '
 912       ;
 913     };
 914
 915     if (
 916       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 917     ) {
 918       DBIx::Class::Exception->throw( sprintf (
 919         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 920         $argdesc, @{$fr}[1,2]
 921       ), 'with_stacktrace');
 922     }
 923
 924     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 925
 926     $mark;
 927   }
 928 }
 929
 930 sub fail_on_internal_call {
 931   my ($fr, $argdesc);
 932   {
 933     package DB;
 934     $fr = [ CORE::caller(1) ];
 935     $argdesc = ref $DB::args[0]
 936       ? DBIx::Class::_Util::refdesc($DB::args[0])
 937       : ( $DB::args[0] . '' )
 938     ;
 939   };
 940
 941   my @fr2;
 942   # need to make allowance for a proxy-yet-direct call
 943   my $check_fr = (
 944     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
 945       and
 946     @fr2 = (CORE::caller(2))
 947       and
 948     (
 949       ( $fr->[3] =~ /([^:])+$/ )[0]
 950         eq
 951       ( $fr2[3] =~ /([^:])+$/ )[0]
 952     )
 953   )
 954     ? \@fr2
 955     : $fr
 956   ;
 957
 958   if (
 959     $argdesc
 960       and
 961     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 962       and
 963     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 964   ) {
 965     DBIx::Class::Exception->throw( sprintf (
 966       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 967       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 968         require B::Deparse;
 969         no strict 'refs';
 970         B::Deparse->new->coderef2text(\&{$fr->[3]})
 971       }),
 972     ), 'with_stacktrace');
 973   }
 974 }
 975
 976 1;