lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 my $mro_recursor_stack;
  12
  13 BEGIN {
  14   package # hide from pause
  15     DBIx::Class::_ENV_;
  16
  17   use Config;
  18
  19   use constant {
  20
  21     # but of course
  22     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  23
  24     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  25
  26     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  27
  28     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  29
  30     ( map
  31       #
  32       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  33       # all envvars without further adjusting its scripts
  34       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  35       #
  36       { substr($_, 5) => !!( $ENV{$_} ) }
  37       qw(
  38         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  39         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  40         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  41         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  42         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  43       )
  44     ),
  45
  46     IV_SIZE => $Config{ivsize},
  47
  48     OS_NAME => $^O,
  49   };
  50
  51   if ( "$]" < 5.009_005) {
  52     require MRO::Compat;
  53     constant->import( OLD_MRO => 1 );
  54
  55     #
  56     # Yes, I know this is a rather PHP-ish name, but please first read
  57     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  58     #
  59     # Even if we are using Class::C3::XS it still won't work, as doing
  60     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  61     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  62     #
  63     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  64       require Digest::MD5;
  65       require Math::BigInt;
  66
  67       # the non-assign-unless-there-is-a-hash is deliberate
  68       ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{gen} ||= (
  69         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  70
  71           ( $mro_recursor_stack->{cache} || {} )->{$_}{methlist} ||= do {
  72
  73             my $class = $_;
  74
  75             no strict 'refs';
  76             my %methlist =
  77               map
  78                 # this is essentially a uniq_by step
  79                 # it is crucial on OLD_MRO
  80                 {( Scalar::Util::refaddr($_) => $_ )}
  81                 map
  82                   {
  83                     (
  84                       ref(\ "${class}::"->{$_} ) ne 'GLOB'
  85                         or
  86                       defined( *{ "${class}::"->{$_} }{CODE} )
  87                     )
  88                     ? ( \&{"${class}::$_"} )
  89                     : ()
  90                   }
  91                   keys %{ "${class}::" }
  92             ;
  93
  94             # RV to be hashed up and turned into a number
  95             join "\0", (
  96               $class,
  97               map {(
  98                 $_, # refaddr is sufficient, ignore names entirely
  99                 attributes::get( $methlist{$_} )
 100               )} sort keys %methlist
 101             ),
 102           }
 103         } ( 'UNIVERSAL', @{
 104           ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{linear_isa}
 105             ||=
 106            mro::get_linear_isa($_[0])
 107         } ) ) ) )
 108       );
 109     };
 110   }
 111   else {
 112     require mro;
 113     constant->import( OLD_MRO => 0 );
 114     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 115   }
 116
 117   # Both of these are no longer used for anything. However bring
 118   # them back after they were purged in 08a8d8f1, as there appear
 119   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 120   # in their production codebases. There is no point in breaking these
 121   # if whatever they used actually continues to work
 122   my $warned;
 123   my $sigh = sub {
 124
 125     require Carp;
 126     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
 127
 128     warn $cluck unless $warned->{$cluck}++;
 129
 130     0;
 131   };
 132   sub DBICTEST () { &$sigh }
 133   sub PEEPEENESS () { &$sigh }
 134 }
 135
 136 # FIXME - this is not supposed to be here
 137 # Carp::Skip to the rescue soon
 138 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 139
 140 use B ();
 141 use Carp 'croak';
 142 use Storable 'nfreeze';
 143 use Scalar::Util qw(weaken blessed reftype refaddr);
 144 use Sub::Quote qw(qsub);
 145 use Sub::Name ();
 146 use attributes ();
 147
 148 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 149 BEGIN { *deep_clone = \&Storable::dclone }
 150
 151 use base 'Exporter';
 152 our @EXPORT_OK = qw(
 153   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 154   fail_on_internal_wantarray fail_on_internal_call
 155   refdesc refcount hrefaddr set_subname describe_class_methods
 156   scope_guard detected_reinvoked_destructor
 157   is_exception dbic_internal_try visit_namespaces
 158   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 159   parent_dir mkdir_p
 160   UNRESOLVABLE_CONDITION
 161 );
 162
 163 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 164
 165 BEGIN {
 166   # add preliminary attribute support
 167   # FIXME FIXME FIXME
 168   # To be revisited when Moo with proper attr support ships
 169   Sub::Quote->VERSION(2.002);
 170 }
 171 # Override forcing no_defer, and adding naming consistency checks
 172 sub quote_sub {
 173   Carp::confess( "Anonymous quoting not supported by the DBIC sub_quote override - supply a sub name" ) if
 174     @_ < 2
 175       or
 176     ! defined $_[1]
 177       or
 178     length ref $_[1]
 179   ;
 180
 181   Carp::confess( "The DBIC sub_quote override expects sub name '$_[0]' to be fully qualified" )
 182     unless $_[0] =~ /::/;
 183
 184   Carp::confess( "The DBIC sub_quote override expects the sub name '$_[0]' to match the supplied 'package' argument" ) if
 185     $_[3]
 186       and
 187     defined $_[3]->{package}
 188       and
 189     index( $_[0], $_[3]->{package} ) != 0
 190   ;
 191
 192   my @caller = caller(0);
 193   my $sq_opts = {
 194     package => $caller[0],
 195     hints => $caller[8],
 196     warning_bits => $caller[9],
 197     hintshash => $caller[10],
 198     %{ $_[3] || {} },
 199
 200     # explicitly forced for everything
 201     no_defer => 1,
 202   };
 203
 204   my $cref = Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 205
 206   # FIXME FIXME FIXME
 207   # To be revisited when Moo with proper attr support ships
 208   if(
 209     # external application does not work on things like :prototype(...), :lvalue, etc
 210     my @attrs = grep {
 211       $_ !~ /^[a-z]/
 212         or
 213       Carp::confess( "The DBIC sub_quote override does not support applying of reserved attribute '$_'" )
 214     } @{ $sq_opts->{attributes} || []}
 215   ) {
 216     Carp::confess( "The DBIC sub_quote override does not allow mixing 'attributes' with 'no_install'" )
 217       if $sq_opts->{no_install};
 218
 219     # might be different from $sq_opts->{package};
 220     my ($install_into) = $_[0] =~ /(.+)::[^:]+$/;
 221
 222     attributes->import( $install_into, $cref, @attrs );
 223   }
 224
 225   $cref;
 226 }
 227
 228 sub sigwarn_silencer ($) {
 229   my $pattern = shift;
 230
 231   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 232
 233   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 234
 235   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 236 }
 237
 238 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 239
 240 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 241
 242 sub refdesc ($) {
 243   croak "Expecting a reference" if ! length ref $_[0];
 244
 245   # be careful not to trigger stringification,
 246   # reuse @_ as a scratch-pad
 247   sprintf '%s%s(0x%x)',
 248     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 249     reftype $_[0],
 250     refaddr($_[0]),
 251   ;
 252 }
 253
 254 sub refcount ($) {
 255   croak "Expecting a reference" if ! length ref $_[0];
 256
 257   # No tempvars - must operate on $_[0], otherwise the pad
 258   # will count as an extra ref
 259   B::svref_2object($_[0])->REFCNT;
 260 }
 261
 262 sub visit_namespaces {
 263   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 264
 265   my $visited_count = 1;
 266
 267   # A package and a namespace are subtly different things
 268   $args->{package} ||= 'main';
 269   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 270   $args->{package} =~ s/^:://;
 271
 272   if ( $args->{action}->($args->{package}) ) {
 273     my $ns =
 274       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 275         .
 276       '::'
 277     ;
 278
 279     $visited_count += visit_namespaces( %$args, package => $_ ) for
 280       grep
 281         # this happens sometimes on %:: traversal
 282         { $_ ne '::main' }
 283         map
 284           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 285           do { no strict 'refs'; keys %$ns }
 286     ;
 287   }
 288
 289   $visited_count;
 290 }
 291
 292 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 293 sub set_subname ($$) {
 294
 295   # fully qualify name
 296   splice @_, 0, 1, caller(0) . "::$_[0]"
 297     if $_[0] !~ /::|'/;
 298
 299   &Sub::Name::subname;
 300 }
 301
 302 sub serialize ($) {
 303   local $Storable::canonical = 1;
 304   nfreeze($_[0]);
 305 }
 306
 307 sub uniq {
 308   my( %seen, $seen_undef, $numeric_preserving_copy );
 309   grep { not (
 310     defined $_
 311       ? $seen{ $numeric_preserving_copy = $_ }++
 312       : $seen_undef++
 313   ) } @_;
 314 }
 315
 316 my $dd_obj;
 317 sub dump_value ($) {
 318   local $Data::Dumper::Indent = 1
 319     unless defined $Data::Dumper::Indent;
 320
 321   my $dump_str = (
 322     $dd_obj
 323       ||=
 324     do {
 325       require Data::Dumper;
 326       my $d = Data::Dumper->new([])
 327         ->Purity(0)
 328         ->Pad('')
 329         ->Useqq(1)
 330         ->Terse(1)
 331         ->Freezer('')
 332         ->Quotekeys(0)
 333         ->Bless('bless')
 334         ->Pair(' => ')
 335         ->Sortkeys(1)
 336         ->Deparse(1)
 337       ;
 338
 339       $d->Sparseseen(1) if modver_gt_or_eq (
 340         'Data::Dumper', '2.136'
 341       );
 342
 343       $d;
 344     }
 345   )->Values([$_[0]])->Dump;
 346
 347   $dd_obj->Reset->Values([]);
 348
 349   $dump_str;
 350 }
 351
 352 sub scope_guard (&) {
 353   croak 'Calling scope_guard() in void context makes no sense'
 354     if ! defined wantarray;
 355
 356   # no direct blessing of coderefs - DESTROY is buggy on those
 357   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 358 }
 359 {
 360   package #
 361     DBIx::Class::_Util::ScopeGuard;
 362
 363   sub DESTROY {
 364     &DBIx::Class::_Util::detected_reinvoked_destructor;
 365
 366     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 367
 368     eval {
 369       $_[0]->[0]->();
 370       1;
 371     }
 372       or
 373     Carp::cluck(
 374       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 375     );
 376   }
 377 }
 378
 379
 380 sub is_exception ($) {
 381   my $e = $_[0];
 382
 383   # FIXME
 384   # this is not strictly correct - an eval setting $@ to undef
 385   # is *not* the same as an eval setting $@ to ''
 386   # but for the sake of simplicity assume the following for
 387   # the time being
 388   return 0 unless defined $e;
 389
 390   my ($not_blank, $suberror);
 391   {
 392     local $SIG{__DIE__} if $SIG{__DIE__};
 393     local $@;
 394     eval {
 395       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 396       # will entirely obviate the need for the encolsing eval{}, as the
 397       # condition we guard against is a missing fallback overload
 398       $not_blank = ( $e ne '' );
 399       1;
 400     } or $suberror = $@;
 401   }
 402
 403   if (defined $suberror) {
 404     if (length (my $class = blessed($e) )) {
 405       carp_unique( sprintf(
 406         'External exception class %s implements partial (broken) overloading '
 407       . 'preventing its instances from being used in simple ($x eq $y) '
 408       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 409       . 'handling this type of brokenness is extremely dangerous on '
 410       . 'exception objects, as it may (and often does) result in silent '
 411       . '"exception substitution". DBIx::Class tries to work around this '
 412       . 'as much as possible, but other parts of your software stack may '
 413       . 'not be even aware of this. Please submit a bugreport against the '
 414       . 'distribution containing %s and in the meantime apply a fix similar '
 415       . 'to the one shown at %s, in order to ensure your exception handling '
 416       . 'is saner application-wide. What follows is the actual error text '
 417       . "as generated by Perl itself:\n\n%s\n ",
 418         $class,
 419         $class,
 420         'http://v.gd/DBIC_overload_tempfix/',
 421         $suberror,
 422       ));
 423
 424       # workaround, keeps spice flowing
 425       $not_blank = !!( length $e );
 426     }
 427     else {
 428       # not blessed yet failed the 'ne'... this makes 0 sense...
 429       # just throw further
 430       die $suberror
 431     }
 432   }
 433   elsif (
 434     # a ref evaluating to '' is definitively a "null object"
 435     ( not $not_blank )
 436       and
 437     length( my $class = ref $e )
 438   ) {
 439     carp_unique( sprintf(
 440       "Objects of external exception class '%s' stringify to '' (the "
 441     . 'empty string), implementing the so called null-object-pattern. '
 442     . 'Given Perl\'s "globally cooperative" exception handling using this '
 443     . 'class of exceptions is extremely dangerous, as it may (and often '
 444     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 445     . 'work around this as much as possible, but other parts of your '
 446     . 'software stack may not be even aware of the problem. Please submit '
 447     . 'a bugreport against the distribution containing %s',
 448
 449       ($class) x 2,
 450     ));
 451
 452     $not_blank = 1;
 453   }
 454
 455   return $not_blank;
 456 }
 457
 458 {
 459   my $callstack_state;
 460
 461   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 462   #
 463   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 464   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 465   sub dbic_internal_try (&;@) {
 466
 467     my $try_cref = shift;
 468     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 469
 470     for my $arg (@_) {
 471
 472       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 473
 474         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 475           if $catch_cref;
 476
 477         $catch_cref = $$arg;
 478       }
 479       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 480         croak 'dbic_internal_try() does not support finally{}';
 481       }
 482       else {
 483         croak(
 484           'dbic_internal_try() encountered an unexpected argument '
 485         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 486         . 'a missing semi-colon before or ' # trailing space important
 487         );
 488       }
 489     }
 490
 491     my $wantarray = wantarray;
 492     my $preexisting_exception = $@;
 493
 494     my @ret;
 495     my $all_good = eval {
 496       $@ = $preexisting_exception;
 497
 498       local $callstack_state->{in_internal_try} = 1
 499         unless $callstack_state->{in_internal_try};
 500
 501       # always unset - someone may have snuck it in
 502       local $SIG{__DIE__} if $SIG{__DIE__};
 503
 504       if( $wantarray ) {
 505         @ret = $try_cref->();
 506       }
 507       elsif( defined $wantarray ) {
 508         $ret[0] = $try_cref->();
 509       }
 510       else {
 511         $try_cref->();
 512       }
 513
 514       1;
 515     };
 516
 517     my $exception = $@;
 518     $@ = $preexisting_exception;
 519
 520     if ( $all_good ) {
 521       return $wantarray ? @ret : $ret[0]
 522     }
 523     elsif ( $catch_cref ) {
 524       for ( $exception ) {
 525         return $catch_cref->($exception);
 526       }
 527     }
 528
 529     return;
 530   }
 531
 532   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 533 }
 534
 535 {
 536   my $destruction_registry = {};
 537
 538   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 539     %$destruction_registry = map {
 540       (defined $_)
 541         ? ( refaddr($_) => $_ )
 542         : ()
 543     } values %$destruction_registry;
 544
 545     weaken($_) for values %$destruction_registry;
 546
 547     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 548     # collected before leaving this scope. Depending on the code above, this
 549     # may very well be just a preventive measure guarding future modifications
 550     undef;
 551   }
 552
 553   # This is almost invariably invoked from within DESTROY
 554   # throwing exceptions won't work
 555   sub detected_reinvoked_destructor {
 556
 557     # quick "garbage collection" pass - prevents the registry
 558     # from slowly growing with a bunch of undef-valued keys
 559     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 560       for keys %$destruction_registry;
 561
 562     if (! length ref $_[0]) {
 563       printf STDERR '%s() expects a blessed reference %s',
 564         (caller(0))[3],
 565         Carp::longmess,
 566       ;
 567       return undef; # don't know wtf to do
 568     }
 569     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 570       weaken( $destruction_registry->{$addr} = $_[0] );
 571       return 0;
 572     }
 573     else {
 574       carp_unique ( sprintf (
 575         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 576       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 577       . 'application, affecting *ALL* classes without active protection against '
 578       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 579       refdesc $_[0],
 580         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 581           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 582           : ''
 583         )
 584       ));
 585
 586       return 1;
 587     }
 588   }
 589 }
 590
 591 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 592 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 593
 594 sub modver_gt_or_eq ($$) {
 595   my ($mod, $ver) = @_;
 596
 597   croak "Nonsensical module name supplied"
 598     if ! defined $mod or $mod !~ $module_name_rx;
 599
 600   croak "Nonsensical minimum version supplied"
 601     if ! defined $ver or $ver !~ $ver_rx;
 602
 603   no strict 'refs';
 604   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 605     ? {}
 606     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 607   );
 608
 609   ! defined $ver_cache->{$ver}
 610     and
 611   $ver_cache->{$ver} = do {
 612
 613     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 614       if SPURIOUS_VERSION_CHECK_WARNINGS;
 615
 616     local $SIG{__DIE__} if $SIG{__DIE__};
 617     local $@;
 618     eval { $mod->VERSION($ver) } ? 1 : 0;
 619   };
 620
 621   $ver_cache->{$ver};
 622 }
 623
 624 sub modver_gt_or_eq_and_lt ($$$) {
 625   my ($mod, $v_ge, $v_lt) = @_;
 626
 627   croak "Nonsensical maximum version supplied"
 628     if ! defined $v_lt or $v_lt !~ $ver_rx;
 629
 630   return (
 631     modver_gt_or_eq($mod, $v_ge)
 632       and
 633     ! modver_gt_or_eq($mod, $v_lt)
 634   ) ? 1 : 0;
 635 }
 636
 637 {
 638   # FIXME - should be a private my(), but I'm too uncertain whether
 639   # all bases are covered
 640   our $describe_class_query_cache;
 641
 642   sub describe_class_methods {
 643     my ($class) = @_;
 644
 645     croak "Expecting a class name"
 646       if not defined $class or $class !~ $module_name_rx;
 647
 648     # use a cache on old MRO, since while we are recursing in this function
 649     # nothing can possibly change (the speedup is immense)
 650     # (yes, people could be tie()ing the stash and adding methods on access
 651     # but there is a limit to how much crazy can be supported here)
 652     #
 653     # we use the cache for linear_isa lookups on new MRO as well - it adds
 654     # a *tiny* speedup, and simplifies the code a lot
 655     #
 656     local $mro_recursor_stack->{cache} = {}
 657       unless $mro_recursor_stack->{cache};
 658
 659     my $my_gen = 0;
 660
 661     $my_gen += get_real_pkg_gen($_) for (
 662       'UNIVERSAL',
 663       ( $class, my @my_ISA ) = @{
 664         $mro_recursor_stack->{cache}{$class}{linear_isa}
 665           ||=
 666         mro::get_linear_isa($class)
 667       }
 668     );
 669
 670     my $slot = $describe_class_query_cache->{$class} ||= {};
 671
 672     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 673
 674       # reset
 675       %$slot = (
 676         class => $class,
 677         isa => [ @my_ISA ], # copy before we shove UNIVERSAL into it
 678         mro => {
 679           type => mro::get_mro($class),
 680         },
 681         cumulative_gen => $my_gen,
 682       );
 683       $slot->{mro}{is_c3} = ($slot->{mro}{type} eq 'c3') ? 1 : 0;
 684
 685       push @my_ISA, 'UNIVERSAL';
 686
 687       # ensure the cache is populated for the parents, code below can then
 688       # efficiently operate over the query_cache directly
 689       describe_class_methods($_) for reverse @my_ISA;
 690
 691       my ($methods_seen_via_ISA_on_old_mro, $current_node_refaddr);
 692       no strict 'refs';
 693
 694       # combine full ISA-order inherited and local method list into a
 695       # "shadowing stack"
 696
 697       (
 698         $current_node_refaddr = refaddr($_)
 699
 700           and
 701
 702         # on complex MI herarchies the method can be anywhere in the
 703         # shadow stack - look through the entire slot, not just [0]
 704         ( ! grep {
 705           refaddr($_) == $current_node_refaddr
 706         } @{ $slot->{methods}{ $_->{name} } || [] } )
 707
 708           and
 709
 710         unshift @{ $slot->{methods}{$_->{name}} }, $_
 711
 712           and
 713
 714         @{ $slot->{methods}{$_->{name}} } > 1
 715
 716           and
 717
 718         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 719
 720       ) for (
 721
 722         # what describe_class_methods for @my_ISA produced above
 723         ( map { $_->[0] } map {
 724           values %{ $describe_class_query_cache->{$_}{methods} }
 725         } reverse @my_ISA ),
 726
 727         # our own non-cleaned subs + their attributes
 728         ( map {
 729           (
 730             # these 2 OR-ed checks are sufficient for 5.10+
 731             (
 732               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 733                 or
 734               defined( *{ "${class}::"->{$_} }{CODE} )
 735             )
 736               and
 737             # need to account for dummy helper crefs under OLD_MRO
 738             (
 739               ! DBIx::Class::_ENV_::OLD_MRO
 740                 or
 741               (
 742                 $methods_seen_via_ISA_on_old_mro ||= do {
 743                   my $rv = {};
 744                   $rv->{$_->{name}}->{ refaddr( \&{ "$_->{via_class}::$_->{name}"} ) } = 1 for
 745                     map { @$_ } map
 746                       { values %{ $describe_class_query_cache->{$_}{methods} } }
 747                       @my_ISA;
 748                   $rv;
 749                 }
 750                   and
 751                 (
 752                   ! $methods_seen_via_ISA_on_old_mro->{$_}
 753                     or
 754                   ! $methods_seen_via_ISA_on_old_mro->{$_}{ refaddr( \&{"${class}::${_}"} ) }
 755                 )
 756               )
 757             )
 758           ) ? {
 759               via_class => $class,
 760               name => $_,
 761               attributes => {
 762                 map { $_ => 1 } attributes::get( \&{"${class}::${_}"} )
 763               },
 764             }
 765             : ()
 766         } keys %{"${class}::"} )
 767       );
 768
 769
 770       # recalculate the pkg_gen on newer perls under Taint mode,
 771       # because of shit like:
 772       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 773       #
 774       if (
 775         ! DBIx::Class::_ENV_::OLD_MRO
 776           and
 777         ${^TAINT}
 778       ) {
 779
 780         $slot->{cumulative_gen} = 0;
 781         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 782           for $class, @my_ISA;
 783       }
 784     }
 785
 786     # RV
 787     +{ %$slot };
 788   }
 789 }
 790
 791
 792 #
 793 # Why not just use some higher-level module or at least File::Spec here?
 794 # Because:
 795 # 1)  This is a *very* rarely used function, and the deptree is large
 796 #     enough already as it is
 797 #
 798 # 2)  (more importantly) Our tooling is utter shit in this area. There
 799 #     is no comprehensive support for UNC paths in PathTools and there
 800 #     are also various small bugs in representation across different
 801 #     path-manipulation CPAN offerings.
 802 #
 803 # Since this routine is strictly used for logical path processing (it
 804 # *must* be able to work with not-yet-existing paths), use this seemingly
 805 # simple but I *think* complete implementation to feed to other consumers
 806 #
 807 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 808 # the impulse to bring in an external dependency. During runtime there
 809 # is exactly one spot that could potentially maybe once in a blue moon
 810 # use this function. Keep it lean.
 811 #
 812 sub parent_dir ($) {
 813   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 814     ? (
 815       $_[0]
 816         .
 817       ( ( length($1) and ! length($2) ) ? '/' : '' )
 818         .
 819       '../'
 820     )
 821     : (
 822       require File::Spec
 823         and
 824       File::Spec->catpath (
 825         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 826         '/',
 827       )
 828     )
 829   ;
 830 }
 831
 832 sub mkdir_p ($) {
 833   require File::Path;
 834   # do not ask for a recent version, use 1.x API calls
 835   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 836 }
 837
 838
 839 {
 840   my $list_ctx_ok_stack_marker;
 841
 842   sub fail_on_internal_wantarray () {
 843     return if $list_ctx_ok_stack_marker;
 844
 845     if (! defined wantarray) {
 846       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 847     }
 848
 849     my $cf = 1;
 850     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 851
 852       # these are public API parts that alter behavior on wantarray
 853       search | search_related | slice | search_literal
 854
 855         |
 856
 857       # these are explicitly prefixed, since we only recognize them as valid
 858       # escapes when they come from the guts of CDBICompat
 859       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 860
 861     ) $/x ) {
 862       $cf++;
 863     }
 864
 865     my ($fr, $want, $argdesc);
 866     {
 867       package DB;
 868       $fr = [ CORE::caller($cf) ];
 869       $want = ( CORE::caller($cf-1) )[5];
 870       $argdesc = ref $DB::args[0]
 871         ? DBIx::Class::_Util::refdesc($DB::args[0])
 872         : 'non '
 873       ;
 874     };
 875
 876     if (
 877       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 878     ) {
 879       DBIx::Class::Exception->throw( sprintf (
 880         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 881         $argdesc, @{$fr}[1,2]
 882       ), 'with_stacktrace');
 883     }
 884
 885     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 886
 887     $mark;
 888   }
 889 }
 890
 891 sub fail_on_internal_call {
 892   my ($fr, $argdesc);
 893   {
 894     package DB;
 895     $fr = [ CORE::caller(1) ];
 896     $argdesc = ref $DB::args[0]
 897       ? DBIx::Class::_Util::refdesc($DB::args[0])
 898       : ( $DB::args[0] . '' )
 899     ;
 900   };
 901
 902   my @fr2;
 903   # need to make allowance for a proxy-yet-direct call
 904   my $check_fr = (
 905     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
 906       and
 907     @fr2 = (CORE::caller(2))
 908       and
 909     (
 910       ( $fr->[3] =~ /([^:])+$/ )[0]
 911         eq
 912       ( $fr2[3] =~ /([^:])+$/ )[0]
 913     )
 914   )
 915     ? \@fr2
 916     : $fr
 917   ;
 918
 919   if (
 920     $argdesc
 921       and
 922     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 923       and
 924     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 925   ) {
 926     DBIx::Class::Exception->throw( sprintf (
 927       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 928       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 929         require B::Deparse;
 930         no strict 'refs';
 931         B::Deparse->new->coderef2text(\&{$fr->[3]})
 932       }),
 933     ), 'with_stacktrace');
 934   }
 935 }
 936
 937 1;