lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 # load es early as we can, usually a noop
   5 use DBIx::Class::StartupCheck;
   6
   7 use warnings;
   8 use strict;
   9
  10 # For the love of everything that is crab-like: DO NOT reach into this
  11 # The entire thing is really fragile and should not be screwed with
  12 # unless absolutely and unavoidably necessary
  13 our $__describe_class_query_cache;
  14
  15 BEGIN {
  16   package # hide from pause
  17     DBIx::Class::_ENV_;
  18
  19   use Config;
  20
  21   use constant {
  22     PERL_VERSION => "$]",
  23     OS_NAME => "$^O",
  24   };
  25
  26   use constant {
  27
  28     # but of course
  29     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  30
  31     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  32
  33     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  34     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  35
  36     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  37
  38     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  39
  40     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  41
  42     ( map
  43       #
  44       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  45       # all envvars without further adjusting its scripts
  46       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  47       #
  48       { substr($_, 5) => !!( $ENV{$_} ) }
  49       qw(
  50         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  51         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  52         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  53         DBIC_ASSERT_NO_ERRONEOUS_METAINSTANCE_USE
  54         DBIC_ASSERT_NO_FAILING_SANITY_CHECKS
  55         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  56         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  57       )
  58     ),
  59
  60     IV_SIZE => $Config{ivsize},
  61   };
  62
  63   if ( PERL_VERSION < 5.009_005) {
  64     require MRO::Compat;
  65     constant->import( OLD_MRO => 1 );
  66
  67     #
  68     # Yes, I know this is a rather PHP-ish name, but please first read
  69     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  70     #
  71     # Even if we are using Class::C3::XS it still won't work, as doing
  72     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  73     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  74     #
  75     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  76       require Digest::MD5;
  77       require Math::BigInt;
  78
  79       my $cur_class;
  80       no strict 'refs';
  81
  82       # the non-assign-unless-there-is-a-hash is deliberate
  83       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  84         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  85
  86           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  87
  88             $cur_class = $_
  89
  90               and
  91
  92             # RV to be hashed up and turned into a number
  93             join "\0", (
  94               $cur_class,
  95               map
  96                 {(
  97                   # stringification should be sufficient, ignore names/refaddr entirely
  98                   $_,
  99                   do {
 100                     my @attrs;
 101                     local $@;
 102                     local $SIG{__DIE__} if $SIG{__DIE__};
 103                     # attributes::get may throw on blessed-false crefs :/
 104                     eval { @attrs = attributes::get( $_ ); 1 }
 105                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 106                     @attrs;
 107                   },
 108                 )}
 109                 map
 110                   {(
 111                     # skip dummy C::C3 helper crefs
 112                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 113                       and
 114                     (
 115                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 116                         or
 117                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 118                     )
 119                   )
 120                     ? ( \&{"${cur_class}::$_"} )
 121                     : ()
 122                   }
 123                   keys %{ "${cur_class}::" }
 124             )
 125           )
 126         } (
 127
 128           @{
 129             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 130               ||=
 131             mro::get_linear_isa($_[0])
 132           },
 133
 134           ((
 135             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 136               ||=
 137             mro::is_universal($_[0])
 138           ) ? () : @{
 139             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 140               ||=
 141             mro::get_linear_isa("UNIVERSAL")
 142           } ),
 143
 144         ) ) ) )
 145       );
 146     };
 147   }
 148   else {
 149     require mro;
 150     constant->import( OLD_MRO => 0 );
 151     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 152   }
 153
 154   # Both of these are no longer used for anything. However bring
 155   # them back after they were purged in 08a8d8f1, as there appear
 156   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 157   # in their production codebases. There is no point in breaking these
 158   # if whatever they used actually continues to work
 159   my $sigh = sub {
 160     DBIx::Class::_Util::emit_loud_diag(
 161       skip_frames => 1,
 162       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 163     );
 164
 165     0;
 166   };
 167   sub DBICTEST () { &$sigh }
 168   sub PEEPEENESS () { &$sigh }
 169 }
 170
 171 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 172
 173 # FIXME - this is not supposed to be here
 174 # Carp::Skip to the rescue soon
 175 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 176
 177 # Ensure it is always there, in case we need to do a $schema-less throw()
 178 use DBIx::Class::Exception ();
 179
 180 use B ();
 181 use Carp 'croak';
 182 use Storable 'nfreeze';
 183 use Scalar::Util qw(weaken blessed reftype refaddr);
 184 use Sub::Name ();
 185 use attributes ();
 186
 187 # Usually versions are not specified anywhere aside the Makefile.PL
 188 # (writing them out in-code is extremely obnoxious)
 189 # However without a recent enough Moo the quote_sub override fails
 190 # in very puzzling and hard to detect ways: so add a version check
 191 # just this once
 192 use Sub::Quote qw(qsub);
 193 BEGIN { Sub::Quote->VERSION('2.002002') }
 194
 195 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 196 BEGIN { *deep_clone = \&Storable::dclone }
 197
 198 use base 'Exporter';
 199 our @EXPORT_OK = qw(
 200   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 201   fail_on_internal_wantarray fail_on_internal_call
 202   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 203   scope_guard detected_reinvoked_destructor emit_loud_diag
 204   true false
 205   is_exception dbic_internal_try visit_namespaces
 206   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 207   parent_dir mkdir_p
 208   UNRESOLVABLE_CONDITION
 209 );
 210
 211 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 212
 213 # Override forcing no_defer, and adding naming consistency checks
 214 our %refs_closed_over_by_quote_sub_installed_crefs;
 215 sub quote_sub {
 216   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 217     @_ < 2
 218       or
 219     ! defined $_[1]
 220       or
 221     length ref $_[1]
 222   ;
 223
 224   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 225     unless (my $stash) = $_[0] =~ /^(.+)::/;
 226
 227   Carp::confess(
 228     "The DBIC sub_quote override does not support 'no_install'"
 229   ) if (
 230     $_[3]
 231       and
 232     $_[3]->{no_install}
 233   );
 234
 235   Carp::confess(
 236     'The DBIC quote_sub override expects the namespace-part of sub name '
 237   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 238   ) if (
 239     $_[3]
 240       and
 241     defined $_[3]->{package}
 242       and
 243     $stash ne $_[3]->{package}
 244   );
 245
 246   my @caller = caller(0);
 247   my $sq_opts = {
 248     package => $caller[0],
 249     hints => $caller[8],
 250     warning_bits => $caller[9],
 251     hintshash => $caller[10],
 252     %{ $_[3] || {} },
 253
 254     # explicitly forced for everything
 255     no_defer => 1,
 256   };
 257
 258   weaken (
 259     # just use a growing counter, no need to perform neither compaction
 260     # nor any special ithread-level handling
 261     $refs_closed_over_by_quote_sub_installed_crefs
 262      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 263       = $_
 264   ) for grep {
 265     length ref $_
 266       and
 267     (
 268       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 269         or
 270       ref $_ ne 'SCALAR'
 271     )
 272   } values %{ $_[2] || {} };
 273
 274   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 275 }
 276
 277 sub sigwarn_silencer ($) {
 278   my $pattern = shift;
 279
 280   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 281
 282   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 283
 284   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 285 }
 286
 287 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 288
 289 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 290
 291 sub refdesc ($) {
 292   croak "Expecting a reference" if ! length ref $_[0];
 293
 294   # be careful not to trigger stringification,
 295   # reuse @_ as a scratch-pad
 296   sprintf '%s%s(0x%x)',
 297     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 298     reftype $_[0],
 299     refaddr($_[0]),
 300   ;
 301 }
 302
 303 sub refcount ($) {
 304   croak "Expecting a reference" if ! length ref $_[0];
 305
 306   # No tempvars - must operate on $_[0], otherwise the pad
 307   # will count as an extra ref
 308   B::svref_2object($_[0])->REFCNT;
 309 }
 310
 311 sub visit_namespaces {
 312   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 313
 314   my $visited_count = 1;
 315
 316   # A package and a namespace are subtly different things
 317   $args->{package} ||= 'main';
 318   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 319   $args->{package} =~ s/^:://;
 320
 321   if ( $args->{action}->($args->{package}) ) {
 322     my $ns =
 323       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 324         .
 325       '::'
 326     ;
 327
 328     $visited_count += visit_namespaces( %$args, package => $_ ) for
 329       grep
 330         # this happens sometimes on %:: traversal
 331         { $_ ne '::main' }
 332         map
 333           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 334           do { no strict 'refs'; keys %$ns }
 335     ;
 336   }
 337
 338   $visited_count;
 339 }
 340
 341 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 342 sub get_subname ($) {
 343   my $gv = B::svref_2object( $_[0] )->GV;
 344   wantarray
 345     ? ( $gv->STASH->NAME, $gv->NAME )
 346     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 347   ;
 348 }
 349 sub set_subname ($$) {
 350
 351   # fully qualify name
 352   splice @_, 0, 1, caller(0) . "::$_[0]"
 353     if $_[0] !~ /::|'/;
 354
 355   &Sub::Name::subname;
 356 }
 357
 358 sub serialize ($) {
 359   # stable hash order
 360   local $Storable::canonical = 1;
 361
 362   # explicitly false - there is nothing sensible that can come out of
 363   # an attempt at CODE serialization
 364   local $Storable::Deparse;
 365
 366   # take no chances
 367   local $Storable::forgive_me;
 368
 369   # FIXME
 370   # A number of codepaths *expect* this to be Storable.pm-based so that
 371   # the STORABLE_freeze hooks in the metadata subtree get executed properly
 372   nfreeze($_[0]);
 373 }
 374
 375 sub uniq {
 376   my( %seen, $seen_undef, $numeric_preserving_copy );
 377   grep { not (
 378     defined $_
 379       ? $seen{ $numeric_preserving_copy = $_ }++
 380       : $seen_undef++
 381   ) } @_;
 382 }
 383
 384 my $dd_obj;
 385 sub dump_value ($) {
 386   local $Data::Dumper::Indent = 1
 387     unless defined $Data::Dumper::Indent;
 388
 389   my $dump_str = (
 390     $dd_obj
 391       ||=
 392     do {
 393       require Data::Dumper;
 394       my $d = Data::Dumper->new([])
 395         ->Purity(0)
 396         ->Pad('')
 397         ->Useqq(1)
 398         ->Terse(1)
 399         ->Freezer('')
 400         ->Quotekeys(0)
 401         ->Bless('bless')
 402         ->Pair(' => ')
 403         ->Sortkeys(1)
 404         ->Deparse(1)
 405       ;
 406
 407       # FIXME - this is kinda ridiculous - there ought to be a
 408       # Data::Dumper->new_with_defaults or somesuch...
 409       #
 410       if( modver_gt_or_eq ( 'Data::Dumper', '2.136' ) ) {
 411         $d->Sparseseen(1);
 412
 413         if( modver_gt_or_eq ( 'Data::Dumper', '2.153' ) ) {
 414           $d->Maxrecurse(1000);
 415
 416           if( modver_gt_or_eq ( 'Data::Dumper', '2.160' ) ) {
 417             $d->Trailingcomma(1);
 418           }
 419         }
 420       }
 421
 422       $d;
 423     }
 424   )->Values([$_[0]])->Dump;
 425
 426   $dd_obj->Reset->Values([]);
 427
 428   $dump_str;
 429 }
 430
 431 my $seen_loud_screams;
 432 sub emit_loud_diag {
 433   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 434
 435   unless ( defined $args->{msg} and length $args->{msg} ) {
 436     emit_loud_diag(
 437       msg => "No 'msg' value supplied to emit_loud_diag()"
 438     );
 439     exit 70;
 440   }
 441
 442   my $msg = "\n" . join( ': ',
 443     ( $0 eq '-e' ? () : $0 ),
 444     $args->{msg}
 445   );
 446
 447   # when we die - we usually want to keep doing it
 448   $args->{emit_dups} = !!$args->{confess}
 449     unless exists $args->{emit_dups};
 450
 451   local $Carp::CarpLevel =
 452     ( $args->{skip_frames} || 0 )
 453       +
 454     $Carp::CarpLevel
 455       +
 456     # hide our own frame
 457     1
 458   ;
 459
 460   my $longmess = Carp::longmess();
 461
 462   # different object references will thwart deduplication without this
 463   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 464
 465   return $seen_loud_screams->{$key} if
 466     $seen_loud_screams->{$key}++
 467       and
 468     ! $args->{emit_dups}
 469   ;
 470
 471   $msg .= $longmess
 472     unless $msg =~ /\n\z/;
 473
 474   print STDERR "$msg\n"
 475     or
 476   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 477
 478   return $seen_loud_screams->{$key}
 479     unless $args->{confess};
 480
 481   # increment *again*, because... Carp.
 482   $Carp::CarpLevel++;
 483
 484   # not $msg - Carp will reapply the longmess on its own
 485   Carp::confess($args->{msg});
 486 }
 487
 488
 489 ###
 490 ### This is *NOT* boolean.pm - deliberately not using a singleton
 491 ###
 492 {
 493   package # hide from pause
 494     DBIx::Class::_Util::_Bool;
 495   use overload
 496     bool => sub { ${$_[0]} },
 497     fallback => 1,
 498   ;
 499 }
 500 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 501 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 502
 503 sub scope_guard (&) {
 504   croak 'Calling scope_guard() in void context makes no sense'
 505     if ! defined wantarray;
 506
 507   # no direct blessing of coderefs - DESTROY is buggy on those
 508   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 509 }
 510 {
 511   package #
 512     DBIx::Class::_Util::ScopeGuard;
 513
 514   sub DESTROY {
 515     &DBIx::Class::_Util::detected_reinvoked_destructor;
 516
 517     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 518
 519     eval {
 520       $_[0]->[0]->();
 521       1;
 522     }
 523       or
 524     DBIx::Class::_Util::emit_loud_diag(
 525       emit_dups => 1,
 526       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 527     );
 528   }
 529 }
 530
 531
 532 sub is_exception ($) {
 533   my $e = $_[0];
 534
 535   # FIXME
 536   # this is not strictly correct - an eval setting $@ to undef
 537   # is *not* the same as an eval setting $@ to ''
 538   # but for the sake of simplicity assume the following for
 539   # the time being
 540   return 0 unless defined $e;
 541
 542   my ($not_blank, $suberror);
 543   {
 544     local $SIG{__DIE__} if $SIG{__DIE__};
 545     local $@;
 546     eval {
 547       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 548       # will entirely obviate the need for the encolsing eval{}, as the
 549       # condition we guard against is a missing fallback overload
 550       $not_blank = ( $e ne '' );
 551       1;
 552     } or $suberror = $@;
 553   }
 554
 555   if (defined $suberror) {
 556     if (length (my $class = blessed($e) )) {
 557       carp_unique( sprintf(
 558         'External exception class %s implements partial (broken) overloading '
 559       . 'preventing its instances from being used in simple ($x eq $y) '
 560       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 561       . 'handling this type of brokenness is extremely dangerous on '
 562       . 'exception objects, as it may (and often does) result in silent '
 563       . '"exception substitution". DBIx::Class tries to work around this '
 564       . 'as much as possible, but other parts of your software stack may '
 565       . 'not be even aware of this. Please submit a bugreport against the '
 566       . 'distribution containing %s and in the meantime apply a fix similar '
 567       . 'to the one shown at %s, in order to ensure your exception handling '
 568       . 'is saner application-wide. What follows is the actual error text '
 569       . "as generated by Perl itself:\n\n%s\n ",
 570         $class,
 571         $class,
 572         'http://v.gd/DBIC_overload_tempfix/',
 573         $suberror,
 574       ));
 575
 576       # workaround, keeps spice flowing
 577       $not_blank = !!( length $e );
 578     }
 579     else {
 580       # not blessed yet failed the 'ne'... this makes 0 sense...
 581       # just throw further
 582       die $suberror
 583     }
 584   }
 585   elsif (
 586     # a ref evaluating to '' is definitively a "null object"
 587     ( not $not_blank )
 588       and
 589     length( my $class = ref $e )
 590   ) {
 591     carp_unique(
 592       "Objects of external exception class '$class' stringify to '' (the "
 593     . 'empty string), implementing the so called null-object-pattern. '
 594     . 'Given Perl\'s "globally cooperative" exception handling using this '
 595     . 'class of exceptions is extremely dangerous, as it may (and often '
 596     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 597     . 'work around this as much as possible, but other parts of your '
 598     . 'software stack may not be even aware of the problem. Please submit '
 599     . "a bugreport against the distribution containing '$class'",
 600     );
 601
 602     $not_blank = 1;
 603   }
 604
 605   return $not_blank;
 606 }
 607
 608 {
 609   my $callstack_state;
 610
 611   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 612   #
 613   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 614   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 615   sub dbic_internal_try (&;@) {
 616
 617     my $try_cref = shift;
 618     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 619
 620     for my $arg (@_) {
 621
 622       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 623
 624         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 625           if $catch_cref;
 626
 627         $catch_cref = $$arg;
 628       }
 629       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 630         croak 'dbic_internal_try() does not support finally{}';
 631       }
 632       else {
 633         croak(
 634           'dbic_internal_try() encountered an unexpected argument '
 635         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 636         . 'a missing semi-colon before or ' # trailing space important
 637         );
 638       }
 639     }
 640
 641     my $wantarray = wantarray;
 642     my $preexisting_exception = $@;
 643
 644     my @ret;
 645     my $all_good = eval {
 646       $@ = $preexisting_exception;
 647
 648       local $callstack_state->{in_internal_try} = 1
 649         unless $callstack_state->{in_internal_try};
 650
 651       # always unset - someone may have snuck it in
 652       local $SIG{__DIE__} if $SIG{__DIE__};
 653
 654       if( $wantarray ) {
 655         @ret = $try_cref->();
 656       }
 657       elsif( defined $wantarray ) {
 658         $ret[0] = $try_cref->();
 659       }
 660       else {
 661         $try_cref->();
 662       }
 663
 664       1;
 665     };
 666
 667     my $exception = $@;
 668     $@ = $preexisting_exception;
 669
 670     if ( $all_good ) {
 671       return $wantarray ? @ret : $ret[0]
 672     }
 673     elsif ( $catch_cref ) {
 674       for ( $exception ) {
 675         return $catch_cref->($exception);
 676       }
 677     }
 678
 679     return;
 680   }
 681
 682   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 683 }
 684
 685 {
 686   my $destruction_registry = {};
 687
 688   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 689     %$destruction_registry = map {
 690       (defined $_)
 691         ? ( refaddr($_) => $_ )
 692         : ()
 693     } values %$destruction_registry;
 694
 695     weaken($_) for values %$destruction_registry;
 696
 697     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 698     # collected before leaving this scope. Depending on the code above, this
 699     # may very well be just a preventive measure guarding future modifications
 700     undef;
 701   }
 702
 703   # This is almost invariably invoked from within DESTROY
 704   # throwing exceptions won't work
 705   sub detected_reinvoked_destructor {
 706
 707     # quick "garbage collection" pass - prevents the registry
 708     # from slowly growing with a bunch of undef-valued keys
 709     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 710       for keys %$destruction_registry;
 711
 712     if (! length ref $_[0]) {
 713       emit_loud_diag(
 714         emit_dups => 1,
 715         msg => (caller(0))[3] . '() expects a blessed reference'
 716       );
 717       return undef; # don't know wtf to do
 718     }
 719     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 720       weaken( $destruction_registry->{$addr} = $_[0] );
 721       return 0;
 722     }
 723     else {
 724       emit_loud_diag( msg => sprintf (
 725         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 726       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 727       . 'application, affecting *ALL* classes without active protection against '
 728       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 729       refdesc $_[0],
 730         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 731           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 732           : ''
 733         )
 734       ));
 735
 736       return 1;
 737     }
 738   }
 739 }
 740
 741 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 742 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 743
 744 sub modver_gt_or_eq ($$) {
 745   my ($mod, $ver) = @_;
 746
 747   croak "Nonsensical module name supplied"
 748     if ! defined $mod or $mod !~ $module_name_rx;
 749
 750   croak "Nonsensical minimum version supplied"
 751     if ! defined $ver or $ver !~ $ver_rx;
 752
 753   my $ver_cache = do {
 754     no strict 'refs';
 755     ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= {}
 756   };
 757
 758   ! defined $ver_cache->{$ver}
 759     and
 760   $ver_cache->{$ver} = do {
 761
 762     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 763       if SPURIOUS_VERSION_CHECK_WARNINGS;
 764
 765     # prevent captures by potential __WARN__ hooks or the like:
 766     # there is nothing of value that can be happening here, and
 767     # leaving a hook in-place can only serve to fail some test
 768     local $SIG{__WARN__} if (
 769       ! SPURIOUS_VERSION_CHECK_WARNINGS
 770         and
 771       $SIG{__WARN__}
 772     );
 773
 774     croak "$mod does not seem to provide a version (perhaps it never loaded)"
 775       unless $mod->VERSION;
 776
 777     local $SIG{__DIE__} if $SIG{__DIE__};
 778     local $@;
 779     eval { $mod->VERSION($ver) } ? 1 : 0;
 780   };
 781
 782   $ver_cache->{$ver};
 783 }
 784
 785 sub modver_gt_or_eq_and_lt ($$$) {
 786   my ($mod, $v_ge, $v_lt) = @_;
 787
 788   croak "Nonsensical maximum version supplied"
 789     if ! defined $v_lt or $v_lt !~ $ver_rx;
 790
 791   return (
 792     modver_gt_or_eq($mod, $v_ge)
 793       and
 794     ! modver_gt_or_eq($mod, $v_lt)
 795   ) ? 1 : 0;
 796 }
 797
 798 {
 799
 800   sub describe_class_methods {
 801     my $args = (
 802       ref $_[0] eq 'HASH'                 ? $_[0]
 803     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 804     :                                       { @_ }
 805     );
 806
 807     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 808
 809     croak "Expecting a class name either as the sole argument or a 'class' option"
 810       if not defined $class or $class !~ $module_name_rx;
 811
 812     croak(
 813       "The supplied 'class' argument is tainted: this is *extremely* "
 814     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 815     . 'https://is.gd/perl_mro_taint_wtf )'
 816     ) if (
 817       DBIx::Class::_ENV_::TAINT_MODE
 818         and
 819       Scalar::Util::tainted($class)
 820     );
 821
 822     $requested_mro ||= mro::get_mro($class);
 823
 824     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 825     my $query_cache_key = "$class|$requested_mro";
 826
 827     my $internal_cache_key =
 828       ( mro::get_mro($class) eq $requested_mro )
 829         ? $class
 830         : $query_cache_key
 831     ;
 832
 833     # use a cache on old MRO, since while we are recursing in this function
 834     # nothing can possibly change (the speedup is immense)
 835     # (yes, people could be tie()ing the stash and adding methods on access
 836     # but there is a limit to how much crazy can be supported here)
 837     #
 838     # we use the cache for linear_isa lookups on new MRO as well - it adds
 839     # a *tiny* speedup, and simplifies the code a lot
 840     #
 841     local $__describe_class_query_cache->{'!internal!'} = {}
 842       unless $__describe_class_query_cache->{'!internal!'};
 843
 844     my $my_gen = 0;
 845
 846     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 847
 848       @{
 849         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 850           ||=
 851         mro::get_linear_isa($class, $requested_mro)
 852       },
 853
 854       ((
 855         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 856           ||=
 857         mro::is_universal($class)
 858       ) ? () : @{
 859         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 860           ||=
 861         mro::get_linear_isa("UNIVERSAL")
 862       }),
 863
 864     ));
 865
 866     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 867
 868     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 869
 870       # reset
 871       %$slot = (
 872         class => $class,
 873         isa => { map { $_ => 1 } @full_ISA },
 874         linear_isa => [
 875           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 876             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 877         ],
 878         mro => {
 879           type => $requested_mro,
 880           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 881         },
 882         cumulative_gen => $my_gen,
 883       );
 884
 885       # remove ourselves from ISA
 886       shift @full_ISA;
 887
 888       # ensure the cache is populated for the parents, code below can then
 889       # efficiently operate over the query_cache directly
 890       describe_class_methods($_) for reverse @full_ISA;
 891
 892       no strict 'refs';
 893
 894       # combine full ISA-order inherited and local method list into a
 895       # "shadowing stack"
 896
 897       (
 898         unshift @{ $slot->{methods}{$_->{name}} }, $_
 899
 900           and
 901
 902         (
 903           $_->{via_class} ne $class
 904             or
 905           $slot->{methods_defined_in_class}{$_->{name}} = $_
 906         )
 907
 908           and
 909
 910         @{ $slot->{methods}{$_->{name}} } > 1
 911
 912           and
 913
 914         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 915
 916       ) for (
 917
 918         # what describe_class_methods for @full_ISA produced above
 919         ( map { values %{
 920           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 921         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 922
 923         # our own non-cleaned subs + their attributes
 924         ( map {
 925           (
 926             # need to account for dummy helper crefs under OLD_MRO
 927             (
 928               ! DBIx::Class::_ENV_::OLD_MRO
 929                 or
 930               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 931             )
 932               and
 933             # these 2 OR-ed checks are sufficient for 5.10+
 934             (
 935               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 936                 or
 937               defined( *{ "${class}::"->{$_} }{CODE} )
 938             )
 939           ) ? {
 940               via_class => $class,
 941               name => $_,
 942               attributes => { map { $_ => 1 } do {
 943                 my @attrs;
 944                 local $@;
 945                 local $SIG{__DIE__} if $SIG{__DIE__};
 946                 # attributes::get may throw on blessed-false crefs :/
 947                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 948                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 949                 @attrs;
 950               } },
 951             }
 952             : ()
 953         } keys %{"${class}::"} )
 954       );
 955
 956
 957       # recalculate the pkg_gen on newer perls under Taint mode,
 958       # because of shit like:
 959       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 960       #
 961       if (
 962         ! DBIx::Class::_ENV_::OLD_MRO
 963           and
 964         DBIx::Class::_ENV_::TAINT_MODE
 965       ) {
 966
 967         $slot->{cumulative_gen} = 0;
 968         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 969           for $class, @full_ISA;
 970       }
 971     }
 972
 973     # RV
 974     +{ %$slot };
 975   }
 976 }
 977
 978
 979 #
 980 # Why not just use some higher-level module or at least File::Spec here?
 981 # Because:
 982 # 1)  This is a *very* rarely used function, and the deptree is large
 983 #     enough already as it is
 984 #
 985 # 2)  (more importantly) Our tooling is utter shit in this area. There
 986 #     is no comprehensive support for UNC paths in PathTools and there
 987 #     are also various small bugs in representation across different
 988 #     path-manipulation CPAN offerings.
 989 #
 990 # Since this routine is strictly used for logical path processing (it
 991 # *must* be able to work with not-yet-existing paths), use this seemingly
 992 # simple but I *think* complete implementation to feed to other consumers
 993 #
 994 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 995 # the impulse to bring in an external dependency. During runtime there
 996 # is exactly one spot that could potentially maybe once in a blue moon
 997 # use this function. Keep it lean.
 998 #
 999 sub parent_dir ($) {
1000   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
1001     ? (
1002       $_[0]
1003         .
1004       ( ( length($1) and ! length($2) ) ? '/' : '' )
1005         .
1006       '../'
1007     )
1008     : (
1009       require File::Spec
1010         and
1011       File::Spec->catpath (
1012         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
1013         '/',
1014       )
1015     )
1016   ;
1017 }
1018
1019 sub mkdir_p ($) {
1020   require File::Path;
1021   # do not ask for a recent version, use 1.x API calls
1022   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
1023 }
1024
1025
1026 {
1027   my $list_ctx_ok_stack_marker;
1028
1029   sub fail_on_internal_wantarray () {
1030     return if $list_ctx_ok_stack_marker;
1031
1032     if (! defined wantarray) {
1033       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
1034     }
1035
1036     my $cf = 1;
1037     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
1038
1039       # these are public API parts that alter behavior on wantarray
1040       search | search_related | slice | search_literal
1041
1042         |
1043
1044       # these are explicitly prefixed, since we only recognize them as valid
1045       # escapes when they come from the guts of CDBICompat
1046       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1047
1048     ) $/x ) {
1049       $cf++;
1050     }
1051
1052     my ($fr, $want, $argdesc);
1053     {
1054       package DB;
1055       $fr = [ CORE::caller($cf) ];
1056       $want = ( CORE::caller($cf-1) )[5];
1057       $argdesc = ref $DB::args[0]
1058         ? DBIx::Class::_Util::refdesc($DB::args[0])
1059         : 'non '
1060       ;
1061     };
1062
1063     if (
1064       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1065     ) {
1066       DBIx::Class::Exception->throw( sprintf (
1067         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1068         $argdesc, @{$fr}[1,2]
1069       ), 'with_stacktrace');
1070     }
1071
1072     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1073
1074     $mark;
1075   }
1076 }
1077
1078 sub fail_on_internal_call {
1079   my ($fr, $argdesc);
1080   {
1081     package DB;
1082     $fr = [ CORE::caller(1) ];
1083     $argdesc =
1084       ( not defined $DB::args[0] )  ? 'UNAVAILABLE'
1085     : ( length ref $DB::args[0] )   ? DBIx::Class::_Util::refdesc($DB::args[0])
1086     : $DB::args[0] . ''
1087     ;
1088   };
1089
1090   my @fr2;
1091   # need to make allowance for a proxy-yet-direct call
1092   my $check_fr = (
1093     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1094       and
1095     @fr2 = (CORE::caller(2))
1096       and
1097     (
1098       ( $fr->[3] =~ /([^:])+$/ )[0]
1099         eq
1100       ( $fr2[3] =~ /([^:])+$/ )[0]
1101     )
1102   )
1103     ? \@fr2
1104     : $fr
1105   ;
1106
1107
1108   die "\nMethod $fr->[3] is not marked with the 'DBIC_method_is_indirect_sugar' attribute\n\n" unless (
1109
1110     # unlikely but who knows...
1111     ! @$fr
1112
1113       or
1114
1115     # This is a weird-ass double-purpose method, only one branch of which is marked
1116     # as an illegal indirect call
1117     # Hence the 'indirect' attribute makes no sense
1118     # FIXME - likely need to mark this in some other manner
1119     $fr->[3] eq 'DBIx::Class::ResultSet::new'
1120
1121       or
1122
1123     # RsrcProxy stuff is special and not attr-annotated on purpose
1124     # Yet it is marked (correctly) as fail_on_internal_call(), as DBIC
1125     # itself should not call these methods as first-entry
1126     $fr->[3] =~ /^DBIx::Class::ResultSourceProxy::[^:]+$/
1127
1128       or
1129
1130     # FIXME - there is likely a more fine-graned way to escape "foreign"
1131     # callers, based on annotations... (albeit a slower one)
1132     # For the time being just skip in a dumb way
1133     $fr->[3] !~ /^DBIx::Class|^DBICx::|^DBICTest::/
1134
1135       or
1136
1137     grep
1138       { $_ eq 'DBIC_method_is_indirect_sugar' }
1139       do { no strict 'refs'; attributes::get( \&{ $fr->[3] }) }
1140   );
1141
1142
1143   if (
1144     defined $fr->[0]
1145       and
1146     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1147       and
1148     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1149   ) {
1150     DBIx::Class::Exception->throw( sprintf (
1151       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1152       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1153         require B::Deparse;
1154         no strict 'refs';
1155         B::Deparse->new->coderef2text(\&{$fr->[3]})
1156       }),
1157     ), 'with_stacktrace');
1158   }
1159 }
1160
1161 if (DBIx::Class::_ENV_::ASSERT_NO_ERRONEOUS_METAINSTANCE_USE) {
1162
1163   no warnings 'redefine';
1164
1165   my $next_bless = defined(&CORE::GLOBAL::bless)
1166     ? \&CORE::GLOBAL::bless
1167     : sub { CORE::bless($_[0], $_[1]) }
1168   ;
1169
1170   *CORE::GLOBAL::bless = sub {
1171     my $class = (@_ > 1) ? $_[1] : CORE::caller();
1172
1173     # allow for reblessing (role application)
1174     return $next_bless->( $_[0], $class )
1175       if defined blessed $_[0];
1176
1177     my $obj = $next_bless->( $_[0], $class );
1178
1179     my $calling_sub = (CORE::caller(1))[3] || '';
1180
1181     (
1182       # before 5.18 ->isa() will choke on the "0" package
1183       # which we test for in several obscure cases, sigh...
1184       !( DBIx::Class::_ENV_::PERL_VERSION < 5.018 )
1185         or
1186       $class
1187     )
1188       and
1189     (
1190       (
1191         $calling_sub !~ /^ (?:
1192           DBIx::Class::Schema::clone
1193             |
1194           DBIx::Class::DB::setup_schema_instance
1195         )/x
1196           and
1197         $class->isa("DBIx::Class::Schema")
1198       )
1199         or
1200       (
1201         $calling_sub ne 'DBIx::Class::ResultSource::new'
1202           and
1203         $class->isa("DBIx::Class::ResultSource")
1204       )
1205     )
1206       and
1207     local $Carp::CarpLevel = $Carp::CarpLevel + 1
1208       and
1209     Carp::confess("Improper instantiation of '$obj': you *MUST* call the corresponding constructor");
1210
1211
1212     $obj;
1213   };
1214 }
1215
1216 1;