lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     ( map
  27       #
  28       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  29       # all envvars without further adjusting its scripts
  30       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  31       #
  32       { substr($_, 5) => !!( $ENV{$_} ) }
  33       qw(
  34         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  35         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  36         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  37         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  38         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  39       )
  40     ),
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55
  56   # Both of these are no longer used for anything. However bring
  57   # them back after they were purged in 08a8d8f1, as there appear
  58   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
  59   # in their production codebases. There is no point in breaking these
  60   # if whatever they used actually continues to work
  61   my $warned;
  62   my $sigh = sub {
  63
  64     require Carp;
  65     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
  66
  67     warn $cluck unless $warned->{$cluck}++;
  68
  69     0;
  70   };
  71   sub DBICTEST () { &$sigh }
  72   sub PEEPEENESS () { &$sigh }
  73 }
  74
  75 # FIXME - this is not supposed to be here
  76 # Carp::Skip to the rescue soon
  77 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  78
  79 use B ();
  80 use Carp 'croak';
  81 use Storable 'nfreeze';
  82 use Scalar::Util qw(weaken blessed reftype refaddr);
  83 use Sub::Quote qw(qsub quote_sub);
  84 use Sub::Name ();
  85
  86 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  87 BEGIN { *deep_clone = \&Storable::dclone }
  88
  89 use base 'Exporter';
  90 our @EXPORT_OK = qw(
  91   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  92   fail_on_internal_wantarray fail_on_internal_call
  93   refdesc refcount hrefaddr set_subname
  94   scope_guard detected_reinvoked_destructor
  95   is_exception dbic_internal_try
  96   quote_sub qsub perlstring serialize deep_clone dump_value
  97   parent_dir mkdir_p
  98   UNRESOLVABLE_CONDITION
  99 );
 100
 101 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 102
 103 sub sigwarn_silencer ($) {
 104   my $pattern = shift;
 105
 106   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 107
 108   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 109
 110   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 111 }
 112
 113 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 114
 115 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 116
 117 sub refdesc ($) {
 118   croak "Expecting a reference" if ! length ref $_[0];
 119
 120   # be careful not to trigger stringification,
 121   # reuse @_ as a scratch-pad
 122   sprintf '%s%s(0x%x)',
 123     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 124     reftype $_[0],
 125     refaddr($_[0]),
 126   ;
 127 }
 128
 129 sub refcount ($) {
 130   croak "Expecting a reference" if ! length ref $_[0];
 131
 132   # No tempvars - must operate on $_[0], otherwise the pad
 133   # will count as an extra ref
 134   B::svref_2object($_[0])->REFCNT;
 135 }
 136
 137 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 138 sub set_subname ($$) {
 139
 140   # fully qualify name
 141   splice @_, 0, 1, caller(0) . "::$_[0]"
 142     if $_[0] !~ /::|'/;
 143
 144   &Sub::Name::subname;
 145 }
 146
 147 sub serialize ($) {
 148   local $Storable::canonical = 1;
 149   nfreeze($_[0]);
 150 }
 151
 152 my $dd_obj;
 153 sub dump_value ($) {
 154   local $Data::Dumper::Indent = 1
 155     unless defined $Data::Dumper::Indent;
 156
 157   my $dump_str = (
 158     $dd_obj
 159       ||=
 160     do {
 161       require Data::Dumper;
 162       my $d = Data::Dumper->new([])
 163         ->Purity(0)
 164         ->Pad('')
 165         ->Useqq(1)
 166         ->Terse(1)
 167         ->Freezer('')
 168         ->Quotekeys(0)
 169         ->Bless('bless')
 170         ->Pair(' => ')
 171         ->Sortkeys(1)
 172         ->Deparse(1)
 173       ;
 174
 175       $d->Sparseseen(1) if modver_gt_or_eq (
 176         'Data::Dumper', '2.136'
 177       );
 178
 179       $d;
 180     }
 181   )->Values([$_[0]])->Dump;
 182
 183   $dd_obj->Reset->Values([]);
 184
 185   $dump_str;
 186 }
 187
 188 sub scope_guard (&) {
 189   croak 'Calling scope_guard() in void context makes no sense'
 190     if ! defined wantarray;
 191
 192   # no direct blessing of coderefs - DESTROY is buggy on those
 193   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 194 }
 195 {
 196   package #
 197     DBIx::Class::_Util::ScopeGuard;
 198
 199   sub DESTROY {
 200     &DBIx::Class::_Util::detected_reinvoked_destructor;
 201
 202     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 203
 204     eval {
 205       $_[0]->[0]->();
 206       1;
 207     }
 208       or
 209     Carp::cluck(
 210       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 211     );
 212   }
 213 }
 214
 215
 216 sub is_exception ($) {
 217   my $e = $_[0];
 218
 219   # FIXME
 220   # this is not strictly correct - an eval setting $@ to undef
 221   # is *not* the same as an eval setting $@ to ''
 222   # but for the sake of simplicity assume the following for
 223   # the time being
 224   return 0 unless defined $e;
 225
 226   my ($not_blank, $suberror);
 227   {
 228     local $SIG{__DIE__} if $SIG{__DIE__};
 229     local $@;
 230     eval {
 231       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 232       # will entirely obviate the need for the encolsing eval{}, as the
 233       # condition we guard against is a missing fallback overload
 234       $not_blank = ( $e ne '' );
 235       1;
 236     } or $suberror = $@;
 237   }
 238
 239   if (defined $suberror) {
 240     if (length (my $class = blessed($e) )) {
 241       carp_unique( sprintf(
 242         'External exception class %s implements partial (broken) overloading '
 243       . 'preventing its instances from being used in simple ($x eq $y) '
 244       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 245       . 'handling this type of brokenness is extremely dangerous on '
 246       . 'exception objects, as it may (and often does) result in silent '
 247       . '"exception substitution". DBIx::Class tries to work around this '
 248       . 'as much as possible, but other parts of your software stack may '
 249       . 'not be even aware of this. Please submit a bugreport against the '
 250       . 'distribution containing %s and in the meantime apply a fix similar '
 251       . 'to the one shown at %s, in order to ensure your exception handling '
 252       . 'is saner application-wide. What follows is the actual error text '
 253       . "as generated by Perl itself:\n\n%s\n ",
 254         $class,
 255         $class,
 256         'http://v.gd/DBIC_overload_tempfix/',
 257         $suberror,
 258       ));
 259
 260       # workaround, keeps spice flowing
 261       $not_blank = !!( length $e );
 262     }
 263     else {
 264       # not blessed yet failed the 'ne'... this makes 0 sense...
 265       # just throw further
 266       die $suberror
 267     }
 268   }
 269   elsif (
 270     # a ref evaluating to '' is definitively a "null object"
 271     ( not $not_blank )
 272       and
 273     length( my $class = ref $e )
 274   ) {
 275     carp_unique( sprintf(
 276       "Objects of external exception class '%s' stringify to '' (the "
 277     . 'empty string), implementing the so called null-object-pattern. '
 278     . 'Given Perl\'s "globally cooperative" exception handling using this '
 279     . 'class of exceptions is extremely dangerous, as it may (and often '
 280     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 281     . 'work around this as much as possible, but other parts of your '
 282     . 'software stack may not be even aware of the problem. Please submit '
 283     . 'a bugreport against the distribution containing %s',
 284
 285       ($class) x 2,
 286     ));
 287
 288     $not_blank = 1;
 289   }
 290
 291   return $not_blank;
 292 }
 293
 294 {
 295   my $callstack_state;
 296
 297   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 298   #
 299   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 300   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 301   sub dbic_internal_try (&;@) {
 302
 303     my $try_cref = shift;
 304     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 305
 306     for my $arg (@_) {
 307
 308       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 309
 310         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 311           if $catch_cref;
 312
 313         $catch_cref = $$arg;
 314       }
 315       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 316         croak 'dbic_internal_try() does not support finally{}';
 317       }
 318       else {
 319         croak(
 320           'dbic_internal_try() encountered an unexpected argument '
 321         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 322         . 'a missing semi-colon before or ' # trailing space important
 323         );
 324       }
 325     }
 326
 327     my $wantarray = wantarray;
 328     my $preexisting_exception = $@;
 329
 330     my @ret;
 331     my $all_good = eval {
 332       $@ = $preexisting_exception;
 333
 334       local $callstack_state->{in_internal_try} = 1
 335         unless $callstack_state->{in_internal_try};
 336
 337       # always unset - someone may have snuck it in
 338       local $SIG{__DIE__} if $SIG{__DIE__};
 339
 340       if( $wantarray ) {
 341         @ret = $try_cref->();
 342       }
 343       elsif( defined $wantarray ) {
 344         $ret[0] = $try_cref->();
 345       }
 346       else {
 347         $try_cref->();
 348       }
 349
 350       1;
 351     };
 352
 353     my $exception = $@;
 354     $@ = $preexisting_exception;
 355
 356     if ( $all_good ) {
 357       return $wantarray ? @ret : $ret[0]
 358     }
 359     elsif ( $catch_cref ) {
 360       for ( $exception ) {
 361         return $catch_cref->($exception);
 362       }
 363     }
 364
 365     return;
 366   }
 367
 368   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 369 }
 370
 371 {
 372   my $destruction_registry = {};
 373
 374   sub CLONE {
 375     %$destruction_registry = map {
 376       (defined $_)
 377         ? ( refaddr($_) => $_ )
 378         : ()
 379     } values %$destruction_registry;
 380
 381     weaken($_) for values %$destruction_registry;
 382
 383     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 384     # collected before leaving this scope. Depending on the code above, this
 385     # may very well be just a preventive measure guarding future modifications
 386     undef;
 387   }
 388
 389   # This is almost invariably invoked from within DESTROY
 390   # throwing exceptions won't work
 391   sub detected_reinvoked_destructor {
 392
 393     # quick "garbage collection" pass - prevents the registry
 394     # from slowly growing with a bunch of undef-valued keys
 395     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 396       for keys %$destruction_registry;
 397
 398     if (! length ref $_[0]) {
 399       printf STDERR '%s() expects a blessed reference %s',
 400         (caller(0))[3],
 401         Carp::longmess,
 402       ;
 403       return undef; # don't know wtf to do
 404     }
 405     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 406       weaken( $destruction_registry->{$addr} = $_[0] );
 407       return 0;
 408     }
 409     else {
 410       carp_unique ( sprintf (
 411         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 412       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 413       . 'application, affecting *ALL* classes without active protection against '
 414       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 415       refdesc $_[0],
 416         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 417           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 418           : ''
 419         )
 420       ));
 421
 422       return 1;
 423     }
 424   }
 425 }
 426
 427 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 428 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 429
 430 sub modver_gt_or_eq ($$) {
 431   my ($mod, $ver) = @_;
 432
 433   croak "Nonsensical module name supplied"
 434     if ! defined $mod or $mod !~ $module_name_rx;
 435
 436   croak "Nonsensical minimum version supplied"
 437     if ! defined $ver or $ver !~ $ver_rx;
 438
 439   no strict 'refs';
 440   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 441     ? {}
 442     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 443   );
 444
 445   ! defined $ver_cache->{$ver}
 446     and
 447   $ver_cache->{$ver} = do {
 448
 449     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 450       if SPURIOUS_VERSION_CHECK_WARNINGS;
 451
 452     local $SIG{__DIE__} if $SIG{__DIE__};
 453     local $@;
 454     eval { $mod->VERSION($ver) } ? 1 : 0;
 455   };
 456
 457   $ver_cache->{$ver};
 458 }
 459
 460 sub modver_gt_or_eq_and_lt ($$$) {
 461   my ($mod, $v_ge, $v_lt) = @_;
 462
 463   croak "Nonsensical maximum version supplied"
 464     if ! defined $v_lt or $v_lt !~ $ver_rx;
 465
 466   return (
 467     modver_gt_or_eq($mod, $v_ge)
 468       and
 469     ! modver_gt_or_eq($mod, $v_lt)
 470   ) ? 1 : 0;
 471 }
 472
 473
 474 #
 475 # Why not just use some higher-level module or at least File::Spec here?
 476 # Because:
 477 # 1)  This is a *very* rarely used function, and the deptree is large
 478 #     enough already as it is
 479 #
 480 # 2)  (more importantly) Our tooling is utter shit in this area. There
 481 #     is no comprehensive support for UNC paths in PathTools and there
 482 #     are also various small bugs in representation across different
 483 #     path-manipulation CPAN offerings.
 484 #
 485 # Since this routine is strictly used for logical path processing (it
 486 # *must* be able to work with not-yet-existing paths), use this seemingly
 487 # simple but I *think* complete implementation to feed to other consumers
 488 #
 489 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 490 # the impulse to bring in an external dependency. During runtime there
 491 # is exactly one spot that could potentially maybe once in a blue moon
 492 # use this function. Keep it lean.
 493 #
 494 sub parent_dir ($) {
 495   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 496     ? (
 497       $_[0]
 498         .
 499       ( ( length($1) and ! length($2) ) ? '/' : '' )
 500         .
 501       '../'
 502     )
 503     : (
 504       require File::Spec
 505         and
 506       File::Spec->catpath (
 507         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 508         '/',
 509       )
 510     )
 511   ;
 512 }
 513
 514 sub mkdir_p ($) {
 515   require File::Path;
 516   # do not ask for a recent version, use 1.x API calls
 517   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 518 }
 519
 520
 521 {
 522   my $list_ctx_ok_stack_marker;
 523
 524   sub fail_on_internal_wantarray () {
 525     return if $list_ctx_ok_stack_marker;
 526
 527     if (! defined wantarray) {
 528       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 529     }
 530
 531     my $cf = 1;
 532     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 533
 534       # these are public API parts that alter behavior on wantarray
 535       search | search_related | slice | search_literal
 536
 537         |
 538
 539       # these are explicitly prefixed, since we only recognize them as valid
 540       # escapes when they come from the guts of CDBICompat
 541       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 542
 543     ) $/x ) {
 544       $cf++;
 545     }
 546
 547     my ($fr, $want, $argdesc);
 548     {
 549       package DB;
 550       $fr = [ CORE::caller($cf) ];
 551       $want = ( CORE::caller($cf-1) )[5];
 552       $argdesc = ref $DB::args[0]
 553         ? DBIx::Class::_Util::refdesc($DB::args[0])
 554         : 'non '
 555       ;
 556     };
 557
 558     if (
 559       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 560     ) {
 561       DBIx::Class::Exception->throw( sprintf (
 562         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 563         $argdesc, @{$fr}[1,2]
 564       ), 'with_stacktrace');
 565     }
 566
 567     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 568
 569     $mark;
 570   }
 571 }
 572
 573 sub fail_on_internal_call {
 574   my ($fr, $argdesc);
 575   {
 576     package DB;
 577     $fr = [ CORE::caller(1) ];
 578     $argdesc = ref $DB::args[0]
 579       ? DBIx::Class::_Util::refdesc($DB::args[0])
 580       : undef
 581     ;
 582   };
 583
 584   if (
 585     $argdesc
 586       and
 587     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 588       and
 589     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 590   ) {
 591     DBIx::Class::Exception->throw( sprintf (
 592       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 593       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 594         require B::Deparse;
 595         no strict 'refs';
 596         B::Deparse->new->coderef2text(\&{$fr->[3]})
 597       }),
 598     ), 'with_stacktrace');
 599   }
 600 }
 601
 602 1;