lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  21
  22     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  23     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  24
  25     # During 5.13 dev cycle HELEMs started to leak on copy
  26     # add an escape for these perls ON SMOKERS - a user will still get death
  27     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  28
  29     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  30
  31     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  32
  33     IV_SIZE => $Config{ivsize},
  34
  35     OS_NAME => $^O,
  36   };
  37
  38   if ($] < 5.009_005) {
  39     require MRO::Compat;
  40     constant->import( OLD_MRO => 1 );
  41   }
  42   else {
  43     require mro;
  44     constant->import( OLD_MRO => 0 );
  45   }
  46 }
  47
  48 # FIXME - this is not supposed to be here
  49 # Carp::Skip to the rescue soon
  50 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  51
  52 use Carp 'croak';
  53 use Scalar::Util qw(weaken blessed reftype);
  54 use List::Util qw(first);
  55 use overload ();
  56
  57 use base 'Exporter';
  58 our @EXPORT_OK = qw(
  59   sigwarn_silencer modver_gt_or_eq fail_on_internal_wantarray
  60   refcount hrefaddr is_exception
  61   is_plain_value is_literal_value
  62 );
  63
  64 sub sigwarn_silencer ($) {
  65   my $pattern = shift;
  66
  67   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  68
  69   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  70
  71   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  72 }
  73
  74 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr }
  75
  76 sub refcount ($) {
  77   croak "Expecting a reference" if ! length ref $_[0];
  78
  79   require B;
  80   # No tempvars - must operate on $_[0], otherwise the pad
  81   # will count as an extra ref
  82   B::svref_2object($_[0])->REFCNT;
  83 }
  84
  85 sub is_exception ($) {
  86   my $e = $_[0];
  87
  88   # this is not strictly correct - an eval setting $@ to undef
  89   # is *not* the same as an eval setting $@ to ''
  90   # but for the sake of simplicity assume the following for
  91   # the time being
  92   return 0 unless defined $e;
  93
  94   my ($not_blank, $suberror);
  95   {
  96     local $@;
  97     eval {
  98       $not_blank = ($e ne '') ? 1 : 0;
  99       1;
 100     } or $suberror = $@;
 101   }
 102
 103   if (defined $suberror) {
 104     if (length (my $class = blessed($e) )) {
 105       carp_unique( sprintf(
 106         'External exception object %s=%s(%s) implements partial (broken) '
 107       . 'overloading preventing it from being used in simple ($x eq $y) '
 108       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 109       . 'handling this type of brokenness is extremely dangerous on '
 110       . 'exception objects, as it may (and often does) result in silent '
 111       . '"exception substitution". DBIx::Class tries to work around this '
 112       . 'as much as possible, but other parts of your software stack may '
 113       . 'not be even aware of this. Please submit a bugreport against the '
 114       . 'distribution containing %s and in the meantime apply a fix similar '
 115       . 'to the one shown at %s, in order to ensure your exception handling '
 116       . 'is saner application-wide. What follows is the actual error text '
 117       . "as generated by Perl itself:\n\n%s\n ",
 118         $class,
 119         reftype $e,
 120         hrefaddr $e,
 121         $class,
 122         'http://v.gd/DBIC_overload_tempfix/',
 123         $suberror,
 124       ));
 125
 126       # workaround, keeps spice flowing
 127       $not_blank = ("$e" ne '') ? 1 : 0;
 128     }
 129     else {
 130       # not blessed yet failed the 'ne'... this makes 0 sense...
 131       # just throw further
 132       die $suberror
 133     }
 134   }
 135
 136   return $not_blank;
 137 }
 138
 139 sub modver_gt_or_eq ($$) {
 140   my ($mod, $ver) = @_;
 141
 142   croak "Nonsensical module name supplied"
 143     if ! defined $mod or ! length $mod;
 144
 145   croak "Nonsensical minimum version supplied"
 146     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 147
 148   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 149     if SPURIOUS_VERSION_CHECK_WARNINGS;
 150
 151   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 152     unless $mod->VERSION;
 153
 154   local $@;
 155   eval { $mod->VERSION($ver) } ? 1 : 0;
 156 }
 157
 158 sub is_literal_value ($) {
 159   (
 160     ref $_[0] eq 'SCALAR'
 161       or
 162     ( ref $_[0] eq 'REF' and ref ${$_[0]} eq 'ARRAY' )
 163   ) ? 1 : 0;
 164 }
 165
 166 # FIXME XSify - this can be done so much more efficiently
 167 sub is_plain_value ($) {
 168   no strict 'refs';
 169   (
 170     # plain scalar
 171     (! length ref $_[0])
 172       or
 173     (
 174       blessed $_[0]
 175         and
 176       # deliberately not using Devel::OverloadInfo - the checks we are
 177       # intersted in are much more limited than the fullblown thing, and
 178       # this is a relatively hot piece of code
 179       (
 180         # FIXME - DBI needs fixing to stringify regardless of DBD
 181         #
 182         # either has stringification which DBI SHOULD prefer out of the box
 183         #first { *{$_ . '::(""'}{CODE} } @{ mro::get_linear_isa( ref $_[0] ) }
 184         overload::Method($_[0], '""')
 185           or
 186         # has nummification and fallback is *not* disabled
 187         (
 188           $_[1] = first { *{"${_}::(0+"}{CODE} } @{ mro::get_linear_isa( ref $_[0] ) }
 189             and
 190           ( ! defined ${"$_[1]::()"} or ${"$_[1]::()"} )
 191         )
 192       )
 193     )
 194   ) ? 1 : 0;
 195 }
 196
 197 {
 198   my $list_ctx_ok_stack_marker;
 199
 200   sub fail_on_internal_wantarray {
 201     return if $list_ctx_ok_stack_marker;
 202
 203     if (! defined wantarray) {
 204       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 205     }
 206
 207     my $cf = 1;
 208     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 209
 210       # these are public API parts that alter behavior on wantarray
 211       search | search_related | slice | search_literal
 212
 213         |
 214
 215       # these are explicitly prefixed, since we only recognize them as valid
 216       # escapes when they come from the guts of CDBICompat
 217       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 218
 219     ) $/x ) {
 220       $cf++;
 221     }
 222
 223     if (
 224       (caller($cf))[0] =~ /^(?:DBIx::Class|DBICx::)/
 225     ) {
 226       my $obj = shift;
 227
 228       DBIx::Class::Exception->throw( sprintf (
 229         "Improper use of %s(%s) instance in list context at %s line %d\n\n\tStacktrace starts",
 230         ref($obj), hrefaddr($obj), (caller($cf))[1,2]
 231       ), 'with_stacktrace');
 232     }
 233
 234     my $mark = [];
 235     weaken ( $list_ctx_ok_stack_marker = $mark );
 236     $mark;
 237   }
 238 }
 239
 240 1;