lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
  27
  28     # During 5.13 dev cycle HELEMs started to leak on copy
  29     # add an escape for these perls ON SMOKERS - a user will still get death
  30     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),
  31
  32     ( map
  33       #
  34       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  35       # all envvars without further adjusting its scripts
  36       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  37       #
  38       { substr($_, 5) => !!( $ENV{$_} ) }
  39       qw(
  40         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  41         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  42         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  43         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  44         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  45       )
  46     ),
  47
  48     IV_SIZE => $Config{ivsize},
  49
  50     OS_NAME => $^O,
  51   };
  52
  53   if ( "$]" < 5.009_005) {
  54     require MRO::Compat;
  55     constant->import( OLD_MRO => 1 );
  56   }
  57   else {
  58     require mro;
  59     constant->import( OLD_MRO => 0 );
  60   }
  61 }
  62
  63 # FIXME - this is not supposed to be here
  64 # Carp::Skip to the rescue soon
  65 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  66
  67 use B ();
  68 use Carp 'croak';
  69 use Storable 'nfreeze';
  70 use Scalar::Util qw(weaken blessed reftype refaddr);
  71 use List::Util qw(first);
  72 use Sub::Quote qw(qsub quote_sub);
  73
  74 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  75 BEGIN { *deep_clone = \&Storable::dclone }
  76
  77 use base 'Exporter';
  78 our @EXPORT_OK = qw(
  79   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  80   fail_on_internal_wantarray fail_on_internal_call
  81   refdesc refcount hrefaddr
  82   scope_guard detected_reinvoked_destructor
  83   is_exception dbic_internal_try
  84   quote_sub qsub perlstring serialize deep_clone
  85   parent_dir mkdir_p
  86   UNRESOLVABLE_CONDITION
  87 );
  88
  89 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  90
  91 sub sigwarn_silencer ($) {
  92   my $pattern = shift;
  93
  94   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  95
  96   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  97
  98   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  99 }
 100
 101 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 102
 103 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 104
 105 sub refdesc ($) {
 106   croak "Expecting a reference" if ! length ref $_[0];
 107
 108   # be careful not to trigger stringification,
 109   # reuse @_ as a scratch-pad
 110   sprintf '%s%s(0x%x)',
 111     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 112     reftype $_[0],
 113     refaddr($_[0]),
 114   ;
 115 }
 116
 117 sub refcount ($) {
 118   croak "Expecting a reference" if ! length ref $_[0];
 119
 120   # No tempvars - must operate on $_[0], otherwise the pad
 121   # will count as an extra ref
 122   B::svref_2object($_[0])->REFCNT;
 123 }
 124
 125 sub serialize ($) {
 126   local $Storable::canonical = 1;
 127   nfreeze($_[0]);
 128 }
 129
 130 sub scope_guard (&) {
 131   croak 'Calling scope_guard() in void context makes no sense'
 132     if ! defined wantarray;
 133
 134   # no direct blessing of coderefs - DESTROY is buggy on those
 135   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 136 }
 137 {
 138   package #
 139     DBIx::Class::_Util::ScopeGuard;
 140
 141   sub DESTROY {
 142     &DBIx::Class::_Util::detected_reinvoked_destructor;
 143
 144     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 145
 146     eval {
 147       $_[0]->[0]->();
 148       1;
 149     }
 150       or
 151     Carp::cluck(
 152       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 153     );
 154   }
 155 }
 156
 157
 158 sub is_exception ($) {
 159   my $e = $_[0];
 160
 161   # FIXME
 162   # this is not strictly correct - an eval setting $@ to undef
 163   # is *not* the same as an eval setting $@ to ''
 164   # but for the sake of simplicity assume the following for
 165   # the time being
 166   return 0 unless defined $e;
 167
 168   my ($not_blank, $suberror);
 169   {
 170     local $@;
 171     eval {
 172       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 173       # will entirely obviate the need for the encolsing eval{}, as the
 174       # condition we guard against is a missing fallback overload
 175       $not_blank = ( $e ne '' );
 176       1;
 177     } or $suberror = $@;
 178   }
 179
 180   if (defined $suberror) {
 181     if (length (my $class = blessed($e) )) {
 182       carp_unique( sprintf(
 183         'External exception class %s implements partial (broken) overloading '
 184       . 'preventing its instances from being used in simple ($x eq $y) '
 185       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 186       . 'handling this type of brokenness is extremely dangerous on '
 187       . 'exception objects, as it may (and often does) result in silent '
 188       . '"exception substitution". DBIx::Class tries to work around this '
 189       . 'as much as possible, but other parts of your software stack may '
 190       . 'not be even aware of this. Please submit a bugreport against the '
 191       . 'distribution containing %s and in the meantime apply a fix similar '
 192       . 'to the one shown at %s, in order to ensure your exception handling '
 193       . 'is saner application-wide. What follows is the actual error text '
 194       . "as generated by Perl itself:\n\n%s\n ",
 195         $class,
 196         $class,
 197         'http://v.gd/DBIC_overload_tempfix/',
 198         $suberror,
 199       ));
 200
 201       # workaround, keeps spice flowing
 202       $not_blank = !!( length $e );
 203     }
 204     else {
 205       # not blessed yet failed the 'ne'... this makes 0 sense...
 206       # just throw further
 207       die $suberror
 208     }
 209   }
 210   elsif (
 211     # a ref evaluating to '' is definitively a "null object"
 212     ( not $not_blank )
 213       and
 214     length( my $class = ref $e )
 215   ) {
 216     carp_unique( sprintf(
 217       "Objects of external exception class '%s' stringify to '' (the "
 218     . 'empty string), implementing the so called null-object-pattern. '
 219     . 'Given Perl\'s "globally cooperative" exception handling using this '
 220     . 'class of exceptions is extremely dangerous, as it may (and often '
 221     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 222     . 'work around this as much as possible, but other parts of your '
 223     . 'software stack may not be even aware of the problem. Please submit '
 224     . 'a bugreport against the distribution containing %s',
 225
 226       ($class) x 2,
 227     ));
 228
 229     $not_blank = 1;
 230   }
 231
 232   return $not_blank;
 233 }
 234
 235 {
 236   my $callstack_state;
 237
 238   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 239   #
 240   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 241   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 242   sub dbic_internal_try (&;@) {
 243
 244     my $try_cref = shift;
 245     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 246
 247     for my $arg (@_) {
 248
 249       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 250
 251         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 252           if $catch_cref;
 253
 254         $catch_cref = $$arg;
 255       }
 256       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 257         croak 'dbic_internal_try() does not support finally{}';
 258       }
 259       else {
 260         croak(
 261           'dbic_internal_try() encountered an unexpected argument '
 262         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 263         . 'a missing semi-colon before or ' # trailing space important
 264         );
 265       }
 266     }
 267
 268     my $wantarray = wantarray;
 269     my $preexisting_exception = $@;
 270
 271     my @ret;
 272     my $all_good = eval {
 273       $@ = $preexisting_exception;
 274
 275       local $callstack_state->{in_internal_try} = 1
 276         unless $callstack_state->{in_internal_try};
 277
 278       # always unset - someone may have snuck it in
 279       local $SIG{__DIE__}
 280         if $SIG{__DIE__};
 281
 282
 283       if( $wantarray ) {
 284         @ret = $try_cref->();
 285       }
 286       elsif( defined $wantarray ) {
 287         $ret[0] = $try_cref->();
 288       }
 289       else {
 290         $try_cref->();
 291       }
 292
 293       1;
 294     };
 295
 296     my $exception = $@;
 297     $@ = $preexisting_exception;
 298
 299     if ( $all_good ) {
 300       return $wantarray ? @ret : $ret[0]
 301     }
 302     elsif ( $catch_cref ) {
 303       for ( $exception ) {
 304         return $catch_cref->($exception);
 305       }
 306     }
 307
 308     return;
 309   }
 310
 311   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 312 }
 313
 314 {
 315   my $destruction_registry = {};
 316
 317   sub CLONE {
 318     $destruction_registry = { map
 319       { defined $_ ? ( refaddr($_) => $_ ) : () }
 320       values %$destruction_registry
 321     };
 322
 323     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 324     # collected before leaving this scope. Depending on the code above, this
 325     # may very well be just a preventive measure guarding future modifications
 326     undef;
 327   }
 328
 329   # This is almost invariably invoked from within DESTROY
 330   # throwing exceptions won't work
 331   sub detected_reinvoked_destructor {
 332
 333     # quick "garbage collection" pass - prevents the registry
 334     # from slowly growing with a bunch of undef-valued keys
 335     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 336       for keys %$destruction_registry;
 337
 338     if (! length ref $_[0]) {
 339       printf STDERR '%s() expects a blessed reference %s',
 340         (caller(0))[3],
 341         Carp::longmess,
 342       ;
 343       return undef; # don't know wtf to do
 344     }
 345     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 346       weaken( $destruction_registry->{$addr} = $_[0] );
 347       return 0;
 348     }
 349     else {
 350       carp_unique ( sprintf (
 351         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 352       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 353       . 'application, affecting *ALL* classes without active protection against '
 354       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 355       refdesc $_[0],
 356         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 357           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 358           : ''
 359         )
 360       ));
 361
 362       return 1;
 363     }
 364   }
 365 }
 366
 367 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 368 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 369
 370 sub modver_gt_or_eq ($$) {
 371   my ($mod, $ver) = @_;
 372
 373   croak "Nonsensical module name supplied"
 374     if ! defined $mod or $mod !~ $module_name_rx;
 375
 376   croak "Nonsensical minimum version supplied"
 377     if ! defined $ver or $ver !~ $ver_rx;
 378
 379   no strict 'refs';
 380   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 381     ? {}
 382     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 383   );
 384
 385   ! defined $ver_cache->{$ver}
 386     and
 387   $ver_cache->{$ver} = do {
 388
 389     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 390       if SPURIOUS_VERSION_CHECK_WARNINGS;
 391
 392     local $@;
 393     local $SIG{__DIE__};
 394     eval { $mod->VERSION($ver) } ? 1 : 0;
 395   };
 396
 397   $ver_cache->{$ver};
 398 }
 399
 400 sub modver_gt_or_eq_and_lt ($$$) {
 401   my ($mod, $v_ge, $v_lt) = @_;
 402
 403   croak "Nonsensical maximum version supplied"
 404     if ! defined $v_lt or $v_lt !~ $ver_rx;
 405
 406   return (
 407     modver_gt_or_eq($mod, $v_ge)
 408       and
 409     ! modver_gt_or_eq($mod, $v_lt)
 410   ) ? 1 : 0;
 411 }
 412
 413
 414 #
 415 # Why not just use some higher-level module or at least File::Spec here?
 416 # Because:
 417 # 1)  This is a *very* rarely used function, and the deptree is large
 418 #     enough already as it is
 419 #
 420 # 2)  (more importantly) Our tooling is utter shit in this area. There
 421 #     is no comprehensive support for UNC paths in PathTools and there
 422 #     are also various small bugs in representation across different
 423 #     path-manipulation CPAN offerings.
 424 #
 425 # Since this routine is strictly used for logical path processing (it
 426 # *must* be able to work with not-yet-existing paths), use this seemingly
 427 # simple but I *think* complete implementation to feed to other consumers
 428 #
 429 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 430 # the impulse to bring in an external dependency. During runtime there
 431 # is exactly one spot that could potentially maybe once in a blue moon
 432 # use this function. Keep it lean.
 433 #
 434 sub parent_dir ($) {
 435   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 436     ? (
 437       $_[0]
 438         .
 439       ( ( length($1) and ! length($2) ) ? '/' : '' )
 440         .
 441       '../'
 442     )
 443     : (
 444       require File::Spec
 445         and
 446       File::Spec->catpath (
 447         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 448         '/',
 449       )
 450     )
 451   ;
 452 }
 453
 454 sub mkdir_p ($) {
 455   require File::Path;
 456   # do not ask for a recent version, use 1.x API calls
 457   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 458 }
 459
 460
 461 {
 462   my $list_ctx_ok_stack_marker;
 463
 464   sub fail_on_internal_wantarray () {
 465     return if $list_ctx_ok_stack_marker;
 466
 467     if (! defined wantarray) {
 468       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 469     }
 470
 471     my $cf = 1;
 472     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 473
 474       # these are public API parts that alter behavior on wantarray
 475       search | search_related | slice | search_literal
 476
 477         |
 478
 479       # these are explicitly prefixed, since we only recognize them as valid
 480       # escapes when they come from the guts of CDBICompat
 481       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 482
 483     ) $/x ) {
 484       $cf++;
 485     }
 486
 487     my ($fr, $want, $argdesc);
 488     {
 489       package DB;
 490       $fr = [ CORE::caller($cf) ];
 491       $want = ( CORE::caller($cf-1) )[5];
 492       $argdesc = ref $DB::args[0]
 493         ? DBIx::Class::_Util::refdesc($DB::args[0])
 494         : 'non '
 495       ;
 496     };
 497
 498     if (
 499       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 500     ) {
 501       DBIx::Class::Exception->throw( sprintf (
 502         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 503         $argdesc, @{$fr}[1,2]
 504       ), 'with_stacktrace');
 505     }
 506
 507     my $mark = [];
 508     weaken ( $list_ctx_ok_stack_marker = $mark );
 509     $mark;
 510   }
 511 }
 512
 513 sub fail_on_internal_call {
 514   my ($fr, $argdesc);
 515   {
 516     package DB;
 517     $fr = [ CORE::caller(1) ];
 518     $argdesc = ref $DB::args[0]
 519       ? DBIx::Class::_Util::refdesc($DB::args[0])
 520       : undef
 521     ;
 522   };
 523
 524   if (
 525     $argdesc
 526       and
 527     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 528       and
 529     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 530   ) {
 531     DBIx::Class::Exception->throw( sprintf (
 532       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 533       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 534         require B::Deparse;
 535         no strict 'refs';
 536         B::Deparse->new->coderef2text(\&{$fr->[3]})
 537       }),
 538     ), 'with_stacktrace');
 539   }
 540 }
 541
 542 1;