lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 # For the love of everything that is crab-like: DO NOT reach into this
  10 # The entire thing is really fragile and should not be screwed with
  11 # unless absolutely and unavoidably necessary
  12 our $__describe_class_query_cache;
  13
  14 BEGIN {
  15   package # hide from pause
  16     DBIx::Class::_ENV_;
  17
  18   use Config;
  19
  20   use constant {
  21     PERL_VERSION => "$]",
  22     OS_NAME => "$^O",
  23   };
  24
  25   use constant {
  26
  27     # but of course
  28     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  29
  30     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  31
  32     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  33     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  34
  35     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  36
  37     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  38
  39     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  40
  41     ( map
  42       #
  43       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  44       # all envvars without further adjusting its scripts
  45       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  46       #
  47       { substr($_, 5) => !!( $ENV{$_} ) }
  48       qw(
  49         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  50         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  51         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  52         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  53         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  54       )
  55     ),
  56
  57     IV_SIZE => $Config{ivsize},
  58   };
  59
  60   if ( PERL_VERSION < 5.009_005) {
  61     require MRO::Compat;
  62     constant->import( OLD_MRO => 1 );
  63
  64     #
  65     # Yes, I know this is a rather PHP-ish name, but please first read
  66     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  67     #
  68     # Even if we are using Class::C3::XS it still won't work, as doing
  69     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  70     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  71     #
  72     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  73       require Digest::MD5;
  74       require Math::BigInt;
  75
  76       my $cur_class;
  77       no strict 'refs';
  78
  79       # the non-assign-unless-there-is-a-hash is deliberate
  80       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  81         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  82
  83           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  84
  85             $cur_class = $_
  86
  87               and
  88
  89             # RV to be hashed up and turned into a number
  90             join "\0", (
  91               $cur_class,
  92               map
  93                 {(
  94                   # stringification should be sufficient, ignore names/refaddr entirely
  95                   $_,
  96                   do {
  97                     my @attrs;
  98                     local $@;
  99                     local $SIG{__DIE__} if $SIG{__DIE__};
 100                     # attributes::get may throw on blessed-false crefs :/
 101                     eval { @attrs = attributes::get( $_ ); 1 }
 102                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 103                     @attrs;
 104                   },
 105                 )}
 106                 map
 107                   {(
 108                     # skip dummy C::C3 helper crefs
 109                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 110                       and
 111                     (
 112                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 113                         or
 114                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 115                     )
 116                   )
 117                     ? ( \&{"${cur_class}::$_"} )
 118                     : ()
 119                   }
 120                   keys %{ "${cur_class}::" }
 121             )
 122           )
 123         } (
 124
 125           @{
 126             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 127               ||=
 128             mro::get_linear_isa($_[0])
 129           },
 130
 131           ((
 132             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 133               ||=
 134             mro::is_universal($_[0])
 135           ) ? () : @{
 136             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 137               ||=
 138             mro::get_linear_isa("UNIVERSAL")
 139           } ),
 140
 141         ) ) ) )
 142       );
 143     };
 144   }
 145   else {
 146     require mro;
 147     constant->import( OLD_MRO => 0 );
 148     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 149   }
 150
 151   # Both of these are no longer used for anything. However bring
 152   # them back after they were purged in 08a8d8f1, as there appear
 153   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 154   # in their production codebases. There is no point in breaking these
 155   # if whatever they used actually continues to work
 156   my $sigh = sub {
 157     DBIx::Class::_Util::emit_loud_diag(
 158       skip_frames => 1,
 159       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 160     );
 161
 162     0;
 163   };
 164   sub DBICTEST () { &$sigh }
 165   sub PEEPEENESS () { &$sigh }
 166 }
 167
 168 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 169
 170 # FIXME - this is not supposed to be here
 171 # Carp::Skip to the rescue soon
 172 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 173
 174 use B ();
 175 use Carp 'croak';
 176 use Storable 'nfreeze';
 177 use Scalar::Util qw(weaken blessed reftype refaddr);
 178 use Sub::Name ();
 179 use attributes ();
 180
 181 # Usually versions are not specified anywhere aside the Makefile.PL
 182 # (writing them out in-code is extremely obnoxious)
 183 # However without a recent enough Moo the quote_sub override fails
 184 # in very puzzling and hard to detect ways: so add a version check
 185 # just this once
 186 use Sub::Quote qw(qsub);
 187 BEGIN { Sub::Quote->VERSION('2.002002') }
 188
 189 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 190 BEGIN { *deep_clone = \&Storable::dclone }
 191
 192 use base 'Exporter';
 193 our @EXPORT_OK = qw(
 194   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 195   fail_on_internal_wantarray fail_on_internal_call
 196   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 197   scope_guard detected_reinvoked_destructor emit_loud_diag
 198   true false
 199   is_exception dbic_internal_try visit_namespaces
 200   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 201   parent_dir mkdir_p
 202   UNRESOLVABLE_CONDITION
 203 );
 204
 205 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 206
 207 # Override forcing no_defer, and adding naming consistency checks
 208 our %refs_closed_over_by_quote_sub_installed_crefs;
 209 sub quote_sub {
 210   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 211     @_ < 2
 212       or
 213     ! defined $_[1]
 214       or
 215     length ref $_[1]
 216   ;
 217
 218   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 219     unless (my $stash) = $_[0] =~ /^(.+)::/;
 220
 221   Carp::confess(
 222     "The DBIC sub_quote override does not support 'no_install'"
 223   ) if (
 224     $_[3]
 225       and
 226     $_[3]->{no_install}
 227   );
 228
 229   Carp::confess(
 230     'The DBIC quote_sub override expects the namespace-part of sub name '
 231   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 232   ) if (
 233     $_[3]
 234       and
 235     defined $_[3]->{package}
 236       and
 237     $stash ne $_[3]->{package}
 238   );
 239
 240   my @caller = caller(0);
 241   my $sq_opts = {
 242     package => $caller[0],
 243     hints => $caller[8],
 244     warning_bits => $caller[9],
 245     hintshash => $caller[10],
 246     %{ $_[3] || {} },
 247
 248     # explicitly forced for everything
 249     no_defer => 1,
 250   };
 251
 252   weaken (
 253     # just use a growing counter, no need to perform neither compaction
 254     # nor any special ithread-level handling
 255     $refs_closed_over_by_quote_sub_installed_crefs
 256      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 257       = $_
 258   ) for grep {
 259     length ref $_
 260       and
 261     (
 262       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 263         or
 264       ref $_ ne 'SCALAR'
 265     )
 266   } values %{ $_[2] || {} };
 267
 268   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 269 }
 270
 271 sub sigwarn_silencer ($) {
 272   my $pattern = shift;
 273
 274   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 275
 276   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 277
 278   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 279 }
 280
 281 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 282
 283 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 284
 285 sub refdesc ($) {
 286   croak "Expecting a reference" if ! length ref $_[0];
 287
 288   # be careful not to trigger stringification,
 289   # reuse @_ as a scratch-pad
 290   sprintf '%s%s(0x%x)',
 291     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 292     reftype $_[0],
 293     refaddr($_[0]),
 294   ;
 295 }
 296
 297 sub refcount ($) {
 298   croak "Expecting a reference" if ! length ref $_[0];
 299
 300   # No tempvars - must operate on $_[0], otherwise the pad
 301   # will count as an extra ref
 302   B::svref_2object($_[0])->REFCNT;
 303 }
 304
 305 sub visit_namespaces {
 306   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 307
 308   my $visited_count = 1;
 309
 310   # A package and a namespace are subtly different things
 311   $args->{package} ||= 'main';
 312   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 313   $args->{package} =~ s/^:://;
 314
 315   if ( $args->{action}->($args->{package}) ) {
 316     my $ns =
 317       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 318         .
 319       '::'
 320     ;
 321
 322     $visited_count += visit_namespaces( %$args, package => $_ ) for
 323       grep
 324         # this happens sometimes on %:: traversal
 325         { $_ ne '::main' }
 326         map
 327           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 328           do { no strict 'refs'; keys %$ns }
 329     ;
 330   }
 331
 332   $visited_count;
 333 }
 334
 335 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 336 sub get_subname ($) {
 337   my $gv = B::svref_2object( $_[0] )->GV;
 338   wantarray
 339     ? ( $gv->STASH->NAME, $gv->NAME )
 340     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 341   ;
 342 }
 343 sub set_subname ($$) {
 344
 345   # fully qualify name
 346   splice @_, 0, 1, caller(0) . "::$_[0]"
 347     if $_[0] !~ /::|'/;
 348
 349   &Sub::Name::subname;
 350 }
 351
 352 sub serialize ($) {
 353   local $Storable::canonical = 1;
 354   nfreeze($_[0]);
 355 }
 356
 357 sub uniq {
 358   my( %seen, $seen_undef, $numeric_preserving_copy );
 359   grep { not (
 360     defined $_
 361       ? $seen{ $numeric_preserving_copy = $_ }++
 362       : $seen_undef++
 363   ) } @_;
 364 }
 365
 366 my $dd_obj;
 367 sub dump_value ($) {
 368   local $Data::Dumper::Indent = 1
 369     unless defined $Data::Dumper::Indent;
 370
 371   my $dump_str = (
 372     $dd_obj
 373       ||=
 374     do {
 375       require Data::Dumper;
 376       my $d = Data::Dumper->new([])
 377         ->Purity(0)
 378         ->Pad('')
 379         ->Useqq(1)
 380         ->Terse(1)
 381         ->Freezer('')
 382         ->Quotekeys(0)
 383         ->Bless('bless')
 384         ->Pair(' => ')
 385         ->Sortkeys(1)
 386         ->Deparse(1)
 387       ;
 388
 389       $d->Sparseseen(1) if modver_gt_or_eq (
 390         'Data::Dumper', '2.136'
 391       );
 392
 393       $d;
 394     }
 395   )->Values([$_[0]])->Dump;
 396
 397   $dd_obj->Reset->Values([]);
 398
 399   $dump_str;
 400 }
 401
 402 my $seen_loud_screams;
 403 sub emit_loud_diag {
 404   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 405
 406   unless ( defined $args->{msg} and length $args->{msg} ) {
 407     emit_loud_diag(
 408       msg => "No 'msg' value supplied to emit_loud_diag()"
 409     );
 410     exit 70;
 411   }
 412
 413   my $msg = "\n$0: $args->{msg}";
 414
 415   # when we die - we usually want to keep doing it
 416   $args->{emit_dups} = !!$args->{confess}
 417     unless exists $args->{emit_dups};
 418
 419   local $Carp::CarpLevel =
 420     ( $args->{skip_frames} || 0 )
 421       +
 422     $Carp::CarpLevel
 423       +
 424     # hide our own frame
 425     1
 426   ;
 427
 428   my $longmess = Carp::longmess();
 429
 430   # different object references will thwart deduplication without this
 431   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 432
 433   return $seen_loud_screams->{$key} if
 434     $seen_loud_screams->{$key}++
 435       and
 436     ! $args->{emit_dups}
 437   ;
 438
 439   $msg .= $longmess
 440     unless $msg =~ /\n\z/;
 441
 442   print STDERR "$msg\n"
 443     or
 444   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 445
 446   return $seen_loud_screams->{$key}
 447     unless $args->{confess};
 448
 449   # increment *again*, because... Carp.
 450   $Carp::CarpLevel++;
 451
 452   # not $msg - Carp will reapply the longmess on its own
 453   Carp::confess($args->{msg});
 454 }
 455
 456
 457 ###
 458 ### This is *NOT* boolean.pm - deliberately not using a singleton
 459 ###
 460 {
 461   package # hide from pause
 462     DBIx::Class::_Util::_Bool;
 463   use overload
 464     bool => sub { ${$_[0]} },
 465     fallback => 1,
 466   ;
 467 }
 468 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 469 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 470
 471 sub scope_guard (&) {
 472   croak 'Calling scope_guard() in void context makes no sense'
 473     if ! defined wantarray;
 474
 475   # no direct blessing of coderefs - DESTROY is buggy on those
 476   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 477 }
 478 {
 479   package #
 480     DBIx::Class::_Util::ScopeGuard;
 481
 482   sub DESTROY {
 483     &DBIx::Class::_Util::detected_reinvoked_destructor;
 484
 485     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 486
 487     eval {
 488       $_[0]->[0]->();
 489       1;
 490     }
 491       or
 492     DBIx::Class::_Util::emit_loud_diag(
 493       emit_dups => 1,
 494       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 495     );
 496   }
 497 }
 498
 499
 500 sub is_exception ($) {
 501   my $e = $_[0];
 502
 503   # FIXME
 504   # this is not strictly correct - an eval setting $@ to undef
 505   # is *not* the same as an eval setting $@ to ''
 506   # but for the sake of simplicity assume the following for
 507   # the time being
 508   return 0 unless defined $e;
 509
 510   my ($not_blank, $suberror);
 511   {
 512     local $SIG{__DIE__} if $SIG{__DIE__};
 513     local $@;
 514     eval {
 515       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 516       # will entirely obviate the need for the encolsing eval{}, as the
 517       # condition we guard against is a missing fallback overload
 518       $not_blank = ( $e ne '' );
 519       1;
 520     } or $suberror = $@;
 521   }
 522
 523   if (defined $suberror) {
 524     if (length (my $class = blessed($e) )) {
 525       carp_unique( sprintf(
 526         'External exception class %s implements partial (broken) overloading '
 527       . 'preventing its instances from being used in simple ($x eq $y) '
 528       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 529       . 'handling this type of brokenness is extremely dangerous on '
 530       . 'exception objects, as it may (and often does) result in silent '
 531       . '"exception substitution". DBIx::Class tries to work around this '
 532       . 'as much as possible, but other parts of your software stack may '
 533       . 'not be even aware of this. Please submit a bugreport against the '
 534       . 'distribution containing %s and in the meantime apply a fix similar '
 535       . 'to the one shown at %s, in order to ensure your exception handling '
 536       . 'is saner application-wide. What follows is the actual error text '
 537       . "as generated by Perl itself:\n\n%s\n ",
 538         $class,
 539         $class,
 540         'http://v.gd/DBIC_overload_tempfix/',
 541         $suberror,
 542       ));
 543
 544       # workaround, keeps spice flowing
 545       $not_blank = !!( length $e );
 546     }
 547     else {
 548       # not blessed yet failed the 'ne'... this makes 0 sense...
 549       # just throw further
 550       die $suberror
 551     }
 552   }
 553   elsif (
 554     # a ref evaluating to '' is definitively a "null object"
 555     ( not $not_blank )
 556       and
 557     length( my $class = ref $e )
 558   ) {
 559     carp_unique(
 560       "Objects of external exception class '$class' stringify to '' (the "
 561     . 'empty string), implementing the so called null-object-pattern. '
 562     . 'Given Perl\'s "globally cooperative" exception handling using this '
 563     . 'class of exceptions is extremely dangerous, as it may (and often '
 564     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 565     . 'work around this as much as possible, but other parts of your '
 566     . 'software stack may not be even aware of the problem. Please submit '
 567     . "a bugreport against the distribution containing '$class'",
 568     );
 569
 570     $not_blank = 1;
 571   }
 572
 573   return $not_blank;
 574 }
 575
 576 {
 577   my $callstack_state;
 578
 579   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 580   #
 581   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 582   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 583   sub dbic_internal_try (&;@) {
 584
 585     my $try_cref = shift;
 586     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 587
 588     for my $arg (@_) {
 589
 590       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 591
 592         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 593           if $catch_cref;
 594
 595         $catch_cref = $$arg;
 596       }
 597       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 598         croak 'dbic_internal_try() does not support finally{}';
 599       }
 600       else {
 601         croak(
 602           'dbic_internal_try() encountered an unexpected argument '
 603         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 604         . 'a missing semi-colon before or ' # trailing space important
 605         );
 606       }
 607     }
 608
 609     my $wantarray = wantarray;
 610     my $preexisting_exception = $@;
 611
 612     my @ret;
 613     my $all_good = eval {
 614       $@ = $preexisting_exception;
 615
 616       local $callstack_state->{in_internal_try} = 1
 617         unless $callstack_state->{in_internal_try};
 618
 619       # always unset - someone may have snuck it in
 620       local $SIG{__DIE__} if $SIG{__DIE__};
 621
 622       if( $wantarray ) {
 623         @ret = $try_cref->();
 624       }
 625       elsif( defined $wantarray ) {
 626         $ret[0] = $try_cref->();
 627       }
 628       else {
 629         $try_cref->();
 630       }
 631
 632       1;
 633     };
 634
 635     my $exception = $@;
 636     $@ = $preexisting_exception;
 637
 638     if ( $all_good ) {
 639       return $wantarray ? @ret : $ret[0]
 640     }
 641     elsif ( $catch_cref ) {
 642       for ( $exception ) {
 643         return $catch_cref->($exception);
 644       }
 645     }
 646
 647     return;
 648   }
 649
 650   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 651 }
 652
 653 {
 654   my $destruction_registry = {};
 655
 656   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 657     %$destruction_registry = map {
 658       (defined $_)
 659         ? ( refaddr($_) => $_ )
 660         : ()
 661     } values %$destruction_registry;
 662
 663     weaken($_) for values %$destruction_registry;
 664
 665     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 666     # collected before leaving this scope. Depending on the code above, this
 667     # may very well be just a preventive measure guarding future modifications
 668     undef;
 669   }
 670
 671   # This is almost invariably invoked from within DESTROY
 672   # throwing exceptions won't work
 673   sub detected_reinvoked_destructor {
 674
 675     # quick "garbage collection" pass - prevents the registry
 676     # from slowly growing with a bunch of undef-valued keys
 677     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 678       for keys %$destruction_registry;
 679
 680     if (! length ref $_[0]) {
 681       emit_loud_diag(
 682         emit_dups => 1,
 683         msg => (caller(0))[3] . '() expects a blessed reference'
 684       );
 685       return undef; # don't know wtf to do
 686     }
 687     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 688       weaken( $destruction_registry->{$addr} = $_[0] );
 689       return 0;
 690     }
 691     else {
 692       emit_loud_diag( msg => sprintf (
 693         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 694       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 695       . 'application, affecting *ALL* classes without active protection against '
 696       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 697       refdesc $_[0],
 698         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 699           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 700           : ''
 701         )
 702       ));
 703
 704       return 1;
 705     }
 706   }
 707 }
 708
 709 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 710 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 711
 712 sub modver_gt_or_eq ($$) {
 713   my ($mod, $ver) = @_;
 714
 715   croak "Nonsensical module name supplied"
 716     if ! defined $mod or $mod !~ $module_name_rx;
 717
 718   croak "Nonsensical minimum version supplied"
 719     if ! defined $ver or $ver !~ $ver_rx;
 720
 721   no strict 'refs';
 722   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 723     ? {}
 724     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 725   );
 726
 727   ! defined $ver_cache->{$ver}
 728     and
 729   $ver_cache->{$ver} = do {
 730
 731     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 732       if SPURIOUS_VERSION_CHECK_WARNINGS;
 733
 734     local $SIG{__DIE__} if $SIG{__DIE__};
 735     local $@;
 736     eval { $mod->VERSION($ver) } ? 1 : 0;
 737   };
 738
 739   $ver_cache->{$ver};
 740 }
 741
 742 sub modver_gt_or_eq_and_lt ($$$) {
 743   my ($mod, $v_ge, $v_lt) = @_;
 744
 745   croak "Nonsensical maximum version supplied"
 746     if ! defined $v_lt or $v_lt !~ $ver_rx;
 747
 748   return (
 749     modver_gt_or_eq($mod, $v_ge)
 750       and
 751     ! modver_gt_or_eq($mod, $v_lt)
 752   ) ? 1 : 0;
 753 }
 754
 755 {
 756
 757   sub describe_class_methods {
 758     my $args = (
 759       ref $_[0] eq 'HASH'                 ? $_[0]
 760     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 761     :                                       { @_ }
 762     );
 763
 764     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 765
 766     croak "Expecting a class name either as the sole argument or a 'class' option"
 767       if not defined $class or $class !~ $module_name_rx;
 768
 769     croak(
 770       "The supplied 'class' argument is tainted: this is *extremely* "
 771     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 772     . 'https://is.gd/perl_mro_taint_wtf )'
 773     ) if (
 774       DBIx::Class::_ENV_::TAINT_MODE
 775         and
 776       Scalar::Util::tainted($class)
 777     );
 778
 779     $requested_mro ||= mro::get_mro($class);
 780
 781     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 782     my $query_cache_key = "$class|$requested_mro";
 783
 784     my $internal_cache_key =
 785       ( mro::get_mro($class) eq $requested_mro )
 786         ? $class
 787         : $query_cache_key
 788     ;
 789
 790     # use a cache on old MRO, since while we are recursing in this function
 791     # nothing can possibly change (the speedup is immense)
 792     # (yes, people could be tie()ing the stash and adding methods on access
 793     # but there is a limit to how much crazy can be supported here)
 794     #
 795     # we use the cache for linear_isa lookups on new MRO as well - it adds
 796     # a *tiny* speedup, and simplifies the code a lot
 797     #
 798     local $__describe_class_query_cache->{'!internal!'} = {}
 799       unless $__describe_class_query_cache->{'!internal!'};
 800
 801     my $my_gen = 0;
 802
 803     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 804
 805       @{
 806         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 807           ||=
 808         mro::get_linear_isa($class, $requested_mro)
 809       },
 810
 811       ((
 812         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 813           ||=
 814         mro::is_universal($class)
 815       ) ? () : @{
 816         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 817           ||=
 818         mro::get_linear_isa("UNIVERSAL")
 819       }),
 820
 821     ));
 822
 823     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 824
 825     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 826
 827       # reset
 828       %$slot = (
 829         class => $class,
 830         isa => { map { $_ => 1 } @full_ISA },
 831         linear_isa => [
 832           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 833             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 834         ],
 835         mro => {
 836           type => $requested_mro,
 837           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 838         },
 839         cumulative_gen => $my_gen,
 840       );
 841
 842       # remove ourselves from ISA
 843       shift @full_ISA;
 844
 845       # ensure the cache is populated for the parents, code below can then
 846       # efficiently operate over the query_cache directly
 847       describe_class_methods($_) for reverse @full_ISA;
 848
 849       no strict 'refs';
 850
 851       # combine full ISA-order inherited and local method list into a
 852       # "shadowing stack"
 853
 854       (
 855         unshift @{ $slot->{methods}{$_->{name}} }, $_
 856
 857           and
 858
 859         (
 860           $_->{via_class} ne $class
 861             or
 862           $slot->{methods_defined_in_class}{$_->{name}} = $_
 863         )
 864
 865           and
 866
 867         @{ $slot->{methods}{$_->{name}} } > 1
 868
 869           and
 870
 871         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 872
 873       ) for (
 874
 875         # what describe_class_methods for @full_ISA produced above
 876         ( map { values %{
 877           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 878         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 879
 880         # our own non-cleaned subs + their attributes
 881         ( map {
 882           (
 883             # need to account for dummy helper crefs under OLD_MRO
 884             (
 885               ! DBIx::Class::_ENV_::OLD_MRO
 886                 or
 887               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 888             )
 889               and
 890             # these 2 OR-ed checks are sufficient for 5.10+
 891             (
 892               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 893                 or
 894               defined( *{ "${class}::"->{$_} }{CODE} )
 895             )
 896           ) ? {
 897               via_class => $class,
 898               name => $_,
 899               attributes => { map { $_ => 1 } do {
 900                 my @attrs;
 901                 local $@;
 902                 local $SIG{__DIE__} if $SIG{__DIE__};
 903                 # attributes::get may throw on blessed-false crefs :/
 904                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 905                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 906                 @attrs;
 907               } },
 908             }
 909             : ()
 910         } keys %{"${class}::"} )
 911       );
 912
 913
 914       # recalculate the pkg_gen on newer perls under Taint mode,
 915       # because of shit like:
 916       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 917       #
 918       if (
 919         ! DBIx::Class::_ENV_::OLD_MRO
 920           and
 921         DBIx::Class::_ENV_::TAINT_MODE
 922       ) {
 923
 924         $slot->{cumulative_gen} = 0;
 925         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 926           for $class, @full_ISA;
 927       }
 928     }
 929
 930     # RV
 931     +{ %$slot };
 932   }
 933 }
 934
 935
 936 #
 937 # Why not just use some higher-level module or at least File::Spec here?
 938 # Because:
 939 # 1)  This is a *very* rarely used function, and the deptree is large
 940 #     enough already as it is
 941 #
 942 # 2)  (more importantly) Our tooling is utter shit in this area. There
 943 #     is no comprehensive support for UNC paths in PathTools and there
 944 #     are also various small bugs in representation across different
 945 #     path-manipulation CPAN offerings.
 946 #
 947 # Since this routine is strictly used for logical path processing (it
 948 # *must* be able to work with not-yet-existing paths), use this seemingly
 949 # simple but I *think* complete implementation to feed to other consumers
 950 #
 951 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 952 # the impulse to bring in an external dependency. During runtime there
 953 # is exactly one spot that could potentially maybe once in a blue moon
 954 # use this function. Keep it lean.
 955 #
 956 sub parent_dir ($) {
 957   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 958     ? (
 959       $_[0]
 960         .
 961       ( ( length($1) and ! length($2) ) ? '/' : '' )
 962         .
 963       '../'
 964     )
 965     : (
 966       require File::Spec
 967         and
 968       File::Spec->catpath (
 969         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 970         '/',
 971       )
 972     )
 973   ;
 974 }
 975
 976 sub mkdir_p ($) {
 977   require File::Path;
 978   # do not ask for a recent version, use 1.x API calls
 979   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 980 }
 981
 982
 983 {
 984   my $list_ctx_ok_stack_marker;
 985
 986   sub fail_on_internal_wantarray () {
 987     return if $list_ctx_ok_stack_marker;
 988
 989     if (! defined wantarray) {
 990       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 991     }
 992
 993     my $cf = 1;
 994     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 995
 996       # these are public API parts that alter behavior on wantarray
 997       search | search_related | slice | search_literal
 998
 999         |
1000
1001       # these are explicitly prefixed, since we only recognize them as valid
1002       # escapes when they come from the guts of CDBICompat
1003       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1004
1005     ) $/x ) {
1006       $cf++;
1007     }
1008
1009     my ($fr, $want, $argdesc);
1010     {
1011       package DB;
1012       $fr = [ CORE::caller($cf) ];
1013       $want = ( CORE::caller($cf-1) )[5];
1014       $argdesc = ref $DB::args[0]
1015         ? DBIx::Class::_Util::refdesc($DB::args[0])
1016         : 'non '
1017       ;
1018     };
1019
1020     if (
1021       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1022     ) {
1023       DBIx::Class::Exception->throw( sprintf (
1024         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1025         $argdesc, @{$fr}[1,2]
1026       ), 'with_stacktrace');
1027     }
1028
1029     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1030
1031     $mark;
1032   }
1033 }
1034
1035 sub fail_on_internal_call {
1036   my ($fr, $argdesc);
1037   {
1038     package DB;
1039     $fr = [ CORE::caller(1) ];
1040     $argdesc = ref $DB::args[0]
1041       ? DBIx::Class::_Util::refdesc($DB::args[0])
1042       : ( $DB::args[0] . '' )
1043     ;
1044   };
1045
1046   my @fr2;
1047   # need to make allowance for a proxy-yet-direct call
1048   my $check_fr = (
1049     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1050       and
1051     @fr2 = (CORE::caller(2))
1052       and
1053     (
1054       ( $fr->[3] =~ /([^:])+$/ )[0]
1055         eq
1056       ( $fr2[3] =~ /([^:])+$/ )[0]
1057     )
1058   )
1059     ? \@fr2
1060     : $fr
1061   ;
1062
1063   if (
1064     $argdesc
1065       and
1066     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1067       and
1068     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1069   ) {
1070     DBIx::Class::Exception->throw( sprintf (
1071       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1072       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1073         require B::Deparse;
1074         no strict 'refs';
1075         B::Deparse->new->coderef2text(\&{$fr->[3]})
1076       }),
1077     ), 'with_stacktrace');
1078   }
1079 }
1080
1081 1;