lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     IV_SIZE => $Config{ivsize},
  40
  41     OS_NAME => $^O,
  42   };
  43
  44   if ($] < 5.009_005) {
  45     require MRO::Compat;
  46     constant->import( OLD_MRO => 1 );
  47   }
  48   else {
  49     require mro;
  50     constant->import( OLD_MRO => 0 );
  51   }
  52 }
  53
  54 # FIXME - this is not supposed to be here
  55 # Carp::Skip to the rescue soon
  56 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  57
  58 use B ();
  59 use Carp 'croak';
  60 use Storable 'nfreeze';
  61 use Scalar::Util qw(weaken blessed reftype);
  62 use List::Util qw(first);
  63
  64 # DO NOT edit away without talking to riba first, he will just put it back
  65 # BEGIN pre-Moo2 import block
  66 BEGIN {
  67   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  68
  69   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  70   # load all of these now, so that lazy-loading does not escape
  71   # the current PERL_STRICTURES_EXTRA setting
  72   require Sub::Quote;
  73   require Sub::Defer;
  74
  75   Sub::Quote->import('quote_sub');
  76   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  77 }
  78 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
  79 # END pre-Moo2 import block
  80
  81 use base 'Exporter';
  82 our @EXPORT_OK = qw(
  83   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  84   fail_on_internal_wantarray fail_on_internal_call
  85   refdesc refcount hrefaddr is_exception
  86   quote_sub qsub perlstring serialize
  87   UNRESOLVABLE_CONDITION
  88 );
  89
  90 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  91
  92 sub sigwarn_silencer ($) {
  93   my $pattern = shift;
  94
  95   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  96
  97   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  98
  99   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 100 }
 101
 102 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 103
 104 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 105
 106 sub refdesc ($) {
 107   croak "Expecting a reference" if ! length ref $_[0];
 108
 109   # be careful not to trigger stringification,
 110   # reuse @_ as a scratch-pad
 111   sprintf '%s%s(0x%x)',
 112     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 113     reftype $_[0],
 114     Scalar::Util::refaddr($_[0]),
 115   ;
 116 }
 117
 118 sub refcount ($) {
 119   croak "Expecting a reference" if ! length ref $_[0];
 120
 121   # No tempvars - must operate on $_[0], otherwise the pad
 122   # will count as an extra ref
 123   B::svref_2object($_[0])->REFCNT;
 124 }
 125
 126 sub serialize ($) {
 127   local $Storable::canonical = 1;
 128   nfreeze($_[0]);
 129 }
 130
 131 sub is_exception ($) {
 132   my $e = $_[0];
 133
 134   # this is not strictly correct - an eval setting $@ to undef
 135   # is *not* the same as an eval setting $@ to ''
 136   # but for the sake of simplicity assume the following for
 137   # the time being
 138   return 0 unless defined $e;
 139
 140   my ($not_blank, $suberror);
 141   {
 142     local $@;
 143     eval {
 144       $not_blank = ($e ne '') ? 1 : 0;
 145       1;
 146     } or $suberror = $@;
 147   }
 148
 149   if (defined $suberror) {
 150     if (length (my $class = blessed($e) )) {
 151       carp_unique( sprintf(
 152         'External exception class %s implements partial (broken) overloading '
 153       . 'preventing its instances from being used in simple ($x eq $y) '
 154       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 155       . 'handling this type of brokenness is extremely dangerous on '
 156       . 'exception objects, as it may (and often does) result in silent '
 157       . '"exception substitution". DBIx::Class tries to work around this '
 158       . 'as much as possible, but other parts of your software stack may '
 159       . 'not be even aware of this. Please submit a bugreport against the '
 160       . 'distribution containing %s and in the meantime apply a fix similar '
 161       . 'to the one shown at %s, in order to ensure your exception handling '
 162       . 'is saner application-wide. What follows is the actual error text '
 163       . "as generated by Perl itself:\n\n%s\n ",
 164         $class,
 165         $class,
 166         'http://v.gd/DBIC_overload_tempfix/',
 167         $suberror,
 168       ));
 169
 170       # workaround, keeps spice flowing
 171       $not_blank = ("$e" ne '') ? 1 : 0;
 172     }
 173     else {
 174       # not blessed yet failed the 'ne'... this makes 0 sense...
 175       # just throw further
 176       die $suberror
 177     }
 178   }
 179
 180   return $not_blank;
 181 }
 182
 183 sub modver_gt_or_eq ($$) {
 184   my ($mod, $ver) = @_;
 185
 186   croak "Nonsensical module name supplied"
 187     if ! defined $mod or ! length $mod;
 188
 189   croak "Nonsensical minimum version supplied"
 190     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 191
 192   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 193     if SPURIOUS_VERSION_CHECK_WARNINGS;
 194
 195   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 196     unless $mod->VERSION;
 197
 198   local $@;
 199   eval { $mod->VERSION($ver) } ? 1 : 0;
 200 }
 201
 202 sub modver_gt_or_eq_and_lt ($$$) {
 203   my ($mod, $v_ge, $v_lt) = @_;
 204
 205   croak "Nonsensical maximum version supplied"
 206     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 207
 208   return (
 209     modver_gt_or_eq($mod, $v_ge)
 210       and
 211     ! modver_gt_or_eq($mod, $v_lt)
 212   ) ? 1 : 0;
 213 }
 214
 215 {
 216   my $list_ctx_ok_stack_marker;
 217
 218   sub fail_on_internal_wantarray () {
 219     return if $list_ctx_ok_stack_marker;
 220
 221     if (! defined wantarray) {
 222       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 223     }
 224
 225     my $cf = 1;
 226     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 227
 228       # these are public API parts that alter behavior on wantarray
 229       search | search_related | slice | search_literal
 230
 231         |
 232
 233       # these are explicitly prefixed, since we only recognize them as valid
 234       # escapes when they come from the guts of CDBICompat
 235       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 236
 237     ) $/x ) {
 238       $cf++;
 239     }
 240
 241     my ($fr, $want, $argdesc);
 242     {
 243       package DB;
 244       $fr = [ caller($cf) ];
 245       $want = ( caller($cf-1) )[5];
 246       $argdesc = ref $DB::args[0]
 247         ? DBIx::Class::_Util::refdesc($DB::args[0])
 248         : 'non '
 249       ;
 250     };
 251
 252     if (
 253       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 254     ) {
 255       DBIx::Class::Exception->throw( sprintf (
 256         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 257         $argdesc, @{$fr}[1,2]
 258       ), 'with_stacktrace');
 259     }
 260
 261     my $mark = [];
 262     weaken ( $list_ctx_ok_stack_marker = $mark );
 263     $mark;
 264   }
 265 }
 266
 267 sub fail_on_internal_call {
 268   my ($fr, $argdesc);
 269   {
 270     package DB;
 271     $fr = [ caller(1) ];
 272     $argdesc = ref $DB::args[0]
 273       ? DBIx::Class::_Util::refdesc($DB::args[0])
 274       : undef
 275     ;
 276   };
 277
 278   if (
 279     $argdesc
 280       and
 281     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 282       and
 283     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 284   ) {
 285     DBIx::Class::Exception->throw( sprintf (
 286       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 287       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 288         require B::Deparse;
 289         no strict 'refs';
 290         B::Deparse->new->coderef2text(\&{$fr->[3]})
 291       }),
 292     ), 'with_stacktrace');
 293   }
 294 }
 295
 296 1;