lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     ( map
  27       #
  28       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  29       # all envvars without further adjusting its scripts
  30       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  31       #
  32       { substr($_, 5) => !!( $ENV{$_} ) }
  33       qw(
  34         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  35         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  36         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  37         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  38         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  39       )
  40     ),
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55
  56   # Both of these are no longer used for anything. However bring
  57   # them back after they were purged in 08a8d8f1, as there appear
  58   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
  59   # in their production codebases. There is no point in breaking these
  60   # if whatever they used actually continues to work
  61   my $warned;
  62   my $sigh = sub {
  63
  64     require Carp;
  65     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
  66
  67     warn $cluck unless $warned->{$cluck}++;
  68
  69     0;
  70   };
  71   sub DBICTEST () { &$sigh }
  72   sub PEEPEENESS () { &$sigh }
  73 }
  74
  75 # FIXME - this is not supposed to be here
  76 # Carp::Skip to the rescue soon
  77 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  78
  79 use B ();
  80 use Carp 'croak';
  81 use Storable 'nfreeze';
  82 use Scalar::Util qw(weaken blessed reftype refaddr);
  83 use Sub::Quote qw(qsub quote_sub);
  84
  85 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  86 BEGIN { *deep_clone = \&Storable::dclone }
  87
  88 use base 'Exporter';
  89 our @EXPORT_OK = qw(
  90   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  91   fail_on_internal_wantarray fail_on_internal_call
  92   refdesc refcount hrefaddr
  93   scope_guard detected_reinvoked_destructor
  94   is_exception dbic_internal_try
  95   quote_sub qsub perlstring serialize deep_clone dump_value
  96   parent_dir mkdir_p
  97   UNRESOLVABLE_CONDITION
  98 );
  99
 100 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 101
 102 sub sigwarn_silencer ($) {
 103   my $pattern = shift;
 104
 105   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 106
 107   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 108
 109   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 110 }
 111
 112 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 113
 114 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 115
 116 sub refdesc ($) {
 117   croak "Expecting a reference" if ! length ref $_[0];
 118
 119   # be careful not to trigger stringification,
 120   # reuse @_ as a scratch-pad
 121   sprintf '%s%s(0x%x)',
 122     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 123     reftype $_[0],
 124     refaddr($_[0]),
 125   ;
 126 }
 127
 128 sub refcount ($) {
 129   croak "Expecting a reference" if ! length ref $_[0];
 130
 131   # No tempvars - must operate on $_[0], otherwise the pad
 132   # will count as an extra ref
 133   B::svref_2object($_[0])->REFCNT;
 134 }
 135
 136 sub serialize ($) {
 137   local $Storable::canonical = 1;
 138   nfreeze($_[0]);
 139 }
 140
 141 my $dd_obj;
 142 sub dump_value ($) {
 143   local $Data::Dumper::Indent = 1
 144     unless defined $Data::Dumper::Indent;
 145
 146   my $dump_str = (
 147     $dd_obj
 148       ||=
 149     do {
 150       require Data::Dumper;
 151       my $d = Data::Dumper->new([])
 152         ->Purity(0)
 153         ->Pad('')
 154         ->Useqq(1)
 155         ->Terse(1)
 156         ->Freezer('')
 157         ->Quotekeys(0)
 158         ->Bless('bless')
 159         ->Pair(' => ')
 160         ->Sortkeys(1)
 161         ->Deparse(1)
 162       ;
 163
 164       $d->Sparseseen(1) if modver_gt_or_eq (
 165         'Data::Dumper', '2.136'
 166       );
 167
 168       $d;
 169     }
 170   )->Values([$_[0]])->Dump;
 171
 172   $dd_obj->Reset->Values([]);
 173
 174   $dump_str;
 175 }
 176
 177 sub scope_guard (&) {
 178   croak 'Calling scope_guard() in void context makes no sense'
 179     if ! defined wantarray;
 180
 181   # no direct blessing of coderefs - DESTROY is buggy on those
 182   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 183 }
 184 {
 185   package #
 186     DBIx::Class::_Util::ScopeGuard;
 187
 188   sub DESTROY {
 189     &DBIx::Class::_Util::detected_reinvoked_destructor;
 190
 191     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 192
 193     eval {
 194       $_[0]->[0]->();
 195       1;
 196     }
 197       or
 198     Carp::cluck(
 199       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 200     );
 201   }
 202 }
 203
 204
 205 sub is_exception ($) {
 206   my $e = $_[0];
 207
 208   # FIXME
 209   # this is not strictly correct - an eval setting $@ to undef
 210   # is *not* the same as an eval setting $@ to ''
 211   # but for the sake of simplicity assume the following for
 212   # the time being
 213   return 0 unless defined $e;
 214
 215   my ($not_blank, $suberror);
 216   {
 217     local $SIG{__DIE__} if $SIG{__DIE__};
 218     local $@;
 219     eval {
 220       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 221       # will entirely obviate the need for the encolsing eval{}, as the
 222       # condition we guard against is a missing fallback overload
 223       $not_blank = ( $e ne '' );
 224       1;
 225     } or $suberror = $@;
 226   }
 227
 228   if (defined $suberror) {
 229     if (length (my $class = blessed($e) )) {
 230       carp_unique( sprintf(
 231         'External exception class %s implements partial (broken) overloading '
 232       . 'preventing its instances from being used in simple ($x eq $y) '
 233       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 234       . 'handling this type of brokenness is extremely dangerous on '
 235       . 'exception objects, as it may (and often does) result in silent '
 236       . '"exception substitution". DBIx::Class tries to work around this '
 237       . 'as much as possible, but other parts of your software stack may '
 238       . 'not be even aware of this. Please submit a bugreport against the '
 239       . 'distribution containing %s and in the meantime apply a fix similar '
 240       . 'to the one shown at %s, in order to ensure your exception handling '
 241       . 'is saner application-wide. What follows is the actual error text '
 242       . "as generated by Perl itself:\n\n%s\n ",
 243         $class,
 244         $class,
 245         'http://v.gd/DBIC_overload_tempfix/',
 246         $suberror,
 247       ));
 248
 249       # workaround, keeps spice flowing
 250       $not_blank = !!( length $e );
 251     }
 252     else {
 253       # not blessed yet failed the 'ne'... this makes 0 sense...
 254       # just throw further
 255       die $suberror
 256     }
 257   }
 258   elsif (
 259     # a ref evaluating to '' is definitively a "null object"
 260     ( not $not_blank )
 261       and
 262     length( my $class = ref $e )
 263   ) {
 264     carp_unique( sprintf(
 265       "Objects of external exception class '%s' stringify to '' (the "
 266     . 'empty string), implementing the so called null-object-pattern. '
 267     . 'Given Perl\'s "globally cooperative" exception handling using this '
 268     . 'class of exceptions is extremely dangerous, as it may (and often '
 269     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 270     . 'work around this as much as possible, but other parts of your '
 271     . 'software stack may not be even aware of the problem. Please submit '
 272     . 'a bugreport against the distribution containing %s',
 273
 274       ($class) x 2,
 275     ));
 276
 277     $not_blank = 1;
 278   }
 279
 280   return $not_blank;
 281 }
 282
 283 {
 284   my $callstack_state;
 285
 286   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 287   #
 288   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 289   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 290   sub dbic_internal_try (&;@) {
 291
 292     my $try_cref = shift;
 293     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 294
 295     for my $arg (@_) {
 296
 297       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 298
 299         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 300           if $catch_cref;
 301
 302         $catch_cref = $$arg;
 303       }
 304       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 305         croak 'dbic_internal_try() does not support finally{}';
 306       }
 307       else {
 308         croak(
 309           'dbic_internal_try() encountered an unexpected argument '
 310         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 311         . 'a missing semi-colon before or ' # trailing space important
 312         );
 313       }
 314     }
 315
 316     my $wantarray = wantarray;
 317     my $preexisting_exception = $@;
 318
 319     my @ret;
 320     my $all_good = eval {
 321       $@ = $preexisting_exception;
 322
 323       local $callstack_state->{in_internal_try} = 1
 324         unless $callstack_state->{in_internal_try};
 325
 326       # always unset - someone may have snuck it in
 327       local $SIG{__DIE__} if $SIG{__DIE__};
 328
 329       if( $wantarray ) {
 330         @ret = $try_cref->();
 331       }
 332       elsif( defined $wantarray ) {
 333         $ret[0] = $try_cref->();
 334       }
 335       else {
 336         $try_cref->();
 337       }
 338
 339       1;
 340     };
 341
 342     my $exception = $@;
 343     $@ = $preexisting_exception;
 344
 345     if ( $all_good ) {
 346       return $wantarray ? @ret : $ret[0]
 347     }
 348     elsif ( $catch_cref ) {
 349       for ( $exception ) {
 350         return $catch_cref->($exception);
 351       }
 352     }
 353
 354     return;
 355   }
 356
 357   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 358 }
 359
 360 {
 361   my $destruction_registry = {};
 362
 363   sub CLONE {
 364     %$destruction_registry = map {
 365       (defined $_)
 366         ? ( refaddr($_) => $_ )
 367         : ()
 368     } values %$destruction_registry;
 369
 370     weaken($_) for values %$destruction_registry;
 371
 372     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 373     # collected before leaving this scope. Depending on the code above, this
 374     # may very well be just a preventive measure guarding future modifications
 375     undef;
 376   }
 377
 378   # This is almost invariably invoked from within DESTROY
 379   # throwing exceptions won't work
 380   sub detected_reinvoked_destructor {
 381
 382     # quick "garbage collection" pass - prevents the registry
 383     # from slowly growing with a bunch of undef-valued keys
 384     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 385       for keys %$destruction_registry;
 386
 387     if (! length ref $_[0]) {
 388       printf STDERR '%s() expects a blessed reference %s',
 389         (caller(0))[3],
 390         Carp::longmess,
 391       ;
 392       return undef; # don't know wtf to do
 393     }
 394     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 395       weaken( $destruction_registry->{$addr} = $_[0] );
 396       return 0;
 397     }
 398     else {
 399       carp_unique ( sprintf (
 400         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 401       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 402       . 'application, affecting *ALL* classes without active protection against '
 403       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 404       refdesc $_[0],
 405         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 406           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 407           : ''
 408         )
 409       ));
 410
 411       return 1;
 412     }
 413   }
 414 }
 415
 416 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 417 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 418
 419 sub modver_gt_or_eq ($$) {
 420   my ($mod, $ver) = @_;
 421
 422   croak "Nonsensical module name supplied"
 423     if ! defined $mod or $mod !~ $module_name_rx;
 424
 425   croak "Nonsensical minimum version supplied"
 426     if ! defined $ver or $ver !~ $ver_rx;
 427
 428   no strict 'refs';
 429   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 430     ? {}
 431     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 432   );
 433
 434   ! defined $ver_cache->{$ver}
 435     and
 436   $ver_cache->{$ver} = do {
 437
 438     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 439       if SPURIOUS_VERSION_CHECK_WARNINGS;
 440
 441     local $SIG{__DIE__} if $SIG{__DIE__};
 442     local $@;
 443     eval { $mod->VERSION($ver) } ? 1 : 0;
 444   };
 445
 446   $ver_cache->{$ver};
 447 }
 448
 449 sub modver_gt_or_eq_and_lt ($$$) {
 450   my ($mod, $v_ge, $v_lt) = @_;
 451
 452   croak "Nonsensical maximum version supplied"
 453     if ! defined $v_lt or $v_lt !~ $ver_rx;
 454
 455   return (
 456     modver_gt_or_eq($mod, $v_ge)
 457       and
 458     ! modver_gt_or_eq($mod, $v_lt)
 459   ) ? 1 : 0;
 460 }
 461
 462
 463 #
 464 # Why not just use some higher-level module or at least File::Spec here?
 465 # Because:
 466 # 1)  This is a *very* rarely used function, and the deptree is large
 467 #     enough already as it is
 468 #
 469 # 2)  (more importantly) Our tooling is utter shit in this area. There
 470 #     is no comprehensive support for UNC paths in PathTools and there
 471 #     are also various small bugs in representation across different
 472 #     path-manipulation CPAN offerings.
 473 #
 474 # Since this routine is strictly used for logical path processing (it
 475 # *must* be able to work with not-yet-existing paths), use this seemingly
 476 # simple but I *think* complete implementation to feed to other consumers
 477 #
 478 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 479 # the impulse to bring in an external dependency. During runtime there
 480 # is exactly one spot that could potentially maybe once in a blue moon
 481 # use this function. Keep it lean.
 482 #
 483 sub parent_dir ($) {
 484   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 485     ? (
 486       $_[0]
 487         .
 488       ( ( length($1) and ! length($2) ) ? '/' : '' )
 489         .
 490       '../'
 491     )
 492     : (
 493       require File::Spec
 494         and
 495       File::Spec->catpath (
 496         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 497         '/',
 498       )
 499     )
 500   ;
 501 }
 502
 503 sub mkdir_p ($) {
 504   require File::Path;
 505   # do not ask for a recent version, use 1.x API calls
 506   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 507 }
 508
 509
 510 {
 511   my $list_ctx_ok_stack_marker;
 512
 513   sub fail_on_internal_wantarray () {
 514     return if $list_ctx_ok_stack_marker;
 515
 516     if (! defined wantarray) {
 517       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 518     }
 519
 520     my $cf = 1;
 521     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 522
 523       # these are public API parts that alter behavior on wantarray
 524       search | search_related | slice | search_literal
 525
 526         |
 527
 528       # these are explicitly prefixed, since we only recognize them as valid
 529       # escapes when they come from the guts of CDBICompat
 530       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 531
 532     ) $/x ) {
 533       $cf++;
 534     }
 535
 536     my ($fr, $want, $argdesc);
 537     {
 538       package DB;
 539       $fr = [ CORE::caller($cf) ];
 540       $want = ( CORE::caller($cf-1) )[5];
 541       $argdesc = ref $DB::args[0]
 542         ? DBIx::Class::_Util::refdesc($DB::args[0])
 543         : 'non '
 544       ;
 545     };
 546
 547     if (
 548       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 549     ) {
 550       DBIx::Class::Exception->throw( sprintf (
 551         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 552         $argdesc, @{$fr}[1,2]
 553       ), 'with_stacktrace');
 554     }
 555
 556     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 557
 558     $mark;
 559   }
 560 }
 561
 562 sub fail_on_internal_call {
 563   my ($fr, $argdesc);
 564   {
 565     package DB;
 566     $fr = [ CORE::caller(1) ];
 567     $argdesc = ref $DB::args[0]
 568       ? DBIx::Class::_Util::refdesc($DB::args[0])
 569       : undef
 570     ;
 571   };
 572
 573   if (
 574     $argdesc
 575       and
 576     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 577       and
 578     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 579   ) {
 580     DBIx::Class::Exception->throw( sprintf (
 581       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 582       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 583         require B::Deparse;
 584         no strict 'refs';
 585         B::Deparse->new->coderef2text(\&{$fr->[3]})
 586       }),
 587     ), 'with_stacktrace');
 588   }
 589 }
 590
 591 1;