lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  40
  41     IV_SIZE => $Config{ivsize},
  42
  43     OS_NAME => $^O,
  44   };
  45
  46   if ($] < 5.009_005) {
  47     require MRO::Compat;
  48     constant->import( OLD_MRO => 1 );
  49   }
  50   else {
  51     require mro;
  52     constant->import( OLD_MRO => 0 );
  53   }
  54 }
  55
  56 # FIXME - this is not supposed to be here
  57 # Carp::Skip to the rescue soon
  58 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  59
  60 use B ();
  61 use Carp 'croak';
  62 use Storable 'nfreeze';
  63 use Scalar::Util qw(weaken blessed reftype);
  64 use List::Util qw(first);
  65 use Sub::Quote qw(qsub quote_sub);
  66
  67 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  68 BEGIN { *deep_clone = \&Storable::dclone }
  69
  70 use base 'Exporter';
  71 our @EXPORT_OK = qw(
  72   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  73   fail_on_internal_wantarray fail_on_internal_call
  74   refdesc refcount hrefaddr is_exception
  75   quote_sub qsub perlstring serialize deep_clone
  76   UNRESOLVABLE_CONDITION
  77 );
  78
  79 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  80
  81 sub sigwarn_silencer ($) {
  82   my $pattern = shift;
  83
  84   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  85
  86   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  87
  88   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  89 }
  90
  91 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  92
  93 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
  94
  95 sub refdesc ($) {
  96   croak "Expecting a reference" if ! length ref $_[0];
  97
  98   # be careful not to trigger stringification,
  99   # reuse @_ as a scratch-pad
 100   sprintf '%s%s(0x%x)',
 101     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 102     reftype $_[0],
 103     Scalar::Util::refaddr($_[0]),
 104   ;
 105 }
 106
 107 sub refcount ($) {
 108   croak "Expecting a reference" if ! length ref $_[0];
 109
 110   # No tempvars - must operate on $_[0], otherwise the pad
 111   # will count as an extra ref
 112   B::svref_2object($_[0])->REFCNT;
 113 }
 114
 115 sub serialize ($) {
 116   local $Storable::canonical = 1;
 117   nfreeze($_[0]);
 118 }
 119
 120 sub is_exception ($) {
 121   my $e = $_[0];
 122
 123   # this is not strictly correct - an eval setting $@ to undef
 124   # is *not* the same as an eval setting $@ to ''
 125   # but for the sake of simplicity assume the following for
 126   # the time being
 127   return 0 unless defined $e;
 128
 129   my ($not_blank, $suberror);
 130   {
 131     local $@;
 132     eval {
 133       $not_blank = ($e ne '') ? 1 : 0;
 134       1;
 135     } or $suberror = $@;
 136   }
 137
 138   if (defined $suberror) {
 139     if (length (my $class = blessed($e) )) {
 140       carp_unique( sprintf(
 141         'External exception class %s implements partial (broken) overloading '
 142       . 'preventing its instances from being used in simple ($x eq $y) '
 143       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 144       . 'handling this type of brokenness is extremely dangerous on '
 145       . 'exception objects, as it may (and often does) result in silent '
 146       . '"exception substitution". DBIx::Class tries to work around this '
 147       . 'as much as possible, but other parts of your software stack may '
 148       . 'not be even aware of this. Please submit a bugreport against the '
 149       . 'distribution containing %s and in the meantime apply a fix similar '
 150       . 'to the one shown at %s, in order to ensure your exception handling '
 151       . 'is saner application-wide. What follows is the actual error text '
 152       . "as generated by Perl itself:\n\n%s\n ",
 153         $class,
 154         $class,
 155         'http://v.gd/DBIC_overload_tempfix/',
 156         $suberror,
 157       ));
 158
 159       # workaround, keeps spice flowing
 160       $not_blank = ("$e" ne '') ? 1 : 0;
 161     }
 162     else {
 163       # not blessed yet failed the 'ne'... this makes 0 sense...
 164       # just throw further
 165       die $suberror
 166     }
 167   }
 168
 169   return $not_blank;
 170 }
 171
 172 sub modver_gt_or_eq ($$) {
 173   my ($mod, $ver) = @_;
 174
 175   croak "Nonsensical module name supplied"
 176     if ! defined $mod or ! length $mod;
 177
 178   croak "Nonsensical minimum version supplied"
 179     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 180
 181   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 182     if SPURIOUS_VERSION_CHECK_WARNINGS;
 183
 184   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 185     unless $mod->VERSION;
 186
 187   local $@;
 188   eval { $mod->VERSION($ver) } ? 1 : 0;
 189 }
 190
 191 sub modver_gt_or_eq_and_lt ($$$) {
 192   my ($mod, $v_ge, $v_lt) = @_;
 193
 194   croak "Nonsensical maximum version supplied"
 195     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 196
 197   return (
 198     modver_gt_or_eq($mod, $v_ge)
 199       and
 200     ! modver_gt_or_eq($mod, $v_lt)
 201   ) ? 1 : 0;
 202 }
 203
 204 {
 205   my $list_ctx_ok_stack_marker;
 206
 207   sub fail_on_internal_wantarray () {
 208     return if $list_ctx_ok_stack_marker;
 209
 210     if (! defined wantarray) {
 211       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 212     }
 213
 214     my $cf = 1;
 215     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 216
 217       # these are public API parts that alter behavior on wantarray
 218       search | search_related | slice | search_literal
 219
 220         |
 221
 222       # these are explicitly prefixed, since we only recognize them as valid
 223       # escapes when they come from the guts of CDBICompat
 224       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 225
 226     ) $/x ) {
 227       $cf++;
 228     }
 229
 230     my ($fr, $want, $argdesc);
 231     {
 232       package DB;
 233       $fr = [ caller($cf) ];
 234       $want = ( caller($cf-1) )[5];
 235       $argdesc = ref $DB::args[0]
 236         ? DBIx::Class::_Util::refdesc($DB::args[0])
 237         : 'non '
 238       ;
 239     };
 240
 241     if (
 242       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 243     ) {
 244       DBIx::Class::Exception->throw( sprintf (
 245         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 246         $argdesc, @{$fr}[1,2]
 247       ), 'with_stacktrace');
 248     }
 249
 250     my $mark = [];
 251     weaken ( $list_ctx_ok_stack_marker = $mark );
 252     $mark;
 253   }
 254 }
 255
 256 sub fail_on_internal_call {
 257   my ($fr, $argdesc);
 258   {
 259     package DB;
 260     $fr = [ caller(1) ];
 261     $argdesc = ref $DB::args[0]
 262       ? DBIx::Class::_Util::refdesc($DB::args[0])
 263       : undef
 264     ;
 265   };
 266
 267   if (
 268     $argdesc
 269       and
 270     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 271       and
 272     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 273   ) {
 274     DBIx::Class::Exception->throw( sprintf (
 275       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 276       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 277         require B::Deparse;
 278         no strict 'refs';
 279         B::Deparse->new->coderef2text(\&{$fr->[3]})
 280       }),
 281     ), 'with_stacktrace');
 282   }
 283 }
 284
 285 1;