lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     IV_SIZE => $Config{ivsize},
  38
  39     OS_NAME => $^O,
  40   };
  41
  42   if ($] < 5.009_005) {
  43     require MRO::Compat;
  44     constant->import( OLD_MRO => 1 );
  45   }
  46   else {
  47     require mro;
  48     constant->import( OLD_MRO => 0 );
  49   }
  50 }
  51
  52 # FIXME - this is not supposed to be here
  53 # Carp::Skip to the rescue soon
  54 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  55
  56 use B ();
  57 use Carp 'croak';
  58 use Storable 'nfreeze';
  59 use Scalar::Util qw(weaken blessed reftype);
  60 use List::Util qw(first);
  61
  62 # DO NOT edit away without talking to riba first, he will just put it back
  63 # BEGIN pre-Moo2 import block
  64 BEGIN {
  65   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  66
  67   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  68   # load all of these now, so that lazy-loading does not escape
  69   # the current PERL_STRICTURES_EXTRA setting
  70   require Sub::Quote;
  71   require Sub::Defer;
  72
  73   Sub::Quote->import('quote_sub');
  74   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  75 }
  76 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
  77 # END pre-Moo2 import block
  78
  79 use base 'Exporter';
  80 our @EXPORT_OK = qw(
  81   sigwarn_silencer modver_gt_or_eq
  82   fail_on_internal_wantarray fail_on_internal_call
  83   refdesc refcount hrefaddr is_exception
  84   quote_sub qsub perlstring serialize
  85   UNRESOLVABLE_CONDITION
  86 );
  87
  88 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  89
  90 sub sigwarn_silencer ($) {
  91   my $pattern = shift;
  92
  93   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  94
  95   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  96
  97   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  98 }
  99
 100 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 101
 102 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 103
 104 sub refdesc ($) {
 105   croak "Expecting a reference" if ! length ref $_[0];
 106
 107   # be careful not to trigger stringification,
 108   # reuse @_ as a scratch-pad
 109   sprintf '%s%s(0x%x)',
 110     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 111     reftype $_[0],
 112     Scalar::Util::refaddr($_[0]),
 113   ;
 114 }
 115
 116 sub refcount ($) {
 117   croak "Expecting a reference" if ! length ref $_[0];
 118
 119   # No tempvars - must operate on $_[0], otherwise the pad
 120   # will count as an extra ref
 121   B::svref_2object($_[0])->REFCNT;
 122 }
 123
 124 sub serialize ($) {
 125   local $Storable::canonical = 1;
 126   nfreeze($_[0]);
 127 }
 128
 129 sub is_exception ($) {
 130   my $e = $_[0];
 131
 132   # this is not strictly correct - an eval setting $@ to undef
 133   # is *not* the same as an eval setting $@ to ''
 134   # but for the sake of simplicity assume the following for
 135   # the time being
 136   return 0 unless defined $e;
 137
 138   my ($not_blank, $suberror);
 139   {
 140     local $@;
 141     eval {
 142       $not_blank = ($e ne '') ? 1 : 0;
 143       1;
 144     } or $suberror = $@;
 145   }
 146
 147   if (defined $suberror) {
 148     if (length (my $class = blessed($e) )) {
 149       carp_unique( sprintf(
 150         'External exception class %s implements partial (broken) overloading '
 151       . 'preventing its instances from being used in simple ($x eq $y) '
 152       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 153       . 'handling this type of brokenness is extremely dangerous on '
 154       . 'exception objects, as it may (and often does) result in silent '
 155       . '"exception substitution". DBIx::Class tries to work around this '
 156       . 'as much as possible, but other parts of your software stack may '
 157       . 'not be even aware of this. Please submit a bugreport against the '
 158       . 'distribution containing %s and in the meantime apply a fix similar '
 159       . 'to the one shown at %s, in order to ensure your exception handling '
 160       . 'is saner application-wide. What follows is the actual error text '
 161       . "as generated by Perl itself:\n\n%s\n ",
 162         $class,
 163         $class,
 164         'http://v.gd/DBIC_overload_tempfix/',
 165         $suberror,
 166       ));
 167
 168       # workaround, keeps spice flowing
 169       $not_blank = ("$e" ne '') ? 1 : 0;
 170     }
 171     else {
 172       # not blessed yet failed the 'ne'... this makes 0 sense...
 173       # just throw further
 174       die $suberror
 175     }
 176   }
 177
 178   return $not_blank;
 179 }
 180
 181 sub modver_gt_or_eq ($$) {
 182   my ($mod, $ver) = @_;
 183
 184   croak "Nonsensical module name supplied"
 185     if ! defined $mod or ! length $mod;
 186
 187   croak "Nonsensical minimum version supplied"
 188     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 189
 190   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 191     if SPURIOUS_VERSION_CHECK_WARNINGS;
 192
 193   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 194     unless $mod->VERSION;
 195
 196   local $@;
 197   eval { $mod->VERSION($ver) } ? 1 : 0;
 198 }
 199
 200 {
 201   my $list_ctx_ok_stack_marker;
 202
 203   sub fail_on_internal_wantarray () {
 204     return if $list_ctx_ok_stack_marker;
 205
 206     if (! defined wantarray) {
 207       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 208     }
 209
 210     my $cf = 1;
 211     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 212
 213       # these are public API parts that alter behavior on wantarray
 214       search | search_related | slice | search_literal
 215
 216         |
 217
 218       # these are explicitly prefixed, since we only recognize them as valid
 219       # escapes when they come from the guts of CDBICompat
 220       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 221
 222     ) $/x ) {
 223       $cf++;
 224     }
 225
 226     my ($fr, $want, $argdesc);
 227     {
 228       package DB;
 229       $fr = [ caller($cf) ];
 230       $want = ( caller($cf-1) )[5];
 231       $argdesc = ref $DB::args[0]
 232         ? DBIx::Class::_Util::refdesc($DB::args[0])
 233         : 'non '
 234       ;
 235     };
 236
 237     if (
 238       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 239     ) {
 240       DBIx::Class::Exception->throw( sprintf (
 241         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 242         $argdesc, @{$fr}[1,2]
 243       ), 'with_stacktrace');
 244     }
 245
 246     my $mark = [];
 247     weaken ( $list_ctx_ok_stack_marker = $mark );
 248     $mark;
 249   }
 250 }
 251
 252 sub fail_on_internal_call {
 253   my ($fr, $argdesc);
 254   {
 255     package DB;
 256     $fr = [ caller(1) ];
 257     $argdesc = ref $DB::args[0]
 258       ? DBIx::Class::_Util::refdesc($DB::args[0])
 259       : undef
 260     ;
 261   };
 262
 263   if (
 264     $argdesc
 265       and
 266     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 267       and
 268     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 269   ) {
 270     DBIx::Class::Exception->throw( sprintf (
 271       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 272       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 273         require B::Deparse;
 274         no strict 'refs';
 275         B::Deparse->new->coderef2text(\&{$fr->[3]})
 276       }),
 277     ), 'with_stacktrace');
 278   }
 279 }
 280
 281 1;